/
kselftests.inc
49 lines (39 loc) · 2.12 KB
/
kselftests.inc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
PACKAGE_ARCH = "${MACHINE_ARCH}"
# kernel selftests dependencies
DEPENDS += "elfutils fuse libcap libcap-ng pkgconfig-native popt rsync-native util-linux clang-native \
${@bb.utils.contains("TARGET_ARCH", "arm", "", "numactl", d)} \
"
inherit kernel-arch
export KST_INSTALL_PATH = "/opt/kselftests/default-in-kernel"
KSELFTESTS_ARGS = "-i -C ${S}/tools/testing/selftests INSTALL_PATH=${D}${KST_INSTALL_PATH} CC="${CC}" LD="${LD}" ARCH=${ARCH}"
do_compile:append() {
# Make sure to install the user space API used by some tests
# but not properly declared as a build dependency
${MAKE} -C ${S} ARCH=${ARCH} headers_install
# Specifying sysroot may help Clang find appropriate headers
export CLANG="clang --sysroot ${STAGING_DIR_TARGET}"
${MAKE} ${KSELFTESTS_ARGS}
}
do_install:append() {
${MAKE} ${KSELFTESTS_ARGS} install
chown -R root:root ${D}
# fixup run_kselftest.sh due to spurious lines starting by "make[1]:"
sed -i '/^make/d' ${D}${KST_INSTALL_PATH}/run_kselftest.sh
}
PACKAGES =+ "kernel-selftests"
FILES:kernel-selftests = "${KST_INSTALL_PATH}"
# The bpf tests depend on that the object files are installed as well.
# OE wont throw an error if files do not exist.
FILES:kernel-selftests += "${KST_INSTALL_PATH}/bpf/*.o"
PACKAGES =+ "kernel-selftests-dbg"
FILES:kernel-selftests-dbg = "${KST_INSTALL_PATH}/*/.debug /usr/src/debug/*"
RDEPENDS:kernel-selftests = "bash bc ethtool fuse-utils iproute2 iproute2-tc iputils-ping glibc-utils ncurses sudo"
RDEPENDS:kernel-selftests =+ "python3-core python3-datetime python3-json python3-pprint"
RDEPENDS:kernel-selftests =+ "util-linux-uuidgen"
RDEPENDS:kernel-selftests:append:x86 = " cpupower"
RDEPENDS:kernel-selftests:append:x86-64 = " cpupower"
INSANE_SKIP:kernel-selftests = "already-stripped"
# Ignore the QA error because kselftests/bpf/ requires object files
# ERROR message:
# ERROR: kselftests-mainline-4.14-r0 do_package_qa: QA Issue: Architecture did not match (Unknown (0), expected AArch64) on /work/hikey-linaro-linux/kselftests-mainline/4.14-r0/packages-split/kselftests-mainline/opt/kselftests/mainline/bpf/test_tcp_estats.o
ERROR_QA:remove = "arch"