gottcode / cutemaze
watch download tarball
public
Forks0Right
Watchers1Right
Description: Top-down maze game
Homepage: http://gottcode.org/cutemaze/
Clone URL: git://github.com/gottcode/cutemaze.git
cutemaze / cutemaze.pro
100644 77 lines (66 sloc) 1.303 kb
raw blame history 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

TEMPLATE = app
QT += svg
CONFIG += warn_on release
macx {
	# Uncomment the following line to compile on PowerPC Macs
	# QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.4u.sdk
	CONFIG += x86 ppc
}
 
qws {
	qtopia_project(qtopia app)
}
 
MOC_DIR = build
OBJECTS_DIR = build
RCC_DIR = build
 
unix: !macx {
	TARGET = cutemaze
} else {
	TARGET = CuteMaze
}
 
HEADERS = src/board.h \
	src/cell.h \
	src/maze.h \
	src/new_game_dialog.h \
	src/path.h \
	src/scores.h \
	src/settings.h \
	src/solver.h \
	src/theme.h \
	src/window.h
 
SOURCES = src/board.cpp \
	src/cell.cpp \
	src/main.cpp \
	src/maze.cpp \
	src/new_game_dialog.cpp \
	src/path.cpp \
	src/scores.cpp \
	src/settings.cpp \
	src/solver.cpp \
	src/theme.cpp \
	src/window.cpp
 
RESOURCES = icons/icons.qrc themes/theme.qrc preview/preview.qrc
macx {
	ICON = icons/cutemaze.icns
}
win32 {
	RC_FILE = icons/icon.rc
}
 
unix: !macx {
	isEmpty(PREFIX) {
		PREFIX = /usr/local
	}
 
	icon.files = icons/cutemaze.png
	desktop.files = icons/cutemaze.desktop
 
	qws {
		target.path = /bin/
		icon.path = /pics/cutemaze
		icon.hint = pics
		desktop.path =	/apps/Games
		desktop.hint = desktop
	} else {
		target.path = $$PREFIX/bin/
		icon.path = $$PREFIX/share/icons/hicolor/48x48/apps
		desktop.path = $$PREFIX/share/applications/
	}
 
	INSTALLS += target icon desktop
}