gottcode / gottet
watch download tarball
public
Forks0Right
Watchers1Right
Description: Tetris clone
Homepage: http://gottcode.org/gottet/
Clone URL: git://github.com/gottcode/gottet.git
gottet / gottet.pro
100644 64 lines (53 sloc) 1.059 kb
raw blame history 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

TEMPLATE = app
CONFIG += warn_on release
macx {
	# Uncomment the following line to compile on PowerPC Macs
	# QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.4u.sdk
	CONFIG += x86 ppc
}
 
qws {
	qtopia_project(qtopia app)
}
 
MOC_DIR = build
OBJECTS_DIR = build
RCC_DIR = build
 
unix: !macx {
	TARGET = gottet
} else {
	TARGET = Gottet
}
 
HEADERS = src/board.h \
	src/piece.h \
	src/score_board.h \
	src/window.h
 
SOURCES = src/board.cpp \
	src/main.cpp \
	src/piece.cpp \
	src/score_board.cpp \
	src/window.cpp
 
macx {
	ICON = icons/gottet.icns
} else:unix {
	RESOURCES = icons/icon.qrc
} else:win32 {
	RC_FILE = icons/icon.rc
}
 
unix: !macx {
	isEmpty(PREFIX) {
		PREFIX = /usr/local
	}
 
	icon.files = icons/gottet.png
	desktop.files = icons/gottet.desktop
 
	qws {
		target.path = /bin/
		icon.path = /pics/gottet
		icon.hint = pics
		desktop.path = /apps/Games
		desktop.hint = desktop
	} else {
		target.path = $$PREFIX/bin/
		icon.path = $$PREFIX/share/icons/hicolor/48x48/apps
		desktop.path = $$PREFIX/share/applications/
	}
 
	INSTALLS += target icon desktop
}