gottcode / tetzle
watch download tarball
public
Forks1Right
Watchers2Right
Fork of rawler/tetzle
Description: A jigsaw puzzle game that uses tetrominoes for the pieces.
Homepage: http://gottcode.org/tetzle/
Clone URL: git://github.com/gottcode/tetzle.git
tetzle / tetzle.pro
100644 76 lines (65 sloc) 1.415 kb
raw blame history 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

TEMPLATE = app
QT += opengl xml
CONFIG += warn_on release
macx {
	# Uncomment the following line to compile on PowerPC Macs
	# QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.4u.sdk
	CONFIG += x86 ppc
}
 
MOC_DIR = build
OBJECTS_DIR = build
RCC_DIR = build
 
unix: !macx {
	TARGET = tetzle
} else {
	TARGET = Tetzle
}
 
HEADERS = src/board.h \
	src/dancing_links.h \
	src/image_dialog.h \
	src/label_image_dialog.h \
	src/label_manager.h \
	src/new_game_dialog.h \
	src/open_game_dialog.h \
	src/overview.h \
	src/piece.h \
	src/solver.h \
	src/tile.h \
	src/thumbnail_list.h \
	src/thumbnail_loader.h \
	src/thumbnail_model.h \
	src/window.h
 
SOURCES = src/board.cpp \
	src/dancing_links.cpp \
	src/image_dialog.cpp \
	src/label_image_dialog.cpp \
	src/label_manager.cpp \
	src/main.cpp \
	src/new_game_dialog.cpp \
	src/open_game_dialog.cpp \
	src/overview.cpp \
	src/piece.cpp \
	src/solver.cpp \
	src/tile.cpp \
	src/thumbnail_list.cpp \
	src/thumbnail_loader.cpp \
	src/thumbnail_model.cpp \
	src/window.cpp
 
macx {
	ICON = icons/tetzle.icns
} else:unix {
	RESOURCES = icons/icon.qrc
} else:win32 {
	RC_FILE = icons/icon.rc
}
 
unix: !macx {
	isEmpty(PREFIX) {
		PREFIX = /usr/local
	}
 
	target.path = $$PREFIX/bin/
 
	icon.path = $$PREFIX/share/icons/hicolor/48x48/apps
	icon.files = icons/tetzle.png
 
	desktop.path = $$PREFIX/share/applications/
	desktop.files = icons/tetzle.desktop
 
	INSTALLS += target icon desktop
}