build.gradle

/*
 * Copyright (c) 2011-Present VMware, Inc. or its affiliates, All Rights Reserved.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *       https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
buildscript {
	repositories {
		maven { url "https://repo.spring.io/plugins-release" }
	}
	dependencies {
		classpath 'org.springframework.build.gradle:propdeps-plugin:0.0.7'
	}
}

plugins {
	id 'com.github.hierynomus.license' version '0.15.0'
	id 'org.asciidoctor.convert' version '2.4.0'
	id 'com.google.osdetector' version '1.6.2'
	id 'org.gradle.test-retry' version '1.1.9'
	id 'com.github.johnrengelman.shadow' version '6.1.0' apply false
	id 'com.jfrog.artifactory' version '4.16.1' apply false
	id 'me.champeau.gradle.japicmp' version '0.2.9' apply false
	id 'de.undercouch.download' version '4.1.1' apply false
	id 'io.spring.javadoc' version '0.0.1' apply false
	id 'io.spring.javadoc-aggregate' version '0.0.1' apply false
}

description = 'Reactive Streams Netty driver'

apply from: "gradle/releaser.gradle"

ext {
	if (project.hasProperty('versionBranch') && version.toString().endsWith("-SNAPSHOT")) {
		versionBranch = versionBranch.replaceAll("\"", "").trim()
		if (!versionBranch.isEmpty()) {
			realVersion = version.toString() + "-" + versionBranch
			project.version = realVersion
			println "Building special snapshot ${project.version}"
		}
	}

	os_suffix = ""
	if (osdetector.classifier in ["linux-x86_64"] || ["osx-x86_64"] || ["windows-x86_64"]) {
		os_suffix = ":" + osdetector.classifier
	}

	//Metrics
	micrometerVersion = '1.5.0' //optional baseline: technically could work with 1.2.x, should work with any 1.3.x

	braveVersion = '5.13.1'

	jsr305Version = '3.0.2'

	// Logging
	slf4jVersion = '1.7.30'
	logbackVersion = '1.2.3'

	// Netty
	nettyDefaultVersion = '4.1.54.Final'
	if (!project.hasProperty("forceNettyVersion")) {
		nettyVersion = nettyDefaultVersion
	}
	else {
		nettyVersion = forceNettyVersion
		println "Netty version defined from command line: ${forceNettyVersion}"
	}

	// Testing
	jacksonDatabindVersion = '2.11.3'
	testAddonVersion = reactorCoreVersion
	assertJVersion = '3.18.1'
	hoverflyJavaVersion = '0.13.1'
	tomcatVersion = '9.0.39'
	boringSslVersion = '2.0.34.Final'
	junitVersion = '5.7.0'
	mockitoVersion = '3.6.0'

	javadocLinks = ["https://docs.oracle.com/javase/7/docs/api/",
					"https://docs.oracle.com/javaee/6/api/",
					"https://fasterxml.github.io/jackson-databind/javadoc/2.5/",
					"https://www.reactive-streams.org/reactive-streams-1.0.3-javadoc/",
					"https://projectreactor.io/docs/core/release/api/",
					"https://netty.io/4.1/api/",
					"https://projectreactor.io/docs/netty/release/api/",] as String[]
}

subprojects {
	group = 'io.projectreactor.netty'

	apply plugin: 'java'
	apply plugin: 'jacoco'
	apply plugin: 'propdeps'
	apply plugin: 'license'
	apply plugin: 'org.gradle.test-retry'
	apply from: "${rootDir}/gradle/setup.gradle"
	apply from: "${rootDir}/gradle/javadoc.gradle"
	apply from: "${rootDir}/gradle/errorprone.gradle"

	jacoco {
		toolVersion = '0.8.5'
	}

	jacocoTestReport {
		reports {
			xml.enabled = true
			html.enabled = true
		}
	}

	[compileJava, compileTestJava]*.options*.compilerArgs = ["-Xlint:varargs",
															 "-Xlint:cast",
															 "-Xlint:classfile",
															 "-Xlint:dep-ann",
															 "-Xlint:divzero",
															 "-Xlint:empty",
															 "-Xlint:finally",
															 "-Xlint:overrides",
															 "-Xlint:path",
															 "-Xlint:processing",
															 "-Xlint:static",
															 "-Xlint:try",
															 "-Xlint:deprecation",
															 "-Xlint:unchecked",
															 "-Xlint:-serial",      // intentionally disabled
															 "-Xlint:-options",     // intentionally disabled
															 "-Xlint:fallthrough",
															 "-Xlint:rawtypes"
	]

	compileJava {
		sourceCompatibility = 1.8
		targetCompatibility = 1.8
	}

	compileTestJava {
		sourceCompatibility = 1.8
		targetCompatibility = 1.8
	}

	if (JavaVersion.current().isJava8Compatible()) {
		compileTestJava.options.compilerArgs += "-parameters"
		tasks.withType(Javadoc) {
			options.addStringOption('Xdoclint:none', '-quiet')
			options.addStringOption('encoding', 'UTF-8')
		}
	}

	[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'
	sourceSets.test.resources.srcDirs = ["src/test/resources", "src/test/java"]

	configurations.all {
		exclude group: 'commons-logging', module: 'commons-logging'
	}

	project.tasks.withType(Test).all {
		// run tests with IPv4 only when IPv6 is available
		if (project.hasProperty('preferIPv4Stack')) {
			systemProperty("java.net.preferIPv4Stack", "true")
		}
		// run tests with preferring IPv6 addresses
		if (project.hasProperty('preferIPv6Addresses')) {
			systemProperty("java.net.preferIPv6Addresses", "true")
		}
		systemProperty("java.awt.headless", "true")
		systemProperty("reactor.trace.cancel", "true")
		systemProperty("reactor.trace.nocapacity", "true")
		systemProperty("testGroups", project.properties.get("testGroups"))
		systemProperty("io.netty.leakDetection.level", "paranoid")
		scanForTestClasses = false
		include '**/*Tests.*'
		include '**/*Test.*'
		include '**/*Spec.*'
		exclude '**/*Abstract*.*'

		useJUnitPlatform()
	}

	test {
		testLogging {
			showExceptions true
			exceptionFormat "full"
			maxGranularity 3
		}

		onOutput { descriptor, event ->
			if (event.message.contains("ResourceLeakDetector")) {
				logger.error("ERROR: Test: " + descriptor + " produced resource leak: " + event.message)
			}
		}

		retry {
			maxFailures = 10
			maxRetries = 1
		}
	}

	repositories {
		mavenCentral()
		if (version.endsWith('-SNAPSHOT') || version.contains('-SNAPSHOT-')) { //classic or customized snapshots
			if (System.getenv()["bamboo_buildNumber"] == null) {
				mavenLocal()
			}
			else {
				println 'Bamboo CI detected, avoiding use of mavenLocal()'
			}
			maven { url 'https://repo.spring.io/libs-snapshot' }
			maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
		}
		maven { url 'https://repo.spring.io/libs-milestone' }
		maven { url 'https://repo.spring.io/libs-release' }
		maven { url "https://oss.sonatype.org/content/repositories/releases/" }
		jcenter()
	}

	tasks.withType(GenerateModuleMetadata) {
		enabled = false
	}

	jar {
		manifest {
			attributes("Created-By": "${System.getProperty("java.version")} (${System.getProperty("java.specification.vendor")})",
					"Implementation-Title": project.name,
					"Implementation-Version": project.version)
		}
	}

	check.dependsOn jacocoTestReport

	license {
		header rootProject.file("${rootDir}/codequality/HEADER")
		includes(["**/*.java", "**/*.css"])
		strictCheck true
		mapping {
			java = 'SLASHSTAR_STYLE'
			css = 'SLASHSTAR_STYLE'
		}
	}
}

configurations.all {
	// check for updates every build
	resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
}