Tool code initial commit

Author: mikhailmoiseev

.gitignore

@@ -0,0 +1,83 @@
+### C template
+# Prerequisites
+*.d
+
+# Object files
+*.o
+*.ko
+*.obj
+*.elf
+
+# Linker output
+*.ilk
+*.map
+*.exp
+
+# Precompiled Headers
+*.gch
+*.pch
+
+# Libraries
+*.lib
+*.a
+*.la
+*.lo
+
+# Shared objects (inc. Windows DLLs)
+*.dll
+*.so
+*.so.*
+*.dylib
+
+# Executables
+*.exe
+*.out
+*.app
+*.i*86
+*.x86_64
+*.hex
+
+# Debug files
+*.dSYM/
+*.su
+*.idb
+*.pdb
+*.log
+test/smem/vcs
+test/smem/vcs_sc
+
+# Kernel Module Compile Results
+*.mod*
+*.cmd
+.tmp_versions/
+modules.order
+Module.symvers
+Mkfile.old
+dkms.conf
+### C++ template
+# Prerequisites
+
+# Compiled Object files
+*.slo
+
+# Precompiled Headers
+
+# Compiled Dynamic libraries
+
+# Fortran module files
+*.mod
+*.smod
+
+# Compiled Static libraries
+*.lai
+
+# Executables
+
+# SystemC elaboration
+*.scelab
+
+# Clion
+.idea/
+
+# Misc
+sc_tool/arc

CMakeLists.txt

@@ -0,0 +1,111 @@
+#******************************************************************************
+# Copyright (c) 2020, Intel Corporation. All rights reserved.
+# 
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception.
+# 
+# *****************************************************************************
+
+cmake_minimum_required(VERSION 3.5)
+project(sctool)
+
+set(CMAKE_CXX_STANDARD 17)
+
+find_package(LLVM 7.0.0 REQUIRED CONFIG)
+
+message(STATUS "Found LLVM ${LLVM_PACKAGE_VERSION}")
+message(STATUS "Using LLVMConfig.cmake in: ${LLVM_DIR}")
+message(STATUS "LIBDIR ${LLVM_LIBRARY_DIRS}")
+message(STATUS "LLVM_TOOLS_BINARY_DIR ${LLVM_TOOLS_BINARY_DIR}")
+message(STATUS "LLVM_INCLUDE_DIRS ${LLVM_INCLUDE_DIRS}")
+message(STATUS "CMAKE_BUILD_TYPE ${CMAKE_BUILD_TYPE}")
+
+include_directories(${LLVM_INCLUDE_DIRS})
+link_directories(${LLVM_LIBRARY_DIRS})
+add_definitions(${LLVM_DEFINITIONS})
+
+
+# Support for using custom linker
+if( LLVM_USE_LINKER )
+    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fuse-ld=${LLVM_USE_LINKER}")
+    set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -fuse-ld=${LLVM_USE_LINKER}")
+    set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -fuse-ld=${LLVM_USE_LINKER}")
+    message("USING CUSTOM LINKER: ${CMAKE_EXE_LINKER_FLAGS}")
+endif()
+
+set(BUILD_SHARED_LIBS ON)
+
+# Patched SystemC kernel with additional elaboration instrumentation
+add_subdirectory(systemc)
+
+# SystemC Precompiled header to speed-up parsing in debug build
+SET(CLANG_CXX_EXECUTABLE ${LLVM_TOOLS_BINARY_DIR}/clang++)
+SET(CLANG_INT_INC_DIR ${LLVM_LIBRARY_DIR}/clang/${LLVM_PACKAGE_VERSION}/include)
+
+message(STATUS "CLANG_CXX_EXECUTABLE ${CLANG_CXX_EXECUTABLE}")
+message(STATUS "CLANG_INT_INC_DIR ${CLANG_INT_INC_DIR}")
+
+SET(SYSTEMC_PCH ${CMAKE_BINARY_DIR}/systemc/systemc.h.pch)
+
+# Create SystemC pre-compiled headers
+add_custom_command(OUTPUT ${SYSTEMC_PCH}
+        COMMAND
+        ${CLANG_CXX_EXECUTABLE} -Xclang -emit-pch -x c++-header
+        ${CMAKE_SOURCE_DIR}/systemc/src/systemc.h -o ${SYSTEMC_PCH} ${MSVC_FLAGS}
+        -D__SC_TOOL__ -D__SC_TOOL_ANALYZE__ -DNDEBUG -std=c++14 
+        -I${CMAKE_SOURCE_DIR}/systemc/src
+        DEPENDS systemc
+        COMMENT "Generating SystemC precompiled header ${SYSTEMC_PCH}"
+        )
+add_custom_target(systemcPCH DEPENDS ${SYSTEMC_PCH})
+
+set(CMAKE_POSITION_INDEPENDENT_CODE ON)
+
+# Dynamic Elaboration (Requires GDB 8.0.1 configured with Python3)
+add_subdirectory(sc_elab)
+
+# ScTool main library
+add_subdirectory(sc_tool)
+
+# Integration tests :  SystemC Design -> Elaboration -> StaticAnalysis
+set(SYSTEMC_INCLUDE_DIR ${CMAKE_CURRENT_LIST_DIR}/systemc/src)
+include(cmake/svc_target.cmake)
+
+enable_testing()
+
+# Compile tests and test designs
+if( ${CMAKE_BUILD_TYPE} STREQUAL "Debug" ) 
+    message (STATUS "Debug mode: add tests and test designs")
+    add_subdirectory(tests)
+    add_subdirectory(designs)
+endif()
+
+###############################################################################
+
+# Install targets
+install (EXPORT SVCTargets NAMESPACE SVC::
+         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/SVC)
+
+# Create the SVCConfig.cmake, installed @ICSC_HOME/lib/cmake/SVC
+include(CMakePackageConfigHelpers)
+configure_package_config_file(cmake/SVCConfig.cmake.in
+  ${CMAKE_CURRENT_BINARY_DIR}/SVCConfig.cmake
+  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/SVC)
+
+install(FILES ${PROJECT_BINARY_DIR}/SVCConfig.cmake cmake/svc_target.cmake
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/SVC)
+
+# Install sctMemory
+install(DIRECTORY components/memory/sctmemory DESTINATION include)
+
+# Install sctCommon
+install(DIRECTORY components/common/sctcommon DESTINATION include)
+
+# Install release mode CMakeLists and scripts
+if( ${CMAKE_BUILD_TYPE} STREQUAL "Release" ) 
+    message (STATUS "Release mode: copy CMakeLists and scripts")
+    install(FILES cmake/CMakeLists.txt
+                  cmake/setenv.sh
+                  cmake/README
+            DESTINATION $ENV{ICSC_HOME}) 
+
+endif()

cmake/CMakeLists.txt

@@ -0,0 +1,25 @@
+#******************************************************************************
+# Copyright (c) 2020, Intel Corporation. All rights reserved.
+# 
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception.
+# 
+# *****************************************************************************
+#
+# Intel(r) Compiler for SystemC*, version 1.3.7 
+#
+# *****************************************************************************
+ 
+cmake_minimum_required(VERSION 3.12)
+
+## C++ standard 
+set(CMAKE_CXX_STANDARD 17)
+
+enable_testing()
+
+## SVC package contains ICSC and SystemC libraries
+find_package(SVC REQUIRED)
+
+## Add examples, tests and user designs
+add_subdirectory(icsc/examples)
+add_subdirectory(icsc/tests)
+add_subdirectory(icsc/designs)

cmake/README

@@ -0,0 +1,37 @@
+#******************************************************************************
+# Copyright (c) 2020, Intel Corporation. All rights reserved.
+# 
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception.
+# 
+# *****************************************************************************
+#
+# Intel(r) Compiler for SystemC*, version 1.3.7 
+#
+# *****************************************************************************
+
+-------------------------------------------------------------------------------
+1. Build and run examples, tests and designs
+-------------------------------------------------------------------------------
+
+* Run bash shell
+$ bash
+
+* Setup ICSC environment
+$ source setenv.sh
+
+* Build sources
+$ mkdir build && cd build
+$ cmake ../
+$ make -j8
+
+* Run SystemVerilog generation
+$ ctest -j8
+
+* Check the generated SystemVerilog in sv_out folder
+$cd examples/counter/sv_out
+$cat counter.sv
+
+* Run SystemC simulation for an example
+$ cd examples/counter
+$ ./counter
+

cmake/SVCConfig.cmake.in

@@ -0,0 +1,37 @@
+#******************************************************************************
+# Copyright (c) 2020, Intel Corporation. All rights reserved.
+# 
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception.
+# 
+# *****************************************************************************
+
+# - Config file for the SVC package
+# It defines the following variables:
+#  SystemC_TARGET_ARCH - Target architecture according to the Accellera SystemC conventions
+#  SystemC_CXX_STANDARD - Preferred C++ standard
+#  SystemC_CXX_STANDARD_REQUIRED - Determine whether the selected C++ standard is a requirement
+#  CLANG_INT_INC_DIR - Location of Clang internal headers, required to run tool
+@PACKAGE_INIT@
+
+# Checking PThread are installed, required for SystemC 
+include(CMakeFindDependencyMacro)
+
+# if (@CMAKE_USE_PTHREADS_INIT@)
+  set (THREADS_PREFER_PTHREAD_FLAG ON)
+  find_dependency (Threads)
+  if (NOT CMAKE_USE_PTHREADS_INIT)
+    message (SEND_ERROR "Failed to find the Pthreads library required to implement the SystemC coroutines and async_request_update() of primitive channels on Unix.")
+  endif (NOT CMAKE_USE_PTHREADS_INIT)
+# endif (@CMAKE_USE_PTHREADS_INIT@)
+
+# Contains includes and options for each used library (SystemC, ScTool, SysCRTTI)
+include ("${CMAKE_CURRENT_LIST_DIR}/SVCTargets.cmake")
+include ("${CMAKE_CURRENT_LIST_DIR}/svc_target.cmake")
+
+# Are configured at cmake run 
+set (SystemC_TARGET_ARCH @SystemC_TARGET_ARCH@)
+set (SystemC_CXX_STANDARD @CMAKE_CXX_STANDARD@)
+set (SystemC_CXX_STANDARD_REQUIRED @CMAKE_CXX_STANDARD_REQUIRED@)
+
+# CLang internal headers, required as sc_tool located out of CLang folder
+set (CLANG_INT_INC_DIR "$ENV{ICSC_HOME}/lib/clang/7.0.0/include")

cmake/setenv.sh

@@ -0,0 +1,25 @@
+#******************************************************************************
+# Copyright (c) 2020, Intel Corporation. All rights reserved.
+# 
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception.
+# 
+# *****************************************************************************
+#
+# Intel(r) Compiler for SystemC*, version 1.3.7 
+#
+# *****************************************************************************
+
+# Setup environment to run examples, tests and user designs
+
+#!/bin/bash
+export SHELL=/bin/sh
+
+export ICSC_HOME="$( cd "$( dirname "${BASH_SOURCE[0]}" )" >/dev/null 2>&1 && pwd )"
+
+export CMAKE_PREFIX_PATH=$ICSC_HOME
+export PATH=$ICSC_HOME/bin:$ICSC_HOME/include:$PATH
+export LD_LIBRARY_PATH=$LD_LIBRARY_PATH:$ICSC_HOME/lib64:$ICSC_HOME/lib
+export SYSTEMC_HOME=$ICSC_HOME
+
+
+