-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathEnclojure.elm
1258 lines (1065 loc) · 47 KB
/
Enclojure.elm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
module Enclojure exposing
( Env, init
, Exception, evalPure
, EvalResult(..), Step, eval, continueEval
, getStepEnv, setStepEnv, getStepValue
, Doc(..), FnInfo, documentation
)
{-| Enclojure is a Clojure-like scripting language for Elm apps. Enclojure is experimental software and subject to breaking API changes.
# Initialize
@docs Env, init
# Pure programs
@docs Exception, evalPure
# Side-effecting programs
@docs EvalResult, Step, eval, continueEval
# Manipulating execution environment
@docs getStepEnv, setStepEnv, getStepValue
# Extracting documentation
@docs Doc, FnInfo, documentation
-}
import Array exposing (Array)
import Dict exposing (Dict)
import Enclojure.Callable as Callable exposing (Callable)
import Enclojure.Common
exposing
( Continuation
, Env
, Exception(..)
, FnInfo
, IO(..)
, Number(..)
, Ref(..)
, Thunk(..)
, Value(..)
, toThunk
)
import Enclojure.Extra.Maybe exposing (orElse)
import Enclojure.Lib as Lib
import Enclojure.Lib.String as LibString
import Enclojure.Located as Located exposing (Located(..))
import Enclojure.Reader as Reader
import Enclojure.Reader.Macros as Macros
import Enclojure.Runtime as Runtime
import Enclojure.Value as Value
import Enclojure.ValueMap as ValueMap exposing (ValueMap, ValueMapEntry)
import Enclojure.ValueSet as ValueSet exposing (ValueSet)
import Parser
{-| An Enclojure exception value.
-}
type alias Exception =
Enclojure.Common.Exception
{-| An execution environment. Think of this as the current state of the interpreter.
-}
type alias Env io =
Enclojure.Common.Env io
resolveSymbol : Env io -> String -> Result Exception (Value io)
resolveSymbol env symbol =
Runtime.fetchLexical symbol env
|> orElse (\_ -> Runtime.fetchGlobal symbol env)
|> Result.fromMaybe (Value.exception ("Unknown symbol " ++ symbol) |> Runtime.throw env)
{-| Introduce a redundant closure to prevent closure shadowing via tail-call optimization
in functions with continuations. See: <https://github.com/elm/compiler/issues/2017>
Elm compiler doesn’t seem to be able to optimize this away.
-}
closureHack3 : a -> b -> c -> (a -> b -> c -> d) -> d
closureHack3 a b c f =
f a b c
evalExpression : Located (Value io) -> Env io -> Continuation io -> Located (Enclojure.Common.Step io)
evalExpression mutableExpr mutableEnv mutableK =
closureHack3
mutableExpr
mutableEnv
mutableK
(\(Located loc expr) inputEnv k ->
let
env =
Runtime.setCurrentStackFrameLocation loc inputEnv
in
case expr of
Vector v ->
evalVector (Located loc v) env k
Map m ->
evalMap (Located loc m) env k
Set s ->
evalSet (Located loc s) env k
Symbol s ->
case resolveSymbol env s of
Ok v ->
Located loc ( Ok ( Const v, env ), Just (Thunk k) )
Err e ->
Located loc ( Err ( e, env ), Just (Thunk k) )
String s ->
Located loc ( Ok ( Const (String s), env ), Just (Thunk k) )
Keyword s ->
Located loc ( Ok ( Const (Keyword s), env ), Just (Thunk k) )
Number (Float _) ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
Number (Int _) ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
MapEntry _ ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
Nil ->
Located loc ( Ok ( Const Nil, env ), Just (Thunk k) )
Bool _ ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
Ref _ ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
Regex _ _ ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
Fn _ _ ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
List l ->
case l of
-- special forms
((Located _ (Symbol name)) as fnExpr) :: argExprs ->
specialFormsByName
|> Dict.get name
|> Maybe.map (\form -> form.eval (Located loc argExprs) env k)
|> Maybe.withDefault (evalApply fnExpr (Located loc argExprs) env k)
-- apply
fnExpr :: argExprs ->
evalApply fnExpr (Located loc argExprs) env k
-- empty list ()
[] ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
Throwable _ ->
Located loc ( Ok ( Const expr, env ), Just (Thunk k) )
)
evalVector : Located (Array (Located (Value io))) -> Env io -> Continuation io -> Located (Enclojure.Common.Step io)
evalVector (Located loc vecV) env k =
Located loc
( Ok ( Const (Vector Array.empty), env )
, vecV
|> Array.foldr
(\e a ->
\(Located _ v) envNow ->
case v of
Vector array ->
evalExpression e
envNow
(\ret retEnv ->
Located loc
( Ok ( Const (Vector (Array.push ret array)), retEnv )
, Just (Thunk a)
)
)
_ ->
Located loc
( Err
( Value.exception "Interpreter error: vector evaluation yielded a non-vector"
|> Runtime.throw envNow
, envNow
)
, Just (Thunk a)
)
)
k
|> Thunk
|> Just
)
evalMap : Located (ValueMap io) -> Env io -> Continuation io -> Step io
evalMap (Located mapLoc map) env k =
Located mapLoc
( Ok ( Const (Map ValueMap.empty), env )
, map
|> ValueMap.toList
|> List.map (Located mapLoc)
|> List.foldl
(\e a ->
\(Located loc v) renv ->
case v of
Map m ->
evalMapEntry e
renv
(\(Located mapEntryLoc mapEntryV) mapEntryEnv ->
case mapEntryV of
MapEntry ( key, value ) ->
Located mapEntryLoc
( Ok
( Const (Map (ValueMap.insert key value m))
, mapEntryEnv
)
, Just (Thunk a)
)
_ ->
Located loc
( Value.exception "Interpreter error: Map entry evaluation yielded a non-map entry"
|> Runtime.throw mapEntryEnv
|> (\ex -> ( ex, mapEntryEnv ))
|> Err
, Just (Thunk a)
)
)
_ ->
Located loc
( Value.exception "Interpreter error: Map evaluation yielded a non-map"
|> Runtime.throw renv
|> (\ex -> ( ex, renv ))
|> Err
, Just (Thunk a)
)
)
k
|> Thunk
|> Just
)
evalMapEntry : Located (ValueMapEntry io) -> Env io -> Continuation io -> Step io
evalMapEntry (Located loc ( key, value )) env k =
evalExpression (Located.unknown key)
env
(\keyRet keyEnv ->
evalExpression value
keyEnv
(\valRet valEnv ->
Located loc
( Ok ( Const (MapEntry ( Located.getValue keyRet, valRet )), valEnv )
, Just (Thunk k)
)
)
)
evalSet : Located (ValueSet io) -> Env io -> Continuation io -> Step io
evalSet (Located setLoc set) env k =
Located setLoc
( Ok ( Const (Set ValueSet.empty), env )
, set
|> ValueSet.toList
|> List.map (Located setLoc)
|> List.foldl
(\e a ->
\(Located loc v) renv ->
case v of
Set s ->
evalExpression e
renv
(\(Located setEntryLoc setEntry) setEntryEnv ->
Located setEntryLoc
( Ok
( Const (Set (ValueSet.insert setEntry s))
, setEntryEnv
)
, Just (Thunk a)
)
)
_ ->
Located loc
( Value.exception "Interpreter error: Set evaluation yielded a non-set"
|> Runtime.throw renv
|> (\ex -> ( ex, renv ))
|> Err
, Just (Thunk a)
)
)
k
|> Thunk
|> Just
)
destructure : Located (Value io) -> Located (Value io) -> Result (Located Exception) (List ( String, Value io ))
destructure arg template =
case template of
Located _ (Symbol name) ->
Ok [ ( name, Located.getValue arg ) ]
Located loc (Map templateMap) ->
arg
|> Located.getValue
|> Value.toMap
|> Result.fromMaybe (Located loc (Exception "type error: destructured value is not associative" []))
|> Result.andThen
(\map ->
let
keywordKeys =
templateMap
|> ValueMap.get (Keyword "keys")
|> Maybe.map Located.getValue
|> Maybe.withDefault (List [])
|> Value.trySequenceOf Value.trySymbol
|> Result.fromMaybe (Located loc (Exception "type error: :keys must be a vector of symbols" []))
|> Result.map
(\keys ->
keys
|> List.map
(\key ->
( key
, ValueMap.get (Keyword key) map
|> Maybe.map Located.getValue
|> Maybe.withDefault Nil
)
)
)
stringKeys =
templateMap
|> ValueMap.get (Keyword "strs")
|> Maybe.map Located.getValue
|> Maybe.withDefault (List [])
|> Value.trySequenceOf Value.trySymbol
|> Result.fromMaybe (Located loc (Exception "type error: :strs must be a vector of symbols" []))
|> Result.map
(\keys ->
keys
|> List.map
(\key ->
( key
, ValueMap.get (String key) map
|> Maybe.map Located.getValue
|> Maybe.withDefault Nil
)
)
)
otherKeys =
templateMap
|> ValueMap.remove (Keyword "keys")
|> ValueMap.remove (Keyword "strs")
|> ValueMap.remove (Keyword "or")
|> ValueMap.toList
|> List.foldr
(\( keyTemplate, Located _ key ) allBindingsResult ->
allBindingsResult
|> Result.andThen
(\allBindings ->
destructure
(ValueMap.get key map
|> Maybe.withDefault (Located loc Nil)
)
(Located loc keyTemplate)
|> Result.map ((++) allBindings)
)
)
(Ok [])
defaults =
if ValueMap.member (Keyword "or") templateMap then
Err (Located loc (Exception ":or is not supported" []))
else
Ok []
in
Result.map4 (\a b c d -> a ++ b ++ c ++ d)
defaults
keywordKeys
stringKeys
otherKeys
)
Located loc (Vector aliasedVector) ->
let
asKeyword =
Array.get (Array.length aliasedVector - 2) aliasedVector
|> Maybe.andThen (Located.getValue >> Value.tryKeyword)
asTemplate =
Array.get (Array.length aliasedVector - 1) aliasedVector
|> Maybe.andThen (Located.getValue >> Value.trySymbol)
( vec, asBindings ) =
Maybe.map2
(\_ tmpl ->
( Array.slice 0 -2 aliasedVector, [ ( tmpl, Located.getValue arg ) ] )
)
asKeyword
asTemplate
|> Maybe.withDefault ( aliasedVector, [] )
in
case Array.toList vec of
[] ->
Ok asBindings
[ Located _ (Symbol "&"), nextTemplate ] ->
arg
|> Located.getValue
|> Value.toSeq
|> Result.mapError (Located loc)
|> Result.andThen
(\seq ->
destructure (Located.sameAs arg (List seq)) nextTemplate
)
|> Result.map ((++) asBindings)
nextTemplate :: rest ->
arg
|> Located.getValue
|> Value.toSeq
|> Result.mapError (Located loc)
|> Result.andThen
(\argAsList ->
let
newArg =
argAsList |> List.head |> Maybe.withDefault (Located.unknown Nil)
in
destructure newArg nextTemplate
|> Result.andThen
(\boundArgs ->
destructure
(argAsList
|> List.tail
|> Maybe.map List
|> Maybe.withDefault Nil
|> Located.unknown
)
(Located loc (Vector (Array.fromList rest)))
|> Result.map ((++) asBindings)
|> Result.map ((++) boundArgs)
)
)
_ ->
Err (Located.sameAs arg (Exception "Parsing error: arguments didn't match the function definition" []))
mapArgs : List (Located (Value io)) -> List (Located (Value io)) -> Result (Located Exception) (List ( String, Value io ))
mapArgs args bindings =
case ( args, bindings ) of
( _, (Located _ (Symbol "&")) :: (Located _ (Symbol name)) :: [] ) ->
Ok [ ( name, List args ) ]
( _, (Located loc (Symbol "&")) :: [] ) ->
Err (Located loc (Exception "Parsing error: no symbol after &" []))
( (Located loc _) :: _, [] ) ->
Err (Located loc (Exception "Argument error: Too many arguments" []))
( [], (Located loc (Symbol _)) :: _ ) ->
Err (Located loc (Exception "Argument error: Too few arguments" []))
( arg :: restArgs, template :: restBindings ) ->
destructure arg template
|> Result.andThen
(\destructuredArgs ->
mapArgs restArgs restBindings |> Result.map (\b -> destructuredArgs ++ b)
)
( _, (Located loc _) :: _ ) ->
Err (Located loc (Exception "Parsing error: arguments didn't match the function definition" []))
( [], [] ) ->
Ok []
bindArgs : Located (Value io) -> List (Located (Value io)) -> Env io -> Result (Located Exception) (Env io)
bindArgs (Located loc argsExpr) bindings env =
case argsExpr of
List args ->
mapArgs args bindings
|> Result.map
(List.foldl (\( k, v ) aEnv -> Runtime.bindLexical k v aEnv) env)
_ ->
Err (Located loc (Exception "Interpreter error: applied arguments are not a list" []))
mapBindingsToBodies : List (Located (Value io)) -> Result (Located Exception) (List ( List (Located (Value io)), Located (Value io) ))
mapBindingsToBodies signatures =
case signatures of
(Located _ (List ((Located loc (Vector argBindings)) :: body))) :: rest ->
mapBindingsToBodies rest |> Result.map (\r -> ( Array.toList argBindings, wrapInDo (Located loc body) ) :: r)
(Located loc _) :: _ ->
Err (Located loc (Exception "Parsing error: malformed function arity" []))
[] ->
Ok []
listLocate : (a -> Maybe b) -> List a -> Maybe b
listLocate pFn l =
case l of
[] ->
Nothing
e :: rest ->
case pFn e of
Just v ->
Just v
Nothing ->
listLocate pFn rest
exctractFnNameAndDoc : List (Located (Value io)) -> ( Maybe String, Maybe String, List (Located (Value io)) )
exctractFnNameAndDoc exprs =
case exprs of
(Located _ (Symbol name)) :: (Located _ (String doc)) :: rest ->
( Just name, Just doc, rest )
(Located _ (Symbol name)) :: rest ->
( Just name, Nothing, rest )
(Located _ (String doc)) :: rest ->
( Nothing, Just doc, rest )
_ ->
( Nothing, Nothing, exprs )
evalFn : Located (List (Located (Value io))) -> Env io -> Continuation io -> Step io
evalFn (Located loc exprs) fnEnv k =
let
( name, doc, arity ) =
exctractFnNameAndDoc exprs
in
case arity of
(Located _ (Vector argBindings)) :: body ->
Located loc
( Ok
( Fn
{ name = name
, doc = doc
, signatures = [ argBindings |> Array.toList |> List.map (Located.getValue >> Value.inspect) ]
}
(\fn ->
(\args callsiteEnv ->
let
callEnvResult =
{ callsiteEnv | lexicalScope = fnEnv.lexicalScope }
|> (name
|> Maybe.map (\n -> Runtime.bindLexical n fn.self)
|> Maybe.withDefault identity
)
|> Runtime.bindLexical "recur" fn.self
|> bindArgs args (Array.toList argBindings)
in
case callEnvResult of
Ok callEnv ->
evalExpression (wrapInDo (Located loc body))
callEnv
(scrubLocalEnv callsiteEnv fn.k)
Err e ->
Located.sameAs e ( Err ( Located.getValue e, fnEnv ), Just (Thunk fn.k) )
)
|> Thunk
)
|> Const
, fnEnv
)
, Just (Thunk k)
)
signatures ->
let
fnSignatures =
signatures
|> List.filterMap
(Located.getValue
>> Value.tryList
>> Maybe.andThen List.head
>> Maybe.map Located.getValue
>> Maybe.andThen Value.tryVector
>> Maybe.map Array.toList
>> Maybe.map (List.map (Located.getValue >> Value.inspect))
)
in
Located loc
( ( (\fn ->
(\args callsiteEnv ->
let
callEnvBodyResult =
{ callsiteEnv | lexicalScope = fnEnv.lexicalScope }
|> (name
|> Maybe.map (\n -> Runtime.bindLexical n fn.self)
|> Maybe.withDefault identity
)
|> Runtime.bindLexical "recur" fn.self
|> (\env ->
mapBindingsToBodies signatures
|> Result.andThen
(listLocate
(\( bindings, body ) ->
bindArgs args bindings env
|> Result.toMaybe
|> Maybe.map (\e -> ( e, body ))
)
>> Result.fromMaybe
(Located loc
(Exception
"Argument error: no matching arity"
[]
)
)
)
)
in
case callEnvBodyResult of
Ok ( callEnv, fnBody ) ->
evalExpression fnBody
callEnv
(scrubLocalEnv callsiteEnv fn.k)
Err e ->
Located.sameAs e ( Err ( Located.getValue e, callsiteEnv ), Just (Thunk fn.k) )
)
|> Thunk
)
|> Fn { name = name, signatures = fnSignatures, doc = Nothing }
|> Const
, fnEnv
)
|> Ok
, Just (Thunk k)
)
scrubLocalEnv : Env io -> Continuation io -> Continuation io
scrubLocalEnv priorEnv k =
\v env ->
Located.sameAs v ( Ok ( Const <| Located.getValue v, { env | lexicalScope = priorEnv.lexicalScope } ), Just (Thunk k) )
evalLet : Located (List (Located (Value io))) -> Env io -> Continuation io -> Step io
evalLet (Located loc body) env k =
let
parseBindings bindings =
case bindings of
template :: value :: rest ->
parseBindings rest
|> Result.map (\r -> ( template, value ) :: r)
[] ->
Ok []
_ ->
Value.exception "Syntax error: let received an uneven number of binding pairs"
|> Runtime.throw env
|> Located loc
|> Err
in
case body of
(Located bodyLoc (Vector bindings)) :: doBody ->
Located loc
( Ok ( Const Nil, env )
, Just
(bindings
|> Array.toList
|> parseBindings
|> Result.map
(List.foldr
(\( template, e ) a ->
\_ eenv ->
evalExpression e
eenv
(\ret retEnv ->
Located loc
( destructure ret template
|> Result.mapError (\ex -> ( Located.getValue ex, retEnv ))
|> Result.andThen
(\destructuredBindings ->
Ok <|
( Const Nil
, destructuredBindings
|> List.foldl (\( name, v ) -> Runtime.bindLexical name v) retEnv
)
)
, Just (Thunk a)
)
)
)
(\_ renv ->
wrapInDo (Located bodyLoc doBody)
|> (\b -> evalExpression b renv (scrubLocalEnv env k))
)
)
|> Result.map Thunk
|> (\r ->
case r of
Ok v ->
v
Err e ->
Thunk
(\_ errEnv ->
Located.sameAs e
( Err ( Located.getValue e, errEnv )
, Just (Thunk (scrubLocalEnv env k))
)
)
)
)
)
_ ->
Located loc
( Err
( Value.exception "Syntax error: let expects a vector of bindings" |> Runtime.throw env
, env
)
, Just (Thunk k)
)
evalApply : Located (Value io) -> Located (List (Located (Value io))) -> Env io -> Continuation io -> Step io
evalApply fnExpr (Located loc argExprs) env k =
evalExpression fnExpr
env
(\fn fnEnv ->
Located loc
( Ok ( Const (List []), fnEnv )
, Just
(argExprs
|> List.foldr
(\e a ->
\(Located _ args) argsEnv ->
evalExpression e
argsEnv
(\arg argEnv ->
case args of
List ea ->
a (Located loc (List (ea ++ [ arg ]))) argEnv
_ ->
Located loc
( Value.exception "Impossible interpreter state: list evaluation yielded a non-list"
|> Runtime.throw argEnv
|> (\ex -> ( ex, argEnv ))
|> Err
, Just (Thunk a)
)
)
)
(\args argsEnv -> Runtime.apply fn args argsEnv k)
|> Thunk
)
)
)
evalQuote : Located (List (Located (Value io))) -> Env io -> Continuation io -> Step io
evalQuote (Located loc exprs) env k =
case exprs of
[ arg ] ->
Located.sameAs arg
( Ok ( Const <| Located.getValue arg, env )
, Just (Thunk k)
)
_ ->
Located loc
( Err
( Value.exception
("Argument error: Wrong number of arguments ("
++ String.fromInt (List.length exprs)
++ ") passed to quote"
)
|> Runtime.throw env
, env
)
, Just (Thunk k)
)
evalDo : Located (List (Located (Value io))) -> Env io -> Continuation io -> Step io
evalDo (Located loc exprs) env k =
Located loc
( Ok ( Const Nil, env )
, Just
(Thunk
(exprs
|> List.foldr
(\e a -> \_ eenv -> evalExpression e eenv a)
(\r renv -> Located.sameAs r ( Ok ( Const <| Located.getValue r, renv ), Just (Thunk k) ))
)
)
)
evalIf : Located (List (Located (Value io))) -> Env io -> Continuation io -> Step io
evalIf (Located loc args) env k =
case args of
_ :: _ :: _ :: _ :: _ ->
Located loc ( Err ( Value.exception "an if with too many forms" |> Runtime.throw env, env ), Just (Thunk k) )
[ eIf, eThen, eElse ] ->
evalExpression eIf
env
(\ifRet ifEnv ->
if Value.isTruthy (Located.getValue ifRet) then
evalExpression eThen ifEnv k
else
evalExpression eElse ifEnv k
)
[ eIf, eThen ] ->
evalExpression eIf
env
(\ifRet ifEnv ->
if Value.isTruthy (Located.getValue ifRet) then
evalExpression eThen ifEnv k
else
Located loc ( Ok ( Const Nil, ifEnv ), Just (Thunk k) )
)
[ _ ] ->
Located loc ( Err ( Value.exception "an if without then" |> Runtime.throw env, env ), Just (Thunk k) )
[] ->
Located loc ( Err ( Value.exception "an empty if" |> Runtime.throw env, env ), Just (Thunk k) )
evalDef : Located (List (Located (Value io))) -> Env io -> Continuation io -> Step io
evalDef (Located loc args) env k =
case args of
_ :: _ :: _ :: _ ->
Located loc
( Err ( Value.exception "too many arguments to def" |> Runtime.throw env, env )
, Just (Thunk k)
)
[ Located _ (Symbol name), e ] ->
evalExpression e
env
(\eret eenv ->
Located loc
( Ok
( Const (Ref (Var name (Located.getValue eret)))
, Runtime.bindGlobal name (Located.getValue eret) eenv
)
, Just (Thunk k)
)
)
[ _, _ ] ->
Located loc
( Err
( Value.exception "def accepts a symbol and an expression" |> Runtime.throw env
, env
)
, Just (Thunk k)
)
[ Located _ (Symbol name) ] ->
Located loc ( Err ( Value.exception ("empty def " ++ name) |> Runtime.throw env, env ), Just (Thunk k) )
[ _ ] ->
Located loc
( Err ( Value.exception "def expects a symbol as its first argument" |> Runtime.throw env, env )
, Just (Thunk k)
)
[] ->
Located loc ( Err ( Value.exception "no arguments to def" |> Runtime.throw env, env ), Just (Thunk k) )
evalCallable : Callable io
evalCallable =
let
arity1 form env1 k =
evalExpression (Located.unknown form) env1 k
|> Located.getValue
in
Callable.new
|> Callable.setArity1 (Enclojure.Common.Fixed (Value.symbol "str") arity1)
|> Callable.setDoc (Just "Evaluates the form data structure and returns the result.")
wrapInDo : Located (List (Located (Value io))) -> Located (Value io)
wrapInDo (Located loc vs) =
Located loc (List (Located loc (Symbol "do") :: vs))
prelude : Result Exception (List (Located (Value io)))
prelude =
Reader.readString Lib.prelude
|> Result.mapError (Runtime.throw defaultEnv)
defaultEnv : Env io
defaultEnv =
Runtime.emptyEnv
|> Lib.init
-- Eval is implemented in this namespace so lib cannot provide it.
|> Runtime.bindGlobal "eval"
(Fn
{ name = Just "eval"
, doc = evalCallable.doc
, signatures = Callable.signatures evalCallable
}
(toThunk evalCallable)
)
|> LibString.init
{-| Initialize a fresh Enclojure execution environment
-}
init : Env io
init =
prelude
|> Result.map (Located.unknown >> wrapInDo)
|> Result.map (\program -> evalExpression program defaultEnv Runtime.terminate)
|> Result.andThen (continueEvalPure { maxOps = Nothing })
|> Result.map (\( _, env ) -> env)
|> Result.withDefault defaultEnv
{-| Represents an unfinished computation that can be continued using `continueEval`.
-}
type alias Step io =
Located (Enclojure.Common.Step io)
{-| Returned by `eval`
- `Done value` - program completed successfully and returned `value`.
- `Error exception` - program threw `exception`.
- `Continue step` - program reached its `EvalOptions.maxOps` quota and can be resumed with continueEval (perhaps at the next animation frame).
- `RunIO io toStep` - program returned a side effect `io` and expects the caller to handle the side effect and call `toStep` with the result.
-}
type EvalResult io
= RunIO io (Result Exception (Value io) -> Step io)
| Continue (Step io)
| Error Exception
| Done (Value io)
{-| Accepted by `eval`, `continueEval`, and `evalPure`. If `EvalOptions.maxOps` is not Nothing, `eval` and `continueEval`
will return a `Continue step` while `evalPure` will return an error.
-}
type alias EvalOptions =
{ maxOps : Maybe Int }
{-| Evaluates a given Enclojure program in a provided environment. Returns a tuple of
the evaluation result and modified environment. May cause an infinite loop if EvalOptions.maxOps is not specified.
-}
eval : EvalOptions -> Env io -> String -> ( EvalResult io, Env io )
eval options initEnv code =
code
|> Reader.readString
|> Result.mapError (Runtime.throw initEnv)
|> Result.map2
(\a b -> a ++ b)
prelude
|> Result.andThen
(\exprs ->
exprs
|> List.head
|> Maybe.map ((\lv -> Located.sameAs lv exprs) >> wrapInDo)