1. **Задание к лабораторной работе**

По выданному преподавателем варианту разработать и исследовать работу комплекса программ обмена данными в режиме прерывания программы. Основная программа должна изменять содержимое заданной ячейки памяти (Х), которое должно быть представлено как знаковое число. Область допустимых значений изменения Х должна быть ограничена заданной функцией и конструктивными особенностями регистра данных ВУ (8-ми битное знаковое представление). Программа обработки прерывания должна выводить на ВУ модифицированное значение Х в соответствии с вариантом задания, а также игнорировать все необрабатываемые прерывания.

1. Основная программа должна уменьшать на 2 содержимое X (ячейки памяти с адресом 00816) в цикле.
2. Обработчик прерывания должен по нажатию кнопки готовности ВУ-3 осуществлять вывод результат вычисления функции -6X-7, a по нажатию кнопки готовности ВУ-2 вычесть содержимое РД данного ВУ из Х
3. Если Х оказывается вне ОДЗ при выполнении любой операции по его изменению, то необходимо в Х записать максимальное по ОДЗ число.
4. **Ход работы**

**I. Текст исходной программы на языке Ассемблера БЭВМ:**

ORG 000

RET: WORD ?

NOP ;Ячейка для отладочной точки останова

BR INT ;Переход к обработке прерывания

ORG 120

INT: MOV SAVEA ;Сохранение аккумулятора и регистра С

ROL

MOV SAVEC

CHECK2: TSF 2 ;Опрос флага ВУ-2

BR CHECK3 ;Если сброшен, то перейти к опросу флага ВУ-3

BR READY2 ;Иначе перейти к работе с ВУ-2

CHECK3: TSF 3 ;Опрос флага ВУ-3

BR READY1 ;Если сброшен, то перейти к работе с ВУ-1

BR READY3 ;Иначе перейти к работе с ВУ-3

READY2: CLA

IN 2

CMA

INC ;Берем значение из РД ВУ-2 со знаком минус

ADD X

JSR CHECKX ;Проверка на соответствие ОДЗ и запись х в память

CLF 2

BR RSTOR ;Переход к восстановлению аккумулятора и С

READY3: CLA

SUB X

SUB X

SUB X

SUB X

SUB X

SUB X ;Берем произведение 6 и х со знаком минус

SUB SVN ;Вычитаем 7

OUT 3 ;Выводим результат на ВУ-3

CLF 3 ;Сброс флага ВУ-3

BR RSTOR ;Переход к восстановлению аккумулятора и С

READY1: CLF 1 ;Сброс флага ВУ-1

RSTOR: CLA

ADD SAVEC ;Восстановть регистр С

ROR

CLA

CMA

AND SAVEA ;Восстановить аккумулятор не затрагивая С

NOP ;Ячейка для отладочной точки останова

EI ;Разрешить прерывания

BR (RET) ;Вернуться в основную программу

ORG 008

X: WORD 0000 ;Ячейка для записи переменной х

ORG 010

TWO: WORD 0002

SAVEA: WORD ?

SAVEC: WORD ?

SVN: WORD 0007

AHB: WORD 0014 ;Модуль максимального значения х

ALB: WORD 0015 ;Модуль минимального значения х

ORG 020 ;Основная программа

BEGIN: EI ;Разрешить прерывания

CLA

ADD X

LOOP: SUB TWO ;Уменьшаем х на два

JSR CHECKX ;Проверка на соответствие ОДЗ и запись х в память

BR LOOP

;Подпрограмма для проверки и записи х в память

CHECKX: WORD ? ;Адрес возврата

SUB AHB

BPL CORR ;Если х > верхней границы

ADD AHB

ADD ALB

BMI CORR ;Или x < нижней границы то приравнять х верхней границе

SUB ALB

BR MOVING ;В противном случае сразу записать х в память

CORR: CLA

ADD AHB

MOVING: MOV X

BR (CHECKX)

**II. Таблица результатов работы комплекса**

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| **X на шаге 7** | **Содержимое**  **РД ВУ-3**  **На шаге 12** | Содержимое  РД ВУ-2  На шаге 14 | **X на шаге 17** | **X на шаге 21** |
|  |  |  |  |  |
|  |  |  |  |  |
|  |  |  |  |  |

**III. Методика проверки программного комплекса:**

1. Загрузить комплекс программ в память БЭВМ
2. Изменить значения точек останова с адресами 001 и 144 на HLT
3. Нажать на кнопку «Компилировать»
4. Запустить основную программу в автоматическом режиме с адреса 020
5. **Для проверки правильности обработки прерывания от ВУ-3:**
6. Установить готовность ВУ-3
7. Дождаться останова
8. Записать состояние БЭВМ в начале прерывания
   1. Записать содержимое А и С
   2. Записать содержимое СК
   3. Ввести в КР значение 0008
   4. Нажать на кнопку «Ввод адреса» (F4)
   5. Нажать на кнопку «Чтение» (F6)
   6. Записать младшие 8 бит РД, в котором сейчас находится текущее значение Х
9. Восстановить состояние БЭВМ
   1. Ввести в КР содержимое СК, записанное на предыдущем шаге
   2. Нажать на кнопку «Ввод адреса» (F4)
10. Перейти на вкладку «Работа с ВУ»
11. Нажать на кнопку «Продолжение» (F8)
12. Дождаться останова
13. Убедиться в корректности работы с ВУ-3
    1. Убедиться, что значения А и С совпадают с записанными на шаге 7
    2. Убедиться, что значение в РД ВУ-3 было посчитано верно для текущего Х
14. Нажать на кнопку «Продолжение» (F8)
15. **Для проверки правильности обработки прерывания от ВУ-2:**
16. Ввести в РД ВУ-2 некоторое значение, записать это значение
17. Установить готовность ВУ-2
18. Дождаться останова
19. Записать состояние БЭВМ в начале прерывания
    1. Записать содержимое А и С
    2. Записать содержимое СК
    3. Ввести в КР значение 0008
    4. Нажать на кнопку «Ввод адреса» (F4)
    5. Нажать на кнопку «Чтение» (F6)
    6. Записать младшие 8 бит РД, в котором сейчас находится текущее значение Х
20. Восстановить состояние БЭВМ
    1. Ввести в КР значение содержимое СК, записанное на предыдущем шаге
    2. Нажать на кнопку «Ввод адреса» (F4)
21. Нажать на кнопку «Продолжение» (F8)
22. Дождаться останова
23. Убедиться в корректности работы с ВУ-2
    1. Убедиться, что значения А и С совпадают с записанными на шаге 17
    2. Записать содержимое СК
    3. Ввести в КР значение 0008
    4. Нажать на кнопку «Ввод адреса» (F4)
    5. Нажать на кнопку «Чтение» (F6)
    6. Записать младшие 8 бит РД, в котором сейчас находится новое значение Х
    7. Убедиться, что новое значение Х было посчитано верно
24. Восстановить состояние БЭВМ
    1. Ввести в КР значение содержимое СК, записанное на предыдущем шаге
    2. Нажать на кнопку «Ввод адреса» (F4)
25. Нажать на кнопку «Продолжение» (F8)