⎕IO ⎕ML ⎕WX VERSION AF∆PREFIX AF∆LIB←0 1 3 (2018 1 0) '/usr/local' 'cuda'

VS∆PS←⊂'\Program Files (x86)\Microsoft Visual Studio\2017\Enterprise\VC'

VS∆PS,←⊂'\Program Files (x86)\Microsoft Visual Studio\2017\Professional\VC'

VS∆PS,←⊂'\Program Files (x86)\Microsoft Visual Studio\2017\Community\VC'

VS∆PS,¨←⊂'\Auxiliary\Build\vcvarsall.bat'

VS∆PS,←⊂'\Program Files (x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat'

Cmp←{\_←1 ⎕NDELETE f←⍺,soext⍬ ⋄ \_←(⍺,'.cpp')put⍨gc tt⊢a n s←ps ⍵

\_←(⍎opsys'vsc' 'gcc' 'clang')⍺ ⋄ ⎕NEXISTS f:n ⋄ 'COMPILE ERROR' ⎕SIGNAL 22}

MkNS←{ns⊣ns.⍎¨(⊂'0'),⍺∘mkf¨(0⍴⊂''),(1=1⊃⍵)⌿0⊃⍵⊣ns←#.⎕NS ⍬}

Fix←{⍺ MkNS ⍺ Cmp ⍵}

Xml←{⎕XML(0⌷⍉⍵),(,∘⍕⌿2↑1↓⍉⍵),(⊂''),⍪(⊂(¯3+≢⍉⍵)↑,¨'nrsgvyel'),∘⍪¨↓⍕∘,¨⍉3↓⍉⍵}

MKA←{mka⊂⍵⊣'mka'⎕NA'P ',(⍺,soext⍬),'|mkarray <PP'}

EXA←{exa ⍬ ⍵⊣'exa'⎕NA(⍺,soext⍬),'|exarray >PP P'}

FREA←{frea ⍵⊣'frea'⎕NA(⍺,soext⍬),'|frea P'}

opsys←{⍵⊃⍨'Win' 'Lin' 'Mac'⍳⊂3↑⊃'.'⎕WG'APLVersion'}

soext←{opsys'.dll' '.so' '.dylib'}

tie←{0::⎕SIGNAL ⎕EN ⋄ 22::⍵ ⎕NCREATE 0 ⋄ 0 ⎕NRESIZE ⍵ ⎕NTIE 0}

put←{s←(¯128+256|128+'UTF-8'⎕UCS ⍺)⎕NAPPEND(t←tie ⍵)83 ⋄ 1:r←s⊣⎕NUNTIE t}

mkf←{fn←(⍺,soext⍬),'|',('∆'⎕R'\_\_'⊢⍵),'\_dwa '

f←⍵,'←{\_←''dya''⎕NA''',fn,'>PP <PP <PP'' ⋄ '

f,←'\_←''mon''⎕NA''',fn,'>PP P <PP'' ⋄ '

f,'0=⎕NC''⍺'':mon 0 0 ⍵ ⋄ dya 0 ⍺ ⍵} ⋄ 0'}

ccf←{' -o ''',⍵,'.',⍺,''' ''',⍵,'.cpp'' -laf',AF∆LIB,' > ',⍵,'.log 2>&1'}

cci←{'-I''',AF∆PREFIX,'/include'' -L''',AF∆PREFIX,'/lib'' '}

cco←'-std=c++11 -Ofast -g -Wall -fPIC -shared '

ucc←{⍵⍵(⎕SH ⍺⍺,' ',cco,cci,ccf)⍵}

gcc←'g++'ucc'so'

clang←'clang++'ucc'dylib'

vsco←{z←'/W3 /wd4102 /wd4275 /Gm- /O2 /Zc:inline /Zi /Fd"',⍵,'.pdb" '

z,←'/errorReport:prompt /WX- /MD /EHsc /nologo '

z,'/I"%AF\_PATH%\include" /D "NOMINMAX" /D "AF\_DEBUG" '}

vslo←{z←'/link /DLL /OPT:REF /INCREMENTAL:NO /SUBSYSTEM:WINDOWS '

z,←'/LIBPATH:"%AF\_PATH%\lib" /DYNAMICBASE "af', AF∆LIB, '.lib" '

z,'/OPT:ICF /ERRORREPORT:PROMPT /TLBID:1 '}

vsc0←{~∨⌿b←⎕NEXISTS¨VS∆PS:'VISUAL C++?'⎕SIGNAL 99 ⋄ '""','" amd64',⍨⊃b⌿VS∆PS}

vsc1←{' && cd "',(⊃⎕CMD'echo %CD%'),'" && cl ',(vsco ⍵),'/fast "',⍵,'.cpp" '}

vsc2←{(vslo ⍵),'/OUT:"',⍵,'.dll" > "',⍵,'.log""'}

vsc←{⎕CMD('%comspec% /C ',vsc0,vsc1,vsc2)⍵}

f∆ N∆←'ptknrsgvyeld' 'ABEFGLMNOPVZ'

⎕FX∘⍉∘⍪¨f∆,¨'←{'∘,¨(⍕¨⍳≢f∆),¨⊂'⊃⍵}'

⎕FX∘⍉∘⍪¨N∆,¨'m←{'∘,¨(⍕¨⍳≢N∆),¨⊂'=t⍵}'

⎕FX∘⍉∘⍪¨'GLM',¨'←{⍪/(0 '∘,¨(⍕¨N∆⍳'GLM'),¨⊂' 0 0),1+@0⍉↑(⊂4⍴⊂⍬),⍵}'

⎕FX∘⍉∘⍪¨'ABEFO',¨'←{⍪/(0 '∘,¨(⍕¨N∆⍳'ABEFO'),¨⊂' ⍺⍺ 0),1+@0⍉↑(⊂4⍴⊂⍬),⍵}'

⎕FX∘⍉∘⍪¨'NPVZ',¨'←{0(N∆⍳'''∘,¨'NPVZ',¨''')'∘,¨'0(⍎⍵)' '0(⊂⍵)' '⍺⍺(⊂⍵)' '1(⊂⍵)',¨'}'

⎕FX∘⍉∘⍪¨N∆,¨⊂'s←{⍵}' ⋄ at←{⍺ ⍺⍺ ⍵⍵ ⍵} ⋄ new←{⍵} ⋄ wrap←{⍵}

Display←{⍺←'Co-dfns' ⋄ W←w\_new⊂⍺ ⋄ 777::w\_del W

w\_del W⊣W ⍺⍺{w\_close ⍺:⍎'⎕SIGNAL 777' ⋄ ⍺ ⍺⍺ ⍵}⍣⍵⍵⊢⍵}

LoadImage←{⍺←1 ⋄ ⍉loadimg ⍬ ⍵ ⍺}

SaveImage←{⍺←'image.png' ⋄ saveimg (⍉⍵) ⍺}

Image←{~2 3∨.=≢⍴⍵:⎕SIGNAL 4 ⋄ (3≠2⊃3↑⍴⍵)∧3=≢⍴⍵:⎕SIGNAL 5 ⋄ ⍵⊣w\_img (⍉⍵) ⍺}

Plot←{2≠≢⍴⍵:⎕SIGNAL 4 ⋄ ~2 3∨.=1⊃⍴⍵:⎕SIGNAL 5 ⋄ ⍵⊣w\_plot (⍉⍵) ⍺}

Histogram←{⍵⊣w\_hist ⍵,⍺}

∇r←List

r←⎕NS¨1⍴⊂⍬ ⋄ r.Name←,¨⊂'Compile' ⋄ r.Group←⊂'CODFNS'

r[0].Desc←'Compile an object using Co-dfns'

r.Parse←⊂'2S -af=cpu opencl cuda '

∇

Convert←{⍺(⎕SE.SALT.Load '[SALT]/lib/NStoScript -noname').ntgennscode ⍵}

Run←{C I←⍵ ⋄ in out←I.Arguments ⋄ AF∆LIB∘←I.af ''⊃⍨I.af≡0

S←(⊂':Namespace ',out),2↓0 0 0 out Convert ##.THIS.⍎in

'Compile'≡C:{}{\_←{##.THIS.⍎out,'←⍵'}out Fix S⊣⎕EX'##.THIS.',out

⎕CMD'copy "%CUDA\_PATH%\nvvm\bin\nvvm64\*" /Y'/⍨(I.af≡'cuda')∧opsys 1 0 0}⍬}

Help←{'Usage: <object> <target> [-af={cpu,opencl,cuda}]'}

∇Z←Gfx∆Init S

'w\_new'⎕NA'P ',(S,soext⍬),'|w\_new <C[]'

'w\_close'⎕NA'I ',(S,soext ⍬),'|w\_close P'

'w\_del'⎕NA(S,soext⍬),'|w\_del P'

'w\_img'⎕NA(S,soext⍬),'|w\_img <PP P'

'w\_plot'⎕NA(S,soext⍬),'|w\_plot <PP P'

'w\_hist'⎕NA(S,soext⍬),'|w\_hist <PP F8 F8 P'

'loadimg'⎕NA(S,soext⍬),'|loadimg >PP <C[] I'

'saveimg'⎕NA(S,soext⍬),'|saveimg <PP <C[]'

Z ← 0 0 ⍴ ⍬

∇

dct←{⍺[(2×2≠/n,0)+(1↑⍨≢m)+m+n←⌽∨\⌽m←' '≠⍺⍺ ⍵]⍵⍵ ⍵}

dlk←{((x⌷⍴⍵)↑[x←2|1+⍵⍵]⍺),[⍵⍵]⍺⍺@(⊂0 0)⍣('┌'=⊃⍵)⊢⍵}

dwh←{⍵('┬'dlk 1)' │├┌└─'(0⌷⍉)dct,⊃⍪/((≢¨⍺),¨⊂⌈/≢∘⍉¨⍺)↑¨⍺}

dwv←{⍵('├'dlk 0)' ─┬┌┐│'(0⌷⊢)dct(⊣⍪1↓⊢)⊃{⍺,' ',⍵}/(1+⌈/≢¨⍺){⍺↑⍵⍪⍨'│'↑⍨≢⍉⍵}¨⍺}

pp3←{⍺←'○' ⋄ p l←⍵ ⋄ o←0⍴⍨≢p ⋄ \_←l{z⊣o+←⍵≠z←⍺[⍵]}⍣≡⍳≢l ⋄ i←⍋o

d←(⍳≢p)≠p ⋄ \_←p{z⊣d+←⍵≠z←⍺[⍵]}⍣≡p ⋄ p←i⍳p[i] ⋄ d←d[i] ⋄ lbl←((≢p)⍴⍺)[i]

lyr←{i←⍸⍺=d ⋄ k v←↓⍉p[i],∘⊂⌸i ⋄ (⍵∘{⍺[⍵]}¨v)⍺⍺¨@k⊢⍵}

(p=⍳≢p)⌿⊃⍺⍺ lyr⌿(1+⍳⌈/d),⊂⍉∘⍪∘⍕¨lbl}

lb3←{⍺←⍳≢⊃⍵

'(',¨')',¨⍨{⍺,';',⍵}⌿⍕¨(N∆{⍺[⍵]}@2⊢(2⊃⍵){⍺[|⍵]}@{0>⍵}@4↑⊃⍵)[⍺;]}

\_o←{0≥⊃c a e r←p←⍺ ⍺⍺ ⍵:p ⋄ 0≥⊃c a e r2←p←⍺ ⍵⍵ ⍵:p ⋄ c a e(r↑⍨-⌊/≢¨r r2)}

\_s←{0<⊃c a e r←p←⍺ ⍺⍺ ⍵:p ⋄ 0<⊃c2 a2 e r←p←e ⍵⍵ r:p ⋄ (c⌈c2)(a,a2)e r}

\_noenv←{0<⊃c a e r←p←⍺ ⍺⍺ ⍵:p ⋄ c a ⍺ r}

\_env←{0<⊃c a e r←p←⍺ ⍺⍺ ⍵:p ⋄ c a (e ⍵⍵ a) r}

\_then←{0<⊃c a e r←p←⍺ ⍺⍺ ⍵:p ⋄ 0<⊃c a e \_←p←e(⍵⍵ \_s eot)a:p ⋄ c a e r}

\_not←{0<⊃c a e r←⍺ ⍺⍺ ⍵:0 a ⍺ ⍵ ⋄ 2 a ⍺ ⍵}

\_as←{0<⊃c a e r←⍺ ⍺⍺ ⍵:c a e r ⋄ c (,⊂⍵⍵ a) e r}

\_t←{0<⊃c a e r←⍺ ⍺⍺ ⍵:c a e r ⋄ e ⍵⍵ a:c a e r ⋄ 2 ⍬ ⍺ ⍵}

\_ign←{c a e r←⍺ ⍺⍺ ⍵ ⋄ c ⍬ e r}

\_peek←{0<p←⊃⍺ ⍺⍺ ⍵:p ⋄ 0 ⍬ ⍺ ⍵}

\_yes←{0 ⍬ ⍺ ⍵}

\_opt←{⍺(⍺⍺ \_o \_yes)⍵}

\_any←{⍺(⍺⍺ \_s ∇ \_o \_yes)⍵}

\_some←{⍺(⍺⍺ \_s (⍺⍺ \_any))⍵}

\_set←{(0≠≢⍵)∧(⊃⍵)∊⍺⍺:0(,⊃⍵)⍺(1↓⍵) ⋄ 2 ⍬ ⍺ ⍵}

\_tk←{((≢,⍺⍺)↑⍵)≡,⍺⍺:0(⊂,⍺⍺)⍺((≢,⍺⍺)↓⍵) ⋄ 2 ⍬ ⍺ ⍵}

\_eat←{0=≢⍵:2 ⍬ ⍺ ⍵ ⋄ 0(⍺⍺↑⍵)⍺(⍺⍺↓⍵)}

ws←(' ',⎕UCS 9)\_set

aws←ws \_any \_ign

awslf←(⎕UCS 10 13) \_set \_o ws \_any \_ign

gets←aws \_s ('←'\_tk) \_s aws \_ign

him←'¯' \_set ⋄ dot←'.' \_set ⋄ jot←'∘' \_set

lbrc←aws \_s ('{'\_set) \_s aws ⋄ rbrc←aws \_s ('}'\_set) \_s aws

lpar←aws \_s ('('\_tk) \_s aws \_ign ⋄ rpar←aws \_s (')'\_tk) \_s aws \_ign

lbrk←aws \_s ('['\_tk) \_s aws \_ign ⋄ rbrk←aws \_s (']'\_tk) \_s aws \_ign

semi←aws \_s (';'\_tk \_as ('a'V∘,∘⊃)) \_s aws

grd←aws \_s (':'\_tk) \_s aws \_ign

egrd←aws \_s ('::'\_tk) \_s aws \_ign

alpha←'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz∆'\_set

digits←'0123456789'\_set

prims←'+-÷×|\*⍟⌈⌊!<≤=≠≥>∧∨⍲⍱⌷?⍴,⍪⌽⊖⍉∊⍷⊃⍳○~≡≢⊢⊣/⌿\⍀⊤⊥↑↓∪∩⍋⍒∇⌹'

prim←aws \_s (prims \_set) \_s aws

mop←aws \_s ('¨/⌿⍀\⍨'\_set) \_s aws

dop1←aws \_s ('.⍣∘'\_set) \_s aws

dop2←aws \_s ('⍤⍣∘'\_set) \_s aws

dop3←aws \_s ('∘'\_set) \_s aws

eot←aws \_s {(''≡⍵)∨⍬≡⍵:0 ⍬ ⍺ '' ⋄ 2 ⍬ ⍺ ⍵} \_ign

digs←digits \_some

odigs←digits \_any

int←aws \_s digs \_s (him \_opt) \_s aws

float←aws \_s (odigs \_s dot \_s int \_o (digs \_s dot)) \_s aws

name←aws \_s (alpha \_o (digits \_some \_s alpha) \_some) \_s aws

aw←aws \_s ('⍺⍵'\_set) \_s aws

aaww←aws \_s (('⍺⍺'\_tk) \_o ('⍵⍵'\_tk)) \_s aws

sep←aws \_s (('⋄',⎕UCS 10 13) \_set \_ign) \_s aws

nssn←alpha \_s (alpha \_o digits \_any)

nss←awslf \_s (':Namespace'\_tk) \_s aws \_s (nssn \_opt) \_s awslf \_ign

nse←awslf \_s (':EndNamespace'\_tk) \_s awslf \_ign

Sfn←aws \_s (('TFF⎕'\_tk) \_o ('TFFI⎕'\_tk)) \_s aws \_as {P⌽∊⍵}

Prim←prim \_as P

Vt←(⊢⍳⍨0⊃⊣)⊃¯1,⍨1⊃⊣

Var←{⍺(aaww \_o aw \_o (name \_as ⌽) \_t (⍺⍺=Vt) \_as (⍺⍺V∘,∘⊃))⍵}

Num←float \_o int \_as (N∘⌽)

Strand←0 Var \_s (0 Var \_some) \_as (3 A∘⌽)

Pex←{⍺(rpar \_s Ex \_s lpar)⍵}

Atom←Strand \_o (0 Var \_as (1 A)) \_o (Num \_some \_as (0 A∘⌽)) \_o Pex

Brk←rbrk \_s {⍺(Ex \_opt \_s (semi \_s (Ex \_opt) \_any))⍵} \_s lbrk \_as (3 E∘⌽)

Idx←Brk \_s (\_yes \_as {P,'['}) \_s Atom \_as (2 E∘⌽)

Blrp←{⍺(⍺⍺ \_s (⍵⍵ Slrp ∇))⍵}

Slrp←{⍺(⍺⍺ \_o (⍵⍵ \_s ∇) \_o ((1 \_eat) \_s ∇))⍵}

Fa←{e←(⊂'⍵⍵' '⍺⍺','⍺⍵')∘,∘⊂¨↓⍉¯1+3 3 2 2⊤(6 4 4⌿1 5 9)+2×⍳14

a←↓⍉↑(e,¨¨⊂⍺)Gex \_o Ex \_o Fex Stmts \_then Fn¨⊂⍵

m←(0=⊃a)∧∧⌿(∨⍀∘.=⍨⍳14)∨∘.≢⍨1⊃a

~∨⌿m:(⌈⌿⊃a) ⍬ ⍺ ⍵

(1=+⌿m)∧2>m⍳1:0(,⊂0(N∆⍳'F')1 0⍪¨1+@0⊃(0⍴⊂4⍴⊂⍬),⊃m⌿1⊃a)⍺ ⍵

z←⍪⌿↑(⊂0(N∆⍳'F')¯1 0),({1(N∆⍳'F')⍵ 0}¨1+m⌿⍳14)⍪¨(2+@0⊃)¨m⌿1⊃a

0(,⊂z)⍺ ⍵}

Fn←{0=≢⍵:0 ⍬ ⍺ '' ⋄ ns←(n z)⌿⍨m←(Fm∧¯1∊⍨k)⊢z←⍪⌿↑⍵ ⋄ 0=≢ns:0(,⊂z)⍺ ''

r←↓⍉↑⍺∘Fa¨ns ⋄ 0<c←⌈⌿⊃r:c ⍬ ⍺ ⍵

z←(⊂¨¨z)((⊃⍪⌿)⊣@{m})¨⍨↓(m⌿p z)+@0⍉↑⊃¨1⊃r

0(,⊂z)⍺ ''}

Pfe←{⍺(rpar \_s Fex \_s lpar)⍵}

Bfn←rbrc Blrp lbrc \_as {0(N∆⍳'F')¯1(,⊂⌽1↓¯1↓⍵)}

Fnp←Prim \_o (1 Var) \_o Sfn \_o Bfn \_o Pfe

Mop←{⍺((mop \_as P) \_s Afx \_as (1 O))⍵}

Dop1←{⍺((dop1 \_as P) \_s Afx \_as (2 O∘⌽))⍵}

Dop2←{⍺(Atom \_s (dop2 \_as P) \_s Afx \_as (2 O∘⌽))⍵}

Dop3←(dop3 \_as P) \_s Atom \_as (2 O∘⌽) \_o (dot \_s jot \_as (P∘⌽) \_as (1 O))

Bop←{⍺(rbrk \_s Ex \_s lbrk \_s (\_yes \_as {P,'['}) \_s Afx \_as (2 O∘⌽))⍵}

Afx←Mop \_o (Fnp \_s (Dop1 \_o Dop3 \_opt) \_as (⍪/⍳∘≢+@0⍉∘↑∘⌽)) \_o Dop2 \_o Bop

Trn←{⍺(Afx \_s ((Afx \_o Idx \_o Atom) \_s (∇ \_opt) \_opt))⍵} \_as (3 F∘⌽)

Bind←{⍺(gets \_s (name \_as ⌽) \_env (⊣⍪¨⍨⍺⍺,⍨∘⊂⊢) \_as (0(N∆⍳'B')⍺⍺,∘⊂⊢))⍵}

Asgn←gets \_s Brk \_s (name \_as ⌽ \_t (0=Vt) \_as (0 V∘,∘⊃)) \_as (4 E∘⌽)

Fex←Afx \_s (Trn \_opt) \_s (1 Bind \_any) \_as (⍪/⍳∘≢+@0⍉∘↑∘⌽)

IAx←Idx \_o Atom \_s (dop2 \_not)

App←Afx \_s (IAx \_opt) \_as {(≢⍵)E⌽⍵}

Ex←IAx \_s {⍺(0 Bind \_o Asgn \_o App \_s ∇ \_opt)⍵} \_as (⍪/⍳∘≢+@0⍉∘↑∘⌽)

Gex←Ex \_s grd \_s Ex \_as (G∘⌽)

Nlrp←sep \_o eot Slrp (lbrc Blrp rbrc)

Stmts←{⍺(sep \_any \_s (Nlrp \_then (⍺⍺ \_s eot∘⌽)) \_any \_s eot)⍵}

Ns←nss Blrp nse \_then (Ex \_o Fex Stmts \_then Fn) \_s eot \_as (1 F)

ps←{0≠⊃c a e r←⍬ ⍬ Ns∊{⍵/⍨∧\'⍝'≠⍵}¨⍵,¨⎕UCS 10:⎕SIGNAL c

(↓s(-⍳)@3↑⊃a)e(s←0(,'⍵')(,'⍺')'⍺⍺' '⍵⍵'(⊣,n~⊣)⊃a)}

⍝ A B E F G L M N O P V Z

⍝ 0 1 2 3 4 5 6 7 8 9 10 11

tt←{((d t k n)exp sym)←⍵ ⋄ I←{(⊂⍵)⌷⍺}

⍝ Convert to Parent Vector

\_←2{l[⍵[i]]←⍵[¯1+i←⍸0,2=⌿i]⊣p[⍵]←⍺[i←⍺⍸⍵]}⌿⊢∘⊂⌸d⊣p←l←⍳≢d

⍝ Binding Table and Top-level Table

bv←I@{1=t[⍵]}⍣≡⍨i@(p[i←⍸1=t[p]])⍳≢p ⋄ rn←p I⍣≡⍳≢p

⍝ Top-level Exports

i←⍸(1=t)∧(1=k)∧{⍵=p[⍵]}p I@{3≠t[⍵]}⍣≡⍳≢p ⋄ p,←∆←(s←≢p)+⍳≢i ⋄ l,←(≢∆)⍴s,¯1↓∆

l[0]←⊃⌽∆ ⋄ t k,←11 1⍴⍨¨≢i ⋄ n,←n[i] ⋄ p,←∆ ⋄ l,←(≢i)+∆ ⋄ t,←10⍴⍨≢i ⋄ k,←k[i]

n,←bv[i] ⋄ p,←∆ ⋄ l,←(≢i)+∆ ⋄ t k,←10 1⍴⍨¨≢i ⋄ n,←rn[i] ⋄ k[i]←2

⍝ Init Flags

i←⍸(t=3)∧p=⍳s←≢p ⋄ p,←∆←s+⍳≢i ⋄ l,←¯1⍴⍨≢i ⋄ t k,←11 2⍴⍨¨≢i ⋄ n,←i

l[∆,⍸(p=⍳≢p)∧l=⍳≢l]←(⊃∆),∆

⍝ Lift Functions

i←⍸(t=3)∧p≠⍳s←≢p ⋄ l←i(s+⍳)@{⍵∊i}l ⋄ p l(⊣,I)←⊂i ⋄ t k,←10 1⍴⍨¨≢i ⋄ n,←i

p[i]←i ⋄ l[j]←⊃(⌽i),j←⍸(p=⍳≢p)∧l=⍳≢l ⋄ l[i]←(≢i)↑(⊃i),i

⍝ Wrap Return Expressions

i←⍸(t[p]∊3 4)∧(t∊0 2)∨(t=1)∧(k=0)∧~(⍳≢l)∊¯1@{⍵=⍳≢⍵}l ⋄ p,←p[i]

p[i]←(≢l)+⍳≢i ⋄ l←i((≢l)+⍳)@{⍵∊i}l ⋄ l,←l[i] ⋄ l[i]←i ⋄ t k n,←2 0 0⍴⍨¨≢i

⍝ Lift Expressions

i←⍸(t∊8,⍳3)∧m←t[p]≠3 ⋄ xw←x@(l[x])⊢x@(x←⍸m)⊢l ⋄ l←i((≢l)+⍳)@{⍵∊i}l

p,←∆←p[i] ⋄ l,←l[i] ⋄ t,←10⍴⍨≢i ⋄ k,←(8∘=∨k[i]∧1∘=)t[i] ⋄ n,←i

l[∪∆]←∆⊢∘⊃⌸i ⋄ net←{~t[⍵]∊8,⍳5} ⋄ wk←xw I p∘I@(xw∘I=⊢)⍣≡

l[j]←((j×⊢)+×∘~)∘net⍨wk@net⍣≡wk⊢j←i~∆ ⋄ p[i]←p I@(3≠t∘I)⍣≡∆

⍝ Resolve Names

\_←{lv←{⍸⍵∧(t=10)∧n≥0} ⋄ fv←{⍸⍵∧(t=10)∧n<¯4} ⋄ bm←{(t[⍵]=1)∧n[⍵]=⍺}

⍝ Resolve Local Names

n[i](⊢+⊣×0=⊢)←bv[{⍵×n[i]bm ⍵}l I@{~n[i]bm ⍵}⍣≡l[p[i←fv 1]]]

⍝ Inline variable chains

\_←{⍵⌿10=t[n[⍵]]⊣n[⍵]←n[n[⍵]]}⍣{0=≢⍺}lv 10=t[0⌈n]

⍝ Inline primitive references

i←lv t[0⌈n]=9 ⋄ t[i]←9 ⋄ k[i]←0 ⋄ n[i]←n[n[i]]

⍝ Inline operator references

\_←{s←≢p ⋄ h←≢¨c←(⊢∘⊂⌸p)[n[⍵]⍳⍨∪p] ⋄ c←∊c ⋄ p,←p[p[⍵]],∆←h⌿s+⍳≢⍵

l,←(0⍴⍨≢⍵),s+(≢⍵)+(∆,⍪c)⍳∆,⍪l[c] ⋄ \_←{l[⍺]←⍵}/p[⍵]{(⍵,⍺)(l[⍺],⍵)}⌸s+⍳≢⍵

t,←t[c],⍨2⍴⍨≢⍵ ⋄ k,←k[c],⍨6⍴⍨≢⍵ ⋄ n,←n[c],⍨0⍴⍨≢⍵ ⋄ n[⍵]←s+⍳≢⍵

lv(t[p]=2)∧t[0⌈n]=8}⍣{0=≢⍺}lv(t[p]=2)∧t[0⌈n]=8

⍝ Convert raw F calls into E5 closure calls

i←lv(t[p]=2)∧t[0⌈n]=3 ⋄ s←≢p ⋄ p,←p[p[i]] ⋄ t,←2⍴⍨≢i ⋄ k,←5⍴⍨≢i ⋄ n,←n[i]

l,←0⍴⍨≢i ⋄ \_←{l[⍺]←⍵}/p[i]{(⍵,⍺)(l[⍺],⍵)}⌸s+⍳≢i ⋄ n[i]←s+⍳≢i

⍝ Propagate free variables to E5's

i←⍸(t=2)∧k=5 ⋄ ∆←p I@{3≠t[⍵]}⍣≡p[f←fv 1] ⋄ c←f[∊(g←(⊢∘⊂⌸∆),⊂⍬)[j←(∪∆)⍳i]]

s←≢p ⋄ p,←(≢¨g)[j]⌿i ⋄ l,←s+⍳≢c ⋄ t,←t[c] ⋄ k,←k[c] ⋄ n,←n[c]

s+⍳≢c}⍣{0=≢⍺}⍬

⍝ Lift Guard Expressions

⍝ l[gr]←gr←⍸(l[l]=⍳≢l)∧gm←4=t[p] ⋄ n[p[gv]]←n[gv←⍸(10=t)∧gk←gm∧l=⍳≢l]

⍝ p[ge]←p[pg←p[ge←⍸gk∧2=t]] ⋄ l[ge]←l[pg] ⋄ l[pg]←n[pg]←ge

⍝ gn←⍸~gk∧10=t ⋄ p l n←(⊢-1+gv⍸⊢)¨gn∘I¨p l n ⋄ t←t[gn] ⋄ k←k[gn]

⍝ Label jumps

⍝ Inline functions

⍝ Propagate constants

⍝ Fold constants

⍝ Dead, useless code elimination

⍝ Allocate frames

⍝ Function Declarations

i←⍸t=3 ⋄ l[⍸((p=⊢)∧l=⊢)⍳s]←¯1+(≢i)+s←≢l ⋄ p,←j←s+⍳≢i ⋄ l,←s,¯1↓j

t k,←11 0⍴⍨¨≢i ⋄ n,←i

p l t k n exp sym}

gck←(0 0)(0 1)(1 2)(2 0)(2 1)(2 2)(2 5)(2 6)(3 1)(7 0)(9 0)(10 0)(10 1)

gcv←'Aa' 'Av' 'Bx' 'Er' 'Em' 'Ed' 'Ec' 'Eo' 'Fn' 'Na' 'Pm' 'Va' 'Vf'

gck,←(11 0)(11 1)(11 2)

gcv,←'Zp' 'Zx' 'Zi'

gck+←⊂1 0

gcv,←⊂'{''/\* Unhandled '',(⍕⍺),'' \*/'',NL}'

NL←⎕UCS 13 10

gc←{p l t k n exp sym←⍵ ⋄ I←{(⊂⍵)⌷⍺} ⋄ com←{⊃{⍺,',',⍵}/⍵}

o←0⍴⍨≢p ⋄ \_←l{z⊣o+←⍵≠z←⍺[⍵]}⍣≡⍳≢l ⋄ d←(⍳≢p)≠p ⋄ \_←p{z⊣d+←⍵≠z←⍺[⍵]}⍣≡p

z←⍪⍳≢p ⋄ \_←p{z,←p[⍵]}⍣≡z ⋄ i←⍋(-1+d)(1+o I ↑)⍤0 1⊢⌽z

ast←(⍉↑d p l(1+t)k n(⍳≢p))[i;] ⋄ ks←{⍵⊂[0]⍨(⊃⍵)=⍵[;0]}

Aaa←{'(1,dim4(',(⍕≢⍵),'),array(',(⍕≢⍵),',',(Aav ⍵),'));',NL}

Aas←{'(0,eshp,constant(',('¯'⎕R'-'⍕⍵),',eshp,',('f64' 's32'⊃⍨⍵=⌊⍵),'));',NL}

Aav←{'std::vector<',('DI'⊃⍨∧/⍵=⌊⍵),'>{',('¯'⎕R'-'com⍕¨⍵),'}.data()'}

Aa←{h←'A va',⍕6⊃⍺ ⋄ 1=≢ns←dis¨⍵:h,Aas⊃ns ⋄ h,Aaa ns}

Av←{'A va',(⍕6⊃⍺),'=',(⊃,/dis¨⍵),';',NL}

Bx←{fn,'\_c=',(fn←⊃dis¨⍵),'\_f();',NL}

Ec←{'fn',(⍕5⊃⍺),'\_f fn',(⍕6⊃⍺),'\_c;',NL}

Ed←{x f y←dis¨⍵ ⋄ 'A va',(⍕6⊃⍺),';',f,'\_c(',(com('va',⍕6⊃⍺)x y),');',NL}

Em←{f v←dis¨⍵ ⋄ 'A va',(⍕6⊃⍺),';',f,'\_c(',('va',⍕6⊃⍺),',',v,');',NL}

Eop←{com{'\_c',⍨⍣('va'≢2↑⍵)⊢⍵}¨1↓⍵}

Eo←{c←⌽¯1⌽dis¨⍵ ⋄ (⊃c),'\_o fn',(⍕6⊃⍺),'\_c(',(Eop c),');',NL}

Er←{'z=',(⊃dis¨⍵),';z.f=1;R;',NL}

Fn←{NL,'DF(',('fn',⍕6⊃⍺),'\_f){',NL,(⊃,/' ',¨dis¨⍵),'}',NL}

Na←{sym⌷⍨|5⊃⍺}

Pm←{nams⊃⍨syms⍳sym⌷⍨|5⊃⍺}

Zi←{'I isfn',(⍕5⊃⍺),'=0;',NL}

Zp←{'FP(',('fn',⍕5⊃⍺),');',NL}

Zx←{'EF(',(com(sym⌷⍨|5⊃⍺),dis¨⍵),');',NL}

Va←{(x←5⊃⍺)∊-1+⍳4:,'r' 'l' 'll' 'rr'⊃⍨¯1+|x ⋄ ('va' 'fv'⊃⍨x<0),⍕|x}

Vf←{'fn',⍕5⊃⍺}

dis←{h←,1↑⍵ ⋄ c←ks 1↓⍵ ⋄ h(⍎gcv⊃⍨gck⍳⊂h[3 4])c}

⊃,/(⊂rth),(rtn⌷⍨⊂syms⍳,¨'¨/'),(rtn⌿⍨syms∊sym),dis¨ks ast}

syms ←,¨'+' '-' '×' '÷' '\*' '⍟' '|' '○' '⌊' '⌈' '!'

nams ← 'add' 'sub' 'mul' 'div' 'exp' 'log' 'res' 'cir' 'min' 'max' 'fac'

syms,←,¨'<' '≤' '=' '≥' '>' '≠' '~' '∧' '∨' '⍲' '⍱'

nams,← 'lth' 'lte' 'eql' 'gte' 'gth' 'neq' 'not' 'and' 'lor' 'nan' 'nor'

syms,←,¨'⌷' '[' '⍳' '⍴' ',' '⍪' '⌽' '⍉' '⊖' '∊' '⊃'

nams,← 'sqd' 'brk' 'iot' 'rho' 'cat' 'ctf' 'rot' 'trn' 'rtf' 'mem' 'dis'

syms,←,¨'≡' '≢' '⊢' '⊣' '⊤' '⊥' '/' '⌿' '\' '⍀' '?'

nams,← 'eqv' 'nqv' 'rgt' 'lft' 'enc' 'dec' 'red' 'rdf' 'scn' 'scf' 'rol'

syms,←,¨'↑' '↓' '¨' '⍨' '.' '⍤' '⍣' '∘' '∪' '∩'

nams,← 'tke' 'drp' 'map' 'com' 'dot' 'rnk' 'pow' 'jot' 'unq' 'int'

syms,←,¨'⍋' '⍒' '∘.' '⍷' '⊂' '⌹' '⎕FFT' '⎕IFFT' '%u'

nams,← 'gdu' 'gdd' 'oup' 'fnd' 'par' 'mdv' 'fft' 'ift' ''

rth←''

rtn←(⍴nams)⍴⊂''

⍝ E1←{'fn'gcl((⊂n,∘⊃v),e,y)⍵}

⍝ E2←{'fn'gcl((⊂n,∘⊃v),e,y)⍵}

⍝ Ei←{r l f←⊃v ⍵ ⋄ ((⊃n ⍵)('fn'var)⊃⊃e ⍵),'=',((⊃⊃v ⍵)('fn'var)1⊃⊃e ⍵),';',nl}

⍝ O1←{'op'gcl((⊂n,∘⊃v),e,y)⍵}

⍝ O2←{'op'gcl((⊂n,∘⊃v),e,y)⍵}

⍝ O0←{''}

⍝ Of←{'EF(',('∆'⎕R'\_\_'⊃n ⍵),',',(⊃⊃v ⍵),');',nl}

⍝ Fd←{'FP(',(⊃n ⍵),');',nl}

⍝ F0←{'DF(',(⊃n ⍵),'\_f){',nl,'A\*env[]={tenv};',nl}

⍝ F1←{'DF(',(⊃n ⍵),'\_f){',nl,('env0'dnv ⍵),(fnv ⍵)}

⍝ G0←{v←(⊃⊃v ⍵)(''var)1⊃⊃e ⍵

⍝ 'if(1!=cnt(',v,'))err(5);if(',v,'.v.as(s32).scalar<I>()){',nl}

⍝ G1←{'z=',((⊃n ⍵)(''var)⊃⊃e ⍵),';goto L',(⍕⊃l ⍵),';}',nl}

⍝ L0←{'z=',a,';L',(⍕⊃n ⍵),':',(a←(1⊃⊃v ⍵)(''var)1⊃⊃e ⍵),'=z;',nl}

⍝ Z0←{'}', nl,nl}

⍝ Z1←{'}', nl,nl}

⍝ Ze←{'}', nl,nl}

⍝ M0←{(rth⍬),('tenv'dnv ⍵),nl,'A\*env[]={',((0≡⊃⍵)⊃'tenv' 'NULL'),'};',nl,nl}

⍝ S0←{(('{',rk0,srk,'DO(i,prk)cnt\*=sp[i];',spp,sfv,slp)⍵)}

⍝ Y0←{⊃,/((⍳≢⊃n ⍵)((⊣sts¨(⊃l),¨∘⊃s),'}',nl,⊣ste¨(⊃n)var¨∘⊃r)⍵),'}',nl}

⍝ gc←{⊃,/{0=⊃t ⍵:⊂5⍴⍬ ⋄ ⊂(⍎(⊃t ⍵),⍕⊃k ⍵)⍵}⍤1⊢⍵}

fvs←,⍤0(⌿⍨)0≠(≢∘⍴¨⊣) ⋄ cln←'¯'⎕R'-' ⋄ cnm←(syms⍳⊂)⊃(nams,⊂)

lits←{'A(0,eshp,constant(',(cln⍕⍵),',eshp,',('f64' 's32'⊃⍨⍵=⌊⍵),'))'}

litv←{'std::vector<',('DI'⊃⍨∧/⍵=⌊⍵),'>{',(cln⊃{⍺,',',⍵}/⍕¨⍵),'}.data()'}

lita←{'A(1,dim4(',(⍕≢⍵),'),array(',(⍕≢⍵),',',(litv ⍵),'))'}

lit←{' '=⊃0⍴⍵:(cnm ⍵),⍺ ⋄ 1=≢⍵:lits ⍵ ⋄ lita ⍵}

var←{⍺≡,'⍺':,'l' ⋄ ⍺≡,'⍵':,'r' ⋄ ¯1≥⊃⍵:⍺⍺ lit,⍺ ⋄ 'env[',(⍕⊃⍵),'][',(⍕⊃⌽⍵),']'}

dnv←{(0≡z)⊃('A ',⍺,'[',(⍕z←⊃v ⍵),'];')('A\*',⍺,'=NULL;')}

fnv←{z←'A\*env[',(⍕1+⊃s ⍵),']={',(⊃,/(⊂'env0'),{',p[',(⍕⍵),']'}¨⍳⊃s ⍵),'};',nl}

gcl←{z r l n←((3⍴⊂'fn'),⊂⍺){⊃⍺ var/⍵}¨↓(⊃⍵),⍪1⊃⍵ ⋄ n,'(',(⊃{⍺,',',⍵}/z l r~⊂'fn'),',env);',nl}