Low Self-Control, Peer Delinquency and Alcohol Use: An analysis in youth aged 12-20

Tavish King

Brigham Young University

Low Self-Control, Peer Delinquency, and Alcohol Use: An analysis in youth aged 12-20

The primary aim of our study is to determine how self-control and friend delinquency are related to alcohol use. Therefore, we developed the following hypotheses: (1) Controlling for key predictors in our model, we hypothesize that lower self-control will be associated with greater alcohol use. (2) We also predict that higher levels of friend delinquency will be associated with greater alcohol use. (3) Finally, we hypothesize that friend delinquency will moderate the relationship between low self-control and alcohol use. A total of 11,223 youth and young adults completed a survey asking them to describe their demographic background, perceived level of low self-control and delinquency, friend delinquency, and frequency of alcohol, cigarette, and marijuana use in the past year. The original data included samples aged 11-21. Due to low sample counts in the 11- and 21-year-old age group (n = 3), they were not included in the analysis. The study’s final sample included 5,312 males and 5,908 females (n = 11,220). Ages ranged from 12-20 (Mage = 15.58, SD = 1.725). 54.3% of participants identified as White, 18.9% as Black, 8.4% as ethnic, 8.3% as Asian or Pacific Islander, 7.2% as Latinx, and 3.1% as Native American.

**Analysis**

All analyses were conducted in STATA v.18.5. We ran correlation and multiple regression analyses to examine which variables significantly predicted alcohol use in the past year. Alcohol use served as our outcome variable. Both self-control and friend delinquency were standardized so that 0 represented the average level of self-control and friend delinquency in our sample. Self-control was measured so that greater values indicated greater low self-control. Gender status was re-leveled with the male gender as the reference group. Age was centered at the minimum in our sample so that 0 was equal to age 12.

We first fit a model with self-control and friend delinquency and an interaction between the two to serve as a baseline comparison to later models with additional predictors. Next, we believed that cigarette and marijuana use, age, and gender may influence alcohol use. These were added as additional covariates. We compared AIC and R2 values between the two models to move forward with model fitting. Multicollinearity was checked using the post-estimation command “vif” in STATA. The equation below helps convey our final, full model.

**Results**

**Descriptive Statistics**

According to our sample, average alcohol use in the past year was 0.77 (*SD* = 0.82, range 0-6). The distribution of alcohol was right skewed with 25.87% (n = 2,903) of the sample reporting no instances of alcohol use. 17-year-olds showed the highest average consumption of alcohol in the year (*M* = 0.93, *SD* = 0.91) and 12-year-olds showing the lowest average alcohol use (*M* = 0.35, *SD* = 0.51). Between genders, females showed higher average alcohol use (*M* = 0.83, *SD* = 0.84). We ran a two-sided t-test to compare if the gender means were statistically different from one another. Our results showed that the mean alcohol use for females was significantly greater than that for males (*t =* 8.12, *p* < .001).

**Model Results**

As shown in **Table 1**, each continuous predictor was significantly and positively associated with alcohol use, indicating that individuals with higher values on these variables tend to have greater alcohol use.

|  |  |
| --- | --- |
| **Table 1**  Correlations between Alcohol and Continuous Predictors | |
| **Term** | Alcohol |
| Self-Control | 0.092\* |
| Friend Delinquency | 0.307\* |
| Cigarettes | 0.724\* |
| Marijuana | 0.453\* |
| Age | 0.181\* |

In our baseline model, the predictors only explained 10% of the variability in alcohol use (*R2* = 0.10, *F*(3, 11216) = 392.95, *p* < .001). Our final model with the additional predictors increased the explained variance to 58% (*R2* = 0.58, *F*(7, 11212) = 2226.6, *p* < .001), indicating a significant improvement in model fit. The results of our final model are displayed in **Table 2**.

| **Table 2**  *Summary of Multiple Regression Analysis for Key Covariates Predicting Alcohol Use (n = 11,220)* | | | |
| --- | --- | --- | --- |
| **Full Model Summary** | | | |
| **Terms** | **Coeff.** | **S.E.** | **95% CI** |
| Low Self-Control^ | -0.03\*\*\* | 0.01 | -0.05, -0.01 |
| Friend Delinquency^ | 0.06\*\*\* | 0.01 | 0.05, 0.08 |
| Low Self-Control x  Friend Delinquency^ | -0.04\*\*\* | 0.01 | -0.05, -0.02 |
| Cigarette Use (year) | 0.47\*\*\* | 0.01 | 0.45, 0.48 |
| Marijuana Use (year) | 0.40\*\*\* | 0.01 | 0.38, 0.43 |
| Age | 0.07\*\*\* | 0.003 | 0.06, 0.07 |
| Gender:Female | 0.07\*\*\* | 0.01 | 0.05, 0.09 |
| *Note.* Coeff. = coefficient, S.E. = standard error, 95% CI = 95% Confidence Interval. R2 = 0.58, p < .001. ^ = standardized variable. \*\*\* = p < .001 | | | |

In regard to our first order effects (self-control, friend delinquency), a 1-unit increase in low self-control is associated with a -0.03 decrease in alcohol consumption when friend delinquency is at the mean, holding constant other variables (*β* = -0.03, 95%CI [-0.47, 0.01], *p* < .001). Furthermore, a 1-unit increase in friend delinquency is associated with a 0.06 increase in alcohol drinks consumed when low self-control is at the mean, holding constant other variables (*β* = 0.06, 95%CI [0.05, 0.08], *p* < .001). There was a significant interaction between self-control and friend delinquency in predicting alcohol consumption (*β* = -0.04, 95%CI [-0.05, -0.02], *p* < .001), signifying that the relationship between self-control and alcohol consumptions is different for differing values of friend delinquency.

**Figure 1**

*Interaction Between Low Self-Control and Friend Delinquency*

A graph of a number of people

Description automatically generated with medium confidence

**Covariates**

Controlling for other variables, cigarette use was associated with increased alcohol use (*b* = 0.47, 95%CI [0.45, 0.48], *p* < .001), such that for every 1-unit difference, alcohol use increased by 0.47 units. Additionally, marijuana use was associated with increased alcohol use, holding constant all other variables (*b* = 0.4, 95%CI [0.38, 0.43], *p* < .001). Additionally, every 1-year increase in age was associated with a 0.07 unit increase in alcohol use (*b* = 0.07, 95%CI [0.06, 0.07], *p* < .001). Lastly, compared to males, being female was associated with a 0.07 unit increase in alcohol use, holding all other variables constant. This relationship was statistically significant (*b* = 0.07, 95%CI [0.05, 0.09], *p* < .001).


**Conclusion**

We predicted in hypothesis 1 that greater low self-control is associated with greater alcohol use. However, our model results showed that greater low self-control is associated with a reduction in the number of alcohol drinks consumed. In hypothesis 2, we predicted that greater friend delinquency would be associated with higher underage alcohol use. Our results supported this hypothesis and showed that peer delinquency significantly increases alcohol consumption in youth and young adults aged 12 to 20. Lastly, in hypothesis 3, we predicted that friend delinquency would moderate the relationship between low self-control and alcohol use. **Figure 1** illustrates that individuals with greater self-control (moving backward on the plot) and friends with those who engage in high delinquent behavior (2 SD above the mean) are at the greatest risk of consuming alcohol. It appears that despite having high peer delinquency, having higher low-self control tends to mitigate the predicted number of alcohol drinks consumed. Furthermore, at low levels of peer delinquency, greater low self-control begins to show a positive trend toward increased alcohol consumption. Last of all, engaging in other harmful substances (e.g., cigarette and marijuana smoking) shows the strongest positive trend toward greater alcohol consumption.

**Appendix**


**Supplementary Figure 2**

*Relationship between Alcohol Consumption and Low Self-Control*



**Supplementary Figure 3**

*Relationship between Alcohol Consumption and Friend Delinquency*



**Supplementary Figure 4**

*Residual vs. Fitted Plot*

A graph showing a number of dots

Description automatically generated

Note: Residual vs. fitted plot from our final model shows evidence of heteroskedasticity due to the funneling shape of the data points. Further analyses were done in R to determine if we run the risk of having biased standard errors and p-values. Using a Heteroskedastic Corrected Covariance Matrix, we compared our original models SE's and p-values to their corrected values and found no substantial differences that would change our original conclusions. (this one was for my own sanity and fun).

**\*\*\* ANNOTATED CODE \*\*\***

\*clearing any previous data

clear all

\* loading data

use "delinquency\_data"

\* viewing codebook

codebook, compact

// no missing values

// gpa, selfcontrol, and frienddelinquency are standardized

\* Research Questions:

// How is self-control related to alcohol use?

// How is friend's delinquency related to alcohol use?

// How does friend's delinquency influence the relationship between self-control and alcohol use?

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* Viewing Variables \*\*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\*\*AGE (predictor 5)

summarize age

summarize age, detail

tabulate age

// will need to remove ages 11 (1 observation) and 21 (2 observations)

\*\*\*GENDER (predictor 6)

tabulate gender

\*\*\*ETHNICITY

tabulate ethnicity

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* Data Cleaning

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

// steps:

// 1. remove age values 11 & 21

// 2. center age to the minimum

// 3. dummycode male as the baseline in the gender variable (1 level, j-1)

\*\*step 1:

drop if age == 11

drop if age == 21

summarize age // range = 12-20. GOOD!

\*\*step 2:

summarize age

gen age\_c = age - r(min)

// age\_c = age\_centered

\*\*step 3:

generate male\_dummy = 1 if gender == 1 //female is coded as 1 and male will be 0

replace male\_dummy = 0 if gender != 1

// male is now the baseline

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* Exploratory Data Analysis \*\*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

pwcorr alcohol selfcontrol frienddelinquency cigarettes marijuana age\_c male\_dummy

\*\* Descriptives

\*\*\*ALCOHOL (outcome)

summarize alcohol

summarize alcohol, detail

histogram alcohol, start(-0.1) scheme(s1mono) percent

tabulate alcohol

// right skewed with 25.88% of responses reporting 0 instances of alcohol use in the year

// do not need to normalize as it is the response variable

\*\*\*SELF-CONTROL (predictor 1)

// measured as low self-control, indicating higher responses equals greater low self-control (bad)

summarize selfcontrol

summarize selfcontrol, detail

histogram selfcontrol, scheme(s1mono) frequency

// appears normally distributed with some skewness and maybe outliers

\*\*\*FRIEND DELINQUENCY (predictor 2)

summarize frienddelinquency

summarize frienddelinquency, detail

histogram frienddelinquency, scheme(s1mono) percent

tabulate frienddelinquency

// right skewed, non-normal, may consider transformation

// 35.53% reporting friend delinquency 0.75 SDs below the mean of frienddelinquency which indicates that 35.53% have no frienddelinquency. Will not transform

\*\*\*CIGARETTES (predictor 3)

summarize cigarettes

summarize cigarettes, detail

histogram cigarettes

tabulate cigarettes

// similar to alcohol variable, largely right skewed with 37.24% of the sample reporting no cigarette use in the year. Will not transform.

\*\*\*MARIJUANA (predictor 4)

summarize marijuana

summarize marijuana, detail

histogram marijuana

tabulate marijuana

// largely right skewed with 29.57% of the sample reporting no marijuana use in the past year. Will not transform as it wont fix the skewness

\*\*\*AGE AND ALCOHOL

graph box alcohol, over(age)

bysort age: summarize alcohol

\*\*\*GENDER AND ALCOHOL

graph box alcohol, over(gender)

bysort gender: summarize alcohol

ttest alcohol, by(gender)

\*\*linear relationship between selfcontrol and alcohol (supp. figure 2)

twoway (scatter alcohol selfcontrol, msymbol(o) mcolor(black%30) mlwidth(vvthin)) (lfit alcohol selfcontrol, lcolor(red) lwidth(thick)), xscale(r(-1.6 3)) xlabel(-2(1)3, labsize(small)) ylabel(, labsize(small)) xtitle("Low Self-Control (standardized)", size(medium)) ytitle("# of Alcohol Drinks", size(medium)) legend(off) graphregion(color(white)) plotregion(margin(zero))

\*\*linear relationship between frienddelinquency and alcohol (supp. figure 3)

twoway (scatter alcohol frienddelinquency, msymbol(o) mcolor(black%30) mlwidth(vvthin)) (lfit alcohol frienddelinquency, lcolor(red) lwidth(thick)), xscale(r(-1 2.2)) xlabel(-1(1)2, labsize(small)) ylabel(, labsize(small)) xtitle("Friend Delinquency (standardized)", size(medium)) ytitle("# of Alcohol Drinks", size(medium)) legend(off) graphregion(color(white)) plotregion(margin(zero))

\*\*\*\*\*\*\*\*\*\*\*

\* Analysis

\*\*\*\*\*\*\*\*\*\*\*

\* correlation analysis

pwcorr alcohol selfcontrol frienddelinquency cigarettes marijuana age, sig star(.05) obs

\*\* multiple regression analysis

/// baseline model

regress alcohol c.selfcontrol c.frienddelinquency c.selfcontrol#c.frienddelinquency

// r-squared = 0.10

estat ic

// AIC = 26244.94

/// full model

regress alcohol c.selfcontrol c.frienddelinquency c.selfcontrol#c.frienddelinquency c.cigarettes c.marijuana c.age\_c i.male\_dummy

// r-sqaured = 0.58

estat ic

// AIC = 17577.72

vif // checking for multicollinearity

\* interaction plot

margins, at(selfcontrol = (-1.5(1)2.5) frienddelinquency = (-1 0 2)) //min, mean, max

marginsplot, noci ///

scheme(s1mono) ///

legend(pos(6) row(1)) ///

legend(subtitle("Level of Friend Delinquency")) ///

title("") ///

ytitle("Predicted Alcohol Consumption") ///

xtitle("Average level of Self-Control - {it:z} score") ///

legend(order(1 "-1 SD" 2 "Mean" 3 "2 SD"))

\* Additional Figures

\*\* (supp. figure 4)

rvfplot, msymbol(o) mcolor(black%15) yline(0)