Upgraded ShopSync from Groovy to Kotlin DSL in Gradle and changed some translations

.github/workflows/CD-Prod-Play-Phone.yml

@@ -22,7 +22,6 @@ jobs:
         with:
           java-version: '17'
           distribution: 'temurin'
-          cache: gradle
 
       - name: Set up Flutter
         uses: subosito/flutter-action@v2

.github/workflows/CD-Prod-Play-WearOS.yml

@@ -22,7 +22,6 @@ jobs:
         with:
           java-version: '17'
           distribution: 'temurin'
-          cache: gradle
 
       - name: Set up Flutter
         uses: subosito/flutter-action@v2

.github/workflows/CI.yml

@@ -132,7 +132,6 @@ jobs:
         with:
           java-version: '17'
           distribution: 'temurin'
-          cache: gradle
 
       - name: Set up Flutter
         uses: subosito/flutter-action@v2
@@ -188,7 +187,6 @@ jobs:
         with:
           java-version: '17'
           distribution: 'temurin'
-          cache: gradle
 
       - name: Set up Flutter
         uses: subosito/flutter-action@v2

android/app/build.gradle.kts

@@ -0,0 +1,85 @@
+import java.util.Properties
+import java.io.FileInputStream
+
+plugins {
+    id("com.android.application")
+    // START: FlutterFire Configuration
+    id("com.google.gms.google-services")
+    // END: FlutterFire Configuration
+    id("kotlin-android")
+    // The Flutter Gradle Plugin must be applied after the Android and Kotlin Gradle plugins.
+    id("dev.flutter.flutter-gradle-plugin")
+}
+
+val keystoreProperties = Properties()
+val keystorePropertiesFile = rootProject.file("key.properties")
+if (keystorePropertiesFile.exists()) {
+    keystoreProperties.load(FileInputStream(keystorePropertiesFile))
+}
+
+android {
+    namespace = "com.aadishsamir.shopsync"
+    compileSdk = flutter.compileSdkVersion
+    ndkVersion = flutter.ndkVersion
+
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_1_8
+        targetCompatibility = JavaVersion.VERSION_1_8
+    }
+
+    kotlinOptions {
+        jvmTarget = "1.8"
+    }
+
+    signingConfigs {
+        if (keystorePropertiesFile.exists()) {
+            register("release") {
+                keyAlias = keystoreProperties["keyAlias"] as String
+                keyPassword = keystoreProperties["keyPassword"] as String
+                storeFile = keystoreProperties["storeFile"]?.let { file(it.toString()) }
+                storePassword = keystoreProperties["storePassword"] as String
+            }
+        }
+    }
+
+    defaultConfig {
+        applicationId = "com.aadishsamir.shopsync"
+        minSdk = 29
+        targetSdk = 35
+
+        // Enable Credential Manager for Google Sign-In
+        manifestPlaceholders["credentialManagerEnabled"] = true
+    }
+
+    flavorDimensions.add("platform")
+    productFlavors {
+        create("phone") {
+            val phoneBaseVersionCode = 300000000
+            val phoneVersionCode = 7
+            dimension = "platform"
+            manifestPlaceholders.clear()
+            versionName = "5.0.2-phone"
+            versionCode = phoneBaseVersionCode + phoneVersionCode
+        }
+        create("wear") {
+            val wearBaseVersionCode = 400000000
+            val wearVersionCode = 5
+            manifestPlaceholders.clear()
+            dimension = "platform"
+            versionName = "1.2.3-wear"
+            versionCode = wearBaseVersionCode + wearVersionCode
+        }
+    }
+
+    buildTypes {
+        named("release") {
+            if (keystorePropertiesFile.exists()) {
+                signingConfig = signingConfigs.getByName("release")
+            }
+        }
+    }
+}
+
+flutter {
+    source = "../.."
+}

android/build.gradle.kts

@@ -0,0 +1,18 @@
+allprojects {
+    repositories {
+        google()
+        mavenCentral()
+    }
+}
+
+rootProject.layout.buildDirectory.set(file("../build"))
+subprojects {
+    project.layout.buildDirectory.set(file("${rootProject.layout.buildDirectory.get()}/${project.name}"))
+}
+subprojects {
+    project.evaluationDependsOn(":app")
+}
+
+tasks.register<Delete>("clean") {
+    delete(rootProject.layout.buildDirectory)
+}

android/settings.gradle.kts

@@ -0,0 +1,28 @@
+pluginManagement {
+    val flutterSdkPath: String = run {
+        val properties = java.util.Properties()
+        file("local.properties").inputStream().use { properties.load(it) }
+        val flutterSdkPath = properties.getProperty("flutter.sdk")
+        requireNotNull(flutterSdkPath) { "flutter.sdk not set in local.properties" }
+        flutterSdkPath
+    }
+
+    includeBuild("$flutterSdkPath/packages/flutter_tools/gradle")
+
+    repositories {
+        google()
+        mavenCentral()
+        gradlePluginPortal()
+    }
+}
+
+plugins {
+    id("dev.flutter.flutter-plugin-loader") version "1.0.0"
+    id("com.android.application") version "8.6.0" apply false
+    // START: FlutterFire Configuration
+    id("com.google.gms.google-services") version "4.3.15" apply false
+    // END: FlutterFire Configuration
+    id("org.jetbrains.kotlin.android") version "2.1.21" apply false
+}
+
+include(":app")