/\*-------------------------------------------------------------------------------------------\*\*

\*\* PROGRAM: D0AE.SAS

\*\*

\*\* CREATED: NOVEMBER 2016

\*\*

\*\* PURPOSE: CREATE SDTM AE DATASET

\*\*

\*\* PROGRAMMER: A.CHANG

\*\*

\*\* INPUT: RAWLIB.AE

\*\*

\*\* OUTPUT: SDTMLIB.AE

\*\*

\*\* PROTOCOL: PROD-124

\*\*

\*\* MODIFIED: DATE BY NOTE

\*\* ---------- ---------- -----------------------------------------

\*\*

\*\*-------------------------------------------------------------------------------------------\*\*

\*\* PROGRAMMED USING SAS VERSION 9.3 \*\*

\*\*-------------------------------------------------------------------------------------------\*\*/

%include msetup ;

%let printme = 1 ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* BRING IN ORIGINAL ADVERSE EVENTS DATA \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

**proc** **sort** data=rawlib.ae

out=ae ;

by patid seq ;

where aeterm ne '' ;

**run** ;

\*\* NOTE: THERE IS A DATA ISSUE IN RAWLIB.AE WHERE AEANYCD=0 BUT THERE IS \*\*;

\*\* AN AE RECORDED. DECIDED TO INCLUDE THIS OBS BY SUBSETTING \*\*;

\*\* USING AETERM RATHER THAN AEANYCD. (PATID = 115) \*\*;

**data** ae (keep= studyid domain &pat aeseq aeterm aedecod aebodsys aesevn aesev aereln aerel

aestdtc aeendtc aeacn aeacnoth aeser) ;

attrib

studyid length = $**8** label = 'Study Identifier '

domain length = $**2** label = 'Domain Abbreviation '

&pat length = $**16** label = 'Unique Subject Identifier '

aeseq length = **3** label = 'Sequence Number '

aeterm length = $**120** label = 'Reported Term for the Adverse Event '

aedecod length = $**100** label = 'Dictionary-Derived Term '

aebodsys length = $**100** label = 'Body System or Organ Class '

aesevn length = **3** label = 'Severity/Intensity (N) '

aesev length = $**20** label = 'Severity/Intensity '

aereln length = **3** label = 'Causality (N) '

aerel length = $**20** label = 'Causality '

aestdtc length = $**30** label = 'Start Date/Time of Adverse Event '

aeendtc length = $**30** label = 'End Date/Time of Adverse Event '

aeacn length = $**20** label = 'Action Taken with Study Treatment '

aeacnoth length = $**20** label = 'Other Action Taken '

aeser length = $**1** label = 'Serious Event '

;

set ae (rename=(seq=aeseq aesoc=aebodsys aesevcd=aesevn aerelcd=aereln)

drop= pageno e\_stat aeanycd);

\*\*-- ASSIGN REQUIRED SDTM VARIABLES --\*\*;

studyid = compress(proto) ;

domain = 'AE' ;

&pat = studyid || '-' || '0' || put(inv\_no,**2.**) || '-' || put(patid,**3.**) ;

\*\*-- MAP AESEV ACCORDING TO CRF --\*\*;

if aesevn = **1** then aesev = 'MILD' ;

else if aesevn = **2** then aesev = 'MODERATE' ;

else if aesevn = **3** then aesev = 'SEVERE' ;

else if aesevn = **4** then aesev = 'LIFE-THREATENING' ;

else put "WARN" "ING: UNEXPECTED AESEVCD " aesevn= ;

\*\*-- MAP AEREL ACCORDING TO CRF --\*\*;

if aereln = **1** then aerel = 'UNRELATED' ;

else if aereln = **2** then aerel = 'POSSIBLY' ;

else if aereln = **3** then aerel = 'PROBABLY' ;

else if aereln = **4** then aerel = 'DEFINITELY' ;

else put "WARN" "ING: UNEXPECTED AERELCD " aereln= ;

\*\*-- AESTDTC, AEENDTC IN ISO8601 --\*\*;

aestdtc = put(aestdt,yymmdd10.) || 'T' || put(aesttm,tod5.2) ;

aeendtc = put(aeendt,yymmdd10.) || 'T' || put(aeentm,tod5.2) ;

\*\*-- AEACN, AEACNOTH, AESER --\*\*;

if aetxcd = **1** then aeacnoth = 'Treatment' ;

if aeprencd = **2** and aeacnoth = '' then

do ;

aeacn = 'DRUG WITHDRAWN' ;

aeacnoth = 'PROD stopped' ;

end ;

else if aeprencd = **2** and aeacnoth ne '' then

do ;

aeacn = 'DRUG WITHDRAWN' ;

aeacnoth = aeacnoth || ', ' || 'PROD stopped' ;

end ;

if aedccd = **3** and aeacnoth = '' then aeacnoth = 'Discontinued trial' ;

else if aedccd = **3** and aeacnoth ne '' then

aeacnoth = aeacnoth || ', ' || 'Discontinued trial' ;

if aesercd = **.** then aeser = 'N' ;

else if aesercd = **4** and aeacnoth = '' then

do ;

aeacnoth = 'SAE Reported' ;

aeser = 'Y' ;

end ;

else if aesercd = **4** and aeacnoth ne '' then

do ;

aeacnoth = aeacnoth || ', ' || 'SAE Reported' ;

aeser = 'Y' ;

end ;

if aenoatcd = **0** then

do ;

if aeacnoth ne '' then put "WARN" "ING: CHECK ACTIONS TAKEN AE DATA." ;

aeacnoth = 'None' ;

end ;

run ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* OUTPUT SDTM AE DATASET \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

options replace ;

**proc** **sql** ;

create table sdtmlib.ae (label='Adverse Events') as

select studyid, domain, &pat, aeseq, aeterm, aedecod, aebodsys, aesevn, aesev

, aereln, aerel, aestdtc, aeendtc, aeacn, aeacnoth, aeser

from ae

order by &pat ;

**quit** ;

options noreplace ;

title "CHECK ADVERSE EVENTS SDTM DATASET" ;

**proc** **print** data=sdtmlib.ae ;

where &printme ;

**run** ;

title ;

/\*-------------------------------------------------------------------------------------------\*\*

\*\* PROGRAM: D0DM.SAS

\*\*

\*\* CREATED: NOVEMBER 2016

\*\*

\*\* PURPOSE: CREATE SDTM DM DATASET

\*\*

\*\* PROGRAMMER: A.CHANG

\*\*

\*\* INPUT: RAWLIB.DEMO

\*\*

\*\* OUTPUT: SDTMLIB.DM

\*\*

\*\* PROTOCOL: PROD-124

\*\*

\*\* MODIFIED: DATE BY NOTE

\*\* ---------- ---------- -----------------------------------------

\*\*

\*\*-------------------------------------------------------------------------------------------\*\*

\*\* PROGRAMMED USING SAS VERSION 9.3 \*\*

\*\*-------------------------------------------------------------------------------------------\*\*/

%include msetup ;

%let printme = 1 ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* BRING IN ORIGINAL DEMOGRAPHICS DATA \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* NOTE: MODIFIED MAGE.SAS IN ORDER TO DISPLAY AGE TO THE TENTH \*\*;

\*\* DECIMAL PLACE AS REQUIRED BY MOCKUPS \*\*;

**data** dm (keep= studyid domain &pat subjid country rfstdtc rfendtc siteid brthdtc age ageu sex race) ;

attrib

studyid length = $**8** label = 'Study Identifier '

domain length = $**2** label = 'Domain Abbreviation '

&pat length = $**16** label = 'Unique Subject Identifier '

subjid length = $**7** label = 'Subject Identifier for the Study '

country length = $**3** label = 'Country '

rfstdtc length = $**10** label = 'Subject Reference Start Date/Time '

rfendtc length = $**10** label = 'Subject Reference End Date/Time '

siteid length = $**3** label = 'Study Site Identifier '

brthdtc length = $**10** label = 'Date/Time of Birth '

age length = **3** label = 'Age '

ageu length = $**5** label = 'Age Units '

sex length = $**1** label = 'Sex '

race length = $**30** label = 'Race '

;

set rawlib.demo ;

\*\*-- ASSIGN REQUIRED SDTM VARIABLES --\*\*;

studyid = compress(proto) ;

domain = 'DM' ;

siteid = '0' || put(inv\_no,**2.**) ;

subjid = siteid || '-' || put(patid,**3.**) ;

&pat = studyid || '-' || subjid ;

rfstdtc = put(icdt,mmddyy10.) ;

rfendtc = put(icdt,mmddyy10.) ;

\*\*-- SET COUNTRY --\*\*;

country = 'USA' ;

\*\*-- DERIVE AGE --\*\*;

brthdtc = put(birthdt,mmddyy10.) ;

%***mage***(indate=icdt,dobvar=birthdt)

\*agechk = (icdt-birthdt)/365.25 ;

ageu = 'YEARS' ;

run ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* MERGE WITH ARM AND ARMCD FROM EXPOSURE DATASET \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

**data** ex ;

set rawlib.exposure ;

length &pat $**16** ;

&pat = compress(proto) || '-' || '0' || put(inv\_no,**2.**) || '-' || put(patid,**3.**) ;

run ;

**proc** **sort** data=ex nodupkey

out=ex (keep= usubjid cohort);

by &pat ;

**run** ;

**data** dm (drop= cohort) ;

attrib

armcd length = $**1** label = 'Planned Arm Code '

arm length = $**60** label = 'Description of Planned Arm '

;

merge dm (in=indm)

ex ;

by &pat ;

armcd = put(cohort,**1.**) ;

if armcd = '1' then arm = 'Bag in Infusion 1 / Bottle in Infusion 2' ;

else if armcd = '2' then arm = 'Bottle in Infusion 1 / Bag in Infusion 2' ;

if indm ;

run ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* OUTPUT SDTM DM DATASET \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

options replace ;

**proc** **sql** ;

create table sdtmlib.dm (label='Demography') as

select studyid, domain, &pat, subjid, country, rfstdtc, rfendtc, siteid

, brthdtc, age, ageu, sex, race, armcd, arm

from dm

order by &pat ;

**quit** ;

options noreplace ;

title "CHECK DEMOGRAPHY SDTM DATASET" ;

**proc** **print** data=sdtmlib.dm ;

where &printme ;

**run** ;

title ;

/\*-------------------------------------------------------------------------------------------\*\*

\*\* PROGRAM: D0SUPPDM.SAS

\*\*

\*\* CREATED: NOVEMBER 2016

\*\*

\*\* PURPOSE: CREATE SDTM SUPPDM DATASET

\*\*

\*\* PROGRAMMER: A.CHANG

\*\*

\*\* INPUT: RAWLIB.DEMO

\*\*

\*\* OUTPUT: SDTMLIB.SUPPDM

\*\*

\*\* PROTOCOL: PROD-124

\*\*

\*\* MODIFIED: DATE BY NOTE

\*\* ---------- ---------- -----------------------------------------

\*\*

\*\*-------------------------------------------------------------------------------------------\*\*

\*\* PROGRAMMED USING SAS VERSION 9.3 \*\*

\*\*-------------------------------------------------------------------------------------------\*\*/

%include msetup ;

%let printme = 1 ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* BRING IN ORIGINAL DEMOGRAPHICS DATA \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

**data** suppdm (keep= studyid rdomain &pat qnam qlabel qval qorig) ;

attrib

studyid length = $**8** label = 'Study Identifier '

rdomain length = $**2** label = 'Related Domain Abbreviation '

&pat length = $**16** label = 'Unique Subject Identifier '

qnam length = $**8** label = 'Qualifier Variable Name '

qlabel length = $**40** label = 'Qualifier Variable Label '

qval length = $**200** label = 'Data Value '

qorig length = $**10** label = 'Origin '

;

set rawlib.demo ;

\*\*-- ASSIGN REQUIRED SDTM VARIABLES --\*\*;

studyid = compress(proto) ;

rdomain = 'DM' ;

&pat = studyid || '-' || '0' || put(inv\_no,**2.**) || '-' || put(patid,**3.**) ;

\*\*-- RACEOTH --\*\*;

qnam = 'RACEOTH' ;

qlabel = 'Race, Other' ;

if race = 'OTHER' then qval = raceoth ;

qorig = pageno ;

run ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* OUTPUT SDTM DM DATASET \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

options replace ;

**proc** **sql** ;

create table sdtmlib.suppdm (label='Supplemental Qualifiers DM') as

select studyid, rdomain, &pat, qnam, qlabel, qval, qorig

from suppdm

order by &pat ;

**quit** ;

options noreplace ;

title "CHECK SUPPLEMENTAL QUALIFIERS DM DATASET" ;

**proc** **print** data=sdtmlib.suppdm ;

where &printme ;

**run** ;

title ;

/\*-------------------------------------------------------------------------------------------\*\*

\*\* PROGRAM: D0VS.SAS

\*\*

\*\* CREATED: NOVEMBER 2016

\*\*

\*\* PURPOSE: CREATE SDTM VS DATASET

\*\*

\*\* PROGRAMMER: A.CHANG

\*\*

\*\* INPUT: RAWLIB.VITAL, RAWLIB.VITALTPT

\*\*

\*\* OUTPUT: SDTMLIB.VS

\*\*

\*\* PROTOCOL: PROD-124

\*\*

\*\* MODIFIED: DATE BY NOTE

\*\* ---------- ---------- -----------------------------------------

\*\*

\*\*-------------------------------------------------------------------------------------------\*\*

\*\* PROGRAMMED USING SAS VERSION 9.3 \*\*

\*\*-------------------------------------------------------------------------------------------\*\*/

%include msetup ;

%let printme = 1 ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* BRING IN ORIGINAL VITAL SIGNS DATA \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

**data** vs (drop= inv\_no patid proto seq vstptm) ;

attrib

studyid length = $**8** label = 'Study Identifier '

domain length = $**2** label = 'Domain Abbreviation '

&pat length = $**16** label = 'Unique Subject Identifier '

visitnum length = **3** label = 'Visit Number '

visit length = $**12** label = 'Visit Name '

vstpt length = $**40** label = 'Planned Time Point Name '

;

set rawlib.vital (in=a drop= pageno e\_stat weightun heightun)

rawlib.vitaltpt (in=b rename=(vstacttm=vsacttm) drop= pageno e\_stat) ;

\*\*-- ASSIGN REQUIRED SDTM VARIABLES --\*\*;

studyid = proto ;

domain = 'VS' ;

&pat = studyid || '-' || '0' || put(inv\_no,**2.**) || '-' || put(patid,**3.**) ;

\*\*-- ASSIGN VSTPT, VISIT AND VISITNUM --\*\*;

if a then

do ;

if visit = 'STUDY DAY 1' then

do ;

vstpt = 'SCREENING & BASELINE' ;

visitnum = **1** ;

end ;

else if visit = 'STUDY DAY 2' then

do ;

vstpt = 'STUDY DAY 2' ;

visitnum = **2** ;

end ;

end ;

if b then

do ;

vstpt = vstptm ;

visitnum = **1** ;

visit = 'STUDY DAY 1' ;

tptfl = 'Y' ;

end ;

run ;

**proc** **sort** data=vs ;

by usubjid visitnum vsacttm ;

**run** ;

**data** vs (drop= date tptfl vsacttm vsdt) ;

attrib

vsdtc length = $**30** label = 'Date/Time of Measurements '

;

set vs ;

\*\*-- ASSIGN STUDY DAY 1 DATE TO VITALTPT DATA --\*\*;

retain date **.** ;

if vstpt = 'SCREENING & BASELINE' then date = vsdt ;

if tptfl = 'Y' then vsdt = date ;

\*\*-- COMBINE VISIT DATE/TIME IN ISO 8601 FORMAT --\*\*;

vsdtc = put(vsdt,yymmdd10.) || 'T' || put(vsacttm,tod5.2) ;

run ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* RESTRUCTURE VITAL SIGNS DATA (ONE RECORD FOR EACH TEST RESULT) \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

**data** vs (keep= studyid domain &pat visitnum visit vsdtc vsseq vstpt vstestcd vstest vsorres vsorresu vsstresc vsstresn vsstresu) ;

attrib

vsseq length = **3** label = 'Sequence Number '

vstestcd length = $**8** label = 'Vital Signs Test Short Name '

vstest length = $**40** label = 'Vital Signs Test Name '

vsorres length = $**20** label = 'Result or Finding in Original Units '

vsorresu length = $**20** label = 'Original Units '

vsstresc length = $**10** label = 'Character Result/Finding in Std Format '

vsstresn length = **8** label = 'Numeric Result/Finding in Standard Units '

vsstresu length = $**20** label = 'Standard Units '

;

set vs ;

by usubjid ;

if first.usubjid then vsseq = **0** ;

\*\* OUTPUT FOR PULSE \*\*;

vsseq + **1** ;

vstestcd = 'PULSE' ;

vstest = 'Pulse Rate' ;

vsorres = put(heart,**3.**) ;

vsorresu = 'BEATS/MIN' ;

vsstresc = put(heart,**3.**) ;

vsstresn = heart ;

vsstresu = 'BEATS/MIN' ;

if vsorres ne '' then output ;

\*\* OUTPUT FOR SYSBP \*\*;

vsseq + **1** ;

vstestcd = 'SYSBP' ;

vstest = 'Systolic Blood Pressure' ;

vsorres = put(sysbp,**3.**) ;

vsorresu = 'mmHG' ;

vsstresc = put(sysbp,**3.**) ;

vsstresn = sysbp ;

vsstresu = 'mmHG' ;

if vsorres ne '' then output ;

\*\* OUTPUT FOR DIABP \*\*;

vsseq + **1** ;

vstestcd = 'DIABP' ;

vstest = 'Diastolic Blood Pressure' ;

vsorres = put(diabp,**3.**) ;

vsorresu = 'mmHG' ;

vsstresc = put(diabp,**3.**) ;

vsstresn = diabp ;

vsstresu = 'mmHG' ;

if vsorres ne '' then output ;

\*\* OUTPUT FOR OXYSAT \*\*;

vsseq + **1** ;

vstestcd = 'OXYSAT' ;

vstest = 'Oxygen Saturation' ;

vsorres = put(o2sat,**3.**) ;

vsorresu = '%' ;

vsstresc = put(o2sat,**3.**) ;

vsstresn = o2sat ;

vsstresu = '%' ;

if vsorres ne '' then output ;

\*\* OUTPUT FOR RESP \*\*;

vsseq + **1** ;

vstestcd = 'RESP' ;

vstest = 'Respiratory Rate' ;

vsorres = put(resp,**3.**) ;

vsorresu = 'BREATHS/MIN' ;

vsstresc = put(resp,**3.**) ;

vsstresn = resp ;

vsstresu = 'BREATHS/MIN' ;

if vsorres ne '' then output ;

\*\* OUTPUT FOR TEMP \*\*;

vsseq + **1** ;

vstestcd = 'TEMP' ;

vstest = 'Temperature' ;

vsorres = put(temp,**5.1**) ;

vsorresu = 'F' ;

vsstresc = put(temp,**5.1**) ;

vsstresn = temp ;

vsstresu = 'F' ;

if vsorres ne '' then output ;

\*\* OUTPUT FOR WEIGHT \*\*;

vsseq + **1** ;

vstestcd = 'WEIGHT' ;

vstest = 'Weight' ;

vsorres = put(weight,**6.2**) ;

vsorresu = 'KG' ;

vsstresc = put(weight,**6.2**) ;

vsstresn = weight ;

vsstresu = 'KG' ;

if vsorres ne '' then output ;

\*\* OUTPUT FOR HEIGHT \*\*;

vsseq + **1** ;

vstestcd = 'HEIGHT' ;

vstest = 'Height' ;

vsorres = put(height,**5.1**) ;

vsorresu = 'IN' ;

vsstresc = put(height,**5.1**) ;

vsstresn = height ;

vsstresu = 'IN' ;

if vsorres ne '' then output ;

run ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* CREATE BASELINE FLAG (VSBLFL) \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* NOTE: BASELINE WAS TAKEN TO BE VITALS RECORDED AT 0 MINS OR THE LAST \*\*;

\*\* MEASUREMENT PRIOR TO 0 MINS. \*\*;

**proc** **sort** data=vs

out = vsfl ;

by usubjid vstestcd vsseq ;

where vstpt in ('SCREENING & BASELINE', '-5 min', '0 min') and vsorres ne '' ;

**run** ;

**data** vsfl ;

attrib

vsblfl length = $**1** label = 'Baseline Flag '

;

set vsfl ;

by usubjid vstestcd vsseq ;

if last.vstestcd then vsblfl = 'Y' ;

run ;

**proc** **sort** data=vs ;

by usubjid vstestcd vsseq ;

**run** ;

**data** vs ;

merge vs

vsfl (keep= usubjid vstestcd vsseq vsblfl) ;

by usubjid vstestcd vsseq ;

run ;

**proc** **sort** data=vs ;

by usubjid vsseq ;

**run** ;

\*\*-------------------------------------------------------------------------------\*\*;

\*\* OUTPUT SDTM VS DATASET \*\*;

\*\*-------------------------------------------------------------------------------\*\*;

options replace ;

**proc** **sql** ;

create table sdtmlib.vs (label='Vital Signs') as

select studyid, domain, &pat, visitnum, visit, vsdtc, vsseq, vstpt, vstestcd, vstest

, vsorres, vsorresu, vsstresc, vsstresn, vsstresu, vsblfl

from vs

order by &pat, visitnum, vsseq ;

**quit** ;

options noreplace ;

title "CHECK VITAL SIGNS SDTM DATASET" ;

**proc** **print** data=sdtmlib.vs ;

where &printme ;

**run** ;

title ;