附录A PL/0编译系统源代码

program pl0 ; { version 1.0 oct.1989 }

{ PL/0 compiler with code generation }

const norw = 13; { no. of reserved words }

txmax = 100; { length of identifier table }

nmax = 14; { max. no. of digits in numbers }

al = 10; { length of identifiers }

amax = 2047; { maximum address }

levmax = 3; { maximum depth of block nesting }

cxmax = 200; { size of code array }

type symbol =

( nul,ident,number,plus,minus,times,slash,oddsym,eql,neq,lss,

leq,gtr,geq,lparen,rparen,comma,semicolon,period,becomes,

beginsym,endsym,ifsym,thensym,whilesym,dosym,callsym,constsym,

varsym,procsym,readsym,writesym );{\*保留字集合\*}

alfa = packed array[1..al] of char;{\*\*}

objecttyp = (constant,variable,prosedure);

symset = set of symbol;

fct = ( lit,opr,lod,sto,cal,int,jmp,jpc,red,wrt ); { functions }{\*十条汇编指令\*}

instruction = packed record

f : fct; { function code }

l : 0..levmax; { level }

a : 0..amax; { displacement address }

end;

{ lit 0, a : load constant a

opr 0, a : execute operation a

lod l, a : load variable l,a

sto l, a : store variable l,a

cal l, a : call procedure a at level l

int 0, a : increment t-register by a

jmp 0, a : jump to a

jpc 0, a : jump conditional to a

red l, a : read variable l,a

wrt 0, 0 : write stack-top

}

var ch : char; { last character read }{\*读到的最后一个字符\*}

sym: symbol; { last symbol read }{\*读到的最后一个保留字\*}

id : alfa; { last identifier read }{\*读到的最后一个标识符\*}

num: integer; { last number read }{\*读到的最后一个数字\*}

cc : integer; { character count }{\*字符计数\*}

ll : integer; { line length }{\*行的长度\*}

kk,err: integer;

cx : integer; { code allocation index }{\*代码申请索引？\*}

line: array[1..81] of char;

a : alfa;

code : array[0..cxmax] of instruction;

word : array[1..norw] of alfa;

wsym : array[1..norw] of symbol;

ssym : array[char] of symbol;

mnemonic : array[fct] of

packed array[1..5] of char;

declbegsys, statbegsys, facbegsys : symset;

table : array[0..txmax] of

record

name : alfa;

case kind: objecttyp of

constant : (val:integer );

variable,prosedure: (level,adr: integer )

end;

fin : text; { source program file }

sfile: string; { source program file name }

{\*错误处理程序\*}

procedure error( n : integer );

begin

writeln( '\*\*\*\*', ' ':cc-1, '^', n:2 );{\*最近的几个字符出错\*}

err := err+1{\*记录的错误加一\*}

end; { error }

procedure getsym;

var i,j,k : integer;

procedure getch;

begin

if cc = ll { get character to end of line }{\*如果读到了一行结束就开始读下一行\*}

then begin { read next line }

if eof(fin){\*如果文件结束\*}

then begin

writeln('program incomplete');{\*程序不完整，打印错误然后退出\*}

close(fin);

exit;

end;

ll := 0;

cc := 0;

write(cx:4,' '); { print code address }{\*打印代码行的地址\*}

while not eoln(fin) do{\*一直读到这一行末尾，代码保存到缓冲区\*}

begin

ll := ll+1;{\*行的长度增加1\*}

read(fin,ch);{\*读一个字符\*}

write(ch);

line[ll] := ch{\*写入缓冲区\*}

end;

writeln;

readln(fin);

ll := ll+1;

line[ll] := ' ' { process end-line }

end;

cc := cc+1;

ch := line[cc]{\*从缓冲区里面取字符\*}

end; { getch }

begin { procedure getsym; }

while ch = ' ' do{\*如果读到空格就忽略\*}

getch;{\*\*取字符}

if ch in ['a'..'z']{\*如果\*}

then begin { identifier of reserved word }

k := 0;

repeat

if k < al{\*k小于标识符的最大长度\*}

then begin

k := k+1;

a[k] := ch{\*保存在数组里面\*}

end;

getch

until not( ch in ['a'..'z','0'..'9']);

if k >= kk { kk : last identifier length }

then kk := k

else repeat{\*用空格对其\*}

a[kk] := ' ';

kk := kk-1

until kk = k;

id := a;

i := 1;

j := norw; { binary search reserved word table }{\*norw是保留字的个数\*}

Repeat{\*二分法查找是否为保留字\*}

k := (i+j) div 2;

if id <= word[k]

then j := k-1;

if id >= word[k]

then i := k+1

until i > j;

if i-1 > j

then sym := wsym[k]

else sym := ident{\*设置是否为标识符\*}

end

else if ch in ['0'..'9']{\*读到一个数字\*}

then begin { number }

k := 0;

num := 0;

sym := number;

repeat

num := 10\*num+(ord(ch)-ord('0'));{\*把数字当作一个一个字符进行处理，得到最终的数字\*}

k := k+1;

getch

until not( ch in ['0'..'9']);

if k > nmax{\*读到的数字不能超过规定的最大值\*}

then error(30)

end

else if ch = ':'

then begin

getch;

if ch = '='

then begin

sym := becomes;{\*标记为赋值语句\*}

getch

end

else sym := nul {\*赋值语句无效\*}

end

else if ch = '<'

then begin

getch;

if ch = '='

then begin

sym := leq;{\*标记为小于等于\*}

getch

end

else if ch = '>'

then begin

sym := neq;{\*标记为不等于\*}

getch

end

else sym := lss{\*否则就是小于\*}

end

else if ch = '>'

then begin

getch;

if ch = '='

then begin

sym := geq;{\*标记为大于等于\*}

getch

end

else sym := gtr{\*标记为大于号\*}

end

else begin

sym := ssym[ch];

getch

end

end; { getsym }

{\*生成目标代码\*}

procedure gen( x: fct; y,z : integer ); {\*fct是目标代码指令集\*}

begin

if cx > cxmax{\*生成的代码过长\*}

then begin

writeln('program too long');

close(fin);

exit

end;

with code[cx] do

begin

f := x;{\*指令\*}

l := y;{\*层级\*}

a := z{\*地址\*}

end;

cx := cx+1{\*下一条指令\*}

end; { gen }

procedure test( s1,s2 :symset; n: integer ); {\*测试当前字符是否合法\*}

begin

if not ( sym in s1 ){\*不在合法集合当中\*}

then begin

error(n);{\*报错\*}

s1 := s1+s2;

while not( sym in s1) do

Getsym{\*取下一个字符\*}

end

end; { test }

procedure block( lev,tx : integer; fsys : symset );

var dx : integer; { data allocation index }{\*数据区地址\*}

tx0: integer; { initial table index }{\*初始化表的地址\*}

cx0: integer; { initial code index }{\*初始代码地址\*}

procedure enter( k : objecttyp ); {\*操作符号表\*}

begin { enter object into table }

tx := tx+1;{\*索引加1\*}

with table[tx] do

begin

name := id;{\*写名称\*}

kind := k;{\*写类型\*}

case k of

constant : begin{\*如果是常量\*}

if num > amax{\*超出最大地址\*}

then begin

error(30);{\*报错\*}

num := 0

end;

val := num{\*值记录到符号表\*}

end;

variable : begin{\*变量\*}

level := lev;{\*记录层级\*}

adr := dx;{\*设置索引\*}

dx := dx+1{\*索引加一\*}

end;

prosedure: level := lev;

end

end

end; { enter }

function position ( id : alfa ): integer; {\*在符号表查找层级\*}

var i : integer;

begin

table[0].name := id;

i := tx;

while table[i].name <> id do{\*从最高层循环查找\*}

i := i-1;

position := i{\*返回层级\*}

end; { position }

procedure constdeclaration; {\*处理常量定义\*}

begin

if sym = ident{\*取一个标识符\*}

then begin

getsym;

if sym in [eql,becomes]

then begin

if sym = becomes{\*如果是：=那么就报错\*}

then error(1);

getsym;

if sym = number{\*如果是数字就插入到符号表里\*}

then begin

enter(constant);

getsym

end

else error(2){\*报错\*}

end

else error(3)

end

else error(4)

end; { constdeclaration }

procedure vardeclaration; {\*处理变量声明\*}

begin

if sym = ident{\*如果是标识符\*}

then begin

enter(variable);{\*插入到符号表里\*}

getsym

end

else error(4)

end; { vardeclaration }

procedure listcode;

var i : integer;

begin

for i := cx0 to cx-1 do{\*对所有的指令索引\*}

with code[i] do

writeln( i:4, mnemonic[f]:7,l:3, a:5){\*打印序号、函数指令、层级、地址\*}

end; { listcode }

procedure statement( fsys : symset );{\*处理语句\*}

var i,cx1,cx2: integer;

procedure expression( fsys: symset); {\*处理表达式\*}

var addop : symbol;

procedure term( fsys : symset); {\*处理项\*}

var mulop: symbol ;

procedure factor( fsys : symset );{\*处理因子\*}

var i : integer;

begin

test( facbegsys, fsys, 24 );

while sym in facbegsys do{\*如果是合法字符\*}

begin

if sym = ident{\*如果是标识符\*}

then begin

i := position(id);{\*取层级\*}

if i= 0{\*发现符号表里没有\*}

then error(11){\*报错\*}

else

with table[i] do

case kind of

constant : gen(lit,0,val);{\*生成P-CODE指令，将常量放到栈顶\*}

variable : gen(lod,lev-level,adr);{\*变量放到数据栈栈顶\*}

prosedure: error(21){\*如果是过程名就报错\*}

end;

getsym

end

else if sym = number{\*如果是数字\*}

then begin

if num > amax{\*看是否越界\*}

then begin

error(30);{\*报错\*}

num := 0

end;

gen(lit,0,num);{\*数字放到栈顶\*}

getsym

end

else if sym = lparen{\*如果是左括号\*}

then begin

getsym;{\*取下一个\*}

expression([rparen]+fsys);{\*处理表达式\*}

if sym = rparen{\*如果是右括号\*}

then getsym{\*取下一个字符\*}

else error(22){\*不是右括号就报错\*}

end;

test(fsys,[lparen],23)

end

end; { factor }

begin { procedure term( fsys : symset); {\*先处理因子\*}

var mulop: symbol ; }

factor( fsys+[times,slash]);

while sym in [times,slash] do{\*如果是乘除符号\*}

begin

mulop := sym;{\*记录乘除符号\*}

getsym;

factor( fsys+[times,slash] );{\*继续分析因子\*}

if mulop = times

then gen( opr,0,4 )

else gen( opr,0,5)

end

end; { term }

begin { procedure expression( fsys: symset); {\*处理表达式\*}

var addop : symbol; }

if sym in [plus, minus]{\*如果是加减号\*}

then begin

addop := sym;{\*记录\*}

getsym;

term( fsys+[plus,minus]);{\*继续处理表达式\*}

if addop = minus{\*如果是减号\*}

then gen(opr,0,1)

end

else term( fsys+[plus,minus]);

while sym in [plus,minus] do{\*如果读到加减号后面一定还有项\*}

begin

addop := sym;{\*记录\*}

getsym;

term( fsys+[plus,minus] );{\*继续处理项\*}

if addop = plus

then gen( opr,0,2)

else gen( opr,0,3)

end

end; { expression }

procedure condition( fsys : symset ); {\*条件分析\*}

var relop : symbol;

begin

if sym = oddsym{\*如果是if\*}

then begin

getsym;

expression(fsys);{\*处理表达式\*}

gen(opr,0,6)

end

else begin

expression( [eql,neq,lss,gtr,leq,geq]+fsys);

if not( sym in [eql,neq,lss,leq,gtr,geq])

then error(20)

else begin

relop := sym;

getsym;

expression(fsys);

case relop of{\*判断是>/>=/<=/</<>/=中的哪一个\*}

eql : gen(opr,0,8);

neq : gen(opr,0,9);

lss : gen(opr,0,10);

geq : gen(opr,0,11);

gtr : gen(opr,0,12);

leq : gen(opr,0,13);

end

end

end

end; { condition }

begin { procedure statement( fsys : symset ); {\*处理表语句\*}

var i,cx1,cx2: integer; }

if sym = ident{\*如果是标识符\*}

then begin

i := position(id);{\*取层级\*}

if i= 0{\*在符号表里没找到\*}

then error(11){\*报错\*}

else if table[i].kind <> variable

then begin { giving value to non-variation }{\*类型不是变量\*}

error(12);{\*报错\*}

i := 0

end;

getsym;

if sym = becomes{\*如果是赋值语句\*}

then getsym

else error(13);

expression(fsys);{\*进行表达式分析\*}

if i <> 0

then

with table[i] do

gen(sto,lev-level,adr)

end

else if sym = callsym{\*如果是过程调用\*}

then begin

getsym;

if sym <> ident{\*如果不是标识符\*}

then error(14)

else begin

i := position(id);{\*取层级\*}

if i = 0{\*找不到就报错\*}

then error(11)

else

with table[i] do

if kind = prosedure{\*检查符号表中对应的是否为过程名\*}

then gen(cal,lev-level,adr){\*放到栈顶\*}

else error(15);{\*类型不对就报错\*}

getsym

end

end

else if sym = ifsym{\*如果是if语句\*}

then begin

getsym;

condition([thensym,dosym]+fsys);{\*调用条件判断\*}

if sym = thensym{\*如果是then\*}

then getsym

else error(16);{\*报错\*}

cx1 := cx;

gen(jpc,0,0);{\*生成跳转指令\*}

statement(fsys);{\*分析语句\*}

code[cx1].a := cx

end

else if sym = beginsym{\*如果是复合语句\*}

then begin

getsym;

statement([semicolon,endsym]+fsys);{\*调用处理语句\*}

while sym in ([semicolon]+statbegsys) do

begin

if sym = semicolon{\*如果是分号\*}

then getsym{\*取下一个字符\*}

else error(10);{\*否则报错\*}

statement([semicolon,endsym]+fsys){\*继续处理语句\*}

end;

if sym = endsym{\*如果是end\*}

then getsym{\*取下一个字符\*}

else error(17){\*报错\*}

end

else if sym = whilesym{\*如果是while语句\*}

then begin

cx1 := cx;{\*记录地址\*}

getsym;

condition([dosym]+fsys);{\*当作条件进行分析\*}

cx2 := cx;

gen(jpc,0,0);{\*生成条件跳转指令\*}

if sym = dosym{\*如果是do\*}

then getsym

else error(18);{\*不是do就报错\*}

statement(fsys);{\*处理<语句>\*}

gen(jmp,0,cx1);{\*生成返回到cx1的那条语句的跳转指令\*}

code[cx2].a := cx{\*记录地址\*}

end

else if sym = readsym{\*如果是读语句\*}

then begin

getsym;

if sym = lparen{\*如果是左括号\*}

then

repeat

getsym;

if sym = ident{\*如果是左括号\*}

then begin

i := position(id);{\*获取标识符的层级\*}

if i = 0{\*在符号表里找不到就报错\*}

then error(11)

else if table[i].kind <> variable{\*找到的不是变量也报错\*}

then begin

error(12);

i := 0

end

else with table[i] do

gen(red,lev-level,adr){\*生成P-CODE读指令\*}

end

else error(4);

getsym;

until sym <> comma{\*直到没有读到逗号\*}

else error(40);

if sym <> rparen{\*如果不是右括号就报错\*}

then error(22);

getsym

end

else if sym = writesym{\*如果读到写语句\*}

then begin

getsym;

if sym = lparen{\*读到左括号\*}

then begin

repeat

getsym;

expression([rparen,comma]+fsys);{\*处理表达式\*}

gen(wrt,0,0);{\*生成写指令\*}

until sym <> comma;{\*循环直到不是逗号\*}

if sym <> rparen{\*如果不是右括号就报错\*}

then error(22);

getsym

end

else error(40)

end;

test(fsys,[],19){\*判断当前字符是否是合法字符\*}

end; { statement }

begin { procedure block( lev,tx : integer; fsys : symset );

var dx : integer; /\* data allocation index \*/

tx0: integer; /\*initial table index \*/

cx0: integer; /\* initial code index \*/ }

dx := 3;

tx0 := tx;

table[tx].adr := cx;

gen(jmp,0,0); { jump from declaration part to statement part }{\*无条件跳转\*}

if lev > levmax{\*超过最大层级就报错\*}

then error(32);

repeat

if sym = constsym{\*如果读到const语句\*}

then begin

getsym;

repeat

constdeclaration;{\*将定义的常量插入符号表中\*}

while sym = comma do{\*如果是逗号就一直循环\*}

begin

getsym;

constdeclaration{\*插入\*}

end;

if sym = semicolon{\*如果是分号\*}

then getsym

else error(5)

until sym <> ident

end;

if sym = varsym{\*如果遇到变量声明var\*}

then begin

getsym;

repeat

vardeclaration;{\*将声明的变量名插入符号表\*}

while sym = comma do{\*如果是逗号，说明后面的都是变量，就循环插入\*}

begin

getsym;

vardeclaration

end;

if sym = semicolon{\*遇到分号说明开始下一行\*}

then getsym

else error(5)

until sym <> ident;

end;

while sym = procsym do{\*如果是过程调用语句\*}

begin

getsym;

if sym = ident{\*如果是标识符\*}

then begin

enter(prosedure);{\*登陆符号表\*}

getsym

end

else error(4);

if sym = semicolon{\*如果是分号\*}

then getsym

else error(5);{\*不是分号就报错\*}

block(lev+1,tx,[semicolon]+fsys);{\*编译过程，循环调用，注意层级加一\*}

if sym = semicolon{\*如果是分号\*}

then begin

getsym;

test( statbegsys+[ident,procsym],fsys,6){\*测试当前字符是否是合法字符\*}

end

else error(5)

end;

test( statbegsys+[ident],declbegsys,7){\*检查当前字符是否合法\*}

until not ( sym in declbegsys );

code[table[tx0].adr].a := cx; { back enter statement code's start adr. }

with table[tx0] do

begin

adr := cx; { code's start address } {\*生成的指令的地址\*}

end;

cx0 := cx;

gen(int,0,dx); { topstack point to operation area }

statement( [semicolon,endsym]+fsys);

gen(opr,0,0); { return }

test( fsys, [],8 );

listcode;{\*列出指令集\*}

end { block };

procedure interpret; {\*执行P-code指令\*}

const stacksize = 500;{\*设置栈大小为500\*}

var p,b,t: integer; { program-,base-,topstack-register }

i : instruction;{ instruction register }

s : array[1..stacksize] of integer; { data store }

function base( l : integer ): integer;

var b1 : integer;

begin { find base l levels down }

b1 := b;

while l > 0 do

begin

b1 := s[b1];

l := l-1

end;

base := b1

end; { base }

begin {\*初始化操作\*}

writeln( 'START PL/0' );

t := 0;

b := 1;

p := 0;

s[1] := 0;

s[2] := 0;

s[3] := 0;

repeat

i := code[p];{\*取出指令为i的指令\*}

p := p+1;{\*下标加一\*}

with i do

case f of

lit : begin{\*赋值压栈\*}

t := t+1;

s[t]:= a;

end;

opr : case a of { operator }

0 : begin { return }

t := b-1;

p := s[t+3];

b := s[t+2];

end;

1 : s[t] := -s[t];{\*取反\*}

2 : begin{\*栈顶数据和次顶数据相加赋给栈顶\*}

t := t-1;

s[t] := s[t]+s[t+1]

end;

3 : begin{\*栈顶数据和次顶数据相减赋给栈顶\*}

t := t-1;

s[t] := s[t]-s[t+1]

end;

4 : begin{\*栈顶数据和次顶数据相乘赋给栈顶\*}

t := t-1;

s[t] := s[t]\*s[t+1]

end;

5 : begin{\*栈顶数据和次顶数据相除赋给栈顶\*}

t := t-1;

s[t] := s[t]div s[t+1]

end;

6 : s[t] := ord(odd(s[t]));{\*判断栈顶是否为奇数\*}

8 : begin{\*判断栈顶和次顶是否相等\*}

t := t-1;

s[t] := ord(s[t]=s[t+1])

end;

9 : begin{\*判断栈顶和次顶是否不相等\*}

t := t-1;

s[t] := ord(s[t]<>s[t+1])

end;

10: begin{\*判断栈顶是否小于次顶\*}

t := t-1;

s[t] := ord(s[t]< s[t+1])

end;

11: begin{\*判断栈顶是否大于等于次顶\*}

t := t-1;

s[t] := ord(s[t] >= s[t+1])

end;

12: begin{\*判断栈顶是否大于次顶\*}

t := t-1;

s[t] := ord(s[t] > s[t+1])

end;

13: begin{\*判断栈顶是否小于等于次顶\*}

t := t-1;

s[t] := ord(s[t] <= s[t+1])

end;

end;

lod : begin{\*取基地址和相对地址的变量放在栈顶\*}

t := t+1;

s[t] := s[base(l)+a]

end;

sto : begin{\*栈顶数据写入基地址和相对地址的变量\*}

s[base(l)+a] := s[t]; { writeln(s[t]); }

t := t-1

end;

cal : begin { generate new block mark }{\*过程调用\*}

s[t+1] := base(l);

s[t+2] := b;

s[t+3] := p;

b := t+1;

p := a;

end;

int : t := t+a;{\*栈顶指针加a\*}

jmp : p := a;{\*无条件跳转\*}

jpc : begin{\*条件跳转\*}

if s[t] = 0

then p := a;

t := t-1;

end;

red : begin{\*读语句\*}

writeln('??:');

readln(s[base(l)+a]);

end;

wrt : begin{\*写语句\*}

writeln(s[t]);

t := t+1

end

end { with,case }

until p = 0;

writeln('END PL/0');

end; { interpret }

begin { main }

writeln('please input source program file name : ');

readln(sfile);{\*文件名字保存到sfile\*}

assign(fin,sfile);{\*sfile值赋给fin\*}

reset(fin);

for ch := 'A' to ';' do

ssym[ch] := nul;

{\*设置关键词\*}

word[1] := 'begin '; word[2] := 'call ';

word[3] := 'const '; word[4] := 'do ';

word[5] := 'end '; word[6] := 'if ';

word[7] := 'odd '; word[8] := 'procedure ';

word[9] := 'read '; word[10]:= 'then ';

word[11]:= 'var '; word[12]:= 'while ';

word[13]:= 'write ';

wsym[1] := beginsym; wsym[2] := callsym;

wsym[3] := constsym; wsym[4] := dosym;

wsym[5] := endsym; wsym[6] := ifsym;

wsym[7] := oddsym; wsym[8] := procsym;

wsym[9] := readsym; wsym[10]:= thensym;

wsym[11]:= varsym; wsym[12]:= whilesym;

wsym[13]:= writesym;

{\*设置符号\*}

ssym['+'] := plus; ssym['-'] := minus;

ssym['\*'] := times; ssym['/'] := slash;

ssym['('] := lparen; ssym[')'] := rparen;

ssym['='] := eql; ssym[','] := comma;

ssym['.'] := period;

ssym['<'] := lss; ssym['>'] := gtr;

ssym[';'] := semicolon;

{\*设置P-CODE指令\*}

mnemonic[lit] := 'LIT '; mnemonic[opr] := 'OPR ';

mnemonic[lod] := 'LOD '; mnemonic[sto] := 'STO ';

mnemonic[cal] := 'CAL '; mnemonic[int] := 'INT ';

mnemonic[jmp] := 'JMP '; mnemonic[jpc] := 'JPC ';

mnemonic[red] := 'RED '; mnemonic[wrt] := 'WRT ';

{\*初始化\*}

declbegsys := [ constsym, varsym, procsym ];

statbegsys := [ beginsym, callsym, ifsym, whilesym];

facbegsys := [ ident, number, lparen ];

err := 0;

cc := 0;

cx := 0;

ll := 0;

ch := ' ';

kk := al;

getsym;{\*取第一个标识符\*}

block( 0,0,[period]+declbegsys+statbegsys );{\*开始编译\*}

if sym <> period

then error(9);

if err = 0{\*不出错则执行P-CODE代码\*}

then interpret

else write('ERRORS IN PL/0 PROGRAM');

writeln;

close(fin){\*关闭文件\*}

end.

# 附录B Pascal-s编译系统源代码

program PASCALS(INPUT,OUTPUT,PRD,PRR);

{ author:N.Wirth, E.T.H. CH-8092 Zurich,1.3.76 }

{ modified by R.E.Berry

Department of computer studies

UniversitY of Lancaster

Variants ot this program are used on

Data General Nova,Apple,and

Western Digital Microengine machines. }

{ further modified by M.Z.Jin

Department of Computer Science&Engineering BUAA,0ct.1989

}

const nkw = 27; { no. of key words }

alng = 10; { no. of significant chars in identifiers }

llng = 121; { input line length }

emax = 322; { max exponent of real numbers }

emin = -292; { min exponent }

kmax = 15; { max no. of significant digits }

tmax = 100; { size of table }

bmax = 20; { size of block-talbe }

amax = 30; { size of array-table }

c2max = 20; { size of real constant table }

csmax = 30; { max no. of cases }

cmax = 800; { size of code }

lmax = 7; { maximum level }

smax = 600; { size of string-table }

ermax = 58; { max error no. }

omax = 63; { highest order code }

xmax = 32767; { 2\*\*15-1 }

nmax = 32767; { 2\*\*15-1 }

lineleng = 132; { output line length }

linelimit = 200;

stacksize = 1450;

type symbol = ( intcon, realcon, charcon, stringcon,

notsy, plus, minus, times, idiv, rdiv, imod, andsy, orsy,

eql, neq, gtr, geq, lss, leq,

lparent, rparent, lbrack, rbrack, comma, semicolon, period,

colon, becomes, constsy, typesy, varsy, funcsy,

procsy, arraysy, recordsy, programsy, ident,

beginsy, ifsy, casesy, repeatsy, whilesy, forsy,

endsy, elsesy, untilsy, ofsy, dosy, tosy, downtosy, thensy);

index = -xmax..+xmax;

alfa = packed array[1..alng]of char;

objecttyp = (konstant, vvariable, typel, prozedure, funktion );

types = (notyp, ints, reals, bools, chars, arrays, records );

symset = set of symbol;

typset = set of types;

item = record

typ: types;

ref: index;

end;

order = packed record

f: -omax..+omax;

x: -lmax..+lmax;

y: -nmax..+nmax

end;

var ch: char; { last character read from source program }

rnum: real; { real number from insymbol }

inum: integer; { integer from insymbol }

sleng: integer; { string length }

cc: integer; { character counter }

lc: integer; { program location counter }

ll: integer; { length of current line }

errpos: integer;

t,a,b,sx,c1,c2:integer; { indices to tables }

iflag, oflag, skipflag, stackdump, prtables: boolean;

sy: symbol; { last symbol read by insymbol }

errs: set of 0..ermax;

id: alfa; { identifier from insymbol }

progname: alfa;

stantyps: typset;

constbegsys, typebegsys, blockbegsys, facbegsys, statbegsys: symset;

line: array[1..llng] of char;

key: array[1..nkw] of alfa;

ksy: array[1..nkw] of symbol;

sps: array[char]of symbol; { special symbols }

display: array[0..lmax] of integer;

tab: array[0..tmax] of { indentifier lable }

packed record

name: alfa;

link: index;

obj: objecttyp;

typ: types;

ref: index;

normal: boolean;

lev: 0..lmax;

adr: integer

end;

atab: array[1..amax] of { array-table }

packed record

inxtyp,eltyp: types;

elref,low,high,elsize,size: index

end;

btab: array[1..bmax] of { block-table }

packed record

last, lastpar, psize, vsize: index

end;

stab: packed array[0..smax] of char; { string table }

rconst: array[1..c2max] of real;

code: array[0..cmax] of order;

psin,psout,prr,prd:text; { default in pascal p }

inf, outf, fprr: string;

procedure errormsg;

var k : integer;

msg: array[0..ermax] of alfa;

begin

msg[0] := 'undef id '; msg[1] := 'multi def ';

msg[2] := 'identifier'; msg[3] := 'program ';

msg[4] := ') '; msg[5] := ': ';

msg[6] := 'syntax '; msg[7] := 'ident,var ';

msg[8] := 'of '; msg[9] := '( ';

msg[10] := 'id,array '; msg[11] := '( ';

msg[12] := '] '; msg[13] := '.. ';

msg[14] := '; '; msg[15] := 'func. type';

msg[16] := '= '; msg[17] := 'boolean ';

msg[18] := 'convar typ'; msg[19] := 'type ';

msg[20] := 'prog.param'; msg[21] := 'too big ';

msg[22] := '. '; msg[23] := 'type(case)';

msg[24] := 'character '; msg[25] := 'const id ';

msg[26] := 'index type'; msg[27] := 'indexbound';

msg[28] := 'no array '; msg[29] := 'type id ';

msg[30] := 'undef type'; msg[31] := 'no record ';

msg[32] := 'boole type'; msg[33] := 'arith type';

msg[34] := 'integer '; msg[35] := 'types ';

msg[36] := 'param type'; msg[37] := 'variab id ';

msg[38] := 'string '; msg[39] := 'no.of pars';

msg[40] := 'real numbr'; msg[41] := 'type ';

msg[42] := 'real type '; msg[43] := 'integer ';

msg[44] := 'var,const '; msg[45] := 'var,proc ';

msg[46] := 'types(:=) '; msg[47] := 'typ(case) ';

msg[48] := 'type '; msg[49] := 'store ovfl';

msg[50] := 'constant '; msg[51] := ':= ';

msg[52] := 'then '; msg[53] := 'until ';

msg[54] := 'do '; msg[55] := 'to downto ';

msg[56] := 'begin '; msg[57] := 'end ';

msg[58] := 'factor';

writeln(psout);

writeln(psout,'key words');

k := 0;

while errs <> [] do

begin

while not( k in errs )do k := k + 1;

writeln(psout, k, ' ', msg[k] );

errs := errs - [k]

end { while errs }

end { errormsg } ;

procedure endskip;

begin { underline skipped part of input }

while errpos < cc do

begin

write( psout, '-');

errpos := errpos + 1

end;

skipflag := false

end { endskip };

procedure nextch; { read next character; process line end }

begin

if cc = ll

then begin

if eof( psin )

then begin

writeln( psout );

writeln( psout, 'program incomplete' );

errormsg;

exit;

end;

if errpos <> 0

then begin

if skipflag then endskip;

writeln( psout );

errpos := 0

end;

write( psout, lc: 5, ' ');

ll := 0;

cc := 0;

while not eoln( psin ) do

begin

ll := ll + 1;

read( psin, ch );

write( psout, ch );

line[ll] := ch

end;

ll := ll + 1;

readln( psin );

line[ll] := ' ';

writeln( psout );

end;

cc := cc + 1;

ch := line[cc];

end { nextch };

procedure error( n: integer );

begin

if errpos = 0

then write ( psout, '\*\*\*\*' );

if cc > errpos

then begin

write( psout, ' ': cc-errpos, '^', n:2);

errpos := cc + 3;

errs := errs +[n]

end

end { error };

procedure fatal( n: integer );

var msg : array[1..7] of alfa;

begin

writeln( psout );

errormsg;

msg[1] := 'identifier'; msg[2] := 'procedures';

msg[3] := 'reals '; msg[4] := 'arrays ';

msg[5] := 'levels '; msg[6] := 'code ';

msg[7] := 'strings ';

writeln( psout, 'compiler table for ', msg[n], ' is too small');

exit; {terminate compilation }

end { fatal };

procedure insymbol; {reads next symbol}

label 1,2,3;

var i,j,k,e: integer;

procedure readscale;

var s,sign: integer;

begin

nextch;

sign := 1;

s := 0;

if ch = '+'

then nextch

else if ch = '-'

then begin

nextch;

sign := -1

end;

if not(( ch >= '0' )and (ch <= '9' ))

then error( 40 )

else repeat

s := 10\*s + ord( ord(ch)-ord('0'));

nextch;

until not(( ch >= '0' ) and ( ch <= '9' ));

e := s\*sign + e

end { readscale };

procedure adjustscale;

var s : integer;

d, t : real;

begin

if k + e > emax

then error(21)

else if k + e < emin

then rnum := 0

else begin

s := abs(e);

t := 1.0;

d := 10.0;

repeat

while not odd(s) do

begin

s := s div 2;

d := sqr(d)

end;

s := s - 1;

t := d \* t

until s = 0;

if e >= 0

then rnum := rnum \* t

else rnum := rnum / t

end

end { adjustscale };

procedure options;

procedure switch( var b: boolean );

begin

b := ch = '+';

if not b

then if not( ch = '-' )

then begin { print error message }

while( ch <> '\*' ) and ( ch <> ',' ) do

nextch;

end

else nextch

else nextch

end { switch };

begin { options }

repeat

nextch;

if ch <> '\*'

then begin

if ch = 't'

then begin

nextch;

switch( prtables )

end

else if ch = 's'

then begin

nextch;

switch( stackdump )

end;

end

until ch <> ','

end { options };

begin { insymbol }

1: while( ch = ' ' ) or ( ch = chr(9) ) do

nextch; { space & htab }

case ch of

'a','b','c','d','e','f','g','h','i',

'j','k','l','m','n','o','p','q','r',

's','t','u','v','w','x','y','z':

begin { identifier of wordsymbol }

k := 0;

id := ' ';

repeat

if k < alng

then begin

k := k + 1;

id[k] := ch

end;

nextch

until not((( ch >= 'a' ) and ( ch <= 'z' )) or (( ch >= '0') and (ch <= '9' )));

i := 1;

j := nkw; { binary search }

repeat

k := ( i + j ) div 2;

if id <= key[k]

then j := k - 1;

if id >= key[k]

then i := k + 1;

until i > j;

if i - 1 > j

then sy := ksy[k]

else sy := ident

end;

'0','1','2','3','4','5','6','7','8','9':

begin { number }

k := 0;

inum := 0;

sy := intcon;

repeat

inum := inum \* 10 + ord(ch) - ord('0');

k := k + 1;

nextch

until not (( ch >= '0' ) and ( ch <= '9' ));

if( k > kmax ) or ( inum > nmax )

then begin

error(21);

inum := 0;

k := 0

end;

if ch = '.'

then begin

nextch;

if ch = '.'

then ch := ':'

else begin

sy := realcon;

rnum := inum;

e := 0;

while ( ch >= '0' ) and ( ch <= '9' ) do

begin

e := e - 1;

rnum := 10.0 \* rnum + (ord(ch) - ord('0'));

nextch

end;

if e = 0

then error(40);

if ch = 'e'

then readscale;

if e <> 0 then adjustscale

end

end

else if ch = 'e'

then begin

sy := realcon;

rnum := inum;

e := 0;

readscale;

if e <> 0

then adjustscale

end;

end;

':':

begin

nextch;

if ch = '='

then begin

sy := becomes;

nextch

end

else sy := colon

end;

'<':

begin

nextch;

if ch = '='

then begin

sy := leq;

nextch

end

else

if ch = '>'

then begin

sy := neq;

nextch

end

else sy := lss

end;

'>':

begin

nextch;

if ch = '='

then begin

sy := geq;

nextch

end

else sy := gtr

end;

'.':

begin

nextch;

if ch = '.'

then begin

sy := colon;

nextch

end

else sy := period

end;

'''':

begin

k := 0;

2: nextch;

if ch = ''''

then begin

nextch;

if ch <> ''''

then goto 3

end;

if sx + k = smax

then fatal(7);

stab[sx+k] := ch;

k := k + 1;

if cc = 1

then begin { end of line }

k := 0;

end

else goto 2;

3: if k = 1

then begin

sy := charcon;

inum := ord( stab[sx] )

end

else if k = 0

then begin

error(38);

sy := charcon;

inum := 0

end

else begin

sy := stringcon;

inum := sx;

sleng := k;

sx := sx + k

end

end;

'(':

begin

nextch;

if ch <> '\*'

then sy := lparent

else begin { comment }

nextch;

if ch = '$'

then options;

repeat

while ch <> '\*' do nextch;

nextch

until ch = ')';

nextch;

goto 1

end

end;

'{':

begin

nextch;

if ch = '$'

then options;

while ch <> '}' do

nextch;

nextch;

goto 1

end;

'+', '-', '\*', '/', ')', '=', ',', '[', ']', ';':

begin

sy := sps[ch];

nextch

end;

'$','"' ,'@', '?', '&', '^', '!':

begin

error(24);

nextch;

goto 1

end

end { case }

end { insymbol };

procedure enter(x0:alfa; x1:objecttyp; x2:types; x3:integer );

begin

t := t + 1; { enter standard identifier }

with tab[t] do

begin

name := x0;

link := t - 1;

obj := x1;

typ := x2;

ref := 0;

normal := true;

lev := 0;

adr := x3;

end

end; { enter }

procedure enterarray( tp: types; l,h: integer );

begin

if l > h

then error(27);

if( abs(l) > xmax ) or ( abs(h) > xmax )

then begin

error(27);

l := 0;

h := 0;

end;

if a = amax

then fatal(4)

else begin

a := a + 1;

with atab[a] do

begin

inxtyp := tp;

low := l;

high := h

end

end

end { enterarray };

procedure enterblock;

begin

if b = bmax

then fatal(2)

else begin

b := b + 1;

btab[b].last := 0;

btab[b].lastpar := 0;

end

end { enterblock };

procedure enterreal( x: real );

begin

if c2 = c2max - 1

then fatal(3)

else begin

rconst[c2+1] := x;

c1 := 1;

while rconst[c1] <> x do

c1 := c1 + 1;

if c1 > c2

then c2 := c1

end

end { enterreal };

procedure emit( fct: integer );

begin

if lc = cmax

then fatal(6);

code[lc].f := fct;

lc := lc + 1

end { emit };

procedure emit1( fct, b: integer );

begin

if lc = cmax

then fatal(6);

with code[lc] do

begin

f := fct;

y := b;

end;

lc := lc + 1

end { emit1 };

procedure emit2( fct, a, b: integer );

begin

if lc = cmax then fatal(6);

with code[lc] do

begin

f := fct;

x := a;

y := b

end;

lc := lc + 1;

end { emit2 };

procedure printtables;

var i: integer;

o: order;

mne: array[0..omax] of

packed array[1..5] of char;

begin

mne[0] := 'LDA '; mne[1] := 'LOD '; mne[2] := 'LDI ';

mne[3] := 'DIS '; mne[8] := 'FCT '; mne[9] := 'INT ';

mne[10] := 'JMP '; mne[11] := 'JPC '; mne[12] := 'SWT ';

mne[13] := 'CAS '; mne[14] := 'F1U '; mne[15] := 'F2U ';

mne[16] := 'F1D '; mne[17] := 'F2D '; mne[18] := 'MKS ';

mne[19] := 'CAL '; mne[20] := 'IDX '; mne[21] := 'IXX ';

mne[22] := 'LDB '; mne[23] := 'CPB '; mne[24] := 'LDC ';

mne[25] := 'LDR '; mne[26] := 'FLT '; mne[27] := 'RED ';

mne[28] := 'WRS '; mne[29] := 'WRW '; mne[30] := 'WRU ';

mne[31] := 'HLT '; mne[32] := 'EXP '; mne[33] := 'EXF ';

mne[34] := 'LDT '; mne[35] := 'NOT '; mne[36] := 'MUS ';

mne[37] := 'WRR '; mne[38] := 'STO '; mne[39] := 'EQR ';

mne[40] := 'NER '; mne[41] := 'LSR '; mne[42] := 'LER ';

mne[43] := 'GTR '; mne[44] := 'GER '; mne[45] := 'EQL ';

mne[46] := 'NEQ '; mne[47] := 'LSS '; mne[48] := 'LEQ ';

mne[49] := 'GRT '; mne[50] := 'GEQ '; mne[51] := 'ORR ';

mne[52] := 'ADD '; mne[53] := 'SUB '; mne[54] := 'ADR ';

mne[55] := 'SUR '; mne[56] := 'AND '; mne[57] := 'MUL ';

mne[58] := 'DIV '; mne[59] := 'MOD '; mne[60] := 'MUR ';

mne[61] := 'DIR '; mne[62] := 'RDL '; mne[63] := 'WRL ';

writeln(psout);

writeln(psout);

writeln(psout);

writeln(psout,' identifiers link obj typ ref nrm lev adr');

writeln(psout);

for i := btab[1].last to t do

with tab[i] do

writeln( psout, i,' ', name, link:5, ord(obj):5, ord(typ):5,ref:5, ord(normal):5,lev:5,adr:5);

writeln( psout );

writeln( psout );

writeln( psout );

writeln( psout, 'blocks last lpar psze vsze' );

writeln( psout );

for i := 1 to b do

with btab[i] do

writeln( psout, i:4, last:9, lastpar:5, psize:5, vsize:5 );

writeln( psout );

writeln( psout );

writeln( psout );

writeln( psout, 'arrays xtyp etyp eref low high elsz size');

writeln( psout );

for i := 1 to a do

with atab[i] do

writeln( psout, i:4, ord(inxtyp):9, ord(eltyp):5, elref:5, low:5, high:5, elsize:5, size:5);

writeln( psout );

writeln( psout );

writeln( psout );

writeln( psout, 'code:');

writeln( psout );

for i := 0 to lc-1 do

begin

write( psout, i:5 );

o := code[i];

write( psout, mne[o.f]:8, o.f:5 );

if o.f < 31

then if o.f < 4

then write( psout, o.x:5, o.y:5 )

else write( psout, o.y:10 )

else write( psout, ' ' );

writeln( psout, ',' )

end;

writeln( psout );

writeln( psout, 'Starting address is ', tab[btab[1].last].adr:5 )

end { printtables };

procedure block( fsys: symset; isfun: boolean; level: integer );

type conrec = record

case tp: types of

ints, chars, bools : ( i:integer );

reals :( r:real )

end;

var dx : integer ; { data allocation index }

prt: integer ; { t-index of this procedure }

prb: integer ; { b-index of this procedure }

x : integer ;

procedure skip( fsys:symset; n:integer);

begin

error(n);

skipflag := true;

while not ( sy in fsys ) do

insymbol;

if skipflag then endskip

end { skip };

procedure test( s1,s2: symset; n:integer );

begin

if not( sy in s1 )

then skip( s1 + s2, n )

end { test };

procedure testsemicolon;

begin

if sy = semicolon

then insymbol

else begin

error(14);

if sy in [comma, colon]

then insymbol

end;

test( [ident] + blockbegsys, fsys, 6 )

end { testsemicolon };

procedure enter( id: alfa; k:objecttyp );

var j,l : integer;

begin

if t = tmax

then fatal(1)

else begin

tab[0].name := id;

j := btab[display[level]].last;

l := j;

while tab[j].name <> id do

j := tab[j].link;

if j <> 0

then error(1)

else begin

t := t + 1;

with tab[t] do

begin

name := id;

link := l;

obj := k;

typ := notyp;

ref := 0;

lev := level;

adr := 0;

normal := false { initial value }

end;

btab[display[level]].last := t

end

end

end { enter };

function loc( id: alfa ):integer;

var i,j : integer; { locate if in table }

begin

i := level;

tab[0].name := id; { sentinel }

repeat

j := btab[display[i]].last;

while tab[j].name <> id do

j := tab[j].link;

i := i - 1;

until ( i < 0 ) or ( j <> 0 );

if j = 0

then error(0);

loc := j

end { loc } ;

procedure entervariable;

begin

if sy = ident

then begin

enter( id, vvariable );

insymbol

end

else error(2)

end { entervariable };

procedure constant( fsys: symset; var c: conrec );

var x, sign : integer;

begin

c.tp := notyp;

c.i := 0;

test( constbegsys, fsys, 50 );

if sy in constbegsys

then begin

if sy = charcon

then begin

c.tp := chars;

c.i := inum;

insymbol

end

else begin

sign := 1;

if sy in [plus, minus]

then begin

if sy = minus

then sign := -1;

insymbol

end;

if sy = ident

then begin

x := loc(id);

if x <> 0

then

if tab[x].obj <> konstant

then error(25)

else begin

c.tp := tab[x].typ;

if c.tp = reals

then c.r := sign\*rconst[tab[x].adr]

else c.i := sign\*tab[x].adr

end;

insymbol

end

else if sy = intcon

then begin

c.tp := ints;

c.i := sign\*inum;

insymbol

end

else if sy = realcon

then begin

c.tp := reals;

c.r := sign\*rnum;

insymbol

end

else skip(fsys,50)

end;

test(fsys,[],6)

end

end { constant };

procedure typ( fsys: symset; var tp: types; var rf,sz:integer );{\*处理类型\*}

var eltp : types;{\*元素类型\*}

elrf, x : integer;{\*元素位置\*}

elsz, offset, t0, t1 : integer;{\*元素大小\*}

procedure arraytyp( var aref, arsz: integer );{\*处理数组元素\*}

var eltp : types;{\*类型\*}

low, high : conrec;{\*上下界\*}

elrf, elsz: integer;{\* 表中位置和数组大小\*}

begin

constant( [colon, rbrack, rparent, ofsy] + fsys, low );{\*对下界进行常量分析\*}

if low.tp = reals{\*如果下界是实数\*}

then begin

error(27);{\*报错\*}

low.tp := ints;{\*转换成整数\*}

low.i := 0{\*初始化下界是0\*}

end;

if sy = colon{\*如果是冒号’:’\*}

then insymbol{\*读下一个字符\*}

else error(13);

constant( [rbrack, comma, rparent, ofsy ] + fsys, high ); {\*对上界进行常量分析\*}

if high.tp <> low.tp{\*如果上下界的类型不一致\*}

then begin

error(27);

high.i := low.i{\*上界赋值为下界，这样数组就只有一个元素\*}

end;

enterarray( low.tp, low.i, high.i );{\*在符号表里记录数组信息\*}

aref := a;

if sy = comma{\*如果是逗号\*}

then begin

insymbol;

eltp := arrays;{\*类型记录为数组\*}

arraytyp( elrf, elsz )

end

else begin

if sy = rbrack{\*如果是右括号\*}

then insymbol

else begin{\*不是右括号则报错\*}

error(12);

if sy = rparent{\*如果是右小括号\*}

then insymbol{\*继续读\*}

end;

if sy = ofsy{\*如果是of\*}

then insymbol{\*继续读\*}

else error(8);{\*不是of就报错\*}

typ( fsys, eltp, elrf, elsz ){\*记录到符号表里\*}

end;

with atab[aref] do

begin

arsz := (high-low+1) \* elsz;{\*记录数组所占的空间\*}

size := arsz;{\*记录大小\*}

eltyp := eltp;{\*记录类型\*}

elref := elrf;{\*记录数组的位置\*}

elsize := elsz{\*记录单个元素的大小\*}

end

end { arraytyp };

begin { typ }

tp := notyp;

rf := 0;

sz := 0;

test( typebegsys, fsys, 10 );{\*测试是否是合法字符\*}

if sy in typebegsys

then begin

if sy = ident{\*如果是标识符\*}

then begin

x := loc(id);{\*取到符号表中的位置\*}

if x <> 0{\*说明在符号表里找到了\*}

then with tab[x] do

if obj <> typel{\*类型不匹配则报错\*}

then error(29)

else begin

tp := typ;{\*记录类型\*}

rf := ref;{\*记录在表中的位置\*}

sz := adr;{\*记录地址\*}

if tp = notyp{\*未定义的类型，报错\*}

then error(30)

end;

insymbol

end

else if sy = arraysy{\*如果是数组\*}

then begin

insymbol;

if sy = lbrack{\*如果是左中括号\*}

then insymbol

else begin{\*如果不是就报错\*}

error(11);

if sy = lparent

then insymbol

end;

tp := arrays;

arraytyp(rf,sz)

end

else begin { records }{\*不是变量不是数组，则是过程名\*}

insymbol;{\*继续读\*}

enterblock;{\*记录名称，注意层级加一\*}

tp := records;

rf := b;

if level = lmax{\*层级到达了最大值\*}

then fatal(5);{\*报错\*}

level := level + 1;{\*层级加一\*}

display[level] := b;

offset := 0;

while not ( sy in fsys - [semicolon,comma,ident]+ [endsy] ) do{\*如果是分号、逗号、标志符就一直循环\*}

begin { field section }

if sy = ident{\*如果是标识符\*}

then begin

t0 := t;

entervariable;{\*登录符号表记录变量名称\*}

while sy = comma do{\*遇到逗号说明后面还是声明变量\*}

begin

insymbol;

entervariable

end;

if sy = colon{\*如果是冒号\*}

then insymbol{\*继续读\*}

else error(5);{\*不是冒号就报错\*}

t1 := t;{\*记录当前索引\*}

typ( fsys + [semicolon, endsy, comma,ident], eltp, elrf, elsz );{\*处理变量类型\*}

while t0 < t1 do

begin

t0 := t0 + 1;

with tab[t0] do

begin{\*记录\*}

typ := eltp;

ref := elrf;

normal := true;

adr := offset;

offset := offset + elsz

end

end

end; { sy = ident }

if sy <> endsy{\*没有读到end就继续\*}

then begin

if sy = semicolon{\*如果是分号\*}

then insymbol

else begin

error(14);

if sy = comma

then insymbol

end;

test( [ident,endsy, semicolon],fsys,6 ){\*判断当前自负是否是合法字符\*}

end

end; { field section }

btab[rf].vsize := offset;

sz := offset;

btab[rf].psize := 0;

insymbol;

level := level – 1{\*处理完毕层级减一\*}

end; { record }

test( fsys, [],6 )

end;

end { typ };

procedure parameterlist; { formal parameter list }{\*处理参数表\*}

var tp : types;

valpar : boolean;

rf, sz, x, t0 : integer;

begin

insymbol;

tp := notyp;{\*初始化\*}

rf := 0;

sz := 0;

test( [ident, varsy], fsys+[rparent], 7 );{\*判断当前字符是否是合法字符\*}

while sy in [ident, varsy] do{\*如果是标识符\*}

begin

if sy <> varsy{\*如果不是var\*}

then valpar := true{\*值形参标记为true\*}

else begin

insymbol;

valpar := false

end;

t0 := t;

entervariable;{\*在符号表里面记录\*}

while sy = comma do{\*循环记录\*}

begin

insymbol;

entervariable;

end;

if sy = colon{\*如果是分号，说明这一行结束了\*}

then begin

insymbol;

if sy <> ident{\*读到的不是标识符就报错\*}

then error(2)

else begin

x := loc(id);{\*在符号表里查找位置\*}

insymbol;

if x <> 0{\*找到了的话就记录下来各种参数\*}

then with tab[x] do

if obj <> typel

then error(29)

else begin

tp := typ;

rf := ref;

if valpar

then sz := adr

else sz := 1

end;

end;

test( [semicolon, rparent], [comma,ident]+fsys, 14 ){\*判断当前字符是否是合法字符\*}

end

else error(5);

while t0 < t do{\*搜索变量\*}

begin

t0 := t0 + 1;

with tab[t0] do

begin{\*开始记录\*}

typ := tp;

ref := rf;

adr := dx;

lev := level;

normal := valpar;

dx := dx + sz

end

end;

if sy <> rparent{\*如果不是右括号\*}

then begin

if sy = semicolon{\*不是分号就报错\*}

then insymbol

else begin

error(14);

if sy = comma

then insymbol

end;

test( [ident, varsy],[rparent]+fsys,6)

end

end { while };

if sy = rparent{\*不是右小括号就报错\*}

then begin

insymbol;

test( [semicolon, colon],fsys,6 )

end

else error(4)

end { parameterlist };

procedure constdec;

var c : conrec;

begin

insymbol;

test([ident], blockbegsys, 2 );

while sy = ident do

begin

enter(id, konstant);

insymbol;

if sy = eql

then insymbol

else begin

error(16);

if sy = becomes

then insymbol

end;

constant([semicolon,comma,ident]+fsys,c);

tab[t].typ := c.tp;

tab[t].ref := 0;

if c.tp = reals

then begin

enterreal(c.r);

tab[t].adr := c1;

end

else tab[t].adr := c.i;

testsemicolon

end

end { constdec };

procedure typedeclaration;

var tp: types;

rf, sz, t1 : integer;

begin

insymbol;

test([ident], blockbegsys,2 );

while sy = ident do

begin

enter(id, typel);

t1 := t;

insymbol;

if sy = eql

then insymbol

else begin

error(16);

if sy = becomes

then insymbol

end;

typ( [semicolon,comma,ident]+fsys, tp,rf,sz );

with tab[t1] do

begin

typ := tp;

ref := rf;

adr := sz

end;

testsemicolon

end

end { typedeclaration };

procedure variabledeclaration;

var tp : types;

t0, t1, rf, sz : integer;

begin

insymbol;

while sy = ident do

begin

t0 := t;

entervariable;

while sy = comma do

begin

insymbol;

entervariable;

end;

if sy = colon

then insymbol

else error(5);

t1 := t;

typ([semicolon,comma,ident]+fsys, tp,rf,sz );

while t0 < t1 do

begin

t0 := t0 + 1;

with tab[t0] do

begin

typ := tp;

ref := rf;

lev := level;

adr := dx;

normal := true;

dx := dx + sz

end

end;

testsemicolon

end

end { variabledeclaration };

procedure procdeclaration;

var isfun : boolean;

begin

isfun := sy = funcsy;

insymbol;

if sy <> ident

then begin

error(2);

id :=' '

end;

if isfun

then enter(id,funktion)

else enter(id,prozedure);

tab[t].normal := true;

insymbol;

block([semicolon]+fsys, isfun, level+1 );

if sy = semicolon

then insymbol

else error(14);

emit(32+ord(isfun)) {exit}

end { proceduredeclaration };

procedure statement( fsys:symset );

var i : integer;

procedure expression(fsys:symset; var x:item); forward;

procedure selector(fsys:symset; var v:item);

var x : item;

a,j : integer;

begin { sy in [lparent, lbrack, period] }

repeat

if sy = period{\*如果是句号？\*}

then begin

insymbol; { field selector }

if sy <> ident{\*如果不是标识符就报错\*}

then error(2)

else begin

if v.typ <> records{\*类型和记录的不一致\*}

then error(31)

else begin { search field identifier }

j := btab[v.ref].last;{\*找到该标识符记录最后的位置\*}

tab[0].name := id;{\*记录\*}

while tab[j].name <> id do{\*匹配标识符\*}

j := tab[j].link;

if j = 0{\*未匹配上则报错\*}

then error(0);

v.typ := tab[j].typ;{\*记录标识符类型\*}

v.ref := tab[j].ref;{\*记录标识符在表中的索引\*}

a := tab[j].adr;{\*记录地址\*}

if a <> 0

then emit1(9,a){\*将a放到栈顶\*}

end;

insymbol

end

end

else begin { array selector }{\*如果是数组\*}

if sy <> lbrack{\*如果不是左中括号\*}

then error(11);{\*报错\*}

repeat

insymbol;

expression( fsys+[comma,rbrack],x);{\*如果下标是表达式，进行表达式处理\*}

if v.typ <> arrays{\*类型不是数组就报错\*}

then error(28)

else begin

a := v.ref;{\*记录在表中的索引\*}

if atab[a].inxtyp <> x.typ{\*如果和查到的类型不一致则报错\*}

then error(26)

else if atab[a].elsize = 1

then emit1(20,a)

else emit1(21,a);

v.typ := atab[a].eltyp;

v.ref := atab[a].elref

end

until sy <> comma;{\*循环直到分号\*}

if sy = rbrack{\*如果不是右中括号就报错\*}

then insymbol

else begin

error(12);

if sy = rparent

then insymbol

end

end

until not( sy in[lbrack, lparent, period]);

test( fsys,[],6){\*检测当前字符是否是合法字符\*}

end { selector };

procedure call( fsys: symset; i:integer );{\*过程调用\*}

var x : item;

lastp,cp,k : integer;

begin

emit1(18,i); { mark stack }

lastp := btab[tab[i].ref].lastpar;{\*找到最后参数在表中的位置\*}

cp := i;{\*记录参数个数\*}

if sy = lparent{\*如果是左括号\*}

then begin { actual parameter list }

repeat

insymbol;

if cp >= lastp{\*如果超过了参数表的最大索引\*}

then error(39){\*报错\*}

else begin

cp := cp + 1;{\*参数个数加一\*}

if tab[cp].normal

then begin { value parameter }

expression( fsys+[comma, colon,rparent],x);{\*计算表达式\*}

if x.typ = tab[cp].typ{\*如果类型和参数表一致\*}

then begin

if x.ref <> tab[cp].ref\*索引不一致则报错\*}

then error(36)

else if x.typ = arrays{\*如果是数组名称\*}

then emit1(22,atab[x.ref].size)

else if x.typ = records{\*如果是record类型\*}

then emit1(22,btab[x.ref].vsize)

end

else if ( x.typ = ints ) and ( tab[cp].typ = reals ){\*如果形参是实形而实参是整形\*}

then emit1(26,0)

else if x.typ <> notyp{\*无类型则报错\*}

then error(36);

end

else begin { variable parameter }

if sy <> ident{\*不是标识符则报错\*}

then error(2)

else begin

k := loc(id);{\*在符号表中查找\*}

insymbol;

if k <> 0{\*找到\*}

then begin

if tab[k].obj <> vvariable{\*不是变量名则报错\*}

then error(37);

x.typ := tab[k].typ;{\*记录类型\*}

x.ref := tab[k].ref;{\*记录索引\*}

if tab[k].normal{\*如果不是变量形参\*}

then emit2(0,tab[k].lev,tab[k].adr){\*load地址\*}

else emit2(1,tab[k].lev,tab[k].adr);{\*load值\*}

if sy in [lbrack, lparent, period] {\*如果是左中括号或者左小括号或者是句号\*}

then

selector(fsys+[comma,colon,rparent],x);

if ( x.typ <> tab[cp].typ ) or ( x.ref <> tab[cp].ref ){\*查找到的类型或者索引不一致则报错\*}

then error(36)

end

end

end {variable parameter }

end;

test( [comma, rparent],fsys,6)

until sy <> comma;{\*一直到不是逗号\*}

if sy = rparent

then insymbol

else error(4)

end;

if cp < lastp{\*调用过程时参数太少\*}

then error(39); { too few actual parameters }

emit1(19,btab[tab[i].ref].psize-1 );

if tab[i].lev < level

then emit2(3,tab[i].lev, level )

end { call };

function resulttype( a, b : types) :types;

begin

if ( a > reals ) or ( b > reals )

then begin

error(33);

resulttype := notyp

end

else if ( a = notyp ) or ( b = notyp )

then resulttype := notyp

else if a = ints

then if b = ints

then resulttype := ints

else begin

resulttype := reals;

emit1(26,1)

end

else begin

resulttype := reals;

if b = ints

then emit1(26,0)

end

end { resulttype } ;

procedure expression( fsys: symset; var x: item );

var y : item;

op : symbol;

procedure simpleexpression( fsys: symset; var x: item );

var y : item;

op : symbol;

procedure term( fsys: symset; var x: item );

var y : item;

op : symbol;

procedure factor( fsys: symset; var x: item );{\*处理因子\*}

var i,f : integer;

procedure standfct( n: integer );{\*处理标准函数\*}

var ts : typset;

begin { standard function no. n }

if sy = lparent{\*不是左括号就报错\*}

then insymbol

else error(9);

if n < 17

then begin

expression( fsys+[rparent], x );{\*处理表达式\*}

case n of

{ abs, sqr } 0,2: begin{\*调用abs或sqr函数\*}

ts := [ints, reals];

tab[i].typ := x.typ;

if x.typ = reals

then n := n + 1

end;

{ odd, chr } 4,5: ts := [ints];{\*调用odd或chr函数，设置参数类型为整型\*}

{ odr } 6: ts := [ints,bools,chars]; {\*调用odr函数，设置参数类型为整形、布尔型或字符型\*}

{ succ,pred } 7,8 : begin

ts := [ints, bools,chars]; {\*调用succ或pred函数，设置参数类型为整形、布尔型或字符型\*}

tab[i].typ := x.typ

end;

{ round,trunc } 9,10,11,12,13,14,15,16:

{ sin,cos,... } begin

ts := [ints,reals]; {\*调用sin或cos等函数，设置参数类型为整形或实形\*}

if x.typ = ints

then emit1(26,0)

end;

end; { case }

if x.typ in ts{\*如果表达式的结果类型在参数类型之中\*}

then emit1(8,n)

else if x.typ <> notyp{\*如果表达式类型不在参数类型中且也不是无类型，则报错\*}

then error(48);

end

else begin { n in [17,18] }

if sy <> ident{\*读到的不是标识符\*}

then error(2){\*报错\*}

else if id <> 'input '{\*如果读到的不是input\*}

then error(0){\*报错\*}

else insymbol;

emit1(8,n);

end;

x.typ := tab[i].typ;{\*把x的类型赋为参数表中的类型\*}

if sy = rparent{\*如果不是左括号则报错\*}

then insymbol

else error(4)

end { standfct } ;

begin { factor }

x.typ := notyp;{\*初始化\*}

x.ref := 0;

test( facbegsys, fsys,58 );{\*判断当前字符是否合法\*}

while sy in facbegsys do

begin

if sy = ident{\*如果读到了标识符\*}

then begin

i := loc(id);{\*在参数表中找到位置\*}

insymbol;

with tab[i] do

case obj of

konstant: begin{\*如果是常量\*}

x.typ := typ;{\*设置类型\*}

x.ref := 0;{\*位置设置为\*}

if x.typ = reals{\*如果类型是实形\*}

then emit1(25,adr)

else emit1(24,adr)

end;

vvariable:begin{\*如果是变量\*}

x.typ := typ;{\*设置类型\*}

x.ref := ref;{\*设置在表中的位置\*}

if sy in [lbrack, lparent,period]{\*如果是左中括号、左小括号或者句号\*}

then begin

if normal{\*如果标识符不是变量形参\*}

then f := 0{\*做一个记录\*}

else f := 1;

emit2(f,lev,adr);

selector(fsys,x);

if x.typ in stantyps{\*如果返回的结果类型是标准类型\*}

then emit(34)

end

else begin

if x.typ in stantyps{\*如果是标准类型\*}

then if normal{\*做一个记录\*}

then f := 1

else f := 2

else if normal

then f := 0

else f := 1;

emit2(f,lev,adr)

end

end;

typel,prozedure: error(44); {\*如果标识符种类为类型或者过程，则报错\*}

funktion: begin

x.typ := typ;{\*记录类型\*}

if lev <> 0{\*层级不为0\*}

then call(fsys,i){\*进行函数调用\*}

else standfct(adr){\*否则执行标准函数\*}

end

end { case,with }

end

else if sy in [ charcon,intcon,realcon ]{\*如果读到的是字符常量、整型常量或者实型常量\*}

then begin

if sy = realcon{\*如果是整实形常量\*}

then begin

x.typ := reals;{\*记录类型为实形\*}

enterreal(rnum);{\*插入参数表\*}

emit1(25,c1)

end

else begin{\*和上面的实形操作类似\*}

if sy = charcon

then x.typ := chars

else x.typ := ints;

emit1(24,inum)

end;

x.ref := 0;

insymbol

end

else if sy = lparent{\*读到了左括号\*}

then begin

insymbol;

expression(fsys + [rparent],x);{\*分析表达式\*}

if sy = rparent{\*不是右括号则报错\*}

then insymbol

else error(4)

end

else if sy = notsy{\*读到了not\*}

then begin

insymbol;

factor(fsys,x);{\*递归进行因子分析\*}

if x.typ = bools{\*如果x类型是布尔形\*}

then emit(35)

else if x.typ <> notyp{\*如果不是布尔也不是无类型，则报错\*}

then error(32)

end;

test(fsys,facbegsys,6){\*判断当前字符是否是合法字符\*}

end { while }

end { factor };

begin { term }

factor( fsys + [times,rdiv,idiv,imod,andsy],x);

while sy in [times,rdiv,idiv,imod,andsy] do

begin

op := sy;

insymbol;

factor(fsys+[times,rdiv,idiv,imod,andsy],y );

if op = times

then begin

x.typ := resulttype(x.typ, y.typ);

case x.typ of

notyp: ;

ints : emit(57);

reals: emit(60);

end

end

else if op = rdiv

then begin

if x.typ = ints

then begin

emit1(26,1);

x.typ := reals;

end;

if y.typ = ints

then begin

emit1(26,0);

y.typ := reals;

end;

if (x.typ = reals) and (y.typ = reals)

then emit(61)

else begin

if( x.typ <> notyp ) and (y.typ <> notyp)

then error(33);

x.typ := notyp

end

end

else if op = andsy

then begin

if( x.typ = bools )and(y.typ = bools)

then emit(56)

else begin

if( x.typ <> notyp ) and (y.typ <> notyp)

then error(32);

x.typ := notyp

end

end

else begin { op in [idiv,imod] }

if (x.typ = ints) and (y.typ = ints)

then if op = idiv

then emit(58)

else emit(59)

else begin

if ( x.typ <> notyp ) and (y.typ <> notyp)

then error(34);

x.typ := notyp

end

end

end { while }

end { term };

begin { simpleexpression }

if sy in [plus,minus]

then begin

op := sy;

insymbol;

term( fsys+[plus,minus],x);

if x.typ > reals

then error(33)

else if op = minus

then emit(36)

end

else term(fsys+[plus,minus,orsy],x);

while sy in [plus,minus,orsy] do

begin

op := sy;

insymbol;

term(fsys+[plus,minus,orsy],y);

if op = orsy

then begin

if ( x.typ = bools )and(y.typ = bools)

then emit(51)

else begin

if( x.typ <> notyp) and (y.typ <> notyp)

then error(32);

x.typ := notyp

end

end

else begin

x.typ := resulttype(x.typ,y.typ);

case x.typ of

notyp: ;

ints: if op = plus

then emit(52)

else emit(53);

reals:if op = plus

then emit(54)

else emit(55)

end { case }

end

end { while }

end { simpleexpression };

begin { expression }

simpleexpression(fsys+[eql,neq,lss,leq,gtr,geq],x);

if sy in [ eql,neq,lss,leq,gtr,geq]

then begin

op := sy;

insymbol;

simpleexpression(fsys,y);

if(x.typ in [notyp,ints,bools,chars]) and (x.typ = y.typ)

then case op of

eql: emit(45);

neq: emit(46);

lss: emit(47);

leq: emit(48);

gtr: emit(49);

geq: emit(50);

end

else begin

if x.typ = ints

then begin

x.typ := reals;

emit1(26,1)

end

else if y.typ = ints

then begin

y.typ := reals;

emit1(26,0)

end;

if ( x.typ = reals)and(y.typ=reals)

then case op of

eql: emit(39);

neq: emit(40);

lss: emit(41);

leq: emit(42);

gtr: emit(43);

geq: emit(44);

end

else error(35)

end;

x.typ := bools

end

end { expression };

procedure assignment( lv, ad: integer );

var x,y: item;

f : integer;

begin { tab[i].obj in [variable,prozedure] }

x.typ := tab[i].typ;

x.ref := tab[i].ref;

if tab[i].normal

then f := 0

else f := 1;

emit2(f,lv,ad);

if sy in [lbrack,lparent,period]

then selector([becomes,eql]+fsys,x);

if sy = becomes

then insymbol

else begin

error(51);

if sy = eql

then insymbol

end;

expression(fsys,y);

if x.typ = y.typ

then if x.typ in stantyps

then emit(38)

else if x.ref <> y.ref

then error(46)

else if x.typ = arrays

then emit1(23,atab[x.ref].size)

else emit1(23,btab[x.ref].vsize)

else if(x.typ = reals )and (y.typ = ints)

then begin

emit1(26,0);

emit(38)

end

else if ( x.typ <> notyp ) and ( y.typ <> notyp )

then error(46)

end { assignment };

procedure compoundstatement;

begin

insymbol;

statement([semicolon,endsy]+fsys);

while sy in [semicolon]+statbegsys do

begin

if sy = semicolon

then insymbol

else error(14);

statement([semicolon,endsy]+fsys)

end;

if sy = endsy

then insymbol

else error(57)

end { compoundstatement };

procedure ifstatement;

var x : item;

lc1,lc2: integer;

begin

insymbol;

expression( fsys+[thensy,dosy],x);

if not ( x.typ in [bools,notyp])

then error(17);

lc1 := lc;

emit(11); { jmpc }

if sy = thensy

then insymbol

else begin

error(52);

if sy = dosy

then insymbol

end;

statement( fsys+[elsesy]);

if sy = elsesy

then begin

insymbol;

lc2 := lc;

emit(10);

code[lc1].y := lc;

statement(fsys);

code[lc2].y := lc

end

else code[lc1].y := lc

end { ifstatement };

procedure casestatement;{\*\*处理case语句}

var x : item;

i,j,k,lc1 : integer;

casetab : array[1..csmax]of{\*存放着case里面的所有种类\*}

packed record

val,lc : index

end;

exittab : array[1..csmax] of integer;

procedure caselabel;

var lab : conrec;

k : integer;

begin

constant( fsys+[comma,colon],lab );{\*处理常量\*}

if lab.tp <> x.typ{\*如果类型不匹配，则报错\*}

then error(47)

else if i = csmax{\*数组满了，则报错\*}

then fatal(6)

else begin

i := i+1;{\*数组下标加一\*}

k := 0;

casetab[i].val := lab.i;{\*将标签记录到数组当中\*}

casetab[i].lc := lc;

repeat

k := k+1

until casetab[k].val = lab.i;{\*找到是否有重复的标签\*}

if k < i{\*如果找到了则报错\*}

then error(1); { multiple definition }

end

end { caselabel };

procedure onecase;

begin

if sy in constbegsys{\*如果是常量\*}

then begin

caselabel; {\*调用caselabel\*}

while sy = comma do{\*读到的是逗号则一直循环\*}

begin

insymbol;

caselabel{\*调用caselabel\*}

end;

if sy = colon{\*如果不是分号，则报错\*}

then insymbol

else error(5);

statement([semicolon,endsy]+fsys);{\*处理<语句>\*}

j := j+1;

exittab[j] := lc;{\*记录代码位置\*}

emit(10){\*生成跳转指令\*}

end

end { onecase };

begin { casestatement }

insymbol;

i := 0;

j := 0;

expression( fsys + [ofsy,comma,colon],x );{\*\*处理表达式}

if not( x.typ in [ints,bools,chars,notyp ]){\*如果不是这几种类型，则报错\*}

then error(23);

lc1 := lc;{\*记录代码地址\*}

emit(12); {jmpx}{\*生成跳转指令\*}

if sy = ofsy{\*读到的不是of则报错\*}

then insymbol

else error(8);

onecase;{\*调用onecase\*}

while sy = semicolon do{\*读到分号则一直循环\*}

begin

insymbol;

onecase{\*调用onecase\*}

end;

code[lc1].y := lc;

for k := 1 to i do

begin

emit1( 13,casetab[k].val);{\*生成CAS指令，实参是casetable的值\*}

emit1( 13,casetab[k].lc);{\* 生成CAS指令，实参是casetable的值代码地址\*}

end;

emit1(10,0);

for k := 1 to j do

code[exittab[k]].y := lc;{\*记录代码地址\*}

if sy = endsy{\*如果读到的不是end，则报错\*}

then insymbol

else error(57)

end { casestatement };

procedure repeatstatement;{\*repeat语句\*}

var x : item;

lc1: integer;

begin

lc1 := lc;{\*记录代码地址\*}

insymbol;

statement( [semicolon,untilsy]+fsys);{\*处理语句\*}

while sy in [semicolon]+statbegsys do

begin

if sy = semicolon{\*如果读到了分号\*}

then insymbol

else error(14);{\*没读到分号则报错\*}

statement([semicolon,untilsy]+fsys){\*处理语句\*}

end;

if sy = untilsy{\*如果读到了until\*}

then begin

insymbol;

expression(fsys,x);{\*处理表达式\*}

if not(x.typ in [bools,notyp] ){\*如果表达式的类型不是布尔型或无类型，则报错\*}

then error(17);

emit1(11,lc1);{\*生成跳转语句\*}

end

else error(53)

end { repeatstatement };

procedure whilestatement;

var x : item;

lc1,lc2 : integer;

begin

insymbol;

lc1 := lc;

expression( fsys+[dosy],x);

if not( x.typ in [bools, notyp] )

then error(17);

lc2 := lc;

emit(11);

if sy = dosy

then insymbol

else error(54);

statement(fsys);

emit1(10,lc1);

code[lc2].y := lc

end { whilestatement };

procedure forstatement;{\*for语句\*}

var cvt : types;

x : item;

i,f,lc1,lc2 : integer;

begin

insymbol;

if sy = ident{\*读到了标示符\*}

then begin

i := loc(id);{\*取在符号表中的位置\*}

insymbol;

if i = 0{\*没找到\*}

then cvt := ints{\*标记为int类型\*}

else if tab[i].obj = vvariable{\*如果是变量\*}

then begin

cvt := tab[i].typ; {\*记录变量类型\*}

if not tab[i].normal{\*如果不是变量形参，则报错\*}

then error(37)

else emit2(0,tab[i].lev, tab[i].adr );{\*生成指令\*}

if not ( cvt in [notyp, ints, bools, chars]){\*如果不是这些规定的类型，则报错\*}

then error(18)

end

else begin{\*报错\*}

error(37);

cvt := ints

end

end

else skip([becomes,tosy,downtosy,dosy]+fsys,2);{\*跳过这些代码\*}

if sy = becomes{\*如果是赋值符号\*}

then begin

insymbol;

expression( [tosy, downtosy,dosy]+fsys,x);{\*处理表达式\*}

if x.typ <> cvt{\*如果表达式的类型和赋值语句左边变量的类型不一致\*}

then error(19);{\*报错\*}

end

else skip([tosy, downtosy,dosy]+fsys,51);{\*跳过这些代码\*}

f := 14;

if sy in [tosy,downtosy]{\*如果是to或者downto语句\*}

then begin

if sy = downtosy{\*如果是downto\*}

then f := 16;

insymbol;

expression([dosy]+fsys,x);{\*处理表达式\*}

if x.typ <> cvt{\*类型不一致，则报错\*}

then error(19)

end

else skip([dosy]+fsys,55);{\*跳过这些代码\*}

lc1 := lc;{\*记录代码地址\*}

emit(f);{\*生成跳转指令\*}

if sy = dosy{\*如果是do语句\*}

then insymbol{\*继续读\*}

else error(54);{\*否则报错\*}

lc2 := lc;{\*记录代码地址\*}

statement(fsys);{\*处理语句\*}

emit1(f+1,lc2);

code[lc1].y := lc{\*记录代码地址\*}

end { forstatement };

procedure standproc( n: integer );

var i,f : integer;

x,y : item;

begin

case n of

1,2 : begin { read }

if not iflag

then begin

error(20);

iflag := true

end;

if sy = lparent

then begin

repeat

insymbol;

if sy <> ident

then error(2)

else begin

i := loc(id);

insymbol;

if i <> 0

then if tab[i].obj <> vvariable

then error(37)

else begin

x.typ := tab[i].typ;

x.ref := tab[i].ref;

if tab[i].normal

then f := 0

else f := 1;

emit2(f,tab[i].lev,tab[i].adr);

if sy in [lbrack,lparent,period]

then selector( fsys+[comma,rparent],x);

if x.typ in [ints,reals,chars,notyp]

then emit1(27,ord(x.typ))

else error(41)

end

end;

test([comma,rparent],fsys,6);

until sy <> comma;

if sy = rparent

then insymbol

else error(4)

end;

if n = 2

then emit(62)

end;

3,4 : begin { write }

if sy = lparent

then begin

repeat

insymbol;

if sy = stringcon

then begin

emit1(24,sleng);

emit1(28,inum);

insymbol

end

else begin

expression(fsys+[comma,colon,rparent],x);

if not( x.typ in stantyps )

then error(41);

if sy = colon

then begin

insymbol;

expression( fsys+[comma,colon,rparent],y);

if y.typ <> ints

then error(43);

if sy = colon

then begin

if x.typ <> reals

then error(42);

insymbol;

expression(fsys+[comma,rparent],y);

if y.typ <> ints

then error(43);

emit(37)

end

else emit1(30,ord(x.typ))

end

else emit1(29,ord(x.typ))

end

until sy <> comma;

if sy = rparent

then insymbol

else error(4)

end;

if n = 4

then emit(63)

end; { write }

end { case };

end { standproc } ;

begin { statement }

if sy in statbegsys+[ident]

then case sy of

ident : begin

i := loc(id);

insymbol;

if i <> 0

then case tab[i].obj of

konstant,typel : error(45);

vvariable: assignment( tab[i].lev,tab[i].adr);

prozedure: if tab[i].lev <> 0

then call(fsys,i)

else standproc(tab[i].adr);

funktion: if tab[i].ref = display[level]

then assignment(tab[i].lev+1,0)

else error(45)

end { case }

end;

beginsy : compoundstatement;

ifsy : ifstatement;

casesy : casestatement;

whilesy : whilestatement;

repeatsy: repeatstatement;

forsy : forstatement;

end; { case }

test( fsys, [],14);

end { statement };

begin { block }

dx := 5;

prt := t;

if level > lmax

then fatal(5);

test([lparent,colon,semicolon],fsys,14);

enterblock;

prb := b;

display[level] := b;

tab[prt].typ := notyp;

tab[prt].ref := prb;

if ( sy = lparent ) and ( level > 1 )

then parameterlist;

btab[prb].lastpar := t;

btab[prb].psize := dx;

if isfun

then if sy = colon

then begin

insymbol; { function type }

if sy = ident

then begin

x := loc(id);

insymbol;

if x <> 0

then if tab[x].typ in stantyps

then tab[prt].typ := tab[x].typ

else error(15)

end

else skip( [semicolon]+fsys,2 )

end

else error(5);

if sy = semicolon

then insymbol

else error(14);

repeat

if sy = constsy

then constdec;

if sy = typesy

then typedeclaration;

if sy = varsy

then variabledeclaration;

btab[prb].vsize := dx;

while sy in [procsy,funcsy] do

procdeclaration;

test([beginsy],blockbegsys+statbegsys,56)

until sy in statbegsys;

tab[prt].adr := lc;

insymbol;

statement([semicolon,endsy]+fsys);

while sy in [semicolon]+statbegsys do

begin

if sy = semicolon

then insymbol

else error(14);

statement([semicolon,endsy]+fsys);

end;

if sy = endsy

then insymbol

else error(57);

test( fsys+[period],[],6 )

end { block };

procedure interpret;

var ir : order ; { instruction buffer }

pc : integer; { program counter }

t : integer; { top stack index }

b : integer; { base index }

h1,h2,h3: integer;

lncnt,ocnt,blkcnt,chrcnt: integer; { counters }

ps : ( run,fin,caschk,divchk,inxchk,stkchk,linchk,lngchk,redchk );

fld: array [1..4] of integer; { default field widths }

display : array[0..lmax] of integer;

s : array[1..stacksize] of { blockmark: }

record

case cn : types of { s[b+0] = fct result }

ints : (i: integer ); { s[b+1] = return adr }

reals :(r: real ); { s[b+2] = static link }

bools :(b: boolean ); { s[b+3] = dynamic link }

chars :(c: char ) { s[b+4] = table index }

end;

procedure dump;

var p,h3 : integer;

begin

h3 := tab[h2].lev;

writeln(psout);

writeln(psout);

writeln(psout,' calling ', tab[h2].name );

writeln(psout,' level ',h3:4);

writeln(psout,' start of code ',pc:4);

writeln(psout);

writeln(psout);

writeln(psout,' contents of display ');

writeln(psout);

for p := h3 downto 0 do

writeln(psout,p:4,display[p]:6);

writeln(psout);

writeln(psout);

writeln(psout,' top of stack ',t:4,' frame base ':14,b:4);

writeln(psout);

writeln(psout);

writeln(psout,' stack contents ':20);

writeln(psout);

for p := t downto 1 do

writeln( psout, p:14, s[p].i:8);

writeln(psout,'< = = = >':22)

end; {dump }

procedure inter0;

begin

case ir.f of

0 : begin { load addrss }

t := t + 1;

if t > stacksize

then ps := stkchk

else s[t].i := display[ir.x]+ir.y

end;

1 : begin { load value }

t := t + 1;

if t > stacksize

then ps := stkchk

else s[t] := s[display[ir.x]+ir.y]

end;

2 : begin { load indirect }

t := t + 1;

if t > stacksize

then ps := stkchk

else s[t] := s[s[display[ir.x]+ir.y].i]

end;

3 : begin { update display }

h1 := ir.y;

h2 := ir.x;

h3 := b;

repeat

display[h1] := h3;

h1 := h1-1;

h3 := s[h3+2].i

until h1 = h2

end;

8 : case ir.y of

0 : s[t].i := abs(s[t].i);

1 : s[t].r := abs(s[t].r);

2 : s[t].i := sqr(s[t].i);

3 : s[t].r := sqr(s[t].r);

4 : s[t].b := odd(s[t].i);

5 : s[t].c := chr(s[t].i);

6 : s[t].i := ord(s[t].c);

7 : s[t].c := succ(s[t].c);

8 : s[t].c := pred(s[t].c);

9 : s[t].i := round(s[t].r);

10 : s[t].i := trunc(s[t].r);

11 : s[t].r := sin(s[t].r);

12 : s[t].r := cos(s[t].r);

13 : s[t].r := exp(s[t].r);

14 : s[t].r := ln(s[t].r);

15 : s[t].r := sqrt(s[t].r);

16 : s[t].r := arcTan(s[t].r);

17 : begin

t := t+1;

if t > stacksize

then ps := stkchk

else s[t].b := eof(prd)

end;

18 : begin

t := t+1;

if t > stacksize

then ps := stkchk

else s[t].b := eoln(prd)

end;

end;

9 : s[t].i := s[t].i + ir.y; { offset }

end { case ir.y }

end; { inter0 }

procedure inter1;

var h3, h4: integer;

begin

case ir.f of

10 : pc := ir.y ; { jump }

11 : begin { conditional jump }

if not s[t].b

then pc := ir.y;

t := t - 1

end;

12 : begin { switch }

h1 := s[t].i;

t := t-1;

h2 := ir.y;

h3 := 0;

repeat

if code[h2].f <> 13

then begin

h3 := 1;

ps := caschk

end

else if code[h2].y = h1

then begin

h3 := 1;

pc := code[h2+1].y

end

else h2 := h2 + 2

until h3 <> 0

end;

14 : begin { for1up }

h1 := s[t-1].i;

if h1 <= s[t].i

then s[s[t-2].i].i := h1

else begin

t := t - 3;

pc := ir.y

end

end;

15 : begin { for2up }

h2 := s[t-2].i;

h1 := s[h2].i+1;

if h1 <= s[t].i

then begin

s[h2].i := h1;

pc := ir.y

end

else t := t-3;

end;

16 : begin { for1down }

h1 := s[t-1].i;

if h1 >= s[t].i

then s[s[t-2].i].i := h1

else begin

pc := ir.y;

t := t - 3

end

end;

17 : begin { for2down }

h2 := s[t-2].i;

h1 := s[h2].i-1;

if h1 >= s[t].i

then begin

s[h2].i := h1;

pc := ir.y

end

else t := t-3;

end;

18 : begin { mark stack }

h1 := btab[tab[ir.y].ref].vsize;

if t+h1 > stacksize

then ps := stkchk

else begin

t := t+5;

s[t-1].i := h1-1;

s[t].i := ir.y

end

end;

19 : begin { call }

h1 := t-ir.y; { h1 points to base }

h2 := s[h1+4].i; { h2 points to tab }

h3 := tab[h2].lev;

display[h3+1] := h1;

h4 := s[h1+3].i+h1;

s[h1+1].i := pc;

s[h1+2].i := display[h3];

s[h1+3].i := b;

for h3 := t+1 to h4 do

s[h3].i := 0;

b := h1;

t := h4;

pc := tab[h2].adr;

if stackdump

then dump

end;

end { case }

end; { inter1 }

procedure inter2;

begin

case ir.f of

20 : begin { index1 }

h1 := ir.y; { h1 points to atab }

h2 := atab[h1].low;

h3 := s[t].i;

if h3 < h2

then ps := inxchk

else if h3 > atab[h1].high

then ps := inxchk

else begin

t := t-1;

s[t].i := s[t].i+(h3-h2)

end

end;

21 : begin { index }

h1 := ir.y ; { h1 points to atab }

h2 := atab[h1].low;

h3 := s[t].i;

if h3 < h2

then ps := inxchk

else if h3 > atab[h1].high

then ps := inxchk

else begin

t := t-1;

s[t].i := s[t].i + (h3-h2)\*atab[h1].elsize

end

end;

22 : begin { load block }

h1 := s[t].i;

t := t-1;

h2 := ir.y+t;

if h2 > stacksize

then ps := stkchk

else while t < h2 do

begin

t := t+1;

s[t] := s[h1];

h1 := h1+1

end

end;

23 : begin { copy block }

h1 := s[t-1].i;

h2 := s[t].i;

h3 := h1+ir.y;

while h1 < h3 do

begin

s[h1] := s[h2];

h1 := h1+1;

h2 := h2+1

end;

t := t-2

end;

24 : begin { literal }

t := t+1;

if t > stacksize

then ps := stkchk

else s[t].i := ir.y

end;

25 : begin { load real }

t := t+1;

if t > stacksize

then ps := stkchk

else s[t].r := rconst[ir.y]

end;

26 : begin { float }

h1 := t-ir.y;

s[h1].r := s[h1].i

end;

27 : begin { read }

if eof(prd)

then ps := redchk

else case ir.y of

1 : read(prd, s[s[t].i].i);

2 : read(prd, s[s[t].i].r);

4 : read(prd, s[s[t].i].c);

end;

t := t-1

end;

28 : begin { write string }

h1 := s[t].i;

h2 := ir.y;

t := t-1;

chrcnt := chrcnt+h1;

if chrcnt > lineleng

then ps := lngchk;

repeat

write(prr,stab[h2]);

h1 := h1-1;

h2 := h2+1

until h1 = 0

end;

29 : begin { write1 }

chrcnt := chrcnt + fld[ir.y];

if chrcnt > lineleng

then ps := lngchk

else case ir.y of

1 : write(prr,s[t].i:fld[1]);

2 : write(prr,s[t].r:fld[2]);

3 : if s[t].b

then write('true')

else write('false');

4 : write(prr,chr(s[t].i));

end;

t := t-1

end;

end { case }

end; { inter2 }

procedure inter3;

begin

case ir.f of

30 : begin { write2 }

chrcnt := chrcnt+s[t].i;

if chrcnt > lineleng

then ps := lngchk

else case ir.y of

1 : write(prr,s[t-1].i:s[t].i);

2 : write(prr,s[t-1].r:s[t].i);

3 : if s[t-1].b

then write('true')

else write('false');

end;

t := t-2

end;

31 : ps := fin;

32 : begin { exit procedure }

t := b-1;

pc := s[b+1].i;

b := s[b+3].i

end;

33 : begin { exit function }

t := b;

pc := s[b+1].i;

b := s[b+3].i

end;

34 : s[t] := s[s[t].i];

35 : s[t].b := not s[t].b;

36 : s[t].i := -s[t].i;

37 : begin

chrcnt := chrcnt + s[t-1].i;

if chrcnt > lineleng

then ps := lngchk

else write(prr,s[t-2].r:s[t-1].i:s[t].i);

t := t-3

end;

38 : begin { store }

s[s[t-1].i] := s[t];

t := t-2

end;

39 : begin

t := t-1;

s[t].b := s[t].r=s[t+1].r

end;

end { case }

end; { inter3 }

procedure inter4;

begin

case ir.f of

40 : begin

t := t-1;

s[t].b := s[t].r <> s[t+1].r

end;

41 : begin

t := t-1;

s[t].b := s[t].r < s[t+1].r

end;

42 : begin

t := t-1;

s[t].b := s[t].r <= s[t+1].r

end;

43 : begin

t := t-1;

s[t].b := s[t].r > s[t+1].r

end;

44 : begin

t := t-1;

s[t].b := s[t].r >= s[t+1].r

end;

45 : begin

t := t-1;

s[t].b := s[t].i = s[t+1].i

end;

46 : begin

t := t-1;

s[t].b := s[t].i <> s[t+1].i

end;

47 : begin

t := t-1;

s[t].b := s[t].i < s[t+1].i

end;

48 : begin

t := t-1;

s[t].b := s[t].i <= s[t+1].i

end;

49 : begin

t := t-1;

s[t].b := s[t].i > s[t+1].i

end;

end { case }

end; { inter4 }

procedure inter5;

begin

case ir.f of

50 : begin

t := t-1;

s[t].b := s[t].i >= s[t+1].i

end;

51 : begin

t := t-1;

s[t].b := s[t].b or s[t+1].b

end;

52 : begin

t := t-1;

s[t].i := s[t].i+s[t+1].i

end;

53 : begin

t := t-1;

s[t].i := s[t].i-s[t+1].i

end;

54 : begin

t := t-1;

s[t].r := s[t].r+s[t+1].r;

end;

55 : begin

t := t-1;

s[t].r := s[t].r-s[t+1].r;

end;

56 : begin

t := t-1;

s[t].b := s[t].b and s[t+1].b

end;

57 : begin

t := t-1;

s[t].i := s[t].i\*s[t+1].i

end;

58 : begin

t := t-1;

if s[t+1].i = 0

then ps := divchk

else s[t].i := s[t].i div s[t+1].i

end;

59 : begin

t := t-1;

if s[t+1].i = 0

then ps := divchk

else s[t].i := s[t].i mod s[t+1].i

end;

end { case }

end; { inter5 }

procedure inter6;

begin

case ir.f of

60 : begin

t := t-1;

s[t].r := s[t].r\*s[t+1].r;

end;

61 : begin

t := t-1;

s[t].r := s[t].r/s[t+1].r;

end;

62 : if eof(prd)

then ps := redchk

else readln;

63 : begin

writeln(prr);

lncnt := lncnt+1;

chrcnt := 0;

if lncnt > linelimit

then ps := linchk

end

end { case };

end; { inter6 }

begin { interpret }

s[1].i := 0;

s[2].i := 0;

s[3].i := -1;

s[4].i := btab[1].last;

display[0] := 0;

display[1] := 0;

t := btab[2].vsize-1;

b := 0;

pc := tab[s[4].i].adr;

lncnt := 0;

ocnt := 0;

chrcnt := 0;

ps := run;

fld[1] := 10;

fld[2] := 22;

fld[3] := 10;

fld[4] := 1;

repeat

ir := code[pc];

pc := pc+1;

ocnt := ocnt+1;

case ir.f div 10 of

0 : inter0;

1 : inter1;

2 : inter2;

3 : inter3;

4 : inter4;

5 : inter5;

6 : inter6;

end; { case }

until ps <> run;

if ps <> fin

then begin

writeln(prr);

write(prr, ' halt at', pc :5, ' because of ');

case ps of

caschk : writeln(prr,'undefined case');

divchk : writeln(prr,'division by 0');

inxchk : writeln(prr,'invalid index');

stkchk : writeln(prr,'storage overflow');

linchk : writeln(prr,'too much output');

lngchk : writeln(prr,'line too long');

redchk : writeln(prr,'reading past end or file');

end;

h1 := b;

blkcnt := 10; { post mortem dump }

repeat

writeln( prr );

blkcnt := blkcnt-1;

if blkcnt = 0

then h1 := 0;

h2 := s[h1+4].i;

if h1 <> 0

then writeln( prr, '',tab[h2].name, 'called at', s[h1+1].i:5);

h2 := btab[tab[h2].ref].last;

while h2 <> 0 do

with tab[h2] do

begin

if obj = vvariable

then if typ in stantyps

then begin

write(prr,'',name,'=');

if normal

then h3 := h1+adr

else h3 := s[h1+adr].i;

case typ of

ints : writeln(prr,s[h3].i);

reals: writeln(prr,s[h3].r);

bools: if s[h3].b

then writeln(prr,'true')

else writeln(prr,'false');

chars: writeln(prr,chr(s[h3].i mod 64 ))

end

end;

h2 := link

end;

h1 := s[h1+3].i

until h1 < 0

end;

writeln(prr);

writeln(prr,ocnt,' steps');

end; { interpret }

procedure setup;

begin

key[1] := 'and ';

key[2] := 'array ';

key[3] := 'begin ';

key[4] := 'case ';

key[5] := 'const ';

key[6] := 'div ';

key[7] := 'do ';

key[8] := 'downto ';

key[9] := 'else ';

key[10] := 'end ';

key[11] := 'for ';

key[12] := 'function ';

key[13] := 'if ';

key[14] := 'mod ';

key[15] := 'not ';

key[16] := 'of ';

key[17] := 'or ';

key[18] := 'procedure ';

key[19] := 'program ';

key[20] := 'record ';

key[21] := 'repeat ';

key[22] := 'then ';

key[23] := 'to ';

key[24] := 'type ';

key[25] := 'until ';

key[26] := 'var ';

key[27] := 'while ';

ksy[1] := andsy;

ksy[2] := arraysy;

ksy[3] := beginsy;

ksy[4] := casesy;

ksy[5] := constsy;

ksy[6] := idiv;

ksy[7] := dosy;

ksy[8] := downtosy;

ksy[9] := elsesy;

ksy[10] := endsy;

ksy[11] := forsy;

ksy[12] := funcsy;

ksy[13] := ifsy;

ksy[14] := imod;

ksy[15] := notsy;

ksy[16] := ofsy;

ksy[17] := orsy;

ksy[18] := procsy;

ksy[19] := programsy;

ksy[20] := recordsy;

ksy[21] := repeatsy;

ksy[22] := thensy;

ksy[23] := tosy;

ksy[24] := typesy;

ksy[25] := untilsy;

ksy[26] := varsy;

ksy[27] := whilesy;

sps['+'] := plus;

sps['-'] := minus;

sps['\*'] := times;

sps['/'] := rdiv;

sps['('] := lparent;

sps[')'] := rparent;

sps['='] := eql;

sps[','] := comma;

sps['['] := lbrack;

sps[']'] := rbrack;

sps[''''] := neq;

sps['!'] := andsy;

sps[';'] := semicolon;

end { setup };

procedure enterids;

begin

enter(' ',vvariable,notyp,0); { sentinel }

enter('false ',konstant,bools,0);

enter('true ',konstant,bools,1);

enter('real ',typel,reals,1);

enter('char ',typel,chars,1);

enter('boolean ',typel,bools,1);

enter('integer ',typel,ints,1);

enter('abs ',funktion,reals,0);

enter('sqr ',funktion,reals,2);

enter('odd ',funktion,bools,4);

enter('chr ',funktion,chars,5);

enter('ord ',funktion,ints,6);

enter('succ ',funktion,chars,7);

enter('pred ',funktion,chars,8);

enter('round ',funktion,ints,9);

enter('trunc ',funktion,ints,10);

enter('sin ',funktion,reals,11);

enter('cos ',funktion,reals,12);

enter('exp ',funktion,reals,13);

enter('ln ',funktion,reals,14);

enter('sqrt ',funktion,reals,15);

enter('arctan ',funktion,reals,16);

enter('eof ',funktion,bools,17);

enter('eoln ',funktion,bools,18);

enter('read ',prozedure,notyp,1);

enter('readln ',prozedure,notyp,2);

enter('write ',prozedure,notyp,3);

enter('writeln ',prozedure,notyp,4);

enter(' ',prozedure,notyp,0);

end;

begin { main }

setup;

constbegsys := [ plus, minus, intcon, realcon, charcon, ident ];

typebegsys := [ ident, arraysy, recordsy ];

blockbegsys := [ constsy, typesy, varsy, procsy, funcsy, beginsy ];

facbegsys := [ intcon, realcon, charcon, ident, lparent, notsy ];

statbegsys := [ beginsy, ifsy, whilesy, repeatsy, forsy, casesy ];

stantyps := [ notyp, ints, reals, bools, chars ];

lc := 0;

ll := 0;

cc := 0;

ch := ' ';

errpos := 0;

errs := [];

writeln( 'NOTE input/output for users program is console : ' );

writeln;

write( 'Source input file ?');

readln( inf );

assign( psin, inf );

reset( psin );

write( 'Source listing file ?');

readln( outf );

assign( psout, outf );

rewrite( psout );

assign ( prd, 'con' );

write( 'result file : ' );

readln( fprr );

assign( prr, fprr );

reset ( prd );

rewrite( prr );

t := -1;

a := 0;

b := 1;

sx := 0;

c2 := 0;

display[0] := 1;

iflag := false;

oflag := false;

skipflag := false;

prtables := false;

stackdump := false;

insymbol;

if sy <> programsy

then error(3)

else begin

insymbol;

if sy <> ident

then error(2)

else begin

progname := id;

insymbol;

if sy <> lparent

then error(9)

else repeat

insymbol;

if sy <> ident

then error(2)

else begin

if id = 'input '

then iflag := true

else if id = 'output '

then oflag := true

else error(0);

insymbol

end

until sy <> comma;

if sy = rparent

then insymbol

else error(4);

if not oflag then error(20)

end

end;

enterids;

with btab[1] do

begin

last := t;

lastpar := 1;

psize := 0;

vsize := 0;

end;

block( blockbegsys + statbegsys, false, 1 );

if sy <> period

then error(2);

emit(31); { halt }

if prtables

then printtables;

if errs = []

then interpret

else begin

writeln( psout );

writeln( psout, 'compiled with errors' );

writeln( psout );

errormsg;

end;

writeln( psout );

close( psout );

close( prr )

end.