1. <program> 🡪 <moduleDeclarations> <otherModules><driverModule><otherModules>
2. <moduleDeclarations> 🡪 <moduleDeclaration><moduleDeclarations> | ε
3. <moduleDeclaration> 🡪 DECLARE MODULE ID SEMICOL
4. <otherModules> 🡪 <module><otherModules>| ε
5. **<driverModule> 🡪 DRIVERDEF DRIVER PROGRAM DRIVERENDDEF <moduleDef>**
6. <module> 🡪 DEF MODULE ID ENDDEF TAKES INPUT SQBO <input\_plist> SQBC SEMICOL <ret><moduleDef>
7. <ret> 🡪 RETURNS SQBO <output\_plist> SQBC SEMICOL | ε
8. **<input\_plist> 🡪 ID COLON <dataType><R1>**
9. **<R1> 🡪 COMMA ID COLON <dataType> <R1> | ε**
10. **<output\_plist> 🡪 ID COLON <type> <R2>**
11. **<R2> 🡪 COMMA ID COLON <type><R2> | ε**
12. <dataType> 🡪 INTEGER | REAL | BOOLEAN | ARRAY SQBO <range> SQBC OF <type>
13. <type> 🡪 INTEGER | REAL | BOOLEAN
14. <moduleDef> 🡪 START <statements> END
15. <statements> 🡪 <statement> <statements> | ε
16. <statement> 🡪 <ioStmt>|<simpleStmt>|<declareStmt>|<conditionalStmt>|<iterativeStmt>
17. **<ioStmt> 🡪 GET\_VALUE BO ID BC SEMICOL | PRINT BO <var\_new> BC SEMICOL**
18. **<var\_new> 🡪 <var>|TRUE|FALSE**
19. <var> 🡪 ID <whichId> | NUM | RNUM
20. <whichId> 🡪 SQBO ID SQBC | ε
21. <simpleStmt> 🡪 <assignmentStmt> | <moduleReuseStmt>
22. <assignmentStmt> 🡪 ID <whichStmt>
23. <whichStmt> 🡪 <lvalueIDStmt> | <lvalueARRStmt>
24. <lvalueIDStmt> 🡪 ASSIGNOP <expression> SEMICOL
25. <lvalueARRStmt> 🡪 SQBO <index> SQBC ASSIGNOP <expression> SEMICOL
26. <index> -> NUM | ID
27. <moduleReuseStmt> 🡪<optional> USE MODULE ID WITH PARAMETERS <idList>SEMICOL
28. <optional> 🡪 SQBO <idList> SQBC ASSIGNOP | ε
29. **<idList> 🡪 ID <R3>**
30. **<R3> 🡪 COMMA ID <R3> | ε**
31. **<expression> 🡪 <arithmeticOrBooleanExpr> | MINUS BO <arithmeticExpr> BC**
32. **<arithmeticOrBooleanExpr> 🡪 <AnyTerm> <R4> | BO <arithmeticOrBooleanExpr> BC**
33. **<R4> 🡪 <logicalOp> <AnyTerm> <R4> | ε**
34. **<AnyTerm> 🡪 <arithmeticExpr> <R5>**
35. **<R5> 🡪 <relationalOp> <arithmeticExpr><R5> | ε**
36. **<arithmeticExpr> 🡪 <term> <R6>**
37. **<R6> 🡪 <op1> <term> <R6> | ε**
38. **<term> 🡪 <factor> <R7>**
39. **<R7> 🡪 <op2> <factor> <R7>| ε**
40. <factor> 🡪 <var>
41. **<op1> 🡪 PLUS|MINUS**
42. **<op2> 🡪 MUL|DIV**
43. <logicalOp> 🡪 AND | OR
44. <relationalOp> 🡪 LT | LE | GT | GE | EQ | NE
45. <declareStmt> 🡪 DECLARE <idList> COLON <dataType> SEMICOL
46. <conditionalStmt> 🡪 SWITCH BO ID BC START <caseStmts><default> END
47. **<caseStmts> 🡪 CASE <value> COLON <statements> BREAK SEMICOL <R8>**
48. **<R8> 🡪 CASE <value> COLON <statements> BREAK SEMICOL <R8> | ε**
49. <value> 🡪 NUM | TRUE | FALSE
50. <default> 🡪 DEFAULT COLON <statements> BREAK SEMICOL | ε
51. <iterativeStmt> 🡪 FOR BO ID IN <range> BC START <statements> END | WHILE BO <booleanExpr> BC START <statements> END
52. <range> 🡪 NUM RANGEOP NUM

**NOTE: The grammar rules in bold are modifications/additions to the original grammar given in the language specifications document.**