**ADA 05: Algoritmos selectivos**

**Descripción:** Utilizando la herramienta PSeInt realice los siguientes algoritmos mediante Pseudocódigo y diagramas de flujo.

**Notas:**

* Deberá exportar su código a un html y posteriormente pegarlo en word en el ejercicio correspondiente, esto para que el formato a colores se mantenga.
* Deberá exportar sus digramas de flujo al formato de imagen .png y posteriormente pegarlo en word en el ejercicio correspondiente, esto para que el formato a colores se mantenga.
* Recuerde lo siguiente:
  + Utilizar el perfil UADY
  + Escribir comentarios a su código.
  + Utilizar nombres de variables de acuerdo a lo que vaya a almacenar.

1. “El hamburguesín” ofrece hamburguesas sencillas, dobles y triples, las cuales tienen un costo de $20.00, $25.00 y $28.00 respectivamente. La empresa acepta tarjetas de crédito con un cargo de 5% sobre la compra. Suponiendo que los clientes adquieren sólo un tipo de hamburguesa, realice un algoritmo para determinar cuánto debe pagar una persona por N hamburguesas.

**Algoritmo** hamburguesin

*//Definimos variables*

**Definir** tipoHamburguesa **Como** **Entero;**

**Definir** tipoPago **Como** **Entero;**

**Definir** cantidad **Como** **Entero;**

**Definir** costo **Como** **Real;**

**Escribir** "###############################"**;**

**Escribir** " "**;**

**Escribir** " El Hamburguesin"**;**

**Escribir** " "**;**

**Escribir** "###############################"**;**

*//Pedimos información al usuario*

**Escribir** "Ingrese el tipo de hamburguesa:"**;**

**Escribir** " - sencilla (1)"**;**

**Escribir** " - doble (2)"**;**

**Escribir** " - triple (3)"**;**

**Leer** tipoHamburguesa**;**

**Escribir** "Ingrese la cantidad de hamburguesas:"**;**

**Leer** cantidad**;**

**Escribir** "Ingrese su tipo de pago:"**;**

**Escribir** " - efectivo (1)"**;**

**Escribir** " - tarjeta (2)"**;**

**Leer** tipoPago**;**

*//Obtenemos el total por las hamburguesas*

**Segun** tipoHamburguesa **Hacer**

1**:**

costo = 20**;**

2**:**

costo = 25**;**

3**:**

costo = 28**;**

**De** **Otro** **Modo:**

**Escribir** "No tenemos ese tipo de Hamburguesa, vuelva pronto :)."**;**

**Fin** **Segun**

costo=costo**\***cantidad**;**

*//Obtenemos el total por tipo de pago*

**Si** tipoPago**==**2 **Entonces**

costo=costo**\***1.05**;**

**Escribir** "Se le cargará un 5% por pago con tarjeta."**;**

**SiNo**

**Si** costo **==** 1 **Entonces**

**Escribir** "Dinero en efectivo recibido"**;**

**SiNo**

**Escribir** "Aun no contamos con ese metodo de pago"**;**


**Fin** **Si**

**Fin** **Si**

*//Devolvemos el costo*

**Escribir** "Total a pagar: $"**,** costo**,** "MXN."**;**

**FinAlgoritmo**



1. El consultorio del “Dr. Sismi” tiene como política cobrar la consulta con base en el número de cita, de la siguiente forma:
   1. Las tres primeras citas a $200.00 c/u.
   2. Las siguientes dos citas a $150.00 c/u.
   3. Las tres siguientes citas a $100.00 c/u.
   4. Las restantes a $50.00 c/u, mientras dure el tratamiento.

Se requiere un algoritmo para determinar:

a) Cuánto pagará el paciente por la cita.

b) El monto de lo que ha pagado el paciente por el tratamiento.

**Algoritmo** simi

*//Definimos variables*

**Definir** costo **Como** **Real;**

**Definir** costoTratamiento **Como** **Real;**

**Definir** numConsulta **Como** **Entero;**

**Imprimir** "¿Que numero de consulta es?: "**;**

**Leer** numConsulta**;**

*//determinamos precio y costoTratamiento*

**Si** numConsulta **≤** 3 **Entonces**

costo = 200**;**

costoTratamiento = costo **\*** numConsulta**;**

**SiNo** **Si** numConsulta **≤** 5 **Entonces**

costo = 150**;**

costoTratamiento = costo**\*(**numConsulta **-** 3**)** **+** 600**;**

**SiNo** **Si** numConsulta **≤** 8 **Entonces**

costo = 100**;**

costoTratamiento = costo**\*(**numConsulta **-** 5**)** **+** 900**;**

**SiNo**

costo = 50**;**

costoTratamiento = costo**\*(**numConsulta **-** 5**)** **+** 1200**;**

**FinSi**

**FinSi**


**FinSi**

**Imprimir** "La consulta costará $"**,** costo**,** "."**;**

**Imprimir** "El costo total de su tratamiento es de $"**,**costoTratamiento**,**"."**;**

**FinAlgoritmo**

Para la solución de este problema se requiere saber qué número de cita se efectuará, con el cual se podrá́ determinar el costo que tendrá́ la consulta y cuánto se ha gastado en el tratamiento.



1. Realice un algoritmo para determinar el sueldo semanal de un trabajador con base en las horas trabajadas y el pago por hora, considerando que después de las 40 horas cada hora se considera como excedente y se paga el doble.

**Algoritmo** sueldoPorSemana

**Definir** horas **como** **Real;**

**Definir** sueldo **Como** **Real;**

**Definir** pagoHora **Como** **Real;**

**Definir** horasExtras **Como** **Real;**

**Imprimir** "¿Cuanto se paga por hora?: "**;**

**Leer** pagoHora**;**

**Imprimir** "Ingrese la cantidad de horas: "**;**

**Leer** horas**;**

**Si** horas **>** 40 **Entonces**

horasExtras = 2**\*** **(**horas **-** 40**)\***pagoHora**;**

sueldo = horasExtras **+** 40**\***pagoHora**;**


**SiNo**

sueldo = horas**\***pagoHora**;**

**FinSi**

**Imprimir** "El sueldo es de $"**,** sueldo**;**

**FinAlgoritmo**



1. Fábricas “El cometa” produce artículos con claves (1, 2, 3, 4, 5 y 6). Se requiere un algoritmo para calcular los precios de venta, para esto hay que considerar lo siguiente:

Costo de producción = materia prima + mano de obra + gastos de fabricación.

Precio de venta = costo de producción + 45 % de costo de producción.

El costo de la mano de obra se obtiene de la siguiente forma: para los productos con clave 3 ó 4 se carga 75% del costo de la materia prima; para los que tienen clave 1 y 5 se carga 80%, y para los que tienen clave 2 o 6, 85 %. Para calcular el gasto de fabricación se considera que si el artículo que se va a producir tiene claves 2 ó 5, este gasto representa 30% sobre el costo de la materia prima; si las claves son 3 ó 6, representa 35%; si las claves son 1 o 4, representa 28%. La materia prima tiene el mismo costo para cualquier clave. Represente mediante el diagrama de flujo, el -pseudocódigo.

**Algoritmo** ElCometa

*//Definimos variables*

**Definir** claveProducto **Como** **Entero;**

**Definir** precioVenta**,** materiaPrima**,** manoObra**,** fabricacion**,** produccion **Como** **Real;**

**Definir** existeClave **Como** **Logico;**

*//Solicitamos info al usuario*

**Escribir** "Ingresa la clave del producto"**;**

**Leer** claveProducto**;**

existeClave = **Verdadero;**

**Escribir** "Ingresa el costo de materia prima"**;**

**Leer** materiaPrima**;**

*//manoObra*

**Si** claveProducto **==** 3 **O** claveProducto **==** 4 **Entonces**

manoObra = materiaPrima**\***.75**;**

**SiNo**

**Si** claveProducto **==** 1 **O** claveProducto **==** 5 **Entonces**

manoObra = materiaPrima**\***.80**;**

**SiNo**

**Si** claveProducto **==** 2 **O** claveProducto **==** 6 **Entonces**

manoObra = materiaPrima**\***.85**;**

**SiNo**

existeClave = **Falso;**

**Fin** **Si**

**Fin** **Si**

**Fin** **Si**

*//fabricacion*

**Si** existeClave **==** **Verdadero** **Entonces**

**Si** claveProducto **==** 2 **O** claveProducto **==** 5 **Entonces**

fabricacion = materiaPrima**\***.30 **+** materiaPrima**;**

**SiNo**

**Si** claveProducto **==** 3 **O** claveProducto **==** 6 **Entonces**

fabricacion = materiaPrima**\***.35 **+** materiaPrima**;**

**SiNo**

**Si** claveProducto **==** 2 **O** claveProducto **==** 6 **Entonces**

fabricacion = materiaPrima**\***.28 **+** materiaPrima**;**

**Fin** **Si**

**Fin** **Si**

**Fin** **Si**

produccion = materiaPrima **+** manoObra **+** fabricacion**;**

precioVenta = produccion**\***.45**+**produccion**;**

**Escribir** "El precioVenta de venta es: $"**,** precioVenta**;**


**SiNo**

**Escribir** "Esa clave de producto no existe :("**;**

**Escribir** "Reinicie el programa para calcular el precio de venta"**;**

**Fin** **Si**

**FinAlgoritmo**



1. Una compañía de paquetería internacional tiene servicio en algunos países de América del Norte, América Central, América del Sur, Europa y Asia. El costo por el servicio de paquetería se basa en el peso del paquete y la zona a la que va dirigido.

Tabla

Descripción generada automáticamente

Parte de su política implica que los paquetes con un peso superior a 5 kg no son transportados, esto por cuestiones de logística y de seguridad. Realice un algoritmo para determinar el cobro por la entrega de un paquete o, en su caso, el rechazo de la entrega; represéntelo mediante diagrama de flujo y pseudocódigo.

**Algoritmo** PaqueteriaInternacional

*//Definimos variables*

**Definir** costoGramo**,** peso**,** costoTotal **Como** **Real;**

**Definir** zona **Como** **Entero;**

*//Solicitamos información al usuario*

**Escribir** "Ingrese el peso en gramos de su paquete a enviar"**;**

**Leer** peso**;**

**Escribir** "A qué zona lo enviará?"**;**

**Escribir** " - America del norte (1)"**;**

**Escribir** " - America central (2)"**;**

**Escribir** " - America del sur (3)"**;**

**Escribir** " - Europa (4)"**;**

**Escribir** " - Asia (5)"**;**

**Leer** zona**;**

*//Hacemos el calculo dependiendo el peso y la zona*

**si** peso **>** 5000 **Entonces**

**Escribir** " Por cuestiones de logistica no podemos enviar su paquete."**;**

costoGramo=0**;**

**SiNo**

**Segun** zona **Hacer**

1**:**

costoGramo=11**;**

2**:**

costoGramo=10**;**

3**:**

costoGramo=12**;**

4**:**

costoGramo=24**;**

5**:**

costoGramo=27**;**

**De** **Otro** **Modo:**

**Escribir** "No existe esa zona"**;**

costoGramo=0**;**

**Fin** **Segun**

**FinSi**

*//Devolvemos el resultadp*


**Si** costoGramo **≠** 0 **Entonces**

costoTotal = costoGramo **\*** peso**;**

**Escribir** "El costo total para enviar su paquete a la zona "**,** zona**,** " es $"**,** costoTotal**;**

**FinSi**

**FinAlgoritmo**



1. El dueño de un estacionamiento requiere un diagrama de flujo con el algoritmo que le permita determinar cuanto debe cobrar por el uso del estacionamiento a sus clientes. Las tarifas que se tienen son las siguientes:

* Las dos primeras horas a $5.00 c/u.
* Las siguientes tres a $4.00 c/u.
* Las cinco siguientes a $3.00 c/u.
* Después de diez horas el costo por cada una es de dos pesos.

**Algoritmo** Estacionamiento

*//Definimos las variables*

**Definir** horas**,** costo **Como** **Real;**

*//Pedimos los valores al usuario*

**Escribir** "¿Cuántas horas se estacionó?"**;**

**Leer** horas**;**

*//Obtenemos el costo y el pago total*

**Si** horas **≥** 10 **Entonces**

costo = **(**horas**-**10**)\***2 **+** 37**;**

**SiNo**

**Si** horas **≥** 5 **Entonces**

costo = **(**horas**-**5**)\***3 **+** 22**;**

**SiNo**

**Si** horas **≥** 2 **Entonces**

costo = **(**horas**-**2**)\***4 **+** 10**;**

**SiNo**

costo = horas **\*** 5**;**

**Fin** **Si**


**Fin** **Si**

**Fin** **Si**

*//Devolvemos el pago al usuario*

**Escribir** "Su pago por "**,**horas**,**" horas es $"**,**costo**;**

**FinAlgoritmo**



1. El banco “Pueblo desconocido” ha decidido aumentar el límite de crédito de las tarjetas de crédito de sus clientes, para esto considera que, si su cliente tiene tarjeta tipo 1, el aumento será de 25%; si tiene tipo 2, será de 35%; si tiene tipo 3, de 40%, y para cualquier otro tipo, de 50%. Realice un algoritmo y represente su diagrama de flujo y el pseudocódigo para determinar el nuevo límite de crédito que tendrá una persona en su tarjeta.

**Algoritmo** BancoEnPuebloDesconocido

*//Definir¿mos variables*

**Definir** limiteCredito **Como** **Real;**

**Definir** tipo **Como** **Entero;**

**Definir** NuevoLimite **Como** **Real;**

**Definir** Aumento **Como** **Real;**

*//Solicitmoas el limite y el tipo de tarjeta al usuario*

**Escribir** "Ingrese el limite de credito de su tarjeta "**;**

**Leer** limiteCredito**;**

**Escribir** "Ingrese su tipo de tarjeta"**;**

**Leer** tipo**;**

*//Determminamos el aumento*

**Segun** tipo **Hacer**

1**:**

Aumento = .25**;**

2**:**

Aumento = .35**;**

3**:**

Aumento = .4**;**

**De** **Otro** **Modo:**

Aumento = .5**;**

**Fin** **Segun**


*//Calculamos el NuevoLimite*

NuevoLimite = limiteCredito **+** **(**limiteCredito **\*** Aumento**);**

*//Le devolvemos al usuario su nuevo límite de crédito*

**Escribir** "Su nuevo limite de credito es $"**,** NuevoLimite**;**

**FinAlgoritmo**



1. El presidente de la república ha decidido estimular a todos los estudiantes de una universidad mediante la asignación de becas mensuales, para esto se tomarán en consideración los siguientes criterios:

* Para alumnos mayores de 18 años con promedio mayor o igual a 9, la beca será́ de $2000.00; con promedio mayor o igual a 7.5, de $1000.00; para los promedios menores de 7.5 pero mayores o iguales a 6.0, de $500.00; a los demás se les enviará una carta de invitación incitándolos a que estudien más en el próximo ciclo escolar.
* A los alumnos de 18 años o menores de esta edad, con promedios mayores o iguales a 9, se les dará́ $3000; con promedios menores a 9 pero mayores o iguales a 8, $2000; para los alumnos con promedios menores a 8 pero mayores o iguales a 6, se les dará́ $100, y a los alumnos que tengan promedios menores a 6 se les enviará carta de invitación.

Realice el algoritmo correspondiente y represéntelo con un diagrama de flujo.

**Algoritmo** becasAMLO

*//Definimos variables*

**Definir** recibenBeca **Como** **Logico;**

**Definir** edad**,** beca **Como** **Entero;**

**Definir** promedio **Como** **Real;**

*//Solcitamos la información del alumn*

**Escribir** "Ingresar edad del alumnno"**;**

**Leer** edad**;**

**Escribir** "Ingresar promedio final del alumno"**;**

**Leer** promedio**;**

*//Determinamos si reciben beca y cuál*

recibenBeca = **Verdadero;**

**Si** edad **>** 18 **Entonces**

**Si** promedio **≥** 9 **Entonces**

beca = 2000**;**

**SiNo**

**Si** promedio **≥** 7.5 **Entonces**

beca = 1000**;**

**SiNo**

**Si** promedio **≥** 6 **Entonces**

beca = 500**;**

**SiNo**

recibenBeca = **Falso;**

**Fin** **Si**

**Fin** **Si**

**Fin** **Si**

**SiNo**

**Si** promedio **≥** 9 **Entonces**

beca = 3000**;**

**SiNo**

**Si** promedio **≥** 8 **Entonces**

beca = 2000**;**

**SiNo**

**Si** promedio **≥** 6 **Entonces**

beca = 100**;**

**SiNo**

recibenBeca = **Falso;**

**Fin** **Si**

**Fin** **Si**

**Fin** **Si**

**Fin** **Si**

*//Imprimimos el resultado dependiendo si recibe Beca*

**Si** recibenBeca **==** **Verdadero** **Entonces**


**Escribir** "Beca mensual: $"**,** beca**;**

**SiNo**

**Escribir** "Enviar invitación al alumno"**;**

**Fin** **Si**

**FinAlgoritmo**



1. Los alumnos de una escuela desean realizar un viaje de estudios, pero requieren determinar cuanto les costará el pasaje, considerando que las tarifas del autobús son las siguientes: si son más de 100 alumnos, el costo es de $20; si son entre 50 y 100, $35; entre 20 y 49, $40, y si son menos de 20 alumnos, $70 por cada uno. Realice el algoritmo para determinar el costo del pasaje de cada alumno. Represente el algoritmo mediante el diagrama de flujo y el pseudocódigo.

**Algoritmo** ViajeEstudiosPasajes

*//Definimons variables*

**Definir** cantAlumnos **Como** **Entero;**

**Definir** costoPasajeAlumno **Como** **Real;**

*//Leer variables*

**Escribir** "Ingrese la cantidad de alumnos que asistiran al viaje de estud"**;**

**Leer** cantAlumnos**;**

*//Determinamos el costoPasajeAlumno dependiendo la cantidad de alumnos*

**si** cantAlumnos **>** 100 **Entonces**

costoPasajeAlumno = 20**;**

**SiNo**

**si** cantAlumnos **≥** 50 **y** cantAlumnos **≤** 100 **Entonces**

costoPasajeAlumno = 35**;**

**SiNo**

**si** alumnos **≥** 20 **y** cantAlumnos **<** 50 **Entonces**

costoPasajeAlumno = 40**;**

**SiNo**

**si** cantAlumnos **<** 20 **Entonces**

costoPasajeAlumno = 70**;**

**FinSi**

**FinSi**


**FinSi**

**FinSi**

*//Devolvemos el costo del Pasaje por Alumno*

**Escribir** "El costo de pasaje por alumno es de $"**,** costoPasajeAlumno**,** " MXN."**;**

**FinAlgoritmo**



1. El banco “Bandido de peluche” desea calcular para uno de sus clientes el saldo actual, el pago mínimo y el pago para no generar intereses. Los datos que se conocen son: saldo anterior del cliente, monto de las compras que realizó y el pago que depositó en el corte anterior. Para calcular el pago mínimo se debe considerar 15% del saldo actual, y para no generar intereses corresponde 85% del saldo actual, considerando que este saldo debe incluir 12% de los intereses causados por no realizar el pago mínimo y $200 por multa por el mismo motivo. Realice el algoritmo correspondiente y represéntelo mediante el diagrama de flujo y pseudocódigo.

**Algoritmo** SaldoIntereses

*//Definimos Variables*

*//Actuales*

**Definir** saldoActual**,** compra**,** pagoMinimo**,** pagoSinIntereses **Como** **Real;**

*//Relacion Previa*

**Definir** saldoAnterior**,** pagoAnterior**,** pagoMinimoAnt**,** pagoSinInteresesAnt **Como** **Real;**

*//solicitamos al usuario información de su saldo y deposito*

**Imprimir** "Ingrese su saldo:"**;**

**Leer** saldoAnterior**;**

**Imprimir** "Ingrese la cantidad que depósito anteriormente:"**;**

**Leer** pagoAnterior**;**

**Imprimir** "Ingrese el total de su compra:"**;**

**Leer** compra**;**

**Imprimir** "Saldo anterior: $"**,** saldoAnterior**;**

*//Calculamos pagos minimos y saldo actual*

pagoMinimoAnt = saldoAnterior**\***.15**;**

pagoSinInteresesAnt = saldoAnterior**\***.85**;**

saldoActual = saldoAnterior **+** compra **-** pagoAnterior**;;**

*//Agregamos intereses o multa*

**Si** pagoAnterior **<** pagoMinimoAnt **Entonces**

saldoActual = saldoActual **\*** 1.12 **+** 200**;**

**SiNo**

**Si** pagoAnterior **<** pagoSinInteresesAnt **Entonces**

saldoActual = saldoActual **\*** 1.12**;**

**FinSi**

**FinSi**

*//calculamos pagos minimos nuevos*

pagoMinimo = saldoActual**\***.15**;**

pagoSinIntereses = saldoActual**\***.85**;**

*//Devolvemos al usuario su informacion*

**Imprimir** "Su saldo actual es $"**,** saldoActual**;**

**Imprimir** "Para no generar intereses pague: $"**,** pagoSinIntereses**,** "."**;**

**Imprimir** "Para no generar multa por atraso pague: $"**,** pagoMinimo**,** "."**;**

**FinAlgoritmo**

