Skip to content
Permalink
Branch: master
Find file Copy path
Find file Copy path
Fetching contributors…
Cannot retrieve contributors at this time
67 lines (55 sloc) 2.37 KB
# Maintainer: ArchStrike <team@archstrike.org>
buildarch=220
pkgname=interlock-git
_pkgname=interlock
pkgver=20190819.r403
pkgrel=1
groups=('archstrike' 'archstrike-crypto')
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
pkgdesc="File encryption front-end"
url="https://github.com/inversepath/interlock"
license=('GPL3')
depends=('cryptsetup' 'lvm2' 'sudo')
makedepends=('go-pie' 'git' 'inetutils' 'mercurial')
install=interlock.install
source=("${pkgname}::git+${url}.git"
"interlock.service"
"interlock-sysusers.conf"
"interlock-tmpfiles.conf")
sha512sums=('SKIP'
'd9d25e4f5cd2433eb6c5e1131d04b489c95c1b6e017d54d63e3eb9d442cb2c69c0d079ee4c3e02f50556955d012d154b112eec612b2b993a0a3f7bae53298258'
'8b2da279974b08912f46d270f1dfd79e46a67802f1605ffa5290b89b144ab456d2cae02b4ad4d443ca5965277e772cb5ace16656e4430a6d5e3311f287a05eb4'
'2310da21590c1bc1088b564249713621229a5c2263ba7bb3acc1ffc270bdc85ea13c0cff8440f42f6c05519148b01a33116229993964e77d4c6c2f94d3273c64')
pkgver() {
cd ${pkgname}
printf "%s.r%s" "$(git show -s --format=%ci master | sed 's/\ .*//g;s/-//g')" "$(git rev-list --count HEAD)"
}
prepare() {
cd ${pkgname}
sed -i "s#\"debug\": true,#\"debug\": false,#" interlock.conf.default
sed -i "s#\"static_path\": \"static\",#\"static_path\": \"/usr/share/${pkgname}/static\",#" interlock.conf.default
sed -i "s#certs/cert.pem#/var/lib/${_pkgname}/cert.pem#" interlock.conf.default
sed -i "s#certs/key.pem#/var/lib/${_pkgname}/key.pem#" interlock.conf.default
sed -i "s#\"TOTP\"#\"TOTP\",\n \"Signal\"#" interlock.conf.default
}
build() {
cd ${pkgname}
export GOPATH="${srcdir}"
make with_signal
}
package() {
cd ${pkgname}
# binary
install -Dm755 ${_pkgname} "${pkgdir}/usr/bin/${_pkgname}"
# licence
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# static files
install -dm755 "${pkgdir}/usr/share/${pkgname}"
cp -a --no-preserve=ownership static "${pkgdir}/usr/share/${pkgname}"
# config
install -Dm644 interlock.conf.default "${pkgdir}/etc/interlock.conf"
# systemd
install -Dm644 "${srcdir}/interlock-tmpfiles.conf" "${pkgdir}/usr/lib/tmpfiles.d/interlock.conf"
install -Dm644 "${srcdir}/interlock-sysusers.conf" "${pkgdir}/usr/lib/sysusers.d/interlock.conf"
install -Dm644 "${srcdir}/interlock.service" "${pkgdir}/usr/lib/systemd/system/interlock.service"
}
You can’t perform that action at this time.