Bilkent University

Department of Computer Engineering



CS 315 Project 2

Project Report

Can Kırımca 21802271 Section-2

Can Kırşallıoba 21801768 Section-2

**BNF description of RUNE**

**1) Program Definition**

<program> ::= <statement\_list>

<statement\_list> ::= <statement>

| <statement\_list> <statement>

<statement> ::= COMMENT

| <expression> SEMICOLON

| <loop>

| <if>

| <function\_definition>

| <assignment> SEMICOLON

**2) Types and Constants**

<data\_type> ::= INT\_TYPE

| FLOAT\_TYPE

| CHAR\_TYPE

| BOOLEAN\_TYPE

**3) Loop Definition**

<loop> ::= <while\_loop>

| <for\_loop>

<while\_loop> ::= WHILE LP <expression> RP LCB <statement\_list> RCB

<for\_loop> ::= FOR LP <for\_loop\_expression> RP LCB <statement\_list> RCB

<for\_loop\_expression> ::= <assignment> SEMICOLON <expression> SEMICOLON <assignment>

**4) Conditional Definition**

<if> ::= IF LP <expression> RP LCB <statement\_list> RCB <else>

| IF LP <expression> RP LCB <statement\_list> RCB

<else> ::= ELSE LCB <statement\_list> RCB

**5) Expressions**

<expression> ::= <expression> OR <expression2>

             | <expression2>

<expression2> ::= <expression2> AND <expression3>

             | <expression3>

<expression3> ::= <expression3> <equality\_operator> <expression4>

            | <expression4>

<expression4> ::= <expression4> <comparison\_operator> <expression5>

            | <expression5>

<expression5> ::= <expression5> PLUS <expression6>

             | <expression5> MINUS <expression6>

             | <expression6>

<expression6> ::= <expression6> MULTIPLICATION <expression7>

             | <expression6> DIVISION <expression7>

             | <expression6> REMAINDER <expression7>

             | <expression7>

<expression7> ::= <expression8> EXPONENTIATION <expression7>

             | <expression8>

<expression8> ::= LP <expression> RP

             | <expr>

<expr> ::= INT

      | FLOAT

      | CHAR

      | BOOLEAN

      | <function\_call>

      | IDENTIFIER

<function\_call> ::= IDENTIFIER LP <function\_call\_argument\_list> RP

| IDENTIFIER LP RP

| <primitive\_function\_call>

| <input\_statement>

| <output\_statement>

<equality\_operator> ::= EQUAL

| NOT\_EQUAL

<comparison\_operator> ::= GREATER\_THAN

| SMALLER\_THAN

| GREATER\_OR\_EQUAL

| SMALLER\_OR\_EQUAL

<assignment> ::= IDENTIFIER ASSIGNMENT\_OPERATOR <expression>

| <data\_type> IDENTIFIER ASSIGNMENT\_OPERATOR <expression>

**6) Function Definition**

<function\_definition> ::= <void\_with\_return>

| <void\_without\_return>

| <non\_void\_func\_def>

| <only\_return\_func\_def>

<void\_with\_return> ::= VOID\_TYPE IDENTIFIER LP <function\_definition\_argument\_list>

RP LCB <statement\_list> <void\_return\_statement> RCB

| VOID\_TYPE IDENTIFIER LP RP LCB <statement\_list> <void\_return\_statement> RCB

<void\_without\_return> ::= VOID\_TYPE IDENTIFIER LP

<function\_definition\_argument\_list> RP LCB <statement\_list> RCB

| VOID\_TYPE IDENTIFIER LP RP LCB <statement\_list> RCB

<non\_void\_func\_def> ::= <data\_type> IDENTIFIER LP

<function\_definition\_argument\_list> RP LCB <statement\_list> <return\_statement> RCB

| <data\_type> IDENTIFIER LP RP LCB <statement\_list> <return\_statement> RCB

<only\_return\_func\_def> ::= <data\_type> IDENTIFIER LP

<function\_definition\_argument\_list> RP LCB <return\_statement> RCB

| <data\_type> IDENTIFIER LP RP LCB <return\_statement> RCB

<void\_return\_statement> ::= RETURN SEMICOLON

<return\_statement> ::= RETURN <expression> SEMICOLON

<function\_definition\_argument\_list> ::= <function\_definition\_argument> COMMA

<function\_definition\_argument\_list>

| <function\_definition\_argument>

<function\_definition\_argument> ::= INT\_TYPE IDENTIFIER

| FLOAT\_TYPE IDENTIFIER

| CHAR\_TYPE IDENTIFIER

| BOOLEAN\_TYPE IDENTIFIER

<function\_call\_argument\_list> ::= <function\_call\_argument> COMMA

<function\_call\_argument\_list>

| <function\_call\_argument>

<function\_call\_argument> ::= INT

| FLOAT

| CHAR

| BOOLEAN

| IDENTIFIER

| <function\_call>

**7) Input Output Definition**

<input\_statement> ::= SCAN LP RP

<output\_statement> ::= PRINT LP <expression> RP

**8) Drone Functions**

<primitive\_function\_call> ::= <read\_inclination\_function>

| <read\_altitude\_function>

| <read\_temperature\_function>

| <read\_acceleration\_function>

| <turn\_on\_camera\_function>

| <turn\_off\_camera\_function>

| <take\_picture\_function>

| <read\_timestamp\_function>

| <connect\_to\_computer\_function>

| <takeoff\_function>

| <land\_function>

| <get\_flight\_time\_function>

<read\_inclination\_function> ::= READ\_INCLINATION LP RP

<read\_altitude\_function> ::= READ\_ALTITUDE LP RP

<read\_temperature\_function> ::= READ\_TEMPERATURE LP RP

<read\_acceleration\_function> ::= READ\_ACCELERATION LP RP

<turn\_on\_camera\_function> ::= TURN\_ON\_CAMERA LP RP

<turn\_off\_camera\_function> ::= TURN\_OFF\_CAMERA LP RP

<take\_picture\_function> ::= TAKE\_PICTURE LP RP

<read\_timestamp\_function> ::= READ\_TIMESTAMP LP RP

<connect\_to\_computer\_function> ::= CONNECT\_TO\_COMPUTER LP RP

<takeoff\_function> ::= TAKEOFF LP RP

<land\_function> ::= LAND LP RP

<get\_flight\_time> ::= GET\_FLIGHT\_TIME LP RP

**Explanation of the RUNE Language Constructs**

**Types**

In RUNE, there are 4 data types, which are the following: int, float, boolean, and char.

**Int type:**

Int type consists of positive integers, negative integers and zero.

**Float type:**

Float type takes numbers that are in decimal form. The syntax of the float numbers can be written as .4 or 0.4. Float numbers can also range between negative and positive values.

**Char type:**

Char type consists of the single characters in the Unicode. The char type should be written in single quotation marks.

**Boolean Type:**

Boolean type consists of two values: TRUE and FALSE. They are reserved key words so they cannot be used in naming other user defined variables.

**Variables**

The user can define and use variables in the language. This variable can take form of four different types of data as explained in the “Types” section. Example of defining and using a variable is as follows:

float a;

a <- 5.4;

int b <- 87;

**Operators**

In RUNE, six operators are defined. These operators are:

* Assignment operator
* Addition operator
* Subtraction operator
* Multiplication operator
* Division operator
* Exponentiation operator
* Remainder operator
* AND operator
* OR operator

**Assignment Operator (<-):**

In our language assignment operator is coded as “<-“. The reason we chose “<-“ as assignment operator is; since the assignments are taking place from the right-hand side to the left-hand side, it is very intuitive to use it. Hence, increasing the overall readability and writability of the code. An example of its usage is as follows:

a <- 5;

In the example above, 5 is assigned to the variable a.

**Addition Operator (+):**

The addition operator is coded as “+”. An example usage is as follows:

a <- 5 + 3;

In this example, 5 + 3 = 8 is assigned to the variable a.

**Subtraction Operator (-):**

The subtraction operator is coded as “-”. An example usage is as follows:

a <- 7 - 5;

In this example, 7 – 5 = 2 is assigned to the variable a.

The addition and subtraction operators also indicate the positivity/negativity of a number when they are written adjacent to the number (-5 indicates negative 5). Therefore, in addition and subtraction operations, there must be a space between the operands; otherwise, the parser gives a syntax error. An example usage is as follows:

a <- 8 – 6 + 2;

**Multiplication Operator (\*):**

The multiplication operator is coded as “\*”. An example usage is as follows:

a <- 3 \* 4;

In this example, 3 \* 4 = 12 is assigned to the variable a.

**Division Operator (/):**

The division operator is coded as “/”. An example usage is as follows:

a <- 8 / 2;

In this example, 8 / 2 = 4 is assigned to the variable a.

**Exponentiation Operator (\*\*):**

Exponentiation operation will be implemented, just like in Python language.

An example of its usage would be as follows:

  a <- 2\*\*3;

In this example, 2 to the power of 3, which is equal to 8, is assigned to the variable a.

In RUNE, the exponentiation operator is right-associative. An example statement is as follows:

a <- 2\*\*3\*\*2;

In this example, the exponentiation on the right-hand side is calculated first. After calculating 3 to the power of 2, which is equal to 9, the exponentiation on the left-hand side is calculated. In this case, it is 2 to the power of 9, which is equal to 512. Therefore, 512 is assigned to the variable a.

**Remainder Operator (%):**

The remainder operator is coded as %. It returns the remainder left over when one operand is divided by a second operand. An example usage is as follows:

a <- 8 % 5;

In this example, 8 % 5 = 3 is assigned to a.

**AND Operator (&&):**

If the two operands of the AND operator are both TRUE then it returns TRUE. Otherwise, it returns FALSE.

**OR Operator (||):**

If at least one of the operators is TRUE, the operator returns TRUE. Otherwise, it returns FALSE.

**Comments**

Comments are indicated with $ (dollar sign) in RUNE. Any text between two comment signs ($) is considered a comment. A comment can be an in-line comment, or it can have multiple lines. Since the dollar sign is not a common symbol to be found in code, it is easily identifiable in blocks of code. Thus, deciding on the dollar sign as our comment sign made the language more readable and writable. For instance;

                                      $ This is an example comment. $

**Program Definitions**

A program in RUNE consists of a statement list. A statement list can be either one statement or multiple statements. Statements include comments, expressions followed by a semicolon, loops, conditionals, or a function definition. These expressions will be explained in their respective sections.

**Loop Definitions**

We have two loop types in RUNE: while loop and for loop. Even though the syntax is similar to the syntax of C language, the statements inside a for or while block must be enclosed between curly brackets regardless of the number of statements. Example usage of those loops is as follows:

while( height < 30 ) {

print(height);

height <- height + 1;

}

for( int i <- 0; i < 5; i <- i + 1) {

        takePicture();

}

We implemented for loop as well as while loop to offer the choice of writing more functional counting loops when the user wishes to. Hence, increasing the expressivity of the language.

**Conditional Definitions**

In RUNE, we have two types of conditional in order to keep the language simple and friendly for beginners. The two conditionals we have are the if statement and else statement. An else could only follow an if statement. However, an if statement can be a standalone block. If the condition inside the if statement is not satisfied, statements inside the else block (if there is an else block) are executed. The syntax of if and else statements are inspired by C language. The statements after an if or else must be enclosed between curly brackets, regardless of the number of statements. Here is an example if-else block:

if (myNum > 6) {

        myNum <- 0;

} else {

        myNum <- myNum + 1;

}

The language allows each type of expression in an if statement. If this expression is a numerical value, all values except zero is considered TRUE and the statements in the block are executed.

**Expressions**

We have gathered all the expressions in this section of the code. Here, we have expressions of integer types, float types, logical expressions, functions, and operators. For the associativity and the precedence of the operators, we have followed the pattern that was explained to us by our instructor and in our book. We have separated the operators that have different precedence. The operators with the lowest precedence are higher in the hierarchy, and the operator with the highest precedence is at the lowest of the hierarchy. The following table illustrates operator precedence in RUNE:

|  |  |  |
| --- | --- | --- |
| **Operator** | **Precedence** | **Associativity** |
| ( | 9 | **Left to Right** |
| ) | 9 | **Left to Right** |
| \*\* | 8 | **Right to Left** |
| / | 7 | **Left to Right** |
| % | 7 | **Left to Right** |
| \* | 7 | **Left to Right** |
| - | 6 | **Left to Right** |
| + | 6 | **Left to Right** |
| < | 5 | **Left to Right** |
| <= | 5 | **Left to Right** |
| > | 5 | **Left to Right** |
| >= | 5 | **Left to Right** |
| == | 4 | **Left to Right** |
| != | 4 | **Left to Right** |
| && | 3 | **Left to Right** |
| || | 2 | **Left to Right** |
| <- | 1 | **Left to Right** |

***Table 1.*** *Demonstration of the precedence values, larger number means higher precedence.*

**Assignment:** The result of any numerical expression can be assigned to a variable. An example assignment is as follows:

a <- b + 5;

**Function Expression:** It includes an identifier which is the name of the function, a pair of parentheses, and an argument list in those parentheses that will be passed to the function.

**Logical Expression:** Logical Expression: This is an expression that results in a Boolean value. It can be in the following forms:

• TRUE or FALSE

• A comparison (<, >, <=, >=) between two numerical values (can be a function call that returns a numerical value).

• An equality (==, !=) check between two numerical or Boolean values.

**Function Definitions**

We were inspired by the C language for the function definitions, as well. We have a return type, which can be one of the data types we have introduced to the language. However, if the user does not want to return anything in that function, the return type can also be void. For the function's arguments, we have enabled integer, float, char and Boolean. A function may have no argument as well. Every non-void function has a return statement indicating the value returned by the function. A function can also return the value of an expression (such as “a + 5”). A void function can have an empty return statement (return;) as well. In that case, the return statement basically terminates the function call. Here are some example function definitions:

int foo(int num) {

        print(“Inside the function”);

        if(num == 1){

foo2();

}

        return num + 1;

}

int getHeight() {

        return height;

}

void foo3(int num) {

if (num == 1) {

return;

} else {

num <- num + 1;

}

}

**Input and Output Definitions**

For the input and output definitions, we have selected the “scan” and “print” keywords. “scan” gets a value from the user, and “print” outputs the given expression to the console. We chose these two reserved words because they are very intuitive to use for beginners. Also, choosing intuitive words instead of complicated ones enhances the overall readability and writability of the language.

**Drone Function Definitions**

The drone functions which are described in the project document will be implemented as inbuilt functions.

* **readInclination** function takes the data from the gyroscope and returns the value.
* **readAltitude** function takes the data from the barometer and returns the value.
* **readTemperature** function takes the data from the thermometer and returns the value.
* **readAcceleration** function takes the data from the acceleration sensor and returns the value.
* **setCameraState** function changes the state of the camera according to the boolean value passed as an argument. TRUE turns on the camera, and FALSE turns off the camera.
* **takePicture** function uses the camera that is on the drone to take pictures.
* **readTimestamp** function gets the time from the timer, then returns the value.
* **connectToComputer** function forms a connection between the drone and the base computer via wi-fi.
* **takeoff** function allows the drone to be airborne.
* **land** function lands the drone.
* **getFlightTime** function returns the time elapsed during the flight. Unit of the elapsed time is seconds.

**Important Remarks about the General Structure of RUNE**

In RUNE, we did not implement a structure such as main to initiate the code. Instead, we decided to let the user write the functions and the code structures they wish to write directly, just like in Python. The reason we did it this way is, because since RUNE is a drone programming language, we thought that it should be quick and simple to write code.

We do not have any conflicts in RUNE, we strived to eliminate all so that we would produce a language that works seamlessly.

**Evaluation of Our Language in Terms of Readability, Writability, And Reliability**

**Readability**

Our language is designed to be easy to use for users ranging from beginners to experts. The syntax is very close to C group languages. We chose this approach because the C group languages are around for a very long time, and people have grown accustomed to the syntax of them. We have paid close attention not to disregard the orthogonality of the language. We did not assign an operator to multiple operations, hence making RUNE appropriate to orthogonality. When it comes to data types, they are assigned to their respective identifiers to avoid confusion. For instance, the value of a float variable cannot be assigned to an integer variable.

**Writability**

Our language has an adequate number of data types and functionalities so that it does not confuse the writer of the code. Since we have a small number of primitive constructs and consistent sets of rules for combining them, we have enabled orthogonality for the language. We created different and easy forms of writing the same expression to enhance the expressivity of the language, such as using for loops instead of while loops.

**Reliability**

We tried to create the language so that it performs to its specifications under all sorts of conditions. For instance, in terms of type checking, we have enabled one of our functions to accept speed values for both int types and float types. At this stage, we did not implement any sort of exception handling system because we only wrote the BNF and the lex specification file. The same applies to aliasing. For readability and writability, we made sure that all the conditions for them are met, thus enhancing our language's reliability.

**References**

R. W. Sebesta, *Concepts of programming languages*. NY: Pearson, 2019.