add todo projector

Author: ChristianAlexander

lib/todo_backend/application.ex

@@ -9,6 +9,7 @@ defmodule TodoBackend.Application do
   def start(_type, _args) do
     children = [
       TodoBackend.App,
+      TodoBackend.Todos.Supervisor,
       # Start the Ecto repository
       TodoBackend.Repo,
       # Start the Telemetry supervisor

lib/todo_backend/todos/projectors/todo.ex

@@ -0,0 +1,58 @@
+defmodule TodoBackend.Todos.Projectors.Todo do
+  use Commanded.Projections.Ecto,
+    name: "Todos.Projectors.Todo",
+    application: TodoBackend.App,
+    consistency: :strong
+
+  alias TodoBackend.Repo
+
+  alias TodoBackend.Todos.Events.TodoCreated
+  alias TodoBackend.Todos.Events.TodoDeleted
+  alias TodoBackend.Todos.Events.TodoCompleted
+  alias TodoBackend.Todos.Events.TodoUncompleted
+  alias TodoBackend.Todos.Events.TodoTitleUpdated
+  alias TodoBackend.Todos.Events.TodoOrderUpdated
+
+  alias TodoBackend.Todos.Projections.Todo
+
+  project(%TodoCreated{} = created, _, fn multi ->
+    Ecto.Multi.insert(multi, :todo, %Todo{
+      uuid: created.uuid,
+      title: created.title,
+      completed: created.completed,
+      order: created.order
+    })
+  end)
+
+  project(%TodoDeleted{uuid: uuid}, _, fn multi ->
+    Ecto.Multi.delete(multi, :todo, fn _ -> %Todo{uuid: uuid} end)
+  end)
+
+  project(%TodoCompleted{uuid: uuid}, _, fn multi ->
+    case Repo.get(Todo, uuid) do
+      nil -> multi
+      todo -> Ecto.Multi.update(multi, :todo, Todo.update_changeset(todo, %{completed: true}))
+    end
+  end)
+
+  project(%TodoUncompleted{uuid: uuid}, _, fn multi ->
+    case Repo.get(Todo, uuid) do
+      nil -> multi
+      todo -> Ecto.Multi.update(multi, :todo, Todo.update_changeset(todo, %{completed: false}))
+    end
+  end)
+
+  project(%TodoTitleUpdated{uuid: uuid, title: title}, _, fn multi ->
+    case Repo.get(Todo, uuid) do
+      nil -> multi
+      todo -> Ecto.Multi.update(multi, :todo, Todo.update_changeset(todo, %{title: title}))
+    end
+  end)
+
+  project(%TodoOrderUpdated{uuid: uuid, order: order}, _, fn multi ->
+    case Repo.get(Todo, uuid) do
+      nil -> multi
+      todo -> Ecto.Multi.update(multi, :todo, Todo.update_changeset(todo, %{order: order}))
+    end
+  end)
+end

lib/todo_backend/todos/supervisor.ex

@@ -0,0 +1,18 @@
+defmodule TodoBackend.Todos.Supervisor do
+  use Supervisor
+
+  alias TodoBackend.Todos
+
+  def start_link(arg) do
+    Supervisor.start_link(__MODULE__, arg, name: __MODULE__)
+  end
+
+  def init(_arg) do
+    Supervisor.init(
+      [
+        Todos.Projectors.Todo
+      ],
+      strategy: :one_for_one
+    )
+  end
+end