⍝ JSON Parser in APL

# ⍝ Parser Combinators

\_o ← {0 ≥ ⊃ c a r ← p ← ⍺⍺ ⍵ : p ⋄ 0 ≥ ⊃ c a r2 ← p ← ⍵⍵ ⍵ : p ⋄ c a (r ↑⍨ - ⌊/ ≢¨ r r2)}  
 \_s ← {0 < ⊃ c a r ← p ← ⍺⍺ ⍵ : p ⋄ 0 < ⊃ c2 a2 r ← p ← ⍵⍵ r : p ⋄ (c ⌈ c2)(a, a2) r}  
 \_as ← {0 < ⊃ c a r ← ⍺⍺ ⍵ : c a r ⋄ c (,⊂⍵⍵ a) r}  
 \_t ← {0 < ⊃ c a r ← ⍺⍺ ⍵ : c a r ⋄ ⍵⍵ a : c a r ⋄ 2 ⍬ ⍵}  
 \_c ← {(0 ≠ ≢⍵) ∧ (⊃⍵) ∊ ⍺⍺ : 0 (,⊃⍵) (1 ↓ ⍵) ⋄ 2 ⍬ ⍵}  
 \_ign ← {c a r ← ⍺⍺ ⍵ ⋄ c ⍬ r}  
 \_yes ← {0 ⍬ ⍵}  
 \_opt ← {(⍺⍺ \_o \_yes)⍵}  
 \_any ← {(⍺⍺ \_s ∇ \_o \_yes)⍵}  
 \_some ← {(⍺⍺ \_s (⍺⍺ \_any))⍵}  
 \_eat ← {0 (⍺⍺ ↑ ⍵) (⍺⍺ ↓ ⍵)}

# ⍝ BNF Grammar

⍝ value ::= obj | arr | string | float  
⍝ obj ::= "{" [ members ] "}"  
⍝ arr ::= "[" [ values ] "]"  
⍝ members ::= member {"," member}  
⍝ member ::= name ":" value  
⍝ values ::= value {"," value}    
⍝ name ::= "[a-zA-Z\_][a-zA-Z0-9\_]\*"  
⍝ float ::= ^[-+]?[0-9]\*\.?[0-9]+([eE][-+]?[0-9]+)?  
⍝ string ::= ".\*"

q ← '"' \_c \_ign ⋄ d ← ⎕D \_c ⋄ pm ← '-+' \_c \_opt ⋄ w ← (⎕UCS 9 10 13 32) \_c \_any \_ign

lbrk ← w \_s ('[' \_c) \_s w \_ign ⋄ rbrk ← w \_s (']' \_c) \_s w \_ign  
 lbrc ← w \_s ('{' \_c) \_s w \_ign ⋄ rbrc ← w \_s ('}' \_c) \_s w \_ign

string ← w \_s q \_s (1 \_eat \_t ('"' ≢ ⊃) \_any) \_s q \_s w \_as ⊢  
 float ← w \_s pm \_s (d \_any \_s ('.' \_c) \_opt) \_s (d \_some) \_s ('eE' \_c \_s pm \_s (d \_some) \_opt) \_s w \_as ⍎  
 Name ← string \_t {(⊃⍵) (∧⌿ ∊ ∧ (⊃⊣) ∊ 10 ↓ ⊢) ⎕D, '\_', ⎕UCS ,65 97 ∘.+ ⍳26}  
 Values ← {(Value \_s (w \_s (',' \_c) \_s w \_ign \_s Value \_any))⍵}  
 Member ← {(Name \_s (w \_s (':' \_c) \_s w \_ign) \_s Value \_as ⊢)⍵}  
 Members ← Member \_s (w \_s (',' \_c) \_s w \_ign \_s Member \_any)  
 Array ← lbrk \_s Values \_s rbrk \_as ⊢  
 Object ← lbrc \_s Members \_s rbrc \_as ↑  
 Value ← string \_o float \_o Array \_o Object

# ⍝ Example: 1 0 ⊃ *Value* *json*

json ← '{', nl ← ⎕UCS 13  
 json ,← ' "contact": {', nl  
 json ,← ' "name": "First Last",', nl  
 json ,← ' "email" : "अध्यनाम.उपनाम@पृथ्वी.अाकाशगंगा",', nl  
 json ,← ' "address": {', nl  
 json ,← ' "street": "10 Market Road",', nl  
 json ,← ' "city" : "Mumbai, MH",', nl  
 json ,← ' "country" : "भारत",', nl  
 json ,← ' "zip" : 555555', nl  
 json ,← ' },', nl  
 json ,← ' "phone\_numbers": [', nl  
 json ,← ' {"home" : "123 456-7890"},', nl  
 json ,← ' {"office" : "987 654-3210"},', nl  
 json ,← ' {"cell" : "222 444-6666"}', nl  
 json ,← ' ] ', nl  
 json ,← ' }', nl  
 json ,← '}', nl