**Полюга Дмитро Сергійович, ТІ-62**

**Варіант 13(10, 1, 2, 1, 2, 1)**

**Граматика мови програмування**

<program> ::= <declaration\_list> begin <operators\_list> end

<declaration\_list> ::= <declaration\_list> <declaration> ; | <declaration> ;

<declaration> ::= <variable\_type> <variables\_list>

<variable\_type> ::= int | float

<variables\_list> ::= <identifier> | <identifier> , <variables\_list>

<operators\_list> ::= <operators\_list> <operator> ; | <operators\_list> <label> : | <operator> ; | <label> :

<operator> ::= <assignment> | <user\_input> | <user\_output> | <loop> | <conditional\_statement> | goto <label>

<user\_input> ::= cin >> <identifier> | <user\_input> >> <identifier>

<user\_output> ::= cout << <identifier> | <user\_output> << <identifier>

<loop> ::= for <identifier> = <expression> by <expression> to <expression> do <operators\_list> rof

<conditional\_statement> ::= if <LR> then <operators\_list> fi

<assignment> ::= <identifier> = <expression>

<expression> ::= <T> | <expression> + <T> | <expression> - <T> | - <T>

<T> ::= <F> | <T> \* <F> | <T> / <F>

<F> ::= <identifier> | <constant\_fixed\_accuracy> | ( <expression> )

<identifier> ::= <identifier> <character> | <identifier> <digit> | <character>

<character> ::= A | B | C | D | E | F | G | H | I | J | K | L | M | N | O | P | Q | R | S | T | U | V | W | X | Y | Z | a | b | c | d | e | f | g | h | i | j | k | l | m | n | o | p | q | r | s | t | u | v | w | x | y | z

<digit> ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9

<constant\_fixed\_accuracy> ::= <number> | . <number> | <number> . | <number> . <number>

<number > ::= <digit> | <number> <digit>

<LR> ::= <LR> or <LT> | <LT>

<LT> ::= <LT> and <LF> | <LF>

<LF> ::= <relation> | [ <LR> ] | not <LF>

<relation> ::= <expression> <relation\_sign> <expression>

<relation\_sign> ::= < | > | <= | >= | == | !=

<label> ::= # <identifier>

**Таблиця лексем мови програмування**

|  |  |
| --- | --- |
| Id | Name |
| 1 | int |
| 2 | float |
| 3 | begin |
| 4 | end |
| 5 | goto |
| 6 | cin |
| 7 | cout |
| 8 | for |
| 9 | by |
| 10 | to |
| 11 | do |
| 12 | rof |
| 13 | if |
| 14 | then |
| 15 | fi |
| 16 | ; |
| 17 | : |
| 18 | , |
| 19 | = |
| 20 | >> |
| 21 | << |
| 22 | > |
| 23 | < |
| 24 | >= |
| 25 | <= |
| 26 | == |
| 27 | != |
| 28 | + |
| 29 | - |
| 30 | \* |
| 31 | / |
| 32 | ( |
| 33 | ) |
| 34 | or |
| 35 | and |
| 36 | not |
| 37 | [ |
| 38 | ] |
| 100 | IDN |
| 101 | CON |
| 102 | LAB |

**Показовий приклад програми**

float a, d, sum;

int q;

int i;

begin

q = 56;

a = 1.2;

d = .7;

if a > 1 and q < 50 then

goto #f;

fi;

a = (q + a + d) / 100;

#f:

sum = a / d + 1.2 \* q;

for i = 20 by 1 to 30 do

cout << i;

rof;

end

**Вихідні таблиці лексичного аналізатора**

**NEW**

1 – *головна таблиця*

|  |  |
| --- | --- |
| IDN number | IDN |
| 0 | a |
| 1 | d |
| 2 | sum |
| 3 | q |
| 4 | i |

2 – *таблиця ідентифікаторів*

|  |  |  |
| --- | --- | --- |
| CON number | CON | CON type |
| 0 | 56 | int |
| 1 | 1.2 | float |
| 2 | 0.7 | float |
| 3 | 1 | int |
| 4 | 50 | int |
| 5 | 100 | int |
| 6 | 20 | int |
| 7 | 30 | int |

3 – *таблиця констант*

|  |  |
| --- | --- |
| LAB number | LAB |
| 0 | #f |

3 – *таблиця міток*

**Спрощена граматика мови програмування**

program = declaration\_list "begin" operators\_list "end".

declaration\_list = declaration ";" {declaration ";"}.

declaration = type variables\_list.

type = "int" | "float".

variables\_list = "identifier" ("," variables\_list | ).

operators\_list = (operator ";" | "label" ":") {operator ";" | "label" ":"}.

operator = assignment | input | output | loop | conditional\_statement | "goto" "label".

input = "cin" ">>" "identifier" {">>" "identifier"}.

output = "cout" "<<" "identifier" {"<<" "identifier"}.

loop = "for" "identifier" "=" expression "by" expression "to" expression "do" operators\_list "rof".

conditional\_statement = "if" LR "then" operators\_list "fi".

assignment = "identifier" "=" expression.

expression = (T | "-" T) {"+" T | "-" T}.

T = F {"\*" F | "/" F}.

F = "identifier" | "constant\_fixed\_accuracy" | "(" expression ")".

LR = LT {"or" LT}.


LT = LF {"and" LF}.

LF = relation | "[" LR "]" | "not" LF.

relation = expression relation\_sign expression.

relation\_sign = ">" | "<" | ">=" | "<=" | "==" | "!=".

**Скінченний автомат у вигляді діаграми станів**



**Скінченний автомат у вигляді таблиці переходів**

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| **alpha** | **label** | **stack** | **beta** | **semantic subroutine** |
| 1 | int |  | 2 | [≠]err |
| float |  |
| 2 | identifier |  | 3 | [≠]err |
| 3 | , |  | 2 | [≠]err |
| ; |  | 4 |
| 4 | int |  | 2 | [≠]err |
| float |  |
| begin |  | 5 |
| 5 | label |  | 6 | [≠]<п/а operator> ↓7 (b: 20) |
| 6 | : |  | 8 | [≠]err |
| 7 | ; |  | 8 | [≠]err |
| 8 | label |  | 6 | [≠]<п/а operator> ↓7 (b: 20) |
| end |  | 9 |
| 9 |  |  |  | [≠]exit |
| 20 | identifier |  | 21 | [≠]err |
| goto |  | 23 |
| cin |  | 25 |
| cout |  | 28 |
| for |  | 31 |
| if | 42 | 70 (<п/а LR>) |
| 21 | = | 22 | 60 (<п/а expression>) | [≠]err |
| 22 |  |  |  | [≠]exit |
| 23 | label |  | 24 | [≠]err |
| 24 |  |  |  | [≠]exit |
| 25 | >> |  | 26 | [≠]err |
| 26 | identifier |  | 27 | [≠]err |
| 27 | >> |  | 26 | [≠]exit |
| 28 | << |  | 29 | [≠]err |
| 29 | identifier |  | 30 | [≠]err |
| 30 | << |  | 28 | [≠]exit |
| 31 | identifier |  | 32 | [≠]err |
| 32 | = | 33 | 60 (<п/а expression>) | [≠]err |
| 33 | by | 34 | 60 (<п/а expression>) | [≠]err |
| 34 | to | 35 | 60 (<п/а expression>) | [≠]err |
| 35 | do |  | 37 | [≠]err |
| 37 | label |  | 38 | [≠]<п/а operator> ↓39 (b: 20) |
| 38 | : |  | 40 | [≠]err |
| 39 | ; |  | 40 | [≠]err |
| 40 | label |  | 38 | [≠]<п/а operator> ↓39 (b: 20) |
| rof |  | 41 |
| 41 |  |  |  | [≠]exit |
| 42 | then |  | 44 | [≠]err |
| 44 | label |  | 45 | [≠]<п/а operator> ↓46 (b: 20) |
| 45 | : |  | 47 | [≠]err |
| 46 | ; |  | 47 | [≠]err |
| 47 | label |  | 45 | [≠]<п/а operator> ↓46 (b: 20) |
| fi |  | 48 |
| 48 |  |  |  | [≠]exit |
| 60 | - |  | 61 | [≠]err |
| ( | 62 | 60 (<п/а expression>) |
| identifier |  | 63 |
| constant |  |
| 61 | ( | 62 | 60 (<п/а expression>) | [≠]err |
| identifier |  | 63 |
| constant |  |
| 62 | ) |  | 63 | [≠]err |
| 63 | + |  | 61 | [≠]exit |
| - |  |
| \* |  |
| / |  |
| 70 | not |  | 70 | [≠]<п/а expression> ↓71 (b: 60) |
| [ | 72 | 70 (<п/а LR>) |
| 71 | > | 73 | 60 (<п/а expression>) | [≠]err |
| < |
| >= |
| <= |
| == |
| != |
| 72 | ] |  | 73 | [≠]err |
| 73 | and |  | 70 | [≠]exit |
| or |  |

**Граматика простого передування**

<program> ::= <declaration\_list> begin <operators\_list1> end

<declaration\_list> ::= <declaration\_list> <declaration> ; | <declaration> ;

<declaration> ::= <variable\_type> <variables\_list>

<variable\_type> ::= int | float

<variables\_list> ::= IDN | IDN , <variables\_list>

<operators\_list1> ::= <operators\_list>

<operators\_list> ::= <operators\_list> <operator> ; | <operators\_list> LAB : | <operator> ; | LAB :

<operator> ::= <assignment> | <user\_input> | <user\_output> | <loop> | <conditional\_statement> | goto LAB

<user\_input> ::= cin >> IDN | <user\_input> >> IDN

<user\_output> ::= cout << IDN | <user\_output> << IDN

<loop> ::= for IDN = <expression1> by <expression1> to <expression1> do: <operators\_list1> rof

<conditional\_statement> ::= if <LR1> then: <operators\_list1> fi

<assignment> ::= IDN = <expression1>

<expression1> ::= <expression>

<expression> ::= <T1> | <expression> + <T1> | <expression> - <T1> | - <T1>

<T1> ::= <T>

<T> ::= <F> | <T> \* <F> | <T> / <F>

<F> ::= IDN | CON | ( <expression1> )

<LR1> ::= <LR>

<LR> ::= <LR> or <LT> | <LT>

<LT> ::= <LT> and <LF> | <LF>

<LF> ::= <relation> | [ <LR1> ] | not <LF>

<relation> ::= <expression1> <relation\_sign> <expression1>

<relation\_sign> ::= < | > | <= | >= | == | !=