Example code of the QE approximation with non-constant total receptors in NONMEM

$PROBLEM BsAb QE approximation

$INPUT ID TIME DV AMT CMT EVID MDV

; $DATA data\_QE\_SC\_noPeri\_single.csv IGNORE=#

; $DATA data\_QE\_SC\_Peri\_multiple.csv IGNORE=#

$DATA data\_QE\_IVbolus\_noPeri\_single.csv IGNORE=#

; $DATA data\_QE\_IVbolus\_Peri\_multiple.csv IGNORE=#

; $DATA data\_QE\_IVinfusion\_noPeri\_single.csv IGNORE=#

$SUBROUTINE ADVAN13 TOL=9

$MODEL NCOMP=5

$ABBREVIATED DERIV2=NO

$PK

TVkel = THETA(1)

kel = TVkel\*EXP(ETA(1))

TVKD1 = THETA(2)

KD1 = TVKD1\*EXP(ETA(2))

TVKD2 = THETA(3)

KD2 = TVKD2\*EXP(ETA(3))

TValp = THETA(4)

alp = TValp\*EXP(ETA(4))

TVksynA = THETA(5)

ksynA = TVksynA\*EXP(ETA(5))

TVkdegA = THETA(6)

kdegA = TVkdegA\*EXP(ETA(6))

TVksynB = THETA(7)

ksynB = TVksynB\*EXP(ETA(7))

TVkdegB = THETA(8)

kdegB = TVkdegB\*EXP(ETA(8))

TVkintA = THETA(9)

kintA = TVkintA\*EXP(ETA(9))

TVkintB = THETA(10)

kintB = TVkintB\*EXP(ETA(10))

TVkintAB = THETA(11)

kintAB = TVkintAB\*EXP(ETA(11))

TVk12 = THETA(12)

k12 = TVk12\*EXP(ETA(12))

TVk21 = THETA(13)

k21 = TVk21\*EXP(ETA(13))

TVka = THETA(14)

ka = TVka\*EXP(ETA(14))

TVVC = THETA(15)

VC = TVVC\*EXP(ETA(15))

bioSC = THETA(16)

F5 = bioSC

; Initial conditions

A\_0(1) = 0

A\_0(2) = ksynA/kdegA

A\_0(3) = ksynB/kdegB

A\_0(4) = 0

A\_0(5) = 0

$DES

; === Infusion mechanism "by hand"

;

IN = 0

;

TDUR = 0.0001 ; IV bolus mimicked by short IV infusion

;TDUR = 14 ; for IV infusion

;

; --- dose = 335 at t = 0

IF (T.GE.0.AND.T.LE.0+TDUR) THEN

; IN = 0

IN = 335\*TDUR\*\*(-1)

; IN = 670\*TDUR\*\*(-1)

ENDIF

; --- dose = 670 at t = 24

;IF (T.GE.24.AND.T.LE.24+TDUR) THEN

; IN = 670\*TDUR\*\*(-1)

;ENDIF

C = A(1)

RA = A(2)

RB = A(3)

AP = A(4)

AB = A(5)

det1 = C\*KD2\*RA\*\*2+C\*\*2\*KD2\*RA+C\*KD1\*RB\*\*2+C\*\*2\*KD1\*RB+C\*\*2\*RA\*RB

det2 = alp\*KD1\*\*2\*KD2\*\*2+C\*KD1\*KD2\*RA+C\*KD1\*KD2\*RB+KD1\*KD2\*RA\*RB

det3 = alp\*C\*KD1\*KD2\*\*2+alp\*C\*KD1\*\*2\*KD2+alp\*C\*\*2\*KD1\*KD2

det4 = alp\*KD1\*KD2\*\*2\*RA+alp\*KD1\*\*2\*KD2\*RB+alp\*C\*KD1\*KD2\*RA+alp\*C\*KD1\*KD2\*RB

det = (det1+det2+det3+det4)/(alp\*KD1\*\*2\*KD2\*\*2)

m111 = C\*\*2\*KD2\*RA+C\*\*2\*KD1\*RB+alp\*KD1\*\*2\*KD2\*\*2+C\*KD1\*KD2\*RA

m112 = C\*KD1\*KD2\*RB+alp\*C\*KD1\*KD2\*\*2+alp\*C\*KD1\*\*2\*KD2+alp\*C\*\*2\*KD1\*KD2

m11 = (m111+m112)/(alp\*KD1\*\*2\*KD2\*\*2)

m12 = -(C\*\*2\*RA+C\*KD1\*RB+alp\*C\*\*2\*KD1+alp\*C\*KD1\*KD2)/(alp\*KD1\*\*2\*KD2)

m13 = -(C\*\*2\*RB+C\*KD2\*RA+alp\*C\*\*2\*KD2+alp\*C\*KD1\*KD2)/(alp\*KD1\*KD2\*\*2)

m21 = -(C\*RA\*\*2+KD1\*RA\*RB+alp\*C\*KD1\*RA+alp\*KD1\*KD2\*RA)/(alp\*KD1\*\*2\*KD2)

m221 = C\*RA\*\*2+C\*KD1\*RA+KD1\*RA\*RB+alp\*C\*KD1\*\*2+alp\*KD1\*\*2\*KD2

m222 = alp\*KD1\*\*2\*RB+alp\*C\*KD1\*RA+alp\*KD1\*KD2\*RA

m22 = (m221+m222)/(alp\*KD1\*\*2\*KD2)

m23 = -(C\*RA-alp\*C\*RA)/(alp\*KD1\*KD2)

m31 = -(C\*RB\*\*2+KD2\*RA\*RB+alp\*C\*KD2\*RB+alp\*KD1\*KD2\*RB)/(alp\*KD1\*KD2\*\*2)

m32 = -(C\*RB-alp\*C\*RB)/(alp\*KD1\*KD2)

m331 = C\*RB\*\*2+C\*KD2\*RB+KD2\*RA\*RB+alp\*C\*KD2\*\*2+alp\*KD1\*KD2\*\*2

m332 = alp\*KD2\*\*2\*RA+alp\*C\*KD2\*RB+alp\*KD1\*KD2\*RB

m33 = (m331+m332)/(alp\*KD1\*KD2\*\*2)

g11 = IN/VC-kel\*C-kintA\*(RA\*C)/KD1-kintB\*(RB\*C)/KD2

g12 = -kintAB\*(RA\*RB\*C)/(alp\*KD1\*KD2)-k12\*C+k21\*AP/VC+ka\*AB/VC

g1 = g11+g12

g2 = ksynA-kdegA\*RA-kintA\*(RA\*C)/KD1-kintAB\*(RA\*RB\*C)/(alp\*KD1\*KD2)

g3 = ksynB-kdegB\*RB-kintB\*(RB\*C)/KD2-kintAB\*(RA\*RB\*C)/(alp\*KD1\*KD2)

DADT(1) = (m11/det)\*g1 + (m12/det)\*g2 + (m13/det)\*g3

DADT(2) = (m21/det)\*g1 + (m22/det)\*g2 + (m23/det)\*g3

DADT(3) = (m31/det)\*g1 + (m32/det)\*g2 + (m33/det)\*g3

DADT(4) = k12\*C\*VC - k21\*AP

DADT(5) = -ka\*AB

$ERROR

IPRED = A(1)+1e-12

IRES = DV-IPRED

W = SQRT((THETA(18)\*IPRED)\*\*2+THETA(17)\*\*2)

IWRES = IRES/W

Y = IPRED+W\*ERR(1)

$THETA

0.05 FIX ; 1 kel

1E-3 FIX ; 2 KD1

0.01 FIX ; 3 KD2

1 FIX ; 4 alpha

1 FIX ; 5 ksynA

0.1 FIX ; 6 kdegA

10 FIX ; 7 ksynB

0.1 FIX ; 8 kdegB

0.05 FIX ; 9 kintA

0.05 FIX ; 10 kintB

0.1 FIX ; 11 kintAB

0 FIX ; 12 k12 no peripheral = 0, with peripheral = 10

3 FIX ; 13 k21

0.2 FIX ; 14 ka

3 FIX ; 15 V

0.75 FIX ; 16 f SC

0 FIX ; 17 Err add

1 FIX ; 18 Err prop

$OMEGA

0 FIX ; 1

0 FIX ; 2

0 FIX ; 3

0 FIX ; 4

0 FIX ; 5

0 FIX ; 6

0 FIX ; 7

0 FIX ; 8

0 FIX ; 9

0 FIX ; 10

0 FIX ; 11

0 FIX ; 12

0 FIX ; 13

0 FIX ; 14

0 FIX ; 15

$SIGMA

1 FIX

; $ESTIMATION METHOD=1 INTER NOABORT MAXEVAL=9999 PRINT=1 NSIG=3 SIGL=9

; $COV UNCONDITIONAL

$TABLE ID TIME IPRED IRES IWRES NOPRINT ONEHEADER FILE=sdtab01

Example of the dataset with dosing – IV bolus:

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| #ID | TIME | DV | AMT | CMT | EVID | MDV |
| 1 | 0 | . | 1.00E-16 | 1 | 1 | 1 |
| 1 | 0 | 0 | . | 1 | 0 | 0 |
| 1 | 0.0001 | . | 1.00E-16 | 1 | 1 | 1 |
| 1 | 0.5 | 5.96E+00 | . | 1 | 0 | 0 |

Example of the dataset with dosing – IV infusion:

IV infusion over 14 days

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| #ID | TIME | DV | AMT | CMT | EVID | MDV |
| 1 | 0 | . | 1.00E-16 | 1 | 1 | 1 |
| 1 | 0 | 0 | . | 1 | 0 | 0 |
| 1 | 0.5 | 3.79E-07 | . | 1 | 0 | 0 |
| 1 | 13.5 | 18.10837 | . | 1 | 0 | 0 |
| 1 | 14 | . | 1.00E-16 | 1 | 1 | 1 |
| 1 | 14 | 20.34954 | . | 1 | 0 | 0 |

Example of the dataset with dosing – SC:

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| #ID | TIME | DV | AMT | CMT | EVID | MDV |
| 1 | 0 | . | 4020 | 4 | 1 | 1 |
| 1 | 0 | 0 | . | 1 | 0 | 0 |
| 1 | 0.5 | 37.23706 | . | 1 | 0 | 0 |