**Applied Nonmem source code for Eqs. (15)-(23)**

$PROBLEM BsAb QE approximation

$INPUT ID TIME DV YTYPE AMT EVID MDV CMT AMTMLX ADM

$DATA data\_2\_sparse.csv IGNORE=#

$SUBROUTINE ADVAN13 TOL=9

$MODEL NCOMP=3

$ABBREVIATED DERIV2=NO

$PK

TVkel = THETA(1)

kel = TVkel\*EXP(ETA(1))

TVKD1 = THETA(2)

KD1 = TVKD1\*EXP(ETA(2))

TVKD2 = THETA(3)

KD2 = TVKD2\*EXP(ETA(3))

TValp = THETA(4)

alp = TValp\*EXP(ETA(4))

TVRA0 = THETA(5)

RA0 = TVRA0\*EXP(ETA(5))

TVRB0 = THETA(6)

RB0 = TVRB0\*EXP(ETA(6))

TVkint = THETA(7)

kint = TVkint\*EXP(ETA(7))

TVV = THETA(8)

V = TVV\*EXP(ETA(8))

kintA = kint

kintB = kint

kintAB = kint

kdegA = kint

kdegB = kint

ksynA = RA0\*kdegA

ksynB = RB0\*kdegB

; Initial conditions

A\_0(1) = 0

A\_0(2) = RA0

A\_0(3) = RB0

$DES

; === Infusion mechanism "by hand"

;

IN = 0

;

TDUR = 0.0001 ; IV bolus mimicked by short IV infusion

;

; --- dose = 335 at t = 0

IF (T.GE.0.AND.T.LE.0+TDUR) THEN

IN = 1675\*TDUR\*\*(-1)

ENDIF

C = A(1)

RA = A(2)

RB = A(3)

det1 = C\*KD2\*RA\*\*2+C\*\*2\*KD2\*RA+C\*KD1\*RB\*\*2+C\*\*2\*KD1\*RB+C\*\*2\*RA\*RB

det2 = alp\*KD1\*\*2\*KD2\*\*2+C\*KD1\*KD2\*RA+C\*KD1\*KD2\*RB+KD1\*KD2\*RA\*RB

det3 = alp\*C\*KD1\*KD2\*\*2+alp\*C\*KD1\*\*2\*KD2+alp\*C\*\*2\*KD1\*KD2

det4 = alp\*KD1\*KD2\*\*2\*RA+alp\*KD1\*\*2\*KD2\*RB+alp\*C\*KD1\*KD2\*RA+alp\*C\*KD1\*KD2\*RB

det = (det1+det2+det3+det4)/(alp\*KD1\*\*2\*KD2\*\*2)

m111 = C\*\*2\*KD2\*RA+C\*\*2\*KD1\*RB+alp\*KD1\*\*2\*KD2\*\*2+C\*KD1\*KD2\*RA

m112 = C\*KD1\*KD2\*RB+alp\*C\*KD1\*KD2\*\*2+alp\*C\*KD1\*\*2\*KD2+alp\*C\*\*2\*KD1\*KD2

m11 = (m111+m112)/(alp\*KD1\*\*2\*KD2\*\*2)

m12 = -(C\*\*2\*RA+C\*KD1\*RB+alp\*C\*\*2\*KD1+alp\*C\*KD1\*KD2)/(alp\*KD1\*\*2\*KD2)

m13 = -(C\*\*2\*RB+C\*KD2\*RA+alp\*C\*\*2\*KD2+alp\*C\*KD1\*KD2)/(alp\*KD1\*KD2\*\*2)

m21 = -(C\*RA\*\*2+KD1\*RA\*RB+alp\*C\*KD1\*RA+alp\*KD1\*KD2\*RA)/(alp\*KD1\*\*2\*KD2)

m221 = C\*RA\*\*2+C\*KD1\*RA+KD1\*RA\*RB+alp\*C\*KD1\*\*2+alp\*KD1\*\*2\*KD2

m222 = alp\*KD1\*\*2\*RB+alp\*C\*KD1\*RA+alp\*KD1\*KD2\*RA

m22 = (m221+m222)/(alp\*KD1\*\*2\*KD2)

m23 = -(C\*RA-alp\*C\*RA)/(alp\*KD1\*KD2)

m31 = -(C\*RB\*\*2+KD2\*RA\*RB+alp\*C\*KD2\*RB+alp\*KD1\*KD2\*RB)/(alp\*KD1\*KD2\*\*2)

m32 = -(C\*RB-alp\*C\*RB)/(alp\*KD1\*KD2)

m331 = C\*RB\*\*2+C\*KD2\*RB+KD2\*RA\*RB+alp\*C\*KD2\*\*2+alp\*KD1\*KD2\*\*2

m332 = alp\*KD2\*\*2\*RA+alp\*C\*KD2\*RB+alp\*KD1\*KD2\*RB

m33 = (m331+m332)/(alp\*KD1\*KD2\*\*2)

g11 = IN/V-kel\*C-kintA\*(RA\*C)/KD1-kintB\*(RB\*C)/KD2

g12 = -kintAB\*(RA\*RB\*C)/(alp\*KD1\*KD2)

g1 = g11+g12

g2 = ksynA-kdegA\*RA-kintA\*(RA\*C)/KD1-kintAB\*(RA\*RB\*C)/(alp\*KD1\*KD2)

g3 = ksynB-kdegB\*RB-kintB\*(RB\*C)/KD2-kintAB\*(RA\*RB\*C)/(alp\*KD1\*KD2)

DADT(1) = (m11/det)\*g1 + (m12/det)\*g2 + (m13/det)\*g3

DADT(2) = (m21/det)\*g1 + (m22/det)\*g2 + (m23/det)\*g3

DADT(3) = (m31/det)\*g1 + (m32/det)\*g2 + (m33/det)\*g3

$ERROR

IF ( YTYPE == 1 ) THEN

IPRED = A(1)+1e-12

IRES = DV-IPRED

W = SQRT((THETA(10)\*IPRED)\*\*2+THETA(9)\*\*2)

IWRES = IRES/W

Y = IPRED+W\*ERR(1)

ENDIF

IF ( YTYPE == 2 ) THEN

IPRED = A(2)+1e-12

IRES = DV-IPRED

W = SQRT((THETA(12)\*IPRED)\*\*2+THETA(11)\*\*2)

IWRES = IRES/W

Y = IPRED+W\*ERR(1)

ENDIF

IF ( YTYPE == 3 ) THEN

IPRED = A(3)+1e-12

IRES = DV-IPRED

W = SQRT((THETA(14)\*IPRED)\*\*2+THETA(13)\*\*2)

IWRES = IRES/W

Y = IPRED+W\*ERR(1)

ENDIF

$THETA

(0,0.15) ; 1 kel

(0,0.2) ; 2 KD1

(0,0.5) ; 3 KD2

1 FIX ; 4 alpha

(0,15) ; 5 RtotA

(0,80) ; 6 RtotB

(0,0.05) ; 7 kint

(0,2.5) ; 8 V

0 FIX ; 9 Err add

(0,0.3) ; 10 Err prop

0 FIX ; 11 Err add

(0,0.3) ; 12 Err prop

0 FIX ; 13 Err add

(0,0.3) ; 14 Err prop

$OMEGA

1 ; 1

0 FIX ; 2

0 FIX ; 3

0 FIX ; 4

0 FIX ; 5

0 FIX ; 6

0 FIX ; 7

1 ; 8

$SIGMA

1 FIX

$ESTIMATION METHOD=1 INTER NOABORT MAXEVAL=9999 PRINT=1 NSIG=3 SIGL=9

$COV UNCONDITIONAL MATRIX=R

$TABLE ID TIME IPRED YTYPE IRES IWRES NOPRINT ONEHEADER FILE=sdtab01