**Alternative Nonmem source code for Eqs. (15),(17),(25)-(30)**

$PROBLEM BsAb QE approximation with two constant total receptors

$INPUT ID TIME DV YTYPE AMT EVID MDV CMT AMTMLX

$DATA data\_2\_sparse.csv IGNORE=#

$SUBROUTINE ADVAN13 TOL=9

$MODEL NCOMP=1

$ABBREVIATED DERIV2=NO

$PK

TVkel = THETA(1)

kel = TVkel\*EXP(ETA(1))

TVKD1 = THETA(2)

KD1 = TVKD1\*EXP(ETA(2))

TVKD2 = THETA(3)

KD2 = TVKD2\*EXP(ETA(3))

TValp = THETA(4)

alp = TValp\*EXP(ETA(4))

TVRtotA0 = THETA(5)

RtotA0 = TVRtotA0\*EXP(ETA(5))

TVRtotB0 = THETA(6)

RtotB0 = TVRtotB0\*EXP(ETA(6))

TVkint = THETA(7)

kint = TVkint\*EXP(ETA(7))

TVV = THETA(8)

V = TVV\*EXP(ETA(8))

; Initial conditions

A\_0(1) = 0

$DES

; === Infusion mechanism "by hand"

;

IN = 0

;

TDUR = 0.0001 ; IV bolus mimicked by short IV infusion

;

; --- dose = 335 at t = 0

IF (T.GE.0.AND.T.LE.0+TDUR) THEN

; IN = 0

IN = 1675\*TDUR\*\*(-1)

ENDIF

C = A(1)

aa = (1+C/KD2)\*(C/(alp\*KD1\*KD2))

bb = (C\*(RtotA0-RtotB0))/(alp\*KD1\*KD2) + (1+C/KD1)\*(1+C/KD2)

dd = -RtotB0\*(1+C/KD1)

RB = RtotB0

IF (C.GT.0) THEN

RB = (-bb+SQRT(bb\*\*2-4\*aa\*dd))/(2\*aa)

ENDIF

RA = RtotA0 / ( 1 + C/KD1 + RB\*C/(alp\*KD1\*KD2))

det1 = C\*KD2\*RA\*\*2+C\*\*2\*KD2\*RA+C\*KD1\*RB\*\*2+C\*\*2\*KD1\*RB+C\*\*2\*RA\*RB

det2 = alp\*KD1\*\*2\*KD2\*\*2+C\*KD1\*KD2\*RA+C\*KD1\*KD2\*RB+KD1\*KD2\*RA\*RB

det3 = alp\*C\*KD1\*KD2\*\*2+alp\*C\*KD1\*\*2\*KD2+alp\*C\*\*2\*KD1\*KD2

det4 = alp\*KD1\*KD2\*\*2\*RA+alp\*KD1\*\*2\*KD2\*RB+alp\*C\*KD1\*KD2\*RA+alp\*C\*KD1\*KD2\*RB

det = (det1+det2+det3+det4)/(alp\*KD1\*\*2\*KD2\*\*2)

m111 = C\*\*2\*KD2\*RA+C\*\*2\*KD1\*RB+alp\*KD1\*\*2\*KD2\*\*2+C\*KD1\*KD2\*RA

m112 = C\*KD1\*KD2\*RB+alp\*C\*KD1\*KD2\*\*2+alp\*C\*KD1\*\*2\*KD2+alp\*C\*\*2\*KD1\*KD2

m11 = (m111+m112)/(alp\*KD1\*\*2\*KD2\*\*2)

g11 = IN/V-kel\*C-kint\*(RA\*C)/KD1-kint\*(RB\*C)/KD2

g12 = -kint\*(RA\*RB\*C)/(alp\*KD1\*KD2)

g1 = g11+g12

DADT(1) = (m11/det)\*g1

$ERROR

CC = A(1)

aaa = (1+CC/KD2)\*(CC/(alp\*KD1\*KD2))

bbb = (CC\*(RtotA0-RtotB0))/(alp\*KD1\*KD2) + (1+CC/KD1)\*(1+CC/KD2)

ddd = -RtotB0\*(1+CC/KD1)

RBB = RtotB0

IF (CC.GT.0) THEN

RBB = (-bbb+SQRT(bbb\*\*2-4\*aaa\*ddd))/(2\*aaa)

ENDIF

RAA = RtotA0 / ( 1 + CC/KD1 + RBB\*CC/(alp\*KD1\*KD2))

IF ( YTYPE == 1 ) THEN

IPRED = A(1)+1e-12

IRES = DV-IPRED

W = SQRT((THETA(10)\*IPRED)\*\*2+THETA(9)\*\*2)

IWRES = IRES/W

Y = IPRED+W\*ERR(1)

ENDIF

IF ( YTYPE == 2 ) THEN

IPRED = RAA+1e-12

IRES = DV-IPRED

W = SQRT((THETA(12)\*IPRED)\*\*2+THETA(11)\*\*2)

IWRES = IRES/W

Y = IPRED+W\*ERR(1)

ENDIF

IF ( YTYPE == 3 ) THEN

IPRED = RBB+1e-12

IRES = DV-IPRED

W = SQRT((THETA(14)\*IPRED)\*\*2+THETA(13)\*\*2)

IWRES = IRES/W

Y = IPRED+W\*ERR(1)

ENDIF

$THETA

(0,0.15) ; 1 kel

(0,0.2) ; 2 KD1

(0,0.5) ; 3 KD2

1 FIX ; 4 alpha

(0,15) ; 5 RtotA0

(0,80) ; 6 RtotB0

(0,0.05) ; 7 kint

(0,2.5) ; 8 V

0 FIX ; 9 Err add

(0,0.3) ; 10 Err prop

0 FIX ; 11 Err add

(0,0.3) ; 12 Err prop

0 FIX ; 13 Err add

(0,0.3) ; 14 Err prop

$OMEGA

1 ; 1

0 FIX ; 2

0 FIX ; 3

0 FIX ; 4

0 FIX ; 5

0 FIX ; 6

0 FIX ; 7

1 ; 8

$SIGMA

1 FIX

$ESTIMATION METHOD=1 INTER NOABORT MAXEVAL=9999 PRINT=1 NSIG=3 SIGL=9

$COV UNCONDITIONAL MATRIX=R

$TABLE ID TIME IPRED YTYPE IRES IWRES NOPRINT ONEHEADER FILE=sdtab01