-
Notifications
You must be signed in to change notification settings - Fork 21
/
find_split.jl
369 lines (330 loc) · 12.7 KB
/
find_split.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
#############################################
# Get the braking points
#############################################
function get_edges(X::AbstractMatrix{T}, nbins=250) where {T}
edges = Vector{Vector{T}}(undef, size(X, 2))
@threads for i in 1:size(X, 2)
edges[i] = quantile(view(X, :, i), (1:nbins) / nbins)
if length(edges[i]) == 0
edges[i] = [minimum(view(X, :, i))]
end
end
return edges
end
####################################################
# Transform X matrix into a UInt8 binarized matrix
####################################################
function binarize(X, edges)
X_bin = zeros(UInt8, size(X))
@threads for i in 1:size(X, 2)
X_bin[:,i] = searchsortedlast.(Ref(edges[i][1:end - 1]), view(X, :, i)) .+ 1
end
X_bin
end
"""
split_set!
Split row ids into left and right based on best split condition
"""
# function split_set!(left, right, 𝑖, X_bin::Matrix{S}, feat, cond_bin::S, offset=0) where S
# left_count = 0
# right_count = 0
# @inbounds for i in 1:length(𝑖)
# id = 𝑖[i]
# @inbounds if X_bin[id, feat] <= cond_bin
# left_count += 1
# left[offset + left_count] = id
# else
# right_count += 1
# right[offset + right_count] = id
# end
# end
# return (left[1:left_count], right[1:right_count])
# end
"""
Non Allocating split_set!
Take a view into left and right placeholders. Right ids are assigned at the end of the length of the current node set.
"""
function split_set!(left::V, right::V, 𝑖, X_bin::Matrix{S}, feat, cond_bin::S, offset) where {S,V}
left_count = 0
right_count = 0
@inbounds for i in 1:length(𝑖)
@inbounds if X_bin[𝑖[i], feat] <= cond_bin
left_count += 1
left[offset + left_count] = 𝑖[i]
else
right[offset + length(𝑖) - right_count] = 𝑖[i]
right_count += 1
end
end
return (view(left, (offset + 1):(offset + left_count)), view(right, (offset + length(𝑖)):-1:(offset + left_count + 1)))
end
"""
Multi-threads split_set!
Take a view into left and right placeholders. Right ids are assigned at the end of the length of the current node set.
"""
function split_set_chunk!(left, right, block, bid, X_bin, feat, cond_bin, offset, chunk_size, lefts, rights)
left_count = 0
right_count = 0
@inbounds for i in eachindex(block)
@inbounds if X_bin[block[i], feat] <= cond_bin
left_count += 1
left[offset + chunk_size * (bid - 1) + left_count] = block[i]
else
right_count += 1
right[offset + chunk_size * (bid - 1) + right_count] = block[i]
end
end
lefts[bid] = left_count
rights[bid] = right_count
return nothing
end
function split_set_threads!(out, left, right, 𝑖, X_bin::Matrix{S}, feat, cond_bin, offset, chunk_size=2^15) where {S}
left_count = 0
right_count = 0
iter = Iterators.partition(𝑖, chunk_size)
nblocks = length(iter)
lefts = zeros(Int, nblocks)
rights = zeros(Int, nblocks)
@sync for (bid, block) in enumerate(iter)
Threads.@spawn split_set_chunk!(left, right, block, bid, X_bin, feat, cond_bin, offset, chunk_size, lefts, rights)
end
left_sum = sum(lefts)
left_cum = 0
right_cum = 0
@inbounds for bid in 1:nblocks
view(out, offset + left_cum + 1:offset + left_cum + lefts[bid]) .= view(left, offset + chunk_size * (bid - 1) + 1:offset + chunk_size * (bid - 1) + lefts[bid])
view(out, offset + left_sum + right_cum + 1:offset + left_sum + right_cum + rights[bid]) .= view(right, offset + chunk_size * (bid - 1) + 1:offset + chunk_size * (bid - 1) + rights[bid])
left_cum += lefts[bid]
right_cum += rights[bid]
end
return (view(out, offset + 1:offset + sum(lefts)), view(out, offset + sum(lefts)+1:offset + length(𝑖)))
end
"""
update_hist!
GradientRegression
"""
function update_hist!(
::L,
hist::Vector{Vector{T}},
δ𝑤::Matrix{T},
X_bin::Matrix{UInt8},
𝑖::AbstractVector{S},
𝑗::AbstractVector{S}, K) where {L <: GradientRegression,T,S}
@inbounds @threads for j in 𝑗
@inbounds @simd for i in 𝑖
hid = 3 * X_bin[i,j] - 2
hist[j][hid] += δ𝑤[1, i]
hist[j][hid + 1] += δ𝑤[2, i]
hist[j][hid + 2] += δ𝑤[3, i]
end
end
return nothing
end
"""
update_hist!
GaussianRegression
"""
function update_hist!(
::L,
hist::Vector{Vector{T}},
δ𝑤::Matrix{T},
X_bin::Matrix{UInt8},
𝑖::AbstractVector{S},
𝑗::AbstractVector{S}, K) where {L <: GaussianRegression,T,S}
@inbounds @threads for j in 𝑗
@inbounds @simd for i in 𝑖
hid = 5 * X_bin[i,j] - 4
hist[j][hid] += δ𝑤[1, i]
hist[j][hid + 1] += δ𝑤[2, i]
hist[j][hid + 2] += δ𝑤[3, i]
hist[j][hid + 3] += δ𝑤[4, i]
hist[j][hid + 4] += δ𝑤[5, i]
end
end
return nothing
end
"""
update_hist!
Generic fallback
"""
function update_hist!(
::L,
hist::Vector{Vector{T}},
δ𝑤::Matrix{T},
X_bin::Matrix{UInt8},
𝑖::AbstractVector{S},
𝑗::AbstractVector{S}, K) where {L,T,S}
@inbounds @threads for j in 𝑗
@inbounds @simd for i in 𝑖
hid = (2 * K + 1) * (X_bin[i,j] - 1)
for k in 1:(2 * K + 1)
hist[j][hid + k] += δ𝑤[k, i]
end
end
end
return nothing
end
"""
update_gains!
GradientRegression
"""
function update_gains!(
loss::L,
node::TrainNode{T},
𝑗::Vector{S},
params::EvoTypes, K) where {L <: GradientRegression,T,S}
@inbounds @threads for j in 𝑗
node.hL[j][1] = node.h[j][1]
node.hL[j][2] = node.h[j][2]
node.hL[j][3] = node.h[j][3]
node.hR[j][1] = node.∑[1] - node.h[j][1]
node.hR[j][2] = node.∑[2] - node.h[j][2]
node.hR[j][3] = node.∑[3] - node.h[j][3]
@inbounds for bin in 2:params.nbins
binid = 3 * bin - 2
node.hL[j][binid] = node.hL[j][binid - 3] + node.h[j][binid]
node.hL[j][binid + 1] = node.hL[j][binid - 2] + node.h[j][binid + 1]
node.hL[j][binid + 2] = node.hL[j][binid - 1] + node.h[j][binid + 2]
node.hR[j][binid] = node.hR[j][binid - 3] - node.h[j][binid]
node.hR[j][binid + 1] = node.hR[j][binid - 2] - node.h[j][binid + 1]
node.hR[j][binid + 2] = node.hR[j][binid - 1] - node.h[j][binid + 2]
end
hist_gains_cpu!(loss, view(node.gains, :, j), node.hL[j], node.hR[j], params.nbins, params.λ, K)
end
return nothing
end
"""
update_gains!
GaussianRegression
"""
function update_gains!(
loss::L,
node::TrainNode{T},
𝑗::Vector{S},
params::EvoTypes, K) where {L <: GaussianRegression,T,S}
@inbounds @threads for j in 𝑗
node.hL[j][1] = node.h[j][1]
node.hL[j][2] = node.h[j][2]
node.hL[j][3] = node.h[j][3]
node.hL[j][4] = node.h[j][4]
node.hL[j][5] = node.h[j][5]
node.hR[j][1] = node.∑[1] - node.h[j][1]
node.hR[j][2] = node.∑[2] - node.h[j][2]
node.hR[j][3] = node.∑[3] - node.h[j][3]
node.hR[j][4] = node.∑[4] - node.h[j][4]
node.hR[j][5] = node.∑[5] - node.h[j][5]
@inbounds for bin in 2:params.nbins
binid = 5 * bin - 4
node.hL[j][binid] = node.hL[j][binid - 5] + node.h[j][binid]
node.hL[j][binid + 1] = node.hL[j][binid - 4] + node.h[j][binid + 1]
node.hL[j][binid + 2] = node.hL[j][binid - 3] + node.h[j][binid + 2]
node.hL[j][binid + 3] = node.hL[j][binid - 2] + node.h[j][binid + 3]
node.hL[j][binid + 4] = node.hL[j][binid - 1] + node.h[j][binid + 4]
node.hR[j][binid] = node.hR[j][binid - 5] - node.h[j][binid]
node.hR[j][binid + 1] = node.hR[j][binid - 4] - node.h[j][binid + 1]
node.hR[j][binid + 2] = node.hR[j][binid - 3] - node.h[j][binid + 2]
node.hR[j][binid + 3] = node.hR[j][binid - 2] - node.h[j][binid + 3]
node.hR[j][binid + 4] = node.hR[j][binid - 1] - node.h[j][binid + 4]
end
hist_gains_cpu!(loss, view(node.gains, :, j), node.hL[j], node.hR[j], params.nbins, params.λ, K)
end
return nothing
end
"""
update_gains!
Generic fallback
"""
function update_gains!(
loss::L,
node::TrainNode{T},
𝑗::Vector{S},
params::EvoTypes, K) where {L,T,S}
KK = 2 * K + 1
@inbounds @threads for j in 𝑗
@inbounds for k in 1:KK
node.hL[j][k] = node.h[j][k]
node.hR[j][k] = node.∑[k] - node.h[j][k]
end
@inbounds for bin in 2:params.nbins
@inbounds for k in 1:KK
binid = KK * (bin - 1)
node.hL[j][binid + k] = node.hL[j][binid - KK + k] + node.h[j][binid + k]
node.hR[j][binid + k] = node.hR[j][binid - KK + k] - node.h[j][binid + k]
end
end
hist_gains_cpu!(loss, view(node.gains, :, j), node.hL[j], node.hR[j], params.nbins, params.λ, K)
end
return nothing
end
"""
hist_gains_cpu!
GradientRegression
"""
function hist_gains_cpu!(::L, gains::AbstractVector{T}, hL::Vector{T}, hR::Vector{T}, nbins, λ::T, K) where {L <: GradientRegression,T}
@inbounds for bin in 1:nbins
i = 3 * bin - 2
# update gain only if there's non null weight on each of left and right side - except for nbins level, which is used as benchmark for split criteria (gain if no split)
if bin == nbins
@inbounds gains[bin] = hL[i]^2 / (hL[i + 1] + λ * hL[i + 2]) / 2
elseif hL[i + 2] > 1e-5 && hR[i + 2] > 1e-5
@inbounds gains[bin] = (hL[i]^2 / (hL[i + 1] + λ * hL[i + 2]) +
hR[i]^2 / (hR[i + 1] + λ * hR[i + 2])) / 2
end
end
return nothing
end
"""
hist_gains_cpu!
QuantileRegression
"""
function hist_gains_cpu!(::L, gains::AbstractVector{T}, hL::Vector{T}, hR::Vector{T}, nbins, λ::T, K) where {L <: Union{QuantileRegression,L1Regression},T}
@inbounds for bin in 1:nbins
i = 3 * bin - 2
# update gain only if there's non null weight on each of left and right side - except for nbins level, which is used as benchmark for split criteria (gain if no split)
if bin == nbins
@inbounds gains[bin] = abs(hL[i])
elseif hL[i + 2] > 1e-5 && hR[i + 2] > 1e-5
@inbounds gains[bin] = abs(hL[i]) + abs(hR[i])
end
end
return nothing
end
function hist_gains_cpu!(::L, gains::AbstractVector{T}, hL::Vector{T}, hR::Vector{T}, nbins, λ::T, K) where {L <: GaussianRegression,T}
@inbounds for bin in 1:nbins
i = 5 * bin - 4
# update gain only if there's non null weight on each of left and right side - except for nbins level, which is used as benchmark for split criteria (gain if no split)
@inbounds if bin == nbins
gains[bin] = (hL[i]^2 / (hL[i + 2] + λ * hL[i + 4]) + hL[i + 1]^2 / (hL[i + 3] + λ * hL[i + 4])) / 2
elseif hL[i + 4] > 1e-5 && hR[i + 4] > 1e-5
gains[bin] = (hL[i]^2 / (hL[i + 2] + λ * hL[i + 4]) +
hR[i]^2 / (hR[i + 2] + λ * hR[i + 4])) / 2 +
(hL[i + 1]^2 / (hL[i + 3] + λ * hL[i + 4]) +
hR[i + 1]^2 / (hR[i + 3] + λ * hR[i + 4])) / 2
end
end
return nothing
end
function hist_gains_cpu!(::L, gains::AbstractVector{T}, hL::Vector{T}, hR::Vector{T}, nbins, λ::T, K) where {L,T}
@inbounds for bin in 1:nbins
i = (2 * K + 1) * (bin - 1)
# update gain only if there's non null weight on each of left and right side - except for nbins level, which is used as benchmark for split criteria (gain if no split)
if bin == nbins
@inbounds for k in 1:K
if k == 1
gains[bin] = hL[i + k]^2 / (hL[i + k + K] + λ * hL[i + 2 * K + 1]) / 2
else
gains[bin] += hL[i + k]^2 / (hL[i + k + K] + λ * hL[i + 2 * K + 1]) / 2
end
end
elseif hL[i + 4] > 1e-5 && hR[i + 4] > 1e-5
@inbounds for k in 1:K
if k == 1
gains[bin] = (hL[i + k]^2 / (hL[i + k + K] + λ * hL[i + 2 * K + 1]) + hR[i + k]^2 / (hR[i + k + K] + λ * hR[i + 2 * K + 1])) / 2
else
gains[bin] += (hL[i + k]^2 / (hL[i + k + K] + λ * hL[i + 2 * K + 1]) + hR[i + k]^2 / (hR[i + k + K] + λ * hR[i + 2 * K + 1])) / 2
end
end
end
end
return nothing
end