
UNIVERSIDAD DE BUENOS AIRES

**Facultad de Ingeniería**

***Simulación (75.26)***

**“Venta de piezas de bronce”**

Cuatrimestre y año: **1’** **2015**

Profesora Titular: **Horacio** **Rocca**

Docente a cargo del TP: **Pablo Cadoche**

Grupo: **3**

Integrantes:

|  |  |  |
| --- | --- | --- |
| ***Padrón*** | ***Nombre*** | ***Email*** |
| 95202 | Federico Luis Amura | federicoamura@gmail.com |
|  |  |  |
|  |  |  |
|  |  |  |

|  |  |
| --- | --- |
| ***Fecha de 1ra. entrega: 10/06/2015*** |  |
| ***Observaciones:*** | |
| ***Nota final:*** | |

# Enunciado

Se desea simular el funcionamiento de una empresa que vende piezas de bronce para la industria, durante un día. A la misma arriban clientes cada 7 +/- 5 minutos.

Cada cliente es atendido en el mostrador por un empleado que le toma el pedido, el cual luego se prepara (hay 2 personas para ello: se elige uno u otro en forma indistinta), y después otra persona lo factura.

Hay otro empleado, telefonista, que atiende los llamados telefónicos, los cuales se producen cada 10 +/- 6 minutos, y la mitad de esos llamados son pedidos, que el telefonista le pasa a cualquier empleado desocupado (o sea: a los que preparan los pedidos o al que los toma en el mostrador), los llamados tienen mayor prioridad que los pedidos en mostrador, y el tiempo en tomarlos se indica en la tabla, y son preparados y facturados como el resto (por los otros empleados, igual que los de mostrador). El resto de los llamados telefónicos mantienen ocupado a otra persona por 2 +/- 1 minuto, pero no son pedidos (y esa persona no forma parte del sistema). Hay una única línea de teléfono, que se mantiene ocupada el tiempo que el telefonista atiende más el que tardan en tomar el pedido (o los 2+/-1 min. si no es un pedido). Mientras la línea está ocupada los llamados que llegan se pierden (*si no saben hacerlo consulten con su ayudante cómo simularlo*).

La cantidad de Productos de cada pedido varía del siguiente modo:

De 1 a 12 Productos: 60 %

De 13 a 20 Productos: 35 % (“hasta 20”)

De 21 a 100 Productos: 5 % (“hasta 100”)

*Sugerencia: defina una función continua de 4 puntos, el primer par sería 0,1 y el último 1,101*

La cantidad de total de Piezas de cada pedido sigue esta distribución:

De 1 a 20 piezas: 14 %

Hasta 50 piezas: 17 %

Hasta 200 piezas: 22 %

Hasta 500 piezas: 29 %

Hasta 2000 piezas: 17 %

Hasta 15000 piezas: 1 %

*Sugerencia: defina una función continua de 7 puntos, el primer par sería 0,1 y el último 1,15001*

El tiempo empleado en cada pedido es el siguiente:

|  |  |  |  |
| --- | --- | --- | --- |
| Tomar el pedido | | Preparar el pedido | Facturar |
| En mostrador | Por teléfono | el pedido |
| 2+/-1 minuto + | 3 +/- 1 minuto + | 5 +/- 2 minutos + | 120 +/- 30 seg + |
| 10 +/-2 seg por | 7+/- 2 seg por | 5 +/- 2 seg por cada producto + | 5 +/- 2 seg por |
| cada producto | cada producto | (3 +/- 1 seg) por cada 20 piezas | cada producto |

lo que significa que para preparar (es un ejemplo) un pedido que fue tomado en el mostrador, por 10 Productos y un total de 2505 piezas, los tiempos serían:

Tomar: 2 +/- 1 minuto + 10 \* (10 +/- 2) segundos

Preparar: 5 +/- 2 minuto + 10 \* (5 +/- 2) seg + 2505 / 20 *[=126, redondear hacia arriba]* \* (3 +/- 1) seg

Facturar: 120 +/- 30 seg + 10 \* (5 +/- 2) segundos

Tabular:

-El tiempo total para preparar el pedido.

-La cantidad de pedidos sin terminar cada 15 minutos. Se considera terminado después de facturar.

-La cantidad de pedidos sin terminar cuando se termina de tomar uno.

-La cantidad de pedidos sin terminar al terminar de despachar cada uno (una vez facturado).

Simular de 8 a 18 horas.

# Resolución

INITIAL X$EMPLEMOSTRADOR,1

INITIAL X$EMPLEPREPARADOR,2

INITIAL X$EMPLEFACTURADOR,1

INITIAL X$EMPLEHABLADOR,1

INITIAL X$NLINEAS,1

ENPROCESO STORAGE 50000

TOMOOTRO TABLE M1,400,50,30

SINTERQUI TABLE S$ENPROCESO,1,1,500

SINTERPED TABLE S$ENPROCESO,1,1,500

SINTERDES TABLE S$ENPROCESO,1,1,500

CANTPROD FUNCTION RN2,C4

0,1/0.6,13/0.95,21/1,101

CANTPIEZAS FUNCTION RN3,C7

0,1/0.14,21/0.31,51/0.53,201/0.82,501/0.99,2001/1,15001

EMPLEADOSPEDIDOS VARIABLE X$EMPLEMOSTRADOR+X$EMPLEPREPARADOR

EMPLEADOHABLADOR VARIABLE 10+X$EMPLEHABLADOR

EMPLEPREPARADOR VARIABLE 1+X$EMPLEMOSTRADOR

EMPLEFACTURADOR VARIABLE 30+X$EMPLEFACTURADOR

LINEAS VARIABLE 20+X$NLINEAS

;SUBSISTEMA RELOJ

GENERATE ,,,1

ADVANCE 36000

TERMINATE 1

;SUBSISTEMA TABULADOR

GENERATE 900

TABULATE SINTERQUI

TERMINATE

;SUBSISTEMA ARRIBO CLIENTES

GENERATE 420,300,1

ENTER ENPROCESO

ASSIGN NPRODUCTOS,FN$CANTPROD

ASSIGN NPIEZAS,FN$CANTPIEZAS

SELECT MIN 4,1,X$EMPLEMOSTRADOR,,Q

QUEUE \*4

SEIZE \*4

DEPART \*4

ADVANCE 120,60

ASSIGN AUX,P$NPRODUCTOS

TOMO ADVANCE 10,2

LOOP AUX,TOMO

TABULATE SINTERPED

RELEASE \*4

TRANSFER ,PREPARAR

;SUBSISTEMA ARRIBO LLAMADAS

GENERATE 600,360,10

SELECT NU 6,21,V$LINEAS,,,NOLINEA

SEIZE \*6

TRANSFER 0.5,OTRAPER

ENTER ENPROCESO

ASSIGN NPRODUCTOS,FN$CANTPROD

ASSIGN NPIEZAS,FN$CANTPIEZAS

SELECT MIN 4,1,V$EMPLEADOSPEDIDOS,,Q

SEIZE \*4

ADVANCE 180,60

ASSIGN AUX,P$NPRODUCTOS

TOMOPRODL ADVANCE 7,2

LOOP AUX,TOMOPRODL

TABULATE SINTERPED

TRANSFER ,PREPARARL

;SUBSISTEMA EMPLEADO HABLADOR

OTRAPER SELECT NU 5,11,V$EMPLEADOHABLADOR,,,NOHABLADOR

SEIZE \*5

ADVANCE 120,60

RELEASE \*5

RELEASE \*6

TERMINATE

;SUBSISTEMA EMPLEADO PREPARADOR

PREPARAR SELECT MIN 4,V$EMPLEPREPARADOR,V$EMPLEADOSPEDIDOS,,Q

QUEUE \*4

SEIZE \*4

DEPART \*4

PREPARARL ADVANCE 300,120

ASSIGN AUX,P$NPRODUCTOS

PREPPROD ADVANCE 5,2

LOOP AUX,PREPPROD

ASSIGN AUX,P$NPIEZAS

PREPPIEZ ADVANCE 3,1

TEST GE P$AUX,20,LISTO

ASSIGN AUX-,20

TRANSFER ,PREPPIEZ

LISTO RELEASE \*4

TABULATE TOMOOTRO

TRANSFER ,PAGAR

;SUBSISTEMA EMPLEADO FACTURADOR

PAGAR SELECT MIN 4,31,V$EMPLEFACTURADOR,,Q

QUEUE \*4

SEIZE \*4

DEPART \*4

ADVANCE 120,30

ASSIGN AUX,P$NPRODUCTOS

PAGOPROD ADVANCE 5,2

LOOP AUX,PAGOPROD

TABULATE SINTERDES

RELEASE \*4

TEST NE \*6,0,SEGUIR

RELEASE \*6

SEGUIR LEAVE ENPROCESO

TERMINATE

NOLINEA SAVEVALUE NOATIENDEN+,1

TERMINATE

NOHABLADOR SAVEVALUE NOHABLAN+,1

RELEASE \*6

TERMINATE

# Reporte de la simulación

**REPORTE SNAKE**

**Información general**

START\_TIME END\_TIME BLOCKS FACILITIES STORAGES

0 36001 77 6 1

**Bloques no ejecutables**

INITIAL X$EMPLEMOSTRADOR,1

INITIAL X$EMPLEPREPARADOR,2

INITIAL X$EMPLEFACTURADOR,1

INITIAL X$EMPLEHABLADOR,1

INITIAL X$NLINEAS,1

ENPROCESO STORAGE 50000

TOMOOTRO TABLE M1,400,50,30

SINTERQUI TABLE S$ENPROCESO,1,1,500

SINTERPED TABLE S$ENPROCESO,1,1,500

SINTERDES TABLE S$ENPROCESO,1,1,500

TIEMPO TABLE M1,500,60,30

CANTPROD FUNCTION RN2,C4

0,1/0.6,13/0.95,21/1,101

CANTPIEZAS FUNCTION RN3,C7

0,1/0.14,21/0.31,51/0.53,201/0.82,501/0.99,2001/1,15001

EMPLEADOSPEDIDOS VARIABLE X$EMPLEMOSTRADOR+X$EMPLEPREPARADOR

EMPLEADOHABLADOR VARIABLE 10+X$EMPLEHABLADOR

EMPLEPREPARADOR VARIABLE 1+X$EMPLEMOSTRADOR

EMPLEFACTURADOR VARIABLE 30+X$EMPLEFACTURADOR

LINEAS VARIABLE 20+X$NLINEAS

**Bloques ejecutables**

LINE LOC BLOCK\_TYPE ENTRY\_COUNT CURRENT\_COUNT RETRY

21 1 GENERATE ,,,1 1 0 0

22 2 ADVANCE 36000 1 0 0

23 3 TERMINATE 1 1 0 0

25 4 GENERATE 900 40 0 0

26 5 TABULATE SINTERQUI 40 0 0

27 6 TERMINATE 40 0 0

29 7 GENERATE 420,300,1 85 0 0

30 8 ENTER ENPROCESO 85 0 0

31 9 ASSIGN NPRODUCTOS,FN$CANTPROD 85 0 0

32 10 ASSIGN NPIEZAS,FN$CANTPIEZAS 85 0 0

33 11 SELECT MIN 4,1,X$EMPLEMOSTRADOR,,Q 85 0 0

34 12 QUEUE \*4 85 1 0

35 13 SEIZE \*4 84 0 0

36 14 DEPART \*4 84 0 0

37 15 ADVANCE 120,60 84 0 0

38 16 ASSIGN AUX,P$NPRODUCTOS 84 0 0

39 TOMO ADVANCE 10,2 1080 0 0

40 18 LOOP AUX,TOMO 1080 0 0

41 19 TABULATE SINTERPED 84 0 0

42 20 RELEASE \*4 84 0 0

43 21 TRANSFER ,PREPARAR 84 0 0

45 22 GENERATE 600,360,10 59 0 0

46 23 SELECT NU 6,21,V$LINEAS,,,NOLINEA 59 0 0

47 24 SEIZE \*6 40 0 0

48 25 TRANSFER 0.5,OTRAPER 40 0 0

49 26 ENTER ENPROCESO 16 0 0

50 27 ASSIGN NPRODUCTOS,FN$CANTPROD 16 0 0

51 28 ASSIGN NPIEZAS,FN$CANTPIEZAS 16 0 0

52 29 SELECT MIN 4,1,V$EMPLEADOSPEDIDOS,,Q 16 0 0

53 30 SEIZE \*4 16 0 0

54 31 ADVANCE 180,60 16 0 0

55 32 ASSIGN AUX,P$NPRODUCTOS 16 0 0

56 TOMOPRODL ADVANCE 7,2 145 0 0

57 34 LOOP AUX,TOMOPRODL 145 0 0

58 35 TABULATE SINTERPED 16 0 0

59 36 TRANSFER ,PREPARARL 16 0 0

61 OTRAPER SELECT NU 5,11,V$EMPLEADOHABLADOR,,,NOHABLADOR 24 0 0

62 38 SEIZE \*5 24 0 0

63 39 ADVANCE 120,60 24 0 0

64 40 RELEASE \*5 24 0 0

65 41 RELEASE \*6 24 0 0

66 42 TERMINATE 24 0 0

68 PREPARAR SELECT MIN 4,V$EMPLEPREPARADOR,V$EMPLEADOSPEDIDOS,,Q 84 0 0

69 44 QUEUE \*4 84 0 0

70 45 SEIZE \*4 84 0 0

71 46 DEPART \*4 84 0 0

72 PREPARARL ADVANCE 300,120 100 0 0

73 48 ASSIGN AUX,P$NPRODUCTOS 100 0 0

74 PREPPROD ADVANCE 5,2 1209 1 0

75 50 LOOP AUX,PREPPROD 1208 0 0

76 51 ASSIGN AUX,P$NPIEZAS 99 0 0

77 PREPPIEZ ADVANCE 3,1 2796 0 0

78 53 TEST GE P$AUX,20,LISTO 2796 0 0

79 54 ASSIGN AUX-,20 2697 0 0

80 55 TRANSFER ,PREPPIEZ 2697 0 0

81 LISTO RELEASE \*4 99 0 0

82 57 TABULATE TOMOOTRO 99 0 0

83 58 TRANSFER ,PAGAR 99 0 0

85 PAGAR SELECT MIN 4,31,V$EMPLEFACTURADOR,,Q 99 0 0

86 60 QUEUE \*4 99 0 0

87 61 SEIZE \*4 99 0 0

88 62 DEPART \*4 99 0 0

89 63 ADVANCE 120,30 99 0 0

90 64 ASSIGN AUX,P$NPRODUCTOS 99 0 0

91 PAGOPROD ADVANCE 5,2 1205 0 0

92 66 LOOP AUX,PAGOPROD 1205 0 0

93 67 TABULATE SINTERDES 99 0 0

94 68 RELEASE \*4 99 0 0

95 69 TEST NE \*6,0,SEGUIR 99 0 0

96 70 RELEASE \*6 15 0 0

97 SEGUIR LEAVE ENPROCESO 99 0 0

99 72 TABULATE TIEMPO 99 0 0

100 73 TERMINATE 99 0 0

101 NOLINEA SAVEVALUE NOATIENDEN+,1 19 0 0

102 75 TERMINATE 19 0 0

103 NOHABLADOR SAVEVALUE NOHABLAN+,1 0 0 0

104 77 RELEASE \*6 0 0 0

105 78 TERMINATE 0 0 0

**Facilities**

FACILITY ENTRIES UTIL. AVE\_TIME AVAILABLE OWNER PEND INTER RETRY DELAY

1 97 0,796 295,258 1 11 0 0 0 1

2 67 0,823 441,970 1 0 0 0 0 0

3 20 0,284 510,350 1 0 0 0 0 0

11 24 0,087 130,917 1 0 0 0 0 0

21 40 0,555 499,250 1 11 0 0 0 0

31 99 0,499 181,586 1 0 0 0 0 0

**Queues**

QUEUE MAX CONT. ENTRIES ENTRIES(0) AVE.CONT. AVE.TIME AVE.(-0) RETRY

1 3 1 85 34 0,540 228,776 381,294 0

2 2 0 64 18 0,411 231,344 321,870 0

3 1 0 20 11 0,101 182,000 404,444 0

31 3 0 99 74 0,126 45,808 181,400 0

**Storages**

STORAGE CAP. REMAIN. MIN. MAX. ENTRIES AVL. AVE.C. UTIL. RETRY DELAY

ENPROCESO 50000 49998 0 7 101 1 3,630 0,000 0 0

**Tables**

SINTERDES TABLE S$ENPROCESO,1,1,500

MEDIA : 4,071

DESVIACION ESTANDAR : 1,172

CANTIDAD EN RETRY : 0

INTERVALO FRECUENCIA % %ACUMULADO %REMANENTE

0 - 1 0 0,000 0,000 100,000

2 - 2 7 7,071 7,071 92,929

3 - 3 27 27,273 34,343 65,657

4 - 4 31 31,313 65,657 34,343

5 - 5 22 22,222 87,879 12,121

6 - 6 10 10,101 97,980 2,020

7 - 7 2 2,020 100,000 0,000

Las frecuencias restantes (493) son todas cero.

CANTIDAD DE VALORES TABULADOS : 99

VALOR MAXIMO TABULADO : 7,000

SINTERPED TABLE S$ENPROCESO,1,1,500

MEDIA : 3,810

DESVIACION ESTANDAR : 1,293

CANTIDAD EN RETRY : 0

INTERVALO FRECUENCIA % %ACUMULADO %REMANENTE

0 - 1 2 2,000 2,000 98,000

2 - 2 13 13,000 15,000 85,000

3 - 3 29 29,000 44,000 56,000

4 - 4 26 26,000 70,000 30,000

5 - 5 20 20,000 90,000 10,000

6 - 6 8 8,000 98,000 2,000

7 - 7 2 2,000 100,000 0,000

Las frecuencias restantes (493) son todas cero.

CANTIDAD DE VALORES TABULADOS : 100

VALOR MAXIMO TABULADO : 7,000

SINTERQUI TABLE S$ENPROCESO,1,1,500

MEDIA : 3,775

DESVIACION ESTANDAR : 1,074

CANTIDAD EN RETRY : 0

INTERVALO FRECUENCIA % %ACUMULADO %REMANENTE

0 - 1 0 0,000 0,000 100,000

2 - 2 3 7,500 7,500 92,500

3 - 3 16 40,000 47,500 52,500

4 - 4 11 27,500 75,000 25,000

5 - 5 7 17,500 92,500 7,500

6 - 6 3 7,500 100,000 0,000

Las frecuencias restantes (494) son todas cero.

CANTIDAD DE VALORES TABULADOS : 40

VALOR MAXIMO TABULADO : 6,000

TOMOOTRO TABLE M1,400,50,30

MEDIA : 1081,970

DESVIACION ESTANDAR : 597,631

CANTIDAD EN RETRY : 0

INTERVALO FRECUENCIA % %ACUMULADO %REMANENTE

0 - 400 0 0,000 0,000 100,000

401 - 450 3 3,030 3,030 96,970

451 - 500 2 2,020 5,051 94,949

501 - 550 5 5,051 10,101 89,899

551 - 600 3 3,030 13,131 86,869

601 - 650 6 6,061 19,192 80,808

651 - 700 10 10,101 29,293 70,707

701 - 750 8 8,081 37,374 62,626

751 - 800 3 3,030 40,404 59,596

801 - 850 4 4,040 44,444 55,556

851 - 900 4 4,040 48,485 51,515

901 - 950 4 4,040 52,525 47,475

951 - 1000 2 2,020 54,545 45,455

1001 - 1050 9 9,091 63,636 36,364

1051 - 1100 2 2,020 65,657 34,343

1101 - 1150 3 3,030 68,687 31,313

1151 - 1200 2 2,020 70,707 29,293

1201 - 1250 0 0,000 70,707 29,293

1251 - 1300 2 2,020 72,727 27,273

1301 - 1350 2 2,020 74,747 25,253

1351 - 1400 2 2,020 76,768 23,232

1401 - 1450 3 3,030 79,798 20,202

1451 - 1500 3 3,030 82,828 17,172

1501 - 1550 2 2,020 84,848 15,152

1551 - 1600 2 2,020 86,869 13,131

1601 - 1650 3 3,030 89,899 10,101

1651 - 1700 0 0,000 89,899 10,101

1701 - 1750 0 0,000 89,899 10,101

1751 - 1800 0 0,000 89,899 10,101

1801 - Infinito 10 10,101 100,000 0,000

MEDIA OVERFLOW : 2481,300

DESVIACION ESTANDAR OVERFLOW : 611,590

CANTIDAD DE VALORES TABULADOS : 99

VALOR MAXIMO TABULADO : 3753,000

**Savevalues**

SAVEVALUE VALUE RETRY

EMPLEFACTURADOR 1 0

EMPLEHABLADOR 1 0

EMPLEMOSTRADOR 1 0

EMPLEPREPARADOR 2 0

NLINEAS 1 0

NOATIENDEN 19 0

**Cadena de eventos futuros (FEC)**

FEC\_XACT\_NUMBER PRI BDT CURRENT NEXT PARAMETER VALUE

11 0 36002 49 50 6 21

NPRODUCTOS 20

NPIEZAS 13

4 1

AUX 17

8 0 36151 0 22

6 0 36165 0 7

4 0 36900 0 4

# Analisis del reporte

**Bloques ejecutables**

En primer lugar se ve que llegaron 85 pedidos por mostrador y 59 llamadas, de las cuales, se atendieron 40 y de esas, 16 fueron pedidos y 24 fueron derivadas al empleado encargado de hablar en esta simulación.

Podemos también ver donde fue que se quedaron las transacciones al momento de terminar la simulación:

-Una quedo esperando al empleado que toma los pedidos en el mostrador (línea 12)

-Otra, está todavía preparando su pedido (línea 74)

Todas las demás transacciones ya están fuera del sistema.

**Facilities**

Se puede ver el uso que tuvieron todas las facilities que definimos

-La facility 1, el empleado del mostrador, atendió 97 empleados entre personas y llamadas. Fue utilizado el 80% del tiempo aproximadamente y su tiempo de atención por cliente fue cerca de 5 minutos.

-Las facilities 2 y 3, correspondientes a los empleados que preparan los pedidos fueron utilizados de manera un poco despareja, esto se debe al criterio que utilizan los clientes de elegir la mínima cola, haciendo que la facility 2 trabaje más que la 3. Si promediamos la utilización promedio que tuvieron estas, nos podemos hacer una idea del uso que tuvieron en conjunto, que nos da un resultado un poco mayor al 50%

-La facility 11, que es el empleado que atiende los llamados que no son pedidos. Recibió 24 transacciones, fue utilizada menos del 10% y el tiempo promedio fue de 2 minutos aproximadamente

-La facility 21, sería la línea de teléfono, fue utilizada 40 veces (se perdieron 19 llamados por estar siendo utilizada). Se la utilizo alrededor de la mitad del tiempo de la simulación entre todos sus llamados.

-La facility 31, siendo el empleado encargado de la facturación, recibió los 99 pedidos que hubo (tanto en persona como por teléfono) y estuvo trabajando cerca de la mitad del tiempo.

**Queues**

Se pueden ver las filas que se formaron esperando a los 4 empleados (mostrador, preparadores y facturación).

Como las filas más largas fueron la de los empleados del mostrador y de facturación, suena razonable que las primeras mejoras vengan por este lado.

**Storages**

El único storage definido en este modelo fue el del negocio, con una capacidad infinita. Hace referencia a la cantidad de pedidos que se están manejando actualmente en el negocio, cualquiera sea la parte en la que se encuentran.

En este caso, vemos que el máximo fue de 7 transacciones y que hubo 101 en total (los 99 que terminaron y fueron facturados y los 2 que todavía estaban dentro del sistema cuando termino la simulación)

**Tables**

-Sinterdes

Esta tabla hace referencia a los pedidos sin terminar vistos por una transacción que acaba de terminar de ser facturada. Es decir, los pedidos que hay en el negocio, cuando un empleado se va con su pedido.

-Sinterped

Es la tabla correspondiente a los pedidos sin terminar cuando se termina de tomar uno.

-Sinterqui

Es la tabla donde marcamos los pedidos en proceso que vemos cada 15 minutos.

En todos los casos la media se encuentra en los 4 pedidos, siendo los valores más probables 3, 4 y 5. Nada mal para un negocio con 4 empleados, esto nos dice que la cantidad de empleados que tenemos es acorde a la cantidad de pedidos que llegan.

-Tomootro

Esta tabla es el tiempo total en preparar el pedido, es decir, desde que este llego hasta que se lo termino de preparar y paso a ser facturado. La media está por los 18 minutos, aunque tiene bastante desviación y no es tan claramente definido el valor más probable como en las otras tablas. Por eso hay valores desde los 6 minutos, hasta los 30 minutos o más, incluso habiendo un par de picos en los 11 y los 18 minutos.

**Savevalues**

En el programa se utilizó un savevalue NOATIENDEN para contabilizar la cantidad de veces que llega un llamado y las líneas están ocupadas.

Los demás savevalues son la cantidad de facilities con las que cuenta el negocio, todas definidas previamente para evaluar distintas cantidades de empleados. No se modifican.

# Inconvenientes de la simulación

Gracias a las queues se puede ver que en el empleado del mostrador y el facturador son los que tuvieron las mayores colas.

Si hubiese clientes impacientes, que no estén dispuestos a esperar los 6 minutos que hubo promedio de espera, estos serían clientes perdidos. Además, esta es la facility con mayor tiempo de utilización (considerando que el primer empleado preparador podría haber descargado con el segundo). Es lógico proponer mejorar este punto en el primer análisis.

El empleado facturador, también tuvo una cola particularmente larga, la gente suele tomar muy mal el hecho de hacerle esperar incluso cuando se tiene que pagar, sumado esto a que ya vino esperando a los empleados anterior, la impaciencia en esta fila está mucho más agotada. Este puede ser el segundo punto a mejorar.

Viendo el caso de las llamadas, 19 quedaron sin atender, las cuales puede considerarse pedidos perdidos frente a la competencia o cosas que necesitan ser atendidas lo antes posible, como llamados de proveedores, u otras personas relacionadas con el negocio. No es admisible perder llamadas de ese estilo. La cantidad de líneas definitivamente es un cuello de botella.

Volviendo al caso del empleado del mostrador, este ocasionalmente debe atender algún llamado, y es muy molesto para un cliente llegar a un negocio y que nadie lo reciba porque están ocupados con el teléfono. Este empleado debería ser exclusivamente para atender a los clientes que llegan o poder atenderlos mucho más rápido, pero eso depende del pedido del cliente, por lo que no podemos modificarlo. Podemos quitarle esa responsabilidad.

# Alternativas propuestas

**1) Poner una segunda línea de teléfono**

-Esta propuesta mejora el problema de las llamadas perdidas, ahora al tener una segunda línea debería bajar la cantidad de llamadas que no se atienden y que pueden ser pedidos perdidos.

-Solo se modifica la siguiente línea del código:

INITIAL X$NLINEAS,2

-Ahora se ve como solo se pierden 3 llamadas

23 SELECT NU 6,21,V$LINEAS,,,NOLINEA 57

24 SEIZE \*6 54

99 NOLINEA SAVEVALUE NOATIENDEN+,1 3

Gracias a esto podemos decir que se mejoró la situación frente al inconveniente. Solo perder 3 llamados de casi 60 es un número mucho más aceptable.

-Al aplicar esta mejora se recargo un poco más a los empleados, que ahora reciben más pedidos por los teléfonos, por lo que estos pasan a estar ocupados mucho más (aproximadamente 88% para el empleado del mostrador y 62% promediando para los que preparan los pedidos)

-Se esperaba que ocasionalmente llegara un llamado para el empleado hablador mientras está hablando, haciendo que se pierda un llamado por no poder atender, pero este no fue el caso y por lo tanto no haría falta conseguir otro empleado para agregar en esa tarea.

**2) Quitarle la responsabilidad de los llamados al empleado del mostrador**

-Con esto, lograremos que los clientes sean atendidos en promedio, más rápido al llegar al local. Esta es la espera critica para que un cliente sea en definitiva un cliente y no se vaya antes de comprar, por lo que es importante mantenerla en el mínimo.

-Se modifica la siguiente línea del código:

29 SELECT MIN 4,V$EMPLEPREPARADOR,V$EMPLEADOSPEDIDOS,,Q 18

-Con esta mejora:

La cola máxima para ser atendido baja de 3 a 2.

El tiempo de espera promedio baja de 229 a 45 segundos.

El tiempo de espera promedio, solamente considerando los que esperaron, baja de 381 a 177 segundos.

**Queues**

QUEUE MAX ENTRIES ENTRIES(0) AVE.TIME AVE.(-0)

1 2 87 65 44,793 177,136

-Sacándole esa responsabilidad al empleado del mostrador, lógicamente esta cae sobre los empleados encargados de la preparación de los pedidos. Los cuales ahora tienen colas máximas un poco más largas y tiempos de ocupación y espera más altos.

**3) Agregar un empleado más para la facturación**

-Esta mejora plantea reducir la última espera por parte de los clientes, esta espera no está enfocada al hecho de no perder el cliente en el momento si no, de tratar de que se vaya con un buen sentimiento y decida volver en vez de irse agotado por tener que esperar incluso para pagar.

Para esta mejora se tomaron 2 enfoques distintos. En primer lugar, simplemente poner un segundo empleado de facturación igual que el que ya estaba. En segundo lugar, dividir la facturación en 2 partes, una seria la parte fija y otra la parte que es variable según los productos que lleva

-Si se quisiera tomar la lógica de elegir el que tiene la cola mínima el código a editar seria:

INITIAL X$EMPLEFACTURADOR,2

Y el resultado de esta mejora se vería reflejado en los tiempos de la cola de facturación

QUEUE MAX ENTRIES ENTRIES(0) AVE.TIME AVE.(-0)

31 1 95 75 25,179 119,600

32 1 2 2 0,000 0,000

Con esta mejora reducimos las colas de facturación que antes eran de hasta 3 personas y el tiempo de espera promedio baja de 45 a 25 segundos, si solo contamos a los que tuvieron que esperar, pasamos de 181 a 119 segundos. Un punto a notar de esta mejora es que el segundo empleado de facturación solamente atiende 2 clientes, por lo que su ocupación es muy pequeña y puede luego asignársele otra tarea sin afectar estas estadísticas.

-Tomando el enfoque de la división de tareas, hay que modificar las siguientes líneas del código para que tome primero la facility 31 (el primer empleado facturador) y después la 32 (el segundo)

PAGAR ASSIGN 4,31

86 QUEUE \*4

87 SEIZE \*4

88 DEPART \*4

89 ADVANCE 120,30

90 RELEASE \*4

91 ASSIGN 4,32

92 QUEUE \*4

93 SEIZE \*4

94 DEPART \*4

95 ASSIGN AUX,P$NPRODUCTOS

-En el reporte se pueden ver las mejoras que esto trae

QUEUE MAX ENTRIES ENTRIES(0) AVE.TIME AVE.(-0)

31 1 97 78 11,825 60,368

32 2 97 92 5,629 109,200

Ahora los clientes tienen que esperar un promedio de casi 18 segundos para pagar, o 170 segundos, si no contamos a los que esperaron, frente a los 45 o 180 de cuando teníamos un solo empleado. No sería una gran mejora si consideramos que antes los clientes que esperaron lo hicieron apenas unos 10 segundos más, pero también se puede ver que antes esperaron 25 clientes y ahora esperaron 19 en la primera etapa que suma una parte más pequeña y apenas 5 en la segunda, que es la que suma la gran parte de la espera. Ahora teniendo esto en cuenta la espera media en esta etapa es finalmente mucho menor. La única problemática de esta situación es que requiere un empleado extra.

**4) Un segundo empleado en el mostrador**

-Mediante esta mejora se busca reducir el tiempo de espera de los clientes que arriban al negocio.

-Para agregar esta mejora, solamente hay que modificar la línea correspondiente la cantidad de empleados en el mostrador

INITIAL X$EMPLEMOSTRADOR,2

-Con esta mejora vemos los datos que nos devuelve el reporte acerca de esta parte

QUEUE MAX ENTRIES ENTRIES(0) AVE.TIME AVE.(-0)

1 1 74 34 154,797 286,375

2 1 16 13 54,813 292,333

Como vemos, pasamos los tiempos de espera promedio de 229 segundos a 155 como máximo. En caso de solo considerar los que esperaron, pasamos de 381 segundos a 292 como máximo. Además, las colas pasaron a ser de un máximo de 1 persona en vez de 3 como eran antes.

-Cabe destacar que esta mejora se puede ver aún más beneficiada en el caso de que se la combine con quitarle la responsabilidad de tomar pedidos por teléfono a estos empleados. También hay que considerar que esta mejora implica que se contrate otro empleado, pero el tiempo de ocupación de este nuevo empleado es considerablemente menor al del primer empleado del mostrador, por lo que podría combinarse sin problema con la mejora anterior y se podrían aplicar las dos mejoras sin interferir una con la otra.

**5) Todos los empleados toman y preparan pedidos**

-Con esta nueva restructuración, se plantea que los pedidos van a ser mejor distribuidos entre todos los empleados disponibles. Esto mejoraría la situación en que una etapa es el cuello de botella y consume más tiempo que las otras, haciendo que las demás deban esperar que esta libere los recursos para poder continuar operando.

-Con el fin de agregar esta mejora, el código que debe cambiarse es el siguiente

11 SELECT MIN 4,1,V$EMPLEADOSPEDIDOS,,Q

19 ;RELEASE \*4

20 TRANSFER ,PREPARARL

Las líneas 42 a 45 inclusive quedan todas sin efecto, pueden eliminarse sin problema.

-Evaluar esta mejora frente a las demás es bastante difícil, ya que afecta a gran parte del sistema en vez de ser localizada como las demás. Para ver que tanto se mejora con estos cambios, hay que ver el tiempo final que se logra y compararlo con las demás alternativas.

El sistema ahora queda con las siguientes estadísticas.

FACILITY ENTRIES UTIL. AVE\_TIME

1 56 1,000 642,857

2 40 0,750 674,800

3 7 0,226 1161,000

QUEUE MAX ENTRIES ENTRIES(0) AVE.CONT. AVE.TIME AVE.(-0)

1 1 47 2 0,663 507,468 530,022

2 1 33 10 0,225 245,667 352,478

3 1 7 5 0,073 376,286 1317,000

Como puede verse, la utilización del primer empleado es total, la del segundo es de tres cuartos y la del tercer ya es considerablemente menor, por lo que un cuarto empleado ya no es necesario.

También puede verse que las colas ahora son de una persona como máximo. Aunque los tiempos de espera son bastante altos, es difícil compararlos con las alternativas anteriores dado que antes, cada cliente pasaba por dos empleados en vez de uno y que la espera era para estos dos empleados por separado y considerando sus situaciones independientemente.

# Mejora seleccionada

Para todas las opciones ensayadas, se tomó el tiempo final de cada transacción con la tabla TIEMPO. En definitiva, se puede determinar la mejor variante viendo la media de las transacciones dentro del sistema, ya que el tiempo de una transacción es la suma del tiempo que se la procesa, más el tiempo que espera, el cual es el único que podemos modificar con nuestras decisiones y buscamos minimizar.

En conclusión, las medias de nuestros ensayos son:

-Sistema original: 1309,364

-Alternativa 1: 1432,234

-Alternativa 2: 1318,126

-Alternativa 3: 1325,156

-Alternativa 4: 1195,417

-Alternativa 5: 1319,030

Y se puede ver que de todas las alternativas, la que logro menor tiempo promedio en las transacciones fue la 4, la que evalúa la situación de incluir un segundo empleado en el mostrador para tomar los pedidos, como fue mencionado, sería muy interesante ver cómo se puede combinar esta alternativa con la de asignarle a este nuevo empleado también tareas de facturación con el fin de aliviar también esa zona u otras tareas que logren darle más ocupación con el fin de reducir las esperas de los clientes.