Proposal for Generic Subprogram

Version 1.7

Fortran WG, ITSCJ, IPSJ  
Hidetoshi Iwashita

December 24, 2023

# Introduction

The mechanism of a generic identifier for selecting specific procedures is an outstanding feature of Fortran. A generic identifier (generic name, defined operator or =, or defined I/O) identifies one of the specific procedures whose argument types, kinds, or ranks differ from each other. In Fortran, most intrinsic procedures and operators are generic. For example, the arguments of the intrinsic function MAX can be integer, real, or character types, and the operands of the operator + can be integer, real, or complex types. It is a natural and productive programming style to use generic names and operators. The same is true for user-defined procedures and derived types.

Importantly, using a generic identifier should not affect execution performance. Not compromising performance is an essential requirement in Fortran. The generic identifier mechanism achieves it through the following dedicate considerations:

* Selecting a specific procedure depends only on static parameters and is determined at compile time. Therefore, no overhead of judgment or branching remains on the runtime code.
* Since the generic identifier is resolved within or before the compiler front-end, it does not affect the existing sophisticated optimization and code generation within the compiler back-end.

Thus, it can be said that the generic identifier mechanism is a feature that combines convenience and performance for users. Whereas library providers who create specific procedures and publish them as a generic identifier still face a major challenge: combinational explosion. As programmers attempt to generalize the types and ranks of library procedures, the number of specific subprograms can grow enormously, into the tens or hundreds. For example, to define a function whose argument variable has any arithmetic type (integer, real or complex with any kind parameter) and any rank (0 through 15 in standard), the programmer must write totally more than 100 specific function subprograms. Even if such a huge number of specific subprograms could be written using clever editors and tools, maintaining and improving such a number of versions is error-prone and a waste of time.

This paper proposes an extension of the generic identifier mechanism to easily define large numbers of specific procedures. Instead of writing a large number of subprograms, the user only needs to write a **generic subprogram** that defines multiple specific procedures.

In this paper, Section 2 demonstrates examples for quick understanding at first, Section 3 describes the syntax, and Section 4 summarizes.

# Example

Consider a simple function that returns true if the argument is a NaN (not a number) or has at least one NaN array element, and false otherwise. The argument is allowed to be a variable of 32, 64, or 128-byte real type scalar or 1- to 15-dimensional array.

## Original set of specific functions

List 1 shows an example of defining generic function has\_nan with 48 specific functions for all types and all ranks. As you can see, most of the functions have the same body, but since they have different ranks or different kind parameters from each other, they must be written as separate functions in the current Fortran standard.

## Generic subprogram

List 2 shows the equivalent code to the code of List 1, written using the generic subprogram proposed in this paper. A subprogram with the GENERIC prefix is a generic subprogram. The first generic subprogram defines three specific procedures where x is one of real types of 32, 64, and 128 bytes. The second generic subprogram defines specific procedures where x is one of the combinations of 32, 64, or 128-byte real types and ranks from 1 to 15. Every specific procedure defined by the generic subprogram has no name and is referenced by the generic name.

Multiple specific subprograms that have the same body except for type declaration statements for the dummy arguments can be combined into one generic subprogram. This may greatly reduce the amount of program code. In addition, since the generic subprogram is expanded to a list of the corresponding specific procedures, there should be no performance degradation.

List 1. has\_nan defined by specific subprograms

|  |
| --- |
| MODULE mod\_nan\_original  USE :: ieee\_arithmetic  USE :: iso\_fortran\_env  IMPLICIT NONE  INTERFACE has\_nan  MODULE PROCEDURE :: &  has\_nan\_r32\_0, has\_nan\_r32\_1, has\_nan\_r32\_2, has\_nan\_r32\_3, &  has\_nan\_r32\_4, has\_nan\_r32\_5, has\_nan\_r32\_6, has\_nan\_r32\_7, &  has\_nan\_r32\_8, has\_nan\_r32\_9, has\_nan\_r32\_10, has\_nan\_r32\_11, &  has\_nan\_r32\_12, has\_nan\_r32\_13, has\_nan\_r32\_14, has\_nan\_r32\_15, &  has\_nan\_r64\_0, has\_nan\_r64\_1, has\_nan\_r64\_2, has\_nan\_r64\_3, &  has\_nan\_r64\_4, has\_nan\_r64\_5, has\_nan\_r64\_6, has\_nan\_r64\_7, &  has\_nan\_r64\_8, has\_nan\_r64\_9, has\_nan\_r64\_10, has\_nan\_r64\_11, &  has\_nan\_r64\_12, has\_nan\_r64\_13, has\_nan\_r64\_14, has\_nan\_r64\_15, &  has\_nan\_r128\_0, has\_nan\_r128\_1, has\_nan\_r128\_2, has\_nan\_r128\_3, &  has\_nan\_r128\_4, has\_nan\_r128\_5, has\_nan\_r128\_6, has\_nan\_r128\_7, &  has\_nan\_r128\_8, has\_nan\_r128\_9, has\_nan\_r128\_10, has\_nan\_r128\_11, &  has\_nan\_r128\_12, has\_nan\_r128\_13, has\_nan\_r128\_14, has\_nan\_r128\_15  END INTERFACE has\_nan  PRIVATE  PUBLIC :: has\_nan  CONTAINS  FUNCTION has\_nan\_r32\_0(x) RESULT(ans)  **REAL(REAL32)**, INTENT(IN) :: x  LOGICAL :: ans  **ans = ieee\_is\_nan(x)**  END FUNCTION has\_nan\_r32\_0  FUNCTION has\_nan\_r32\_1(x) RESULT(ans)  **REAL(REAL32)**, INTENT(IN) :: x**(:)**  LOGICAL :: ans  **ans = any(ieee\_is\_nan(x))**  END FUNCTION has\_nan\_r32\_1  ... (omit 65 lines of code)  FUNCTION has\_nan\_r32\_15(x) RESULT(ans)  **REAL(REAL32)**, INTENT(IN) :: x**(:,:,:,:,:,:,:,:,:,:,:,:,:,:,:)**  LOGICAL :: ans  **ans = any(ieee\_is\_nan(x))**  END FUNCTION has\_nan\_r32\_15  ... (omit 155 lines of code)  FUNCTION has\_nan\_r128\_15(x) RESULT(ans)  **REAL(REAL128)**, INTENT(IN) :: x**(:,:,:,:,:,:,:,:,:,:,:,:,:,:,:)**  LOGICAL :: ans  **ans = any(ieee\_is\_nan(x))**  END FUNCTION has\_nan\_r128\_15  END MODULE mod\_nan\_original |

List 2. has\_nan defined with generic subprogram

|  |
| --- |
| MODULE mod\_nan\_proposed  USE :: ieee\_arithmetic  USE :: iso\_fortran\_env  PRIVATE  PUBLIC :: has\_nan  CONTAINS  **GENERIC** FUNCTION has\_nan(x) RESULT(ans)  **REAL(REAL32,REAL64,REAL128)**, **RANK(0)**, INTENT(IN) :: x  LOGICAL :: ans  **ans = ieee\_is\_nan(x)**  END FUNCTION has\_nan  **GENERIC** FUNCTION has\_nan(x) RESULT(ans)  **REAL(REAL32,REAL64,REAL128)**, **RANK(1:15)**, INTENT(IN) :: x  LOGICAL :: ans  **ans = any(ieee\_is\_nan(x))**  END FUNCTION has\_nan  END MODULE mod\_nan\_proposed |

# Syntax

A **generic subprogram** is a subprogram that has the GENERIC prefix (3.1), which defines one or more specific procedures that have dummy arguments of different types, kinds, or ranks from each other. The name of a generic subprogram is a generic name for all defined specific procedures. Each specific procedure does not have a specific name.

A **generic type declaration statement** is the type declaration statement that specifies at least one dummy argument of the generic subprogram, which is extended to specify alternative types, kinds, and ranks (3.2).

The interface block and the GENERIC statement are extended to specify the explicit interface of a generic subprogram and to associate a generic subprogram with a generic identifier, which includes an operator, an assignment and a defined input/output (3.3).

The SELECT RANK and TYPE constructs are extended to allow switching codes based on alternative types, kinds and ranks (3.4).

## GENERIC prefix

The GENERIC prefix of a FUNCTION or SUBROUTINE statement specifies that the subprogram is a generic subprogram.

The *prefix-spec*, the *function-stmt*, and the *subroutine-stmt* (F2023:15.6.2.1-3) are extended as follows.

R1530x *prefix-spec* **is** *declaration-type-spec* **or** ELEMENTAL **or** IMPURE  
 **or** MODULE **or** NON\_RECURSIVE **or** PURE  
 **or** RECURCIVE **or** SYMPLE **or** **GENERIC**

R1533x *function-stmt* **is** [ *prefix* ] FUNCTION ***function-spec***  
 ( [ *dummy-arg-name-list* ] ) [ *suffix* ]

R1533a ***function-spec*** **is** *function-name*  
 **or** ***generic-spec***

Constraint: The *function-spec* shall be *generic-spec* if the GENERIC prefix appears in the *prefix* and shall be *function-name* otherwise.

R1538x *subroutine-stmt*  **is** [ *prefix* ] SUBROUTINE ***subroutine-spec***  
 [ ( [ *dummy-arg-list* ] ) [ *proc-language-binding-spec* ] ]

Constraint: If the GENERIC prefix appears in the *prefix*, the *proc-language-binding-spec* shall not appear.

R1538a ***subroutine-spec*** **is** *subroutine-name*  
 **or** ***generic-spec***

Constraint: The *subroutine-spec* shall be *generic-spec* if the GENERIC prefix appears in the *prefix* and shall be *subroutine-name* otherwise.

**Alternative Proposal 1**

Change every ***generic-spec*** in R1553a, R1538a, and the two Constraints to ***generic-name***. That is, OPERATOR ( *defined-operator* ), ASSIGNMENT ( = ), or *defined-i/o-generic-spec* is not allowed as *function-* or *subroutine-spec* in *function-* or *subroutine-stmt*.

Note that this is not a functional decline. To associate a generic procedure with a *generic-spec*, the programmer can use a generic interface block, as shown in NOTE 3 and 3.3.

NOTE 1

|  |
| --- |
| The following is an example of a module that has generic function subprograms as the module subprograms.  MODULE M\_ABSMAX  CONTAINS  GENERIC FUNCTION ABSMAX(X) RESULT(Y)  TYPE(INTEGER,REAL,DOUBLE PRECISION) :: X(:)  TYPEOF(X) :: Y  Y = MAXVAL(ABS(X))  RETURN  END FUNCTION ABSMAX  GENERIC FUNCTION ABSMAX(X) RESULT(Y)  COMPLEX :: X(:)  REAL :: Y  Y = MAXVAL(ABS(X))  RETURN  END FUNCTION ABSMAX  END MODULE M\_ABSMAX  Where TYPE(INTEGER,REAL,DOUBLE PRECISION) specifies that X is an integer, real, or double precision type for each specific procedure (3.2.1). Two module subprograms are generic and specify the same generic name. Since their interfaces are explicit, they can be referenced in the host and sibling scopes. Therefore, the above program is equivalent to the following program.  MODULE M\_ABSMAX  INTERFACE ABSMAX  MODULE PROCEDURE :: ABSMAX\_I, ABSMAX\_R, ABSMAX\_D, ABSMAX\_Z  END INTERFACE  PRIVATE  PUBLIC :: ABSMAX  CONTAINS  FUNCTION ABSMAX\_I(X) RESULT(Y)  TYPE(INTEGER) :: X(:)  TYPEOF(X) :: Y  Y = MAXVAL(ABS(X))  RETURN  END FUNCTION ABSMAX\_I  FUNCTION ABSMAX\_R(X) RESULT(Y)  TYPE(REAL) :: X(:)  TYPEOF(X) :: Y  Y = MAXVAL(ABS(X))  RETURN  END FUNCTION ABSMAX\_R  FUNCTION ABSMAX\_D(X) RESULT(Y)  TYPE(DOUBLE PRECISION) :: X(:)  TYPEOF(X) :: Y  Y = MAXVAL(ABS(X))  RETURN  END FUNCTION ABSMAX\_D  FUNCTION ABSMAX\_Z(X) RESULT(Y)  COMPLEX :: X(:)  REAL :: Y  Y = MAXVAL(ABS(X))  RETURN  END FUNCTION ABSMAX\_Z  END MODULE M\_ABSMAX |

NOTE 2

|  |
| --- |
| Generic subprograms can be external. The following shows an interface block for ABSMAX if the two module generic functions in NOTE 1 would be external.  INTERFACE ABSMAX  GENERIC FUNCTION ABSMAX(X) RESULT(Y)  TYPE(INTEGER,REAL,DOUBLE PRECISION) :: X(:)  TYPEOF(X) :: Y  END FUNCTION ABSMAX  GENERIC FUNCTION ABSMAX(X) RESULT(Y)  COMPLEX :: X(:)  REAL :: Y  END FUNCTION ABSMAX  END INTERFACE ABSMAX |

NOTE 3

|  |
| --- |
| The following example shows a generic subprogram that extends the feature of the + operator.  MODULE coord\_m  USE iso\_fortran\_env  TYPE coord\_t(k)  INTEGER, KIND :: k  REAL(kind=k) :: x, y, z  END TYPE coord\_t  CONTAINS  GENERIC FUNCTION OPERATOR(+)(a, b) RESULT(c)  TYPE(coord\_t(real32,real64)), INTENT(IN) :: a, b  TYPEOF(a) :: c  c%x = a%x + b%x  c%y = a%y + b%y  c%z = a%z + b%z  RETURN  END FUNCTION OPERATOR(+)  END MODULE coord\_m  The type coord\_t has components x, y, and z of real type whose common kind is parameterized. The generic subprogram defines the binary operation + between coord\_t(real32) type objects and between coord\_t(real64) type objects.  A defined operator for a generic subprogram can be specified not only by the FUNCTION or SUBROUTINE statement, but also by an interface block or GENERIC statement. The following code is equivalent to the above one.  MODULE coord\_m  USE iso\_fortran\_env  TYPE coord\_t(k)  INTEGER, KIND :: k  REAL(kind=k) :: x, y, z  END TYPE coord\_t  PRIVATE :: coord\_add  **GENERIC :: OPERATOR(+) => coord\_add**  CONTAINS  GENERIC FUNCTION **coord\_add** RESULT(c)  TYPE(coord\_t(real32,real64)), INTENT(IN) :: a, b  TYPEOF(a) :: c  c%x = a%x + b%x  c%y = a%y + b%y  c%z = a%z + b%z  RETURN  END FUNCTION **coord\_add**  END MODULE coord\_m  Note that in Alternative Proposal 1, the former style is prohibited and only the latter is permitted. |

NOTE 4

|  |
| --- |
| The following example shows a generic subprogram that defines a defined I/O procedure. Here, coord\_t is defined in the module coord\_m of NOTE 3.  GENERIC SUBROUTINE WRITE(FORMATTED)(data, unit, iotype, v\_list, iostat, iomsg)  use coord\_m  class(coord\_t(real32,real64)), intent(in) :: data  integer, intent(in) :: unit  character(\*), intent(in) :: iotype  integer, intent(in) :: v\_list(:)  integer, intent(out) :: iostat  character(\*), intent(inout) :: iomsg  character(10) :: dedit  character(100) :: formt  write(dedit, '( "F", I0, ".", I0 )') v\_list(1), v\_list(2)  formt = "('[ '," // dedit // ",', '," // &  dedit // ",', '," // &  dedit // ",' ]')"  write(unit, fmt=formt, iostat=iostat) data%x, data%y, data%z  END SUBROUTINE WRITE(FORMATTED)  The generic subprogram defines a behavior of the DT edit descriptor in the formatted WRITE statement for types coord\_t(real32) and coord\_t(real64). Using this generic subprogram, the following code works:  type(coord\_t(real32)) :: cod32  type(coord\_t(real64)) :: cod64  cod32%x = 1.1111111111111111111d0  cod32%y = 2.2222222222222222222d0  cod32%z = 3.3333333333333333333d0  write(\*, "(DT(20,17))") cod32  cod64%x = 1.1111111111111111111d0  cod64%y = 2.2222222222222222222d0  cod64%z = 3.3333333333333333333d0  write(\*, "(DT(20,17))") cod64  The example of the result is shown below:  [ 1.11111116409301758, 2.22222232818603516, 3.33333325386047363 ]  [ 1.11111111111111116, 2.22222222222222232, 3.33333333333333348 ] |

Comment:

* Specific procedure names are undefined. Do we need to identify the specific procedures by name or in some other way? If so, how can it be specified?
  + An actual argument can be a procedure name, which must be a specific name. Should we have a notation such as “ABSMAX when the first argument is the default real type”?
  + There seems to be a need to call generic procedures from C language. Is there a need to extend the BIND statement for this case? For example,

BIND (C, NAME="c\_name", ARGS=("float","char[10]")) :: generic\_name

## Generic type declaration statement

A **generic type declaration statement** is the type declaration statement that specifies at least one dummy argument of the generic subprogram. The type declaration statement is defined as follows in Fortran 2023:

R801(asis) *type-declaration-stmt* **is** *declaration-type-spec* [ [ , *attr-spec* ] ... :: ] *entity-decl-list*

The *declaration-type-spec* and the *attr-spec* are extended to specify alternative types (3.2.1), kinds (3.2.2, 3.2.3), and ranks (3.2.4).

Constraint: If a *type-declaration-statement* has alternative types or kinds, at least one entity in the *entity-decl-list* shall be a dummy argument.

Constraint: If a *type-declaration-statement* has alternative ranks, at least one entity in the *entity-decl-list* shall be a dummy argument that does not have an *array-spec*.

NOTE 1

|  |
| --- |
| The *declaration-type-spec* appearing in a *data-component-def-stmt* (F2023:R737), the prefix of a *function-stmt* (F2023:R1529), or an *implicit-spec* (F2023:R867) do not specify alternative types or kinds for entities in the *entity-decl-list*. |

### Alternative type specifier

The *declaration-type-spec* is extended to specify alternative types.

R703x *declaration-type-spec* **is** *intrinsic-type-spec*  
 **or** TYPE ( ***alter-type-spec*** )  
 **or** CLASS ( ***alter-derived-type-spec*** )  
 **or** CLASS ( \* )  
 **or** TYPE ( \* )  
 **or** TYPEOF ( *data-ref* )  
 **or** CLASSOF ( *data-ref*  )

R703a ***alter-type-spec*** **is** *type-spec-list*

Constraint: An *alter-type-spec* shall be one *type-spec* unless it appears in a generic type declaration statement.

R703b ***alter-derived-type-spec*** **is** *derived-type-spec-list*

Constraint: An *alter-derived-type-spec* shall be one *derived-type-spec* unless it appears in a generic type declaration statement.

NOTE 1

|  |
| --- |
| In the first generic subprogram of NOTE1 of 3.1, the generic function ABSMAX has the generic type declaration statement:  TYPE(INTEGER,REAL,DOUBLE PRECISION) :: X(:)  This statement represents that the type of the argument X is one of default integer, default real, and double precision. Thereby, the generic subprogram produces specific procedures corresponding to the types, respectively. |

NOTE2

|  |
| --- |
| The following is an example of a generic subprogram that provides two specific procedures, whose types of the arguments are 32-bit real and mytyp1 with the type parameter p1.  GENERIC SUBROUTINE swap(x,y)  USE :: iso\_fortran\_env, ONLY: real32  USE :: mymod, ONLY: mytyp1, p1, assignment(=)  TYPE(REAL(real32), mytyp1(p1)) :: x(:), y(:), tmp(:)  tmp = x  x = y  y = tmp  END SUBROUTINE |

Comment:

* Alternative dummy arguments must be distinguishable from each other (F2023:15.4.3.4.5). Some constraints might be added for this rule.
* TYPE( ... ) and CLASS( ... ) do not appear together in a *declaration-type-spec*. Therefore, both intrinsic and abstract types cannot be alternative types, and both non-abstract and abstract derived types cannot be alternative types. It might be relaxed if there were use cases.

### Alternative kind specifier for intrinsic type

The *intrinsic-type-spec* is extended to specify alternative kind parameters for intrinsic types.

R794(asis) *intrinsic-type-spec* **is** *integer-type-spec*  
 **or** REAL [ *kind-selector* ]  
 **or** DOUBLE PRECISION  
 **or** COMPLEX [ *kind-selector* ]  
 **or** CHARACTER [ *char-selector* ]  
 **or** LOGICAL [ *kind-selector* ]

R705(asis) *integer-type-spec* **is** INTEGER [ *kind-selector* ]

Constraint: DOUBLE PRECISION and REAL with *kind-selector* shall not appear in the same *alter-type-spec*.

Constraint: If an *intrinsic-type-spec* without *kind-selector* appears in an *alter-type-spec*, other *intrinsic-type-spec*s of the same type shall not appear in the *alter-type-spec*.

The *kind-selector* and the *char-selector* are extended to have alternative kind parameters.

R706x *kind-selector*  **is** ( [ KIND = ] ***alter-kind-spec*** )

R706a ***alter-kind-spec***  **is** \*   
  **or** *kind-spec-list*

R706b *kind-spec*  **is** *scalar-int-constant-expr*

R721x *char-selector*  **is** *length-selector*  **or** ( *type-param-value* , *kind-spec* )  
  **or** ( [ LEN = ] *type-param-value* , KIND = ***alter-kind-spec*** )  
  **or** ( KIND = ***alter-kind-spec*** [ , LEN = *type-param-value* ] )

An *alter-kind-spec* designated as an asterisk specifies that the alternative kind parameters are all kind type parameters for the intrinsic type supported by the processor. An *alter-kind-spec* designated by *kind-spec-list* specifies that the alternative kind parameters are the values of *kind-spec-list*.

Constraint: In a generic type declaration statement, a *kind-spec* shall not have the same value as any other *kind-spec* in the same *intrinsic-type-spec* or in any *intrinsic-type-spec* that is of the same type.

Constraint: An *alter-kind-spec* shall be just one *kind-spec* except when it appears in the *intrinsic-type-spec* of a generic type declaration statement.

NOTE 1

|  |
| --- |
| In a generic type declaration statement:  TYPE(INTEGER(2,4)) :: X, Y  represents that either both X and Y are of integer(kind=2), or both X and Y are of integer(kind=4). The corresponding specific procedures are two. The statement can also be rewritten as follows, keeping the meaning:  TYPE(INTEGER(2,4)) :: X  TYPEOF(X) :: Y  Next, the following combination of generic type declaration statements:  TYPE(INTEGER(2,4)) :: X  TYPE(INTEGER(2,4)) :: Y  has a different meaning from the previous example. It represents four alternatives that correspond to four specific procedures, as follows:  TYPE(INTEGER(2)) :: X; TYPE(INTEGER(2)) :: Y  TYPE(INTEGER(4)) :: X; TYPE(INTEGER(2)) :: Y  TYPE(INTEGER(2)) :: X; TYPE(INTEGER(4)) :: Y  TYPE(INTEGER(4)) :: X; TYPE(INTEGER(4)) :: Y |

NOTE 2

|  |
| --- |
| Examples of generic type declaration statements with alternative types and kinds are:  TYPE(INTEGER, LOGICAL) :: A  INTEGER(kind=2,4),DIMENSION(10,10) :: B  TYPE(INTEGER(kind=2,4), REAL(\*), MYTYPE) :: X, Y(100)  Where MYTYPE is the name of a derived type. If the processor supports kind type parameters 4, 8, and 16 for real type, the last statement above represents the following set of alternative type declaration statements.  TYPE(INTEGER(kind=2)) :: X, Y(100)  TYPE(INTEGER(kind=4)) :: X, Y(100)  TYPE(REAL(kind=4)) :: X, Y(100)  TYPE(REAL(kind=8)) :: X, Y(100)  TYPE(REAL(kind=16)) :: X, Y(100)  TYPE(MYTYPE) :: X, Y(100) |

### Alternative kind specifier for parameterized derived type

The *derived-type-spec* is extended to specify alternative kind parameters for parameterized derived types.

R754(asis) *derived-type-spec* **is** *type-name* [ ( *type-param-spec-list* ) ]

R755x *type-param-spec*  **is** *type-param-value* **or** *keyword* = ***alter-type-param-value***

Instead of C798: A *type-param-spec* shall not be a *type-param-value* unless all preceding *type-param-spec*s in the *type-param-spec-list* are *type-param-value*s.

NOTE 1

|  |
| --- |
| Syntactically, the *keyword* = acts as a separator between *type-param-spec*s in the list. That is, *type-param-spec*s are separated by a comma before the first appearance of the *keyword*, or by “, *keyword* =” thereafter. |

R701a ***alter-type-param-value*** i**s** *scalar-int-expr-list*  
 **or** \*  
 **or** :

Constraint: An *alter-type-param-value* corresponding to a kind type parameter shall be a list of scalar integer constant expressions if it appears in a generic type declaration statement, or a scalar integer constant expression otherwise.

Constraint: An *alter-type-param-value* that does not correspond to a kind type parameter shall be a scalar integer expression, an asterisk, or a colon.

Constraint: Any two *scalar-int-expr*s in a *scalar-int-expr-list* shall not have the same value.

Constraint: If two or more *derived-type-spec*s with the same *type-name* appear in the *declaration-type-spec* of a generic type declaration statement, any two of the *derived-type-spec*s shall meet the following conditions. Here, for a kind parameter, alternative kind values are values of *scalar-int-expr*s if the *type-param-spec* is specified, or the default value otherwise.

* + The derived type have at least one kind parameter.
  + For at least one kind parameter of the derived type, there should be no overlap between each alternative kind values.

Same as C702: A colon shall not be used as a *type-param-value* except in the declaration of an entity that has the POINTER or ALLOCATABLE attribute.

Same as C7100: An asterisk shall not be used as a *type-param-value* in a *type-param-spec* except in the declaration of a dummy argument or associate name or in the allocation of a dummy argument.

NOTE 2

|  |
| --- |
| A dummy argument specified in the generic type declaration statement must be distinguishable (F2023: 15.4.3.4.5) among the specification procedures created. The constraints on parameterized derived types are intended to avoid this situation. The examples are shown below.  For the following type definition:  type mytyp(k, m, n)  integer, kind :: k = 4  integer, kind :: m  integer, len :: n = 100    real(k) :: a(m, n)  end type mytyp  the following *declaration-type-spec*s are correct in generic type declaration statements,   * type( mytyp(8,100,100) ) * type( mytyp(k=8,m=100,200,n=50) ) * type( mytyp(m=10,20), mytyp(m=30) ) * type( mytyp(4,m=10,20), mytyp(8,m=20,30) ) * type( mytyp(m=10,20), mytyp(8,m=20,30) ) * type( mytyp(m=10,20,30,k=8), mytyp(m=20),mytyp(m=30,40) )   and the following *declaration-type-spec*s are incorrect in generic type declaration statements.   * type( mytyp(k=8,m=100,200,100,n=50) )  Error: the pair k=8 and m=100 appears twice. * type( mytyp(8,m=10,20), mytyp(8,m=20,30) )  Error: the pair k=8 and m=20 appears twice. * type( mytyp(m=10,20), mytyp(4,m=10,20) )  Error: the pair k=4 (default) and m=10 and the pair k=4 and m=20 appear twice. * type( mytyp(m=10,20,n=100), mytyp(m=10,40,n=200) )  Error: the pair k=4 (default) and m=10 appears twice. The LEN parameter n is not relevant for the distinction. |

### Alternative rank specifier

The *rank-clause* is extended to specify alternative rank values.

R829x *rank-clause*  **is** RANK ( ***rank-value-range-list*** )  
 **or** **RANKOF ( *data-ref* )**

Constraint: A *data-ref* shall not be *assumed-rank*.

R1148a ***rank-value-range* is** *rank-value*  
  **or** *rank-value* :  
  **or** : *rank-value*  
  **or** *rank-value* : *rank-value*

R1149a *rank-value*  **is** *scalar-int-constant-expr*

Constraint: A *rank-value* in *rank-value-range-list* shall be nonnegative and the value is less than or equal to the maximum rank supported by the processor.

The interpretation of *rank-value-range-list* is the same as the one of *case-value-range-list* described in F2023:11.1.9.2 “Execution of a SELECT CASE construct”. The alternative ranks specified in *rank-clause* are all ranks for which matching occurs.

Constraint: A *rank-value-range* shall be just one *rank-value* except in a *rank-clause* of a *type-declaration-statement* appearing in the specification part of a generic subprogram.

RANKOF ( *data-ref* ) is equivalent to RANK ( RANK ( *data-ref* ) ).

NOTE 1

|  |
| --- |
| Examples of type declaration statements with alternative ranks are:  REAL(8), RANK(0:3) :: A  TYPE(REAL(8)), RANK(1,2,3) :: B  REAL, RANK(10:) :: X, Y(100)  If the maximum array rank supported by the processor is 15, the last statement above represents the following alternative TYPE declaration statements.  REAL, RANK(10) :: X, Y(100)  REAL, RANK(11) :: X, Y(100)  REAL, RANK(12) :: X, Y(100)  REAL, RANK(13) :: X, Y(100)  REAL, RANK(14) :: X, Y(100)  REAL, RANK(15) :: X, Y(100) |

Comment:

* The RANK clause cannot specify lower and upper bounds of assumed-shape arrays. So further extension might be allowed, for example:
  + REAL(8), DIMENSION(0:),(:, 2:10),(0:,:,:) :: A
  + REAL(8) :: A(0:),(:, 2:10),(0:,:,:)
* RANKOF(*data-ref*) is not necessarily needed since it is always rewritten to RANK(RANK(*data-ref)*). However, the following phrase is very useful.
  + TYPEOF(A), RANKOF(A) :: B

## Extension of Interface Block

A **generic interface body** is an interface body of an interface block that has the GENERIC attribute in the *function-stmt* or *subroutine-stmt*. A generic interface body specifies the explicit interface for the generic subprogram. Both specific and generic interface blocks can have generic interface bodies.

Constraint: The name of a generic interface block shall be different from the names of all generic interface bodies it contains.

The *procedure-stmt* in an *interface-block* and the *generic-stmt* are extended as follows:

R1506x *procedure-stmt* **is** [ MODULE ] PROCEDURE [ :: ] ***specific-spec-list***

R1507x ***specific-spec*** **is** *procedure-name*  
 **or** ***generic-spec***

R1510x *generic-stmt* **is** GENERIC [ , *access-spec* ] :: *generic-spec* => ***specific-spec-list***

In paragraph 2 of F2023:15.4.3.2.1 (Generic identifiers),

The *generic-spec* in an *interface-stmt* is a generic identifier for all the procedures in the interface block.

shall be changed to:

The *generic-spec* in an *interface-stmt* is a generic identifier for all the **ultimate specific** procedures in the interface block.

and, in paragraph 3,

A generic name may be the same as any one of the procedure names in the generic interface, or ...

shall be changed to:

A generic name may be the same as any one of the **specific** procedure names in the generic interface, or ...

In paragraph 1 of F2023:15.4.3.3 (GENERIC statement),

A GENERIC statement specifies a generic identifier for one or more specific procedures,

shall be changed to:

A GENERIC statement specifies a generic identifier for one or more specific **or generic** procedures,

NOTE 1

|  |
| --- |
| The following specific interface block specifies generic procedures, foo, which can have an integer or real argument, and goo, which can have a real or complex argument.  interface  generic subroutine foo(a)  type(integer, real) :: a  end subroutine foo  generic subroutine goo(a)  type(real, complex) :: a  end subroutine goo  end interface  In the above example, *generic-spec* cannot be specified in the INTERFACE statement. This is because foo and goo are not distinguishable if the arguments are of the same real type.  The following generic interface block specifies two generic procedures, foo, which can have an integer or real argument, and foobar, which can have an integer, real or complex argument.  interface foobar  generic subroutine foo(a)  type(integer, real) :: a  end subroutine foo  subroutine bar(a)  type(complex) :: a  end subroutine bar  end interface bal |

NOTE 2

|  |
| --- |
| The following module is equivalent to the one of NOTE 3 of 3.1.  MODULE coord\_m  USE iso\_fortran\_env  **PRIVATE :: add\_coord**  TYPE coord\_t(k)  INTEGER, KIND :: k  REAL(kind=k) :: x, y, z  END TYPE coord\_t  **INTERFACE OPERATOR(+)**  **MODULE PROCEDURE :: add\_coord**  **END INTERFACE**  CONTAINS  GENERIC FUNCTION **add\_coord**(a, b) RESULT(c)  TYPE(coord\_t(real32,real64)), INTENT(IN) :: a, b  TYPEOF(a) :: c  c%x = a%x + b%x  c%y = a%y + b%y  c%z = a%z + b%z  RETURN  END FUNCTION **add\_coord**  END MODULE coord\_m  The following GENERIC statement can also be used instead of using the interface block.  **GENERIC :: OPERATOR(+) => add\_coord** |

## Extension of SELECT constructs

### Extension of SELECT RANK construct

The SELECT RANK construct is extended to specify non-assumed-rank variables as the *selector*.

C1155x The *selector* in a *select-rank-stmt* shall be the name of an assumed-rank array **or non-assumed data object**.

Constraint: If the *selector* is not assumed-rank, *associate-name* in the *select-rank-stmt* is not allowed.

R1152x *select-rank-case-stmt* **is** RANK ( ***rank-value-range-list*** ) [ *select-construct-name* ]  
 **or** **RANKOF ( *data-ref* ) [ *select-construct-name* ]**  
 **or** RANK ( \* ) [ *select-construct-name* ]  
 **or** RANK DEFAULT [ *select-construct-name* ]

***rank-value-range*** is defined in R1148a of 3.2.4.

RANKOF ( *data-ref* ) is equivalent to RANK ( RANK ( *data-ref* ) ).

Constraint: If the *selector* is assumed-rank, *rank-value-range-list* shall be a single *rank-value.*

Constraint: If the *selector* is assumed-rank, RANKOF *select-rank-case-stmt* is not allowed.

NOTE 1

|  |
| --- |
| A SELECT RANK construct selects at most one block at runtime if the *selector* is assumed-rank, at compile time otherwise. In a generic subprogram, the programmer can write partially different program codes by rank in a SELECT RANK construct by specifying a dummy argument that has alternative ranks as the *selector.* For example, the two generic subprograms in List 2 of 2.2 can be written as one using the SELECT RANK construct as follows.  GENERIC FUNCTION has\_nan(x) RESULT(ans)  REAL(REAL32,REAL64,REAL128), RANK(**0:15**), INTENT(IN) :: x  LOGICAL :: ans  SELECT RANK(x)  RANK (0)  **ans = ieee\_is\_nan(x)**  RANK (1:15) ! or RANK DEFAULT  **ans = any(ieee\_is\_nan(x))**  END SELECT  END FUNCTION has\_nan  This unification of generic subprograms through the SELECT RANK construct is useful when most of the code is the same but only a few parts differ by rank. |

### Extension of SELECT TYPE construct

The SELECT TYPE construct is extended to support non-polymorphic variables as the *selector*.

A sentence in F2023:11.1.11.1 is changed from:

The selection is based on the dynamic type of an expression.

to:

The selection is based on the dynamic type of an expression if the *selector* is polymorphic, on the declared type of an expression otherwise.

C1164x (R1155) The *selector* in a *select-type-stmt* shall be **a** polymorphic **entity or a non-polymorphic data object**.

R1156x *type-guard-stmt*  **is** TYPE IS ( ***type-spec-list*** ) [ *select-construct-name* ]   
  **or** CLASS IS ( ***derived-type-spec-list*** ) [ *select-construct-name* ]  
  **or** **TYPEOF ( *data-ref* ) [ *select-construct-name* ]  
 or CLASSOF ( *data-ref* ) [ *select-construct-name* ]**  **or** CLASS DEFAULT [ *select-construct-name* ]

TYPEOF ( *data-ref* ) and CLASSOF ( *data-ref* ) are equivalent to TYPE IS ( *type-spec* ) and CLASSOF ( *type-spec* ), respectively, where *type-spec* is the type and kind of *data-ref*.

Constraint: If the *selector* is polymorphic, *type-spec-list* shall be a single *type-spec* and *derived-type-spec-list* shall be a single *derived-type-spec.*

Constraint: If the selector is polymorphic, TYPEOF or CLASSOF *type-guard-stmt* shall not be allowed.

Constraint: If the *selector* is not polymorphic, every kind type parameter of *type-spec*, *derived-type-spec*, or *data-ref* specified in TYPE IS, CLASS IS, TYPEOF or CLASSOF *type-guard-stmt* shall be constant.

C1167x (R1154) If *selector* is **polymorphic but** not unlimited polymorphic, each TYPE IS or CLASS IS *type-guard-stmt* shall specify an extension of the declared type of *selector*.

Comment:

* Description of the length type parameter is not clear enough. Constraint C1165 states that the length type parameter must be assumed, but it may not be suitable for dummy arguments of the generic subprogram.
* Consideration might be insufficient for the case that the dummy argument of a generic subprogram is polymorphic. Both selections by declared type at compile time and by dynamic type at runtime might be required.

# Summary

This paper proposed the following language extensions for the generic subprogram:

* The GENERIC prefix and the *generic-spec* that specify a subprogram as generic,
* Extension of the type declaration statement that specifies alternative types, kinds and ranks of the dummy arguments of a generic subprogram,
* Extension of the interface block that specifies the explicit interfaces of generic subprograms, and
* Extension of the SELECT RANK and TYPE constructs for alternative types, kinds and ranks.

So far, the generic names, operators, assignments, and defined I/O’s provided by the generic identifier mechanism bring great convenience to library users. However, this often required the library providers to create tens or hundreds of specific subprograms; otherwise, they had no choice but to program in a processor-dependent manner or to program leaving decision and branch costs at runtime. Since the generic subprogram significantly reduces the size of the code that describes the specific subprograms, it reduces programming and maintenance costs without compromising execution performance and portability.

# Acknowledgments

I would like to thank John Reid for reading this paper and suggesting some improvements to the presentation. It was his idea to extend SELECT constructs to handle generic dummy arguments. Tomohiro Degawa and the user group Fortran-jp for discussing it from the user’s perspective and offering practical suggestions. And I also thank Hiroyuki Sato and Yasuhiro Hayashi for their useful comments, and Masayuki Takata and Toshihiro Suzuki for pointing out improvements in examples and descriptions. Discussions with Thomas Clune, Brad Richardson, and the Generics subgroup helped improve the alternative type specifier.

# History

Version 1.0 🡪 1.1

* Multiple type specs are allowed not only in the TYPE clause but also in the CLASS clause.
  + R703x was modified with CLASS ( alter-derived-type-spec ).
  + R703b was added.
  + Three constraints are added:
  + Comments about the difference between TYPE and CLASS clauses were eliminated.
* Comments about the idea of TYPE(INTRINSIC), TYPE(ARITHMETIC), etc. were eliminated.
* Mentioned the META SELECT TYPE construct in Comments of 3.2.1.
* Mentioned the META SELECT RANK construct in Comments of 3.2.3.

Version 1.1 🡪 1.2

* The title was changed from “Generic Subprogram” to “Proposal for Generic Subprogram.”

Version 1.2 🡪 1.3

* In List 1, “LOC” was replaced by “lines of code” in three places.
* In 3.1 and 4, “function or subroutine statement” to “FUNCTION or SUBROUTINE statement.”
* In NOTE 3 of 3.1, modified
* In Comment of 3.2.1, added more explanations and one alternative idea.
* In the second item of Comment of 3.2.3, added more explanations and one alternative idea.
* In 5 Acknowledgment, added thanks to Schuko, Makki, and Suzu-P.
* Some typos and trivial modifications.

Version 1.3 🡪 1.4

* In 1. Introduction, improved.
* In 3. Syntax, a new term generic type declaration statement is defined and used.
* In 3, *generic-spec* is allowed in *function/subroutine-stmt* instead of *function/subroutine-name.*
* In 3.1, add NOTE 3 and 4.
* In 3.2.1, add NOTE 1 and 2.
* Add “3.2.3 Alternative kind specifier for parameterized derived type” and reorganized in 3.2.
* In 4. Summary, modified.

Version 1.4 🡪 1.5

* R721x was modified.

Version 1.5 🡪 1.6-7

* In Section 1, trivial modification.
* In 2.2, paragraphs are moved before NOTEs.
* In Section 3, paragraphs 3 and 4 are added.
* In 3.1, Alternative proposal was added.
* In NOTE 3 of 3.1, added: “that extends the feature of the + operator.”
* In NOTE 4 of 3.1, trivial modification.
* In Comment of 3.1, the first item (about the interface block) was deleted.
* In NOTE 2 of 3.2.1, added “, assignment(=)” and deleted the corresponding inline comment.
* In Comment of 3.2.1, the new first item (about distinguishable dummy arguments) was added.
* In Comment of 3.2.1, the last item (about META SELECT TYPE construct) was deleted.
* In Comment of 3.2.4, the second item (about META SELECT RANK construct) was deleted.
* Added 3.3
* Added 3.4
* Section 4 (Summary) was modified for added 3.3 and 3.4.

Version 1.6-7 🡪 1.7

* Affiliation (Fortran WG, ...) is added.
* In Sections 2 and 2.2, minor modifications.
* In Alternative Proposal 1, minor modifications.
* In NOTE 3 of 3.1, added the second code using a GENERIC statement.
* In NOTE 4 of 3.1, added “use coord\_m” and a short description.
* The titles of 3.2, 3.3 and 3.4 were changed.
* In 3.2, the first sentence “A generic type declaration statement is ...” was added.
* In 3.2, type-declaration-statement was modified to type-declaration-stmt.
* In 3.2.1, R702(asis) and C703(asis) was deleted.
* In 3.2.3 C795(asis), C799(asis) and R701(asis) were deleted.
* In Comment of 3.2.4, the second item (necessity of RANKOF(data-ref) ) was added.
* In Comment of 3.4.2, the second item (issue of polymorphic and generic dummy argument) was added.
* Some other minor modifications were made in the whole of 3.2, 3.3 and 3.4.
* Sections 4 (Summary) and 5 (Acknowledgments) are modified.