smFISH Image Analysis and Colocalization Guide:

(Shahar Garin, May 2023)

# **Introduction**

This document aims to thoroughly explain the different steps required for fluorescent image analysis and make them accessible with relatively little knowhow. It requires basic knowledge of working with computers, and how to activate scripts in Fiji (Plugins → Macros → Run…).

Prerequisites, such as file formats or needed values are explained in each section, so please read the instructions carefully.

Examples shown in this guide were mainly based on ER segmentation, but the processes described in it can also be used, as described, for any other organelle you wish. The colocalization script was designed to work with sub-segmented ER images (a process described below, that requires DAPI to mark the cells nuclei), but can also be used on whole ER images. As such, if you use these scripts on any other organelle, it will work just as well.

The guide and scripts were all written and used while using a windows PC. Use of any of the programs of scripts on different system may create issues.

All scripts’ code can be found in this document ([Scripts Code section](#_Scripts_Code:)). Each script code is linked from the title of its corresponding section.

Applications you need to install before beginning:

Fiji can be downloaded for free [here](https://imagej.net/software/fiji/).

YeastMate standalone app can be downloaded for free [here](https://github.com/hoerlteam/YeastMate/releases) (download .exe file)

YeastMate plugin Fiji installation can be performed by following instructions on [this page](https://yeastmate.readthedocs.io/en/latest/fiji/).

RS-FISH plugin Fiji installation can be performed by following instructions on [this page](https://github.com/PreibischLab/RS-FISH#download).

1. [**Using Fiji to convert bio-format files to Tiff, and arranging in folders:**](#_Script_for_conversion)

Most microscope software output images in a format unique to the manufacturer. This file types (bio-formats) can be less accessible for many programs or processes. As such, the first step of image analysis, is making sure all the files are in the correct format.

This macro assumes each channel and scene are saved in a seperate image file (no multi-channel images). File names must be different for each channel. It can have the name of the marker (GFP, DAPI, mCherry, etc.) or an arbitrary name (c1, c2, etc.). The user must know these names and input them (case sensetive).

**Important** – if your files are formatted differently (in a multi channel image, for example) this script won’t work. You must convert each channel to a tif format image and save each channel’s images in a seperate folder.

1. The user will be asked to input the directory containing the images, their file type (sould apear at the end of the file name; tested with stk).
2. The user will be asked to input the number of channels, as well as channel’s name. Channel names must be the same as appears in the corrsponding file’s name (**case sensative**).
3. A new folder will be created in the same folder as the images. A main folder called ‘Tiff Images’ and sub-folders for each of the channels.
4. Each file in the folder will be opened seqeuncially, and saved in its proper folder as a tiff file, with its original name.
5. [**Using YeastMate to create mask images of yeast cells:**](#_Using_YeastMate_to)


One of the first challenges in image analysis is identifying and defining each cell in the image. When it comes to images of yeast cells, YeastMate is a Fiji plugin that provides fast and trustworthy results, using a pre-trained, machine learning approach. The script uses the apps default settings.

It should be noted, to use the YeastMate plugin, you must install its standalone app, and use it to start backends. Failing that, the script described here will not work. The plugin itself must also be installed to Fiji. Also, YeastMate works on single plane images. To choose the best plane from a multiplane image, masks of each plane will be created and the one containing the largest amount of cells will be chosen to be outputted as the final image.


In addition, **YeastMate must run in a computer without interruption**. It can take a long time to get a mask image when using high resolution images with many slices. It is also very resource intensive. Specifically, it requires a large amounts of RAM. If you have many images to process, take that into consideration. For example, when processing 50 images with 12 slices each, at 2048x2048 resolution, the script needed ~4 hours. Timing will vary greatly according to available computing resources.

If you want greater control over the settings for YeastMate, you can use the standalone app, instead of the automated script described here. Explanations of how to use the app can be found [in](https://yeastmate.readthedocs.io/en/latest/gui/) the original author’s website.

1. First, input the folder in which tif files of the cells in visible light (brightfield, usually) can be found.
2. Open YeastMate. The program will start in ‘Start a new job’ tab (this and the following stage can be performed before you run the script).
3. Press ‘Start Backends’ Button. Two console windows will open. Both IO Backend and Detection Backend markers will turn green. Once they are green you may press ‘Ok’ on the popup message.



1. For each image in the folder:
   1. Image is opened.
   2. For each slice:
      1. Yeastmate will create a mask image. Masks will be transforemed to binary images (using MinError tresholding, to capture all cells).
      2. Using Analyze → Analyze Particles, cells are added to the Roi Manager and counted.
   3. The plane with the largest number of identifed cells is chosen.
   4. The chosen plane is duplicated: Image → Duplicate X number of original planes.
   5. The image is converted back to the original image dimentions: Image → Adjust → Size.
   6. The image is converted back to a binary image: Process → Binary → Convert to Mask.
   7. A new, stacked image is created, containing a copy of it in each plane: Image → Stacks → Images to Stack.
   8. The image is saved in the same folder as the original images, under the ‘Cells Masks’ folder.
   9. You will get a binary image, with a white background and the shape of the cells in black. This will be used downstream to identify each cell’s location.



Original Brigthfield Image

Processed Mask Image


**Unsolved Bugs or issues:**

Low quality images, where no cells are identified may occasionally lead to YeastMate crushing for one or more of the slices, resulting the script crushing as well. In such a case the image cannot be used and must be removed before running the script again.

Once the script is done, the Fiji ‘Console’ window may open, presenting an error. The reason for the error is unclear, but it has no effect on the script’s success and can be ignored.


1. **Using Trainable Weka Segmentation to obtain probability map of sub-cellular structures:**

Identfying and defining sub-cellular structures is a more challenging step, the less regular the shape. In case of ER, for example, the shapes vary considerably from cell to cell. The solution from Weka, in the form of a Fiji plugin, allows a user to manually train an algorithm fairly easily, and using the results of the training (a file called a classifier), to perform segmentation of all similar signals in many different images. Here follows a detailed explanation of the training procces.



3

1. Open image of appropriate channel in Fiji.
2. The first step is creating a trained classifier model that will be used on all images.




4

1. If you wish to save time, make sure to only use a single z-plane image for this stage (in a multiple stacks image: Image → Stacks → Stacks to images).


Press Plugins → Segmentation → Trainable Weka Segmentation. The pictured window will open.

1. To train the classifier, you must mark specific areas of each class (your organelle, background etc.). You may add classes by pressing ‘Create new class’. Name each class by pressing ‘Settings’, at the bottom left. The pictured window will open.
2. Change class names to fit your experiment (for example, ‘ER’ and ‘Background’).
3. Under the settings window, you may also change different features that can alter the behavior of the classifier. Notice adding more training features will result in longer training and identification times, and require more computational resources.



8

1. Now the line tool can be used on the image, to mark different classes. It is recommended to adjust brightness/saturation and zoom in for this stage (adjusting brightness won’t affect the classifier).
2. Mark a small segment each time, and press ‘Add to Class’ button. The markings will change color and be added to the list under the class name (pictured).
3. Avoid adding a marking to a class, if the marking is inaccurate. You cannot remove a marking once it’s added. You can start marking again, and an unsaved marking will disappear.



12



1. After marking and adding about a dozen times for each class, press ‘Train classifier’.
2. After training will end, you will be able to see how the different classes are marked on the entire image (pictured).
3. Save the classifier by pressing ‘Save classifier’. You may now retrain it on the same image, or, preferably, on different images.
4. Repeat these steps until you’re happy with the segmentation results. Save the final classifier.
5. Pressing ‘Get probability’ will output a Probability map image that can be used for further processing.
6. [**Use of classifier on a folder of corresponding images:**](#_Script_for_use)

The following script allows the use of a trained classifier on multiple images in a user inputted folder.

Script assumes a classifier was already created (as desceribed above).

Script assumes a folder containing only images of a channel corresponding with chosen classifier.

1. The user is asked to input the folder containing images of the channel they wish to segment and the classifier (in a browse window).
2. It creates a subfolder to save the probability maps images, in the same folder as the images.
3. For each image:
   1. Each z-plane is saved as a seperate file (in ‘seperated\_planes’ folder).
   2. Go over the seperate z-plane images, one at a time and runs a macro that performs the following actions:
      1. Run Trainable Weka Segmentation plugin.
      2. Load classifier.
      3. Create probability map.
      4. Save probability map in subfolder (in ‘temp\_maps’ folder).
      5. Close all.
   3. After all planes from one image have a probability map, open them all.
   4. Stack to a single image (same name + ‘\_map’).
   5. Save probability map image with multiple z-planes in probability maps folder.
   6. Close all.
   7. Delete unnecessary image files from ‘seperated\_planes’ and ‘temp\_maps’ folders.



Original Image

Processed Probability Map

1. [**Creating nER and cER mask files for colocalization calculations:**](#_Script_for_nER)

Yeast ER is usually divided to cortical (cER) and perinuclear (nER) ER. The first is found far from the nuclear membrane, and the second is near it. When checking for colocalization with the ER, it is common to calculate colocalization with both sub-sections separately. To identify between them, an image marking the nucleus is needed (most commonly, DAPI).

This script assumes the Trainable Weka Segmentation process was performed on both ER and DAPI signals and probability maps for both exist. Each must be saved in their own folders (without any subfolders) and the files must be ordered in the same manner. If the files were created using the scripts in this guide, all the conditions will be met.

**Important note:** In cells without a DAPI signal, there will be no way of identifying nER and cER. As such, these cells, in these planes, must be filtered out in the colocalization calculations, downstream (the colocalization script in this guide performs this).

1. The user is asked for the folder of the DAPI probability files and the ER Probability files.
2. The user is asked for the number of dilation steps to be performed on the DAPI signal area. This should be tested by the user with several values, to make sure the resulting images with the two ER sections are satisfactory.
3. For each DAPI image:
   1. Process → Binary → Make Binary. Using Minimum threshold method and assuming light background.


A corresponding binary image is created.

* 1. Process → Binary → Options. Performing dilate as many times as the user decided (default = 3).
  2. For the corresponding ER probability map: Process → Binary → Make Binary. Using Li threshold method and assuming light background.


A corresponding binary image is created.

* 1. Process → Image Calculator… Performs subtraction of the DAPI binary image from the ER binary image, outputting and saving a binary image containing only the cER.
  2. Process → Image Calculator… Performs subtraction of the new cER image form the original ER image, outputting and saving a binary image containing only the nER.


All images are saved in the original ER probability maps folder.



Processed Probability Map



Cortical ER Mask




Perinuclear ER Mask

1. **Manual run of RS-FISH for threshold identification:**

While it is possible to define smFISH signals using Trainable Weka Segmentation, it is a time intensive, unnecessary process. smFISH signals are far simpler than an organelle, and can be identified using specific plugins. RS-FISH, is one such plugin. It’s fast, accurate and takes into account signal intensity between different cross sections. Crucially, it can be automated using Fiji scripts.


**Important:** Before automation, RS-FISH must be used manually on a few images for each signal type you wish to identify. To properly identify FISH spots, RS-FISH requires a signal threshold, which will be different between experimental procedures and different probes.



2

A step by step explanation is provided here, but to gain a full understanding of the process, it is recommended to read the [documentation provided with the plugin](https://github.com/PreibischLab/RS-FISH#readme):

1. Open an image and activate the plugin (Plugins → RS-FISH → RS-FISH).
2. A window will open. Under ‘Mode’, choose ‘Interactive. Under ‘Robust fitting’, choose RANSAC. Mark bot tick boxes and finally, under ‘Spot intensity’, choose ‘Linear Interpolation’ (it should look like it does in the image). Click ok.
3. Several windows will pop up. Move the additional image window side by side with the original image.
4. If you haven’t done so before, change the image’s brightness and contrast so you can clearly see signals. Drag and move the square that appeared on your image so it’ll mark an area with signals in it. You can also manipulate it’s size and shape to you liking, though it shouldn’t be too large. Zoom in to it on both images.
5. Now, when you move across different slices (cross sections of you cell), you can see the signals are marked by a red circle. For each spot, across all planes, only the most intense is marked.
6. In the ‘Adjust difference-of-gaussian values’ window, you can change the Threshold value. Change it several times and test to see the best value, which allows you to capture as many signals as possible, without marking noise. **Always prefer to miss some signals (a false negetive) than to mark noise as signal (false positive).**



5

1. Once an appropriate value is found, you may check it by repeating thep process on a second and third image with the same signal source.
2. The threshold value can be used on all images with the same signal source (a specific probe or other marker), who were subjected to the same capturing method (same channels, same microscope, same exposure time, etc.).
3. [**smFISH spots identification using RS-FISH:**](#_Script_for_smFISH)

Once you have an appropriate threshold, you can use the automation script provided here, to collect data regarding the locations of all spots in your images:

1. The user is asked for the location of the cells masks images directory.
2. The user is asked for the location of the smFISH channel images directory.
3. The user is asked for the spots identification threshold value.
4. Once these are inputted, the script performs the following steps on each image:
   1. Opens cells mask file.
   2. Dilates once to allow identification of signals at the edge of the cell (Process → Binary → Dilate) and watershed to separate close cells (Process → Binary → Watershed).
   3. Selects all cells and add each to roi manager
   4. Open smFISH image.
   5. Select all cells location and remove anything outside of them.
   6. Measure mean intensity of entire image, across all cross sections (used as RS-FISH intensity threshold).
   7. Run RS-FISH, using the provided spots threshold and calculated intensity threshold.
   8. Sort results by ‘z’ value (the slice where it was found).
   9. Save results using current image name.

All results table will be saved as csv files, under the same directory as the smFISH channel images, in a new directory called ‘smFISH Spots”.

1. **[Colocalization of smFISH signals and ER (or any other organelle):](#_Script_for_smFISH_1)**

Once the organelle is well defined in binary files and smFISH spots data is obtained, colocalization can be examined. First, the user must provide a few values. The first, is the radius of the mRNA spots signal, in pixels. To get it, few images should be examined closely, and the pixel radius of a signal must be ascertained. It can be a non-natural number. Colocalization will be checked according to that distance. Meaning, a large number may mark signals far from the organelle as colocalized, and a small value will result in less signals to be identified as associated with the organelle. Take that into consideration when choosing this value.

A second set of values is also required. The user must decide if they wish to filter out cases in which the ER signal takes too great or too small proportion of the cell cross section. For specific cells and cross sections, an organelle like ER can appear to be spread across the entirety of the cell, making any smFISH signals present appear as colocalized. On the other hand, if no organelle signal is available in a specific cross section, you may not want the spots in it to be counted at all. The user will be prompted for both minimum and maximum values (in percentages) of organelle spread within a cross section. It is recommended you go over a few images manually and measure the proportion of organelle signal within cells. You can do that by opening corresponding mask images of the cells and the organelle. Perform analyze particles on the cell image (Analyze → Analyze Particles…) and add them to the roi manager. Then, choose the organelle mask image and perform measure (first, Analyze → Set Measurements and select ‘Area fraction’ and then Analyze → Measure). A table will open with the organelle proportion within each cell. Go over the cells and see which values correspond with cells that are too dense or too sparse with organelle signal. Choose your values accordingly.

This script will prompt the user for the locations of the cells mask images and spots csv files created by RS-FISH (if you wish to identify spots using another method, provide a csv file with headings of ‘x’, ‘y’, and ‘z’. Each spot’s coordinates should appear in the ‘x’ and ‘y’ columns, while the ‘z’ column should be the slice number, where 0 is the first slice and n-1 is the nth slice).

Next the script will ask the user whether ER was sub-segmented (as described in section 5 of this guide). If it was, choose ‘Yes’. If it wasn’t or you wish to colocalize using mask images of a different organelle, choose ‘No’. According to the user’s answer, they will be prompted to provide locations of organelle and DAPI masks (only of ER sub-segmentation was performed).

The user will be asked where they want to save the results tables and lastly, for values of the smFISH signal radius, and the minimum and maximum values of ER coverage per cell, per cross section.

This script is quite complex, so a step-by-step description of its workings won’t be provided. The general description of the script’s process is as follows:

After the user inputs the aforementioned values and folders, the script goes over each image, each plane within the image, each cell and each mRNA. Each mRNA is assigned to its specific cell, as well as given a colocalization assignment of to the organelle. Colocalization is defined by having **any** amount of ER signal at a distance no greater than the radius of the smFISH signal, as provided by the user. In the case both nER and cER signals are present, the one with a greater total signal (i.e., more ER signal pixels) is chosen. The check is done by creating a circle with the provided radius around the smFISH spot’s maxima and measuring the amount of organelle signal inside that circle.

The script filters out cells according to several features: edge cells (containing pixels found in the 2% nearest to the edges), cells with less than 0.15 relative area of DAPI signal, per plane (only if ER sub-segmentation was performed) and cells with less/more than the minimum/maximum percentage of their area containing ER, per plane.

For each image, a CSV file is created in the folder the user inputted. A message with the folder path will be printed to the Fiji log.

**Crucial notes:**

The script must work while no other window is opened in Fiji. It must be run on folders containing only the images described above and no other image or folder. Using the other scripts in the guide to create these images should create such folders. Lastly, for unclear reasons, the script cannot run in batch mode. Meaning, it must open each image it uses and should not be interrupted while it works. **Do not use the computer while it runs** (it’s fairly quick, but if you have many images, try to run it on 2-3 of them to evaluate how long you need to leave your computer).

**Unsolved Bugs or issues:**

At times, an empty results table window remains open after the script is done.it can be closed.

The log will be filled with lines only containing ‘1’. This is an output of the files deletion function, and can be ignored.

# **Scripts Code:**

## **Script for conversion of ‘stk’ to ‘tiff’ and subfolders arrangment:**

// Input source folder and create new folder for converted files  
bioimg\_folder = getDirectory("Select source directory");  
tiff\_folder = bioimg\_folder + "Tiff Images";  
image\_format = getString("What is you file format?", "stk");  
File.makeDirectory(tiff\_folder);  
// Setup folders for experiment  
channel\_num = getNumber("How many channels did you image?", 4);  
channels\_list = newArray(channel\_num);  
**for** (channel\_index=0; channel\_index < channel\_num; channel\_index++) {  
 channel\_name = getString("Name of channel " + channel\_index+1 + " (must be part of file name, case sensative):", "");  
 channel\_folder = tiff\_folder + File.separator + channel\_name;  
 File.makeDirectory(channel\_folder);  
 channels\_list[channel\_index] = channel\_name;  
}  
// Convert bioimg files to tiff  
file\_num = getFileList(bioimg\_folder);  
setBatchMode(**true**);  
**for** (file\_index=0; file\_index < file\_num.length; file\_index++) {  
 **if** (endsWith(file\_num[file\_index], image\_format)) {  
 image\_name = bioimg\_folder + file\_num[file\_index];  
 open(image\_name);  
 **for** (channel\_list\_index=0; channel\_list\_index < channels\_list.length; channel\_list\_index++) {  
 **if** (indexOf(file\_num[file\_index], channels\_list[channel\_list\_index]) != -1) {  
 current\_channel\_name = channels\_list[channel\_list\_index];  
 tiff\_path = tiff\_folder + File.separator + current\_channel\_name + File.separator + file\_num[file\_index];  
 saveAs("tiff", tiff\_path);  
 close();  
 }  
 }  
 }  
}

## **Script for using YeastMate to create mask image of yeast cells:**

cell\_dir = getDirectory("Cell (brightfield) images directory:");  
cell\_list = getFileList(cell\_dir);  
mask\_directory = cell\_dir + "Cells Masks";  
File.makeDirectory(mask\_directory);  
  
waitForUser("Are the YeastMate Backends open? If not, open before continuing.");  
//Go over images in folder  
**for** (img = 0; img < cell\_list.length; img++) {  
 cell\_img\_path = cell\_dir + cell\_list[img];  
 **if** (File.isFile(cell\_img\_path)) {  
 img\_path = cell\_dir + cell\_list[img];  
 open(img\_path);  
 slices\_num = nSlices;  
 //Go over each slice in an image  
 img\_width = getWidth();  
 img\_height = getHeight();  
 **if** (img\_width > 1024 || img\_height > 1024) {  
 run("Size...", "width=1024 height=1024 depth=12 constrain interpolation=Bicubic");  
 }  
 **for** (slice = 0; slice < slices\_num; slice++) {  
 selectWindow(cell\_list[img]);  
 setSlice(slice + 1);  
 run("YeastMate", "scorethresholdsingle=0.9 scorethresholdmating=0.75 scorethresholdbudding=0.75 minnormalizationqualtile=0.015 maxnormalizationqualtile=0.985 addsinglerois=false addmatingrois=false addbuddingrois=false showsegmentation=true onlyselectedclassesinmask=false processeveryframe=false mintrackingoverlap=0.25 ipadress=localhost:11005");  
 }  
 //Convert to mask image  
 run("Images to Stack", " title=seg use");  
 stacked\_mask = getTitle();  
 run("Convert to Mask", "method=MinError background=Dark calculate");  
 //Find slice with max amount of cells  
 max\_cell\_num = 0;  
 max\_slice = 0;  
 **for** (slice = 0; slice < slices\_num; slice++) {  
 selectWindow(stacked\_mask);  
 setSlice(slice + 1);  
 **if** (isOpen("ROI Manager")) {  
 roiManager("reset");  
 }  
 run("Analyze Particles...", "add slice");  
 **if** (roiManager("count") > max\_cell\_num) {  
 max\_cell\_num = roiManager("count");  
 max\_slice = slice;  
 }  
 }  
 //Duplicate max slice and create stack image of it  
 selectWindow(stacked\_mask);  
 setSlice(max\_slice + 1);  
 run("Duplicate...", "title=[Max Slice]");  
 run("Size...", "width=" + img\_width + " height=" + img\_height + " depth=1 constrain interpolation=Bicubic");  
 run("Convert to Mask");  
 **for** (slice = 0; slice < (slices\_num - 1); slice++) {  
 run("Duplicate...", " ");  
 }  
 run("Images to Stack", " title=Max use");  
 saveAs("tiff", mask\_directory + File.separator + cell\_list[img] + "Mask");  
 run("Close All");  
 close("Roi Manager");  
 }  
}

## **Script for use of Trainable Weka Segmentation on a folder of images:**

//Getting image directory from user and creating probability maps folder  
bioimg\_folder = getDirectory("Input image directory:");  
prob\_map\_folder = bioimg\_folder + File.separator + "Probabiliy Maps";  
File.makeDirectory(prob\_map\_folder);  
//Getting trained calassifier file location from user  
classifier\_path = File.openDialog("Input classifier location:");  
  
//Starting time  
startTime = getTime();  
  
//Get list of images  
file\_list = getFileList(bioimg\_folder);  
setBatchMode(**true**);  
**for** (file = 0; file < file\_list.length; file++) {  
 //Make sure file is not a folder (won't go into fsubfolders)  
 image\_path = bioimg\_folder + file\_list[file];  
 //Create folders for seperated slices and maps  
 seperated\_folder = bioimg\_folder + "seperated\_planes";  
 File.makeDirectory(seperated\_folder);  
 temp\_maps\_folder = bioimg\_folder + "temp\_maps";  
 File.makeDirectory(temp\_maps\_folder);  
 **if** (File.isFile(image\_path)) {  
 //Go over files and create a file from each slice in a new directory  
 open(image\_path);  
 run("Image Sequence... ", "dir=[" + seperated\_folder + "] format=TIFF digits=2 use");  
 run("Close All");  
 //Go over new folder, and use classifier to output probability map  
 plane\_list = getFileList(seperated\_folder);  
 **for** (plane = 0; plane < plane\_list.length; plane++) {  
 setBatchMode(**false**);  
 open(seperated\_folder + File.separator + plane\_list[plane]);  
 run("Trainable Weka Segmentation");  
 **while** (!isOpen("Trainable Weka Segmentation v3.3.2")) {  
 wait(100);  
 }  
 selectWindow("Trainable Weka Segmentation v3.3.2");  
 call("trainableSegmentation.Weka\_Segmentation.loadClassifier", classifier\_path);  
 call("trainableSegmentation.Weka\_Segmentation.getProbability");  
 **while** (!isOpen("Probability maps")) {  
 wait(100);  
 }  
 selectWindow("Probability maps");  
 run("Delete Slice");  
 saveAs("tiff", temp\_maps\_folder + File.separator + plane\_list[plane]);  
 //Force garbage collection (important for large images)  
 run("Close All");  
 call("java.lang.System.gc")  
 }  
 setBatchMode(**true**);  
 //Create a multi-plane image from probability maps of all planes  
 map\_list = getFileList(temp\_maps\_folder);  
 **for** (map = 0; map < map\_list.length; map++) {  
 map\_path = temp\_maps\_folder + File.separator + map\_list[map];  
 open(map\_path);  
 }  
 // Save maps as stack  
 run("Images to Stack", "name=" + file\_list[file] + "");  
 saveAs("tiff", prob\_map\_folder + File.separator + file\_list[file] + "\_map");  
 run("Close All");  
 //Delete uneeded files and folders  
 sepereated\_list = getFileList(seperated\_folder);  
 **for** (sep = 0; sep < sepereated\_list.length; sep++) {  
 img\_to\_del = seperated\_folder + File.separator + sepereated\_list[sep];  
 File.delete(img\_to\_del);  
 }  
 maps\_list = getFileList(temp\_maps\_folder);  
 **for** (dmap = 0; dmap < maps\_list.length; dmap++) {  
 map\_to\_del = temp\_maps\_folder + File.separator + maps\_list[dmap];  
 File.delete(map\_to\_del);  
 }  
 File.delete(seperated\_folder + File.separator);  
 File.delete(temp\_maps\_folder + File.separator);  
 }  
}  
//Print elapsed time  
estimatedTime = (getTime() - startTime) \* 0.001;  
IJ.log( "\*\* Finished processing folder in " + estimatedTime + " s \*\*" );

## **Script for nER and cER masks creation:**

//Getting images directory from user and saving lists of files  
dapi\_folder = getDirectory("Choose DAPI probability maps directory:");  
er\_folder = getDirectory("Choose ER probability maps directory:");  
  
dapi\_list = getFileList(dapi\_folder);  
er\_list = getFileList(er\_folder);  
  
dilate\_num = parseInt(getString("How many times should the DAPI mask file be dilated (test to see what gets you the best results for your images)?", "3"));  
setBatchMode(**true**);  
//Go over images   
**for** (file = 0; file < dapi\_list.length; file++) {  
 open(dapi\_folder + dapi\_list[file]);  
 //Convert to mask file  
 run("Make Binary", "method=Minimum background=Light calculate create");  
 dapi\_mask = getTitle();  
 //Save DAPI mask files  
 File.makeDirectory(dapi\_folder + "DAPI Masks");  
 selectWindow(dapi\_mask);  
 saveAs("tif", dapi\_folder + "DAPI Masks" + File.separator + dapi\_mask);  
 // Dilate signal as many times as user chooses  
 selectWindow(dapi\_mask);  
 run("Options...", "iterations="+ dilate\_num + " count=1 pad edm=32-bit do=Dilate stack");  
 open(er\_folder + er\_list[file]);  
 selectWindow(er\_list[file]);  
 run("Make Binary", "method=Li background=Light calculate create");  
 main\_er\_mask = getTitle();  
 imageCalculator("Subtract create stack", main\_er\_mask, dapi\_mask);  
 File.makeDirectory(er\_folder + "cER Masks");  
 saveAs("tif", er\_folder + "cER Masks" + File.separator + main\_er\_mask + "\_cER");  
 cER\_mask = getTitle();  
 imageCalculator("Subtract create stack", main\_er\_mask, cER\_mask);  
 File.makeDirectory(er\_folder + "nER Masks");  
 saveAs("tif", er\_folder + "nER Masks" + File.separator + main\_er\_mask + "\_nER" );  
 run("Close All");  
}

## **Script for smFISH spot identification using RS-FISH:**

Dialog.create("Important");  
Dialog.addMessage("Please make sure to use RS-FISH manually for each probe you're using, to identify proper threshold.");  
Dialog.show();  
//Ask user for cells mask images location  
Dialog.create("Cells masks location");  
Dialog.addMessage("Please input the cells mask images directory:");  
Dialog.show();  
cell\_dir = getDirectory("Cells mask images directory:");  
cell\_list = getFileList(cell\_dir);  
//Ask user for location of FISH images and threshold for RSFISH  
Dialog.create("smFISH images location");  
Dialog.addMessage("Please input the smFISH (probe) images directory:");  
Dialog.show();  
smFISH\_dir = getDirectory("smFISH images directory (probe channel):");  
RSFISH\_Threshold = parseFloat(getString("Threshold for RS FISH:", "0.00180"));  
smFISH\_list = getFileList(smFISH\_dir);  
File.makeDirectory(smFISH\_dir + "smFISH Spots");  
//Go over each image in the folder and create ROI files with all the spots identified  
**for** (img = 0; img < smFISH\_list.length; img++) {  
 FISH\_img\_path = smFISH\_dir + smFISH\_list[img];  
 cells\_mask\_path = cell\_dir + cell\_list[img];  
 **if** (!File.isDirectory(FISH\_img\_path)) {  
 //Use cell masks to remove all areas outside of cells in smFISH image  
 open(cells\_mask\_path);  
 //Dilate to improve edge dot identification and use Watershed to seperate close cells  
 setOption("BlackBackground", **false**);  
 run("Dilate", "stack");  
 run("Watershed", "stack");  
 //Analyze all cells and add to roi manager  
 run("Analyze Particles...", "exclude add slice");  
 run("Close All");  
 open(FISH\_img\_path);  
 title = getTitle();  
 //Select all identified cells and remove anything outside of them  
 roiManager("select", Array.getSequence(roiManager("count")));  
 roiManager("Combine");  
 wait(500);  
 run("Clear Results");  
 run("Clear Outside", "Stack");  
 //Calculate mean intensity of image, to use as threshold  
 roiManager("deselect");  
 close("ROI Manager");  
 selectWindow(title);  
 run("Select All");  
 num\_of\_pix = getWidth() \* getHeight();  
 sum\_of\_intesities = 0;  
 run("Set Measurements...", "integrated redirect=None decimal=5");  
 **for** (slice = 1; slice <= nSlices; slice++) {  
 setSlice(slice);  
 run("Measure");  
 sum\_of\_intesities += getResult("RawIntDen", slice - 1);  
 }  
 mean\_intensity = (sum\_of\_intesities/nSlices)/(num\_of\_pix);  
 close("Results");  
 //Run RSFISH  
 run("RS-FISH", "image=[" + title + "] mode=Advanced anisotropy=1.0000 robust\_fitting=RANSAC compute\_min/max use\_anisotropy spot\_intensity=[Linear Interpolation] sigma=1.50000 threshold=" + RSFISH\_Threshold + " support=3 min\_inlier\_ratio=0.10 max\_error=1.50 spot\_intensity\_threshold=" + mean\_intensity + " background=[No background subtraction] background\_subtraction\_max\_error=0.05 background\_subtraction\_min\_inlier\_ratio=0.10 results\_file=[] num\_threads=16 block\_size\_x=128 block\_size\_y=128 block\_size\_z=16");  
 //Save results table  
 selectWindow("smFISH localizations");  
 table\_name = title + " smFISH localizations.csv";  
 table\_path = smFISH\_dir + "smFISH Spots" + File.separator + title + " smFISH localizations.csv";  
 **if** (Table.size >= 1) {  
 Table.sort("z");  
 saveAs("Results", table\_path);  
 }  
 **else** {  
 //setResult("x", nResults, "No spots");  
 saveAs("Results", table\_path);  
 }  
 //Close all windows before starting next image  
 close(table\_name);  
 run("Close All");  
 close("Log");  
 }  
}

## **Script for smFISH spots and organelle colocalization:**

//get the location of cells masks images  
Dialog.create("Cells masks location");  
Dialog.addMessage("Please input the cells mask images directory:");  
Dialog.show();  
cell\_dir = getDirectory("Cells mask images directory:");  
cell\_list = getFileList(cell\_dir);  
//get the location of smFISH csv files  
Dialog.create("smFISH csv files location");  
Dialog.addMessage("Please input the csv files directory:");  
Dialog.show();  
smFISH\_dir = getDirectory("smFISH csv files directory (created by RSFISH):");  
smFISH\_list = getFileList(smFISH\_dir);  
//ask user if ER is segmented and get proper mask images  
Dialog.create("ER Sub-segmentation");  
Dialog.addChoice("Was ER segmented to nEr and cER using DAPI (Select 'No' if you have one organelle mask)?", newArray("Yes", "No"));  
Dialog.show();  
ER\_seg\_check = Dialog.getChoice();  
**if** (ER\_seg\_check == "Yes") {  
 Dialog.create("nER masks location");  
 Dialog.addMessage("Please input the perinuclear ER mask images directory:");  
 Dialog.show();  
 nER\_dir = getDirectory("Perinuclear ER mask images directory:");  
 nER\_list = getFileList(nER\_dir);  
 Dialog.create("cER masks location");  
 Dialog.addMessage("Please input the cortical ER mask images directory:");  
 Dialog.show();  
 cER\_dir = getDirectory("Cortical ER mask images directory:");  
 cER\_list = getFileList(cER\_dir);  
 //get the location of DAPI mask images   
 Dialog.create("DAPI masks location");  
 Dialog.addMessage("Please input the DAPI mask images directory:");  
 Dialog.show();  
 DAPI\_dir = getDirectory("DAPI mask images directory:");  
 DAPI\_list = getFileList(DAPI\_dir);  
}  
**if** (ER\_seg\_check == "No") {  
 Dialog.create("Organelle masks location");  
 Dialog.addMessage("Please input the Organelle mask images directory:");  
 Dialog.show();  
 whole\_ER\_dir = getDirectory("Organelle mask images directory:");  
 whole\_ER\_list = getFileList(whole\_ER\_dir);  
}  
Dialog.create("Results tables location");  
Dialog.addMessage("Please input the directory you wish results tables will be saved:");  
Dialog.show();  
results\_path = getDirectory("Results Tables Location:");  
smFISH\_signal\_cutoff = parseFloat(getString("Approximate radius of an smFISH signal (in pixels:", "1.5"));  
ER\_signal\_min = parseFloat(getString("Minimum amount of ER signal within a cell:", "20"));  
ER\_signal\_max = parseFloat(getString("Maximum amount of ER signal within a cell:", "80"));  
  
  
**for** (img = 0; img < cell\_list.length; img++) {  
 //Make sure file is not a folder (won't go into subfolders)  
 cell\_img\_path = cell\_dir + cell\_list[img];  
 **if** (ER\_seg\_check == "Yes") {  
 dapi\_img\_path = DAPI\_dir + DAPI\_list[img];  
 nER\_img\_path = nER\_dir + nER\_list[img];  
 cER\_img\_path = cER\_dir + cER\_list[img];   
 }  
 **if** (ER\_seg\_check == "No") {  
 ER\_img\_path = whole\_ER\_dir + whole\_ER\_list[img];  
 }  
 smFISH\_table = smFISH\_dir + smFISH\_list[img];  
 smFISH\_counter = 0;  
 **if** (File.isFile(cell\_img\_path)) {  
 open(smFISH\_table);  
 Table.sort("z");  
 open(cell\_img\_path);  
 //Dilate to improve cER cover and use Watershed to seperate close cells  
 setOption("BlackBackground", **false**);  
 run("Dilate", "stack");  
 run("Watershed", "stack");  
 //Create folders for seperated slices and maps  
 cell\_seperated\_folder = cell\_dir + "seperated\_planes";  
 File.makeDirectory(cell\_seperated\_folder);  
 //Go over cells image and create a file from each slice in a new directory  
 run("Image Sequence... ", "dir=[" + cell\_seperated\_folder + "] format=TIFF digits=2");  
 run("Close All");  
 **if** (ER\_seg\_check == "Yes") {  
 // Go over dapi image and create a file from each slice in a new directory  
 **if** (File.isFile(dapi\_img\_path)) {  
 //Create folders for seperated slices  
 dapi\_seperated\_folder = DAPI\_dir + "seperated\_planes";  
 File.makeDirectory(dapi\_seperated\_folder);  
 open(dapi\_img\_path);  
 run("Image Sequence... ", "dir=[" + dapi\_seperated\_folder + "] format=TIFF digits=2");  
 run("Close All");  
 }  
 // Go over nER image and create a file from each slice in a new directory  
 **if** (File.isFile(nER\_img\_path)) {  
 //Create folders for seperated slices  
 nER\_seperated\_folder = nER\_dir + "seperated\_planes";  
 File.makeDirectory(nER\_seperated\_folder);  
 open(nER\_img\_path);  
 run("Image Sequence... ", "dir=[" + nER\_seperated\_folder + "] format=TIFF digits=2");  
 run("Close All");  
 }  
 // Go over cER image and create a file from each slice in a new directory  
 **if** (File.isFile(cER\_img\_path)) {  
 //Create folders for seperated slices  
 cER\_seperated\_folder = cER\_dir + "seperated\_planes";  
 File.makeDirectory(cER\_seperated\_folder);  
 open(cER\_img\_path);  
 run("Image Sequence... ", "dir=[" + cER\_seperated\_folder + "] format=TIFF digits=2");  
 run("Close All");  
 }  
 }  
 // Go over non-segmented ER image and create a file from each slice in a new directory  
 **if** (ER\_seg\_check == "No") {  
 ER\_seperated\_folder = whole\_ER\_dir + "seperated\_planes";  
 File.makeDirectory(ER\_seperated\_folder);  
 open(ER\_img\_path);  
 run("Image Sequence... ", "dir=[" + ER\_seperated\_folder + "] format=TIFF digits=2");  
 run("Close All");  
 }  
   
 //Go over seperate slices and create ROIs from the cells image  
 cell\_plane\_list = getFileList(cell\_seperated\_folder);  
 **if** (ER\_seg\_check == "Yes") {  
 dapi\_plane\_list = getFileList(dapi\_seperated\_folder);  
 nER\_plane\_list = getFileList(nER\_seperated\_folder);  
 cER\_plane\_list = getFileList(cER\_seperated\_folder);   
 }  
 **if** (ER\_seg\_check == "No") {  
 ER\_plane\_list = getFileList(ER\_seperated\_folder);  
 }  
   
 cell\_slice = cell\_seperated\_folder + File.separator + cell\_plane\_list[0];  
 open(cell\_slice);  
 img\_width = getWidth();  
 img\_height = getHeight();  
 run("Analyze Particles...", "exclude add");  
 //Get total number of cells for image and create arrays for mRNA spot counting of each cell  
 run("Close All");  
 nCells = roiManager("count");  
 tot\_mRNA\_per\_cell = newArray(nCells);  
 **if** (ER\_seg\_check == "Yes") {  
 tot\_colo\_nER = newArray(nCells);  
 tot\_colo\_cER = newArray(nCells);   
 }  
 **if** (ER\_seg\_check == "No") {  
 tot\_colo\_ER = newArray(nCells);  
 }  
 tot\_no\_colo = newArray(nCells);  
 ER\_signal\_size = newArray(nCells);  
 **for** (plane = 0; plane < cell\_plane\_list.length; plane++) {  
 edge\_cells\_list = newArray(nCells);  
 **if** (ER\_seg\_check == "Yes") {  
 dapi\_signal\_list = newArray(nCells);  
 dapi\_slice = dapi\_seperated\_folder + File.separator + dapi\_plane\_list[plane];  
 nER\_slice = nER\_seperated\_folder + File.separator + nER\_plane\_list[plane];  
 cER\_slice = cER\_seperated\_folder + File.separator + cER\_plane\_list[plane];  
 open(cER\_slice);  
 current\_cER = getTitle();  
 open(nER\_slice);  
 current\_nER = getTitle();  
 }  
 **if** (ER\_seg\_check == "No") {  
 ER\_slice = ER\_seperated\_folder + File.separator + ER\_plane\_list[plane];  
 open(ER\_slice);  
 current\_ER = getTitle();  
 }  
 **if** (isOpen("ROI Manager")) {  
 **if** (nCells == 0) {  
 continue;  
 }  
 roiManager("select", Array.getSequence(roiManager("count")));  
 roiManager("delete");  
 }  
 open(cell\_slice);  
 //Exclude any cell ROI whithin edges (2% of pixels in img)  
 max\_x = img\_width \* 0.98;  
 min\_x = img\_width \* 0.02;  
 max\_y = img\_height \* 0.98;  
 min\_y = img\_height \* 0.02;  
 run("Analyze Particles...", "exclude add");  
 filter\_list = newArray();  
 **for** (roi = 0; roi < nCells; roi++) {  
 roi\_xpoints = newArray();  
 roi\_ypoints = newArray();  
 roiManager("select", roi);  
 Roi.getContainedPoints(roi\_xpoints, roi\_ypoints);  
 **for** (pix = 0; pix < roi\_xpoints.length; pix++) {  
 **if** (roi\_xpoints[pix] > max\_x || roi\_xpoints[pix] < min\_x || roi\_ypoints[pix] > max\_y || roi\_ypoints[pix] < min\_y) {  
 edge\_cells\_list[roi] = 1;  
 break;  
 }  
 }  
 }  
 run("Set Measurements...", "area\_fraction redirect=None decimal=5");  
 **if** (ER\_seg\_check == "Yes") {  
 //Register DAPI signal in each cell (disregard planes where there's no DAPI signal in cell - only for sub-segmented ER)  
 open(dapi\_slice);  
 setThreshold(255, 255, "raw");  
 roiManager("select", Array.getSequence(nCells));  
 roiManager("measure");  
 cells\_table = "Cells Table "+ plane;  
 IJ.renameResults(cells\_table);  
 //Go over each result row and and mark any cells with dapi signal  
 dapi\_cutoff = 0.15;  
 **for** (roi = 0; roi < nCells; roi++) {  
 **if** (Table.get("%Area", roi, cells\_table) < dapi\_cutoff) {  
 dapi\_signal\_list[roi] = 1;  
 }  
 }  
 //Register % of ER signal within cell (disregard planes where signal is too great/small)  
 selectWindow(current\_cER);  
 roiManager("select", Array.getSequence(nCells));  
 roiManager("measure");  
 cER\_signal\_table = "cER Signal " + plane;  
 IJ.renameResults(cER\_signal\_table);  
 selectWindow(current\_nER);  
 roiManager("measure");   
 nER\_signal\_table = "nER Signal " + plane;  
 IJ.renameResults(nER\_signal\_table);  
 **for** (roi = 0; roi < nCells; roi++) {  
 **if** (Table.get("%Area", roi, cER\_signal\_table) + Table.get("%Area", roi, nER\_signal\_table) < ER\_signal\_min || Table.get("%Area", roi, cER\_signal\_table) + Table.get("%Area", roi, nER\_signal\_table) > ER\_signal\_max) {  
 ER\_signal\_size[roi] = 1;  
 }  
 }  
 }  
 **if** (ER\_seg\_check == "No") {  
 //Register % of organelle signal within cell (disregard planes where signal is too great/small)  
 selectWindow(current\_ER);  
 roiManager("select", Array.getSequence(nCells));  
 roiManager("measure");  
 ER\_signal\_table = "ER Signal" + plane;  
 IJ.renameResults(ER\_signal\_table);  
 selectWindow(current\_ER);  
 **for** (roi = 0; roi < nCells; roi++) {  
 **if** (Table.get("%Area", roi, ER\_signal\_table) < ER\_signal\_min || Table.get("%Area", roi, ER\_signal\_table) > ER\_signal\_max) {  
 ER\_signal\_size[roi] = 1;  
 }   
   
 }  
 }  
 //Go over mRNAs in this slice, find each's cell and measure colocalization  
 num\_of\_mRNA = Table.size(smFISH\_list[img]);  
 **for** (mRNA = smFISH\_counter; mRNA < num\_of\_mRNA; mRNA++) {  
 //Check "z" column for spot's slice. If z is smaller than current slice + 1, the spot is in current slice.  
 **if** (Table.get("z", mRNA, smFISH\_list[img]) >= (plane + 1)) {  
 break;  
 }  
 smFISH\_counter += 1;  
 //Check for ER, DAPI and edge limits for each cell  
 **for** (cell = 0; cell < nCells; cell++) {  
 **if** (edge\_cells\_list[cell] == 1 || ER\_signal\_size[cell] == 1) {  
 continue;  
 }  
 **if** (ER\_seg\_check == "Yes") {  
 **if** (dapi\_signal\_list[cell] == 1) {  
 continue;  
 }  
 }  
 roiManager("select", cell);  
 current\_X = Table.get("x", mRNA, smFISH\_list[img]);  
 current\_Y = Table.get("y", mRNA, smFISH\_list[img]);  
 **if** (Roi.contains(current\_X, current\_Y)) {  
 //Use ability to draw selection circles on organelle mask image - sub-segmented ER  
 **if** (ER\_seg\_check == "Yes") {  
 selectWindow(current\_cER);  
 //Create circle selection with radius of cutoff given by user, around smFISH spot pixel  
 makeOval(current\_X - smFISH\_signal\_cutoff, current\_Y - smFISH\_signal\_cutoff, smFISH\_signal\_cutoff \* 2, smFISH\_signal\_cutoff \* 2);  
 run("Clear Results");  
 run("Set Measurements...", "mean redirect=None decimal=2");  
 run("Measure");  
 selectWindow(current\_nER);  
 //Create circle selection with radius of cutoff given by user, around smFISH spot pixel  
 makeOval(current\_X - smFISH\_signal\_cutoff, current\_Y - smFISH\_signal\_cutoff, smFISH\_signal\_cutoff \* 2, smFISH\_signal\_cutoff \* 2);  
 run("Measure");  
 //Check if there's ER signal near the smFISH spot  
 **if** (getResult("Mean", 0) != 0 && getResult("Mean", 1) != 0) {  
 **if** (getResult("Mean", 0) > getResult("Mean", 1)) {  
 tot\_colo\_cER[cell]++;  
 continue;   
 }  
 **else** **if** (getResult("Mean", 0) <= getResult("Mean", 1)) {  
 tot\_colo\_nER[cell]++;  
 continue;  
 }  
 }  
 **else** **if** (getResult("Mean", 0) != 0) {  
 tot\_colo\_cER[cell]++;  
 continue;   
 }  
 **else** **if** (getResult("Mean", 1) != 0) {  
 tot\_colo\_nER[cell]++;  
 continue;  
 }  
 **else** {  
 tot\_no\_colo[cell]++;  
 continue;  
 }  
 }  
 //Use ability to draw selection circles on organelle mask image - single mask organelle  
 **if** (ER\_seg\_check == "No") {  
 selectWindow(current\_ER);  
 //Create circle selection with radius of cutoff given by user, around smFISH spot pixel  
 makeOval(current\_X - smFISH\_signal\_cutoff, current\_Y - smFISH\_signal\_cutoff, smFISH\_signal\_cutoff \* 2, smFISH\_signal\_cutoff \* 2);  
 run("Clear Results");  
 run("Set Measurements...", "mean redirect=None decimal=2");  
 run("Measure");  
 //Check if there's ER signal near the smFISH spot  
 **if** (getResult("Mean", 0) != 0) {  
 tot\_colo\_ER[cell]++;  
 continue;  
 }  
 **else** {  
 tot\_no\_colo[cell]++;  
 continue;  
 }  
 }  
   
 //End of Roi loop  
 }  
 //End of cell loop  
 }  
 //End of mRNA loop  
 }  
 close("\*");  
 close("Roi Manager");  
 **if** (ER\_seg\_check == "Yes") {  
 close(cells\_table);  
 close(cER\_signal\_table);  
 close(nER\_signal\_table);  
 }  
 **if** (ER\_seg\_check == "No") {  
 close(ER\_signal\_table);  
 }  
 //End of Plane loop   
 }  
 close("\*");  
 //Remove single plane files  
 //Cells  
 **for** (sep = 0; sep < cell\_plane\_list.length; sep++) {  
 img\_to\_del = cell\_seperated\_folder + File.separator + cell\_plane\_list[sep];  
 File.delete(img\_to\_del);  
 }  
 File.delete(cell\_seperated\_folder);  
 **if** (ER\_seg\_check == "Yes") {  
 //DAPI  
 **for** (sep = 0; sep < dapi\_plane\_list.length; sep++) {  
 img\_to\_del = dapi\_seperated\_folder + File.separator + dapi\_plane\_list[sep];  
 File.delete(img\_to\_del);  
 }  
 File.delete(dapi\_seperated\_folder);  
 //nER  
 **for** (sep = 0; sep < nER\_plane\_list.length; sep++) {  
 img\_to\_del = nER\_seperated\_folder + File.separator + nER\_plane\_list[sep];  
 File.delete(img\_to\_del);  
 }  
 File.delete(nER\_seperated\_folder);  
 //cER  
 **for** (sep = 0; sep < cER\_plane\_list.length; sep++) {  
 img\_to\_del = cER\_seperated\_folder + File.separator + cER\_plane\_list[sep];  
 File.delete(img\_to\_del);  
 }  
 File.delete(cER\_seperated\_folder);  
 }  
 **if** (ER\_seg\_check == "No") {  
 **for** (sep = 0; sep < ER\_plane\_list.length; sep++) {  
 img\_to\_del = ER\_seperated\_folder + File.separator + ER\_plane\_list[sep];  
 File.delete(img\_to\_del);  
 }  
 File.delete(ER\_seperated\_folder);  
 }  
 }  
 //Sum and save data for img  
 results\_table\_name = cell\_list[img] + "Colocalization.csv";  
 Table.create(results\_table\_name);  
 Table.setColumn("Cell #", Array.getSequence(tot\_mRNA\_per\_cell.length), results\_table\_name);  
 Table.setColumn("Total mRNA per Cell", tot\_mRNA\_per\_cell, results\_table\_name);  
 **if** (ER\_seg\_check == "Yes") {  
 Table.setColumn("Total Colocolized With nER", tot\_colo\_nER, results\_table\_name);  
 Table.setColumn("Total Colocolized With cER", tot\_colo\_cER, results\_table\_name);   
 }  
 **if** (ER\_seg\_check == "No") {  
 Table.setColumn("Total Colocolized With Organelle", tot\_colo\_ER, results\_table\_name);  
 }  
 Table.setColumn("Total Not Colocolized with Organelle", tot\_no\_colo, results\_table\_name);  
 //Add edge filtering column and remove appropriate lines from results table  
 Table.setColumn("Edge Cells", edge\_cells\_list, results\_table\_name);  
 **for** (row = nCells - 1; row >= 0; row--) {  
 **if** (Table.get("Edge Cells", row, results\_table\_name) == 1 ) {  
 Table.deleteRows(row, row, results\_table\_name);  
 }  
 }  
 Table.deleteColumn("Edge Cells", results\_table\_name);  
 selectWindow(results\_table\_name);  
 //Save results as csv  
 saveAs("Results", results\_path + results\_table\_name);  
 run("Close All");  
 close(results\_table\_name);  
 close(smFISH\_list[img]);  
//End of img loop  
}  
print ("All images done. Results saved under " + results\_path);