ソフトウェア実験Ⅱ・Ⅲ

テーマ1 レポート

学籍番号：1TE22028G

氏名：一瀬遥希

提出日：2024年12月13日

**1　テーマ 1 についての説明**

テーマ1では, C言語とアセンブリ言語を組み合わせて, C 言語処理系 m68kelf-gcc に付随して提供されているライブラリのうち, 基本的な関数であるread(), write(), printf(), scanf()がMC68VZ328 ボードにおいて動作する環境を構築することを目的としている. これにより, システムレベルでのプログラム操作や, 標準入出力を通じたユーザーインターフェースの基本を学ぶことができる.

具体的には, シリアルポートを使用してデータの入出力を行うためのinbyteとoutbyteという2つのアセンブリ言語サブルーチンを実装する. このサブルーチンは, モニタプログラムが提供するシステムコールGETSTRINGおよびPUTSTRINGを利用することで, 1文字単位の入出力を行う. これらの実装を通じて, C言語からアセンブリ言語を呼び出す方法や, 引数や戻り値の取り扱い方法を学ぶ.

このテーマ1は, C言語プログラムがアセンブリ言語の低レベル操作を活用する際の基本的な技術を習得する重要なステップとなる. 特に, テーマ2以降のマルチタスクカーネル開発や応用プログラム作成の準備段階として位置付けられる.

**2　テーマ 1 の実験全体に占める位置付けの説明**

テーマ1は実験全体の基盤を形成する重要な役割を持つ. C言語とアセンブリ言語間の連携方法を学ぶことで, テーマ2以降のマルチタスクカーネルや応用プログラムの作成に必要な知識を習得できる.

例えば, テーマ2では複数タスクの切り替え処理やリソース管理を扱い, テーマ3では実際の応用プログラムを開発するが, それらすべてにおいてC言語とアセンブリ言語の連携が必須となる. 特に, テーマ1で実装するinbyteとoutbyteを基に, 標準入出力ライブラリの機能を利用するreadやwriteを動作させることが可能になる. このため、テーマ1は以降のテーマで必要となる基礎スキルを身に付けるための準備段階として非常に重要である.

**3　プログラムのリスト・説明**

**3.1　モニタプログラムの初期化**

　以下に, モニタプログラムの初期化部分のプログラムリストを示し, 今回の実験のための変更点について説明を行う.

.extern     start

.global     monitor\_begin

.include    "equdefs.inc"

monitor\_begin:

.section .bss

.even

SYS\_STK: .ds.b 0x4000   | システムスタック領域

.even

SYS\_STK\_TOP:        | システムスタック領域の最後尾

.even

task\_p: .ds.l 1

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\* 初期化

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

.section .text

.even

boot:   \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    \*\* スーパーバイザ & 各種設定を行っている最中の割込禁止

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    move.w  #0x2700,%SR

    lea.l   SYS\_STK\_TOP, %SP | Set SSP

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    \*\* 割り込みコントローラの初期化

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    move.b  #0x40, IVR | ユーザ割り込みベクタ番号を0x40+level に設定．

    move.l  #0x00ff3ffb,IMR | 全割り込みマスク

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    \*\* 送受信 (UART1) 関係の初期化 (割り込みレベルは 4 に固定されている)

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    move.w  #0xe10c, USTCNT1

    move.w  #0x0038, UBAUD1 | baud rate = 230400 bps

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    \*\* タイマ関係の初期化 (割り込みレベルは 6 に固定されている)

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    move.w  #0x0004, TCTL1

    move.l  #uart1\_interrupt, 0x110

    move.l  #timer\_interrupt, 0x118

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    \*\*キューの初期化

    \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

    jsr     Init\_Q

    move.l  #SYSTEM\_CALL,0x080

    move.l  #0x00f3ff9, IMR

    move.w  #0x0000, %SR

    jmp start

　C言語プログラムは, 最初にmain関数が実行されるが, その前にスタックポインタやBSSセクションの初期化などが行われる. 本実験では, 前回作成したモニタプログラムの初期化ルーチンを活用し, 以下のような変更を加えることで, Cプログラムのmain関数を起動するようにした.

1. 初期化ルーチンの先頭にmonitor\_beginというラベルを追加
2. 初期化ルーチン終了後に、main関数があるstartにジャンプするためのjmp startを記述
3. 他のファイルからmonitor\_beginを呼び出せるように.global monitor\_beginを宣言し, startを外部参照するために.extern startを宣言

これにより, Cプログラムの実行前に必要な初期化処理をモニタプログラムで行うことが可能になった.

**3.2　inbyte()のアセンブリ言語による作成**

**3.2.1　inbyte()を含むinchrw.s**

　以下に, inbyteサブルーチンを含むinchrw.sファイル内のプログラムリストとその説明を示す.

.global inbyte

.include "equdefs.inc"

.text

.even

inbyte:

    movem.l %d1-%d3, -(%sp)

inbyte\_loop:

    move.l  #SYSCALL\_NUM\_GETSTRING, %d0

    move.l  #0, %d1

    move.l  #inchrw\_buf, %d2

    move.l  #1, %d3

    trap    #0

    cmpi.l   #0, %d0

    beq     inbyte\_loop

    move.b  inchrw\_buf, %d0

    move.b  %d0, LED0

    movem.l (%sp)+, %d1-%d3

    rts

.section .bss

.even

inchrw\_buf: .ds.b 1

    .even

inbyte()及びinbyte\_loop()は, 引数を取らず, 戻り値としてシリアルポート0から読み込んだ1文字(char型)を返すアセンブリ言語サブルーチンである. この関数は, モニタプログラムが提供するGETSTRINGシステムコールを使用する.

　関数の構成は以下の通りである.

1.　レジスタ退避

サブルーチンの先頭で%d1から%d3のレジスタをスタックに退避し, サブルーチン内での変更が外部に影響しないようにしている.

2.　システムコール呼び出し準備

GETSTRINGシステムコール番号を%d0に設定する. 入力する文字を格納するメモリ上のバッファ（inbyte\_buff）アドレスを%d2に設定する. データのサイズは%d3に1バイトと指定する.

3.　システムコール実行

trap #0命令でシステムコールを呼び出す. この時点でシステムはシリアルポート0から1文字のデータを受信し, 指定されたバッファに格納する.

4.　入力の確認とループ処理

GETSTRINGが成功すると, 戻り値として%d0に1が格納される. もし戻り値が1でなければ, 入力が正しく行われなかったことを意味するため, 再度ループしてシステムコールを呼び出す.

5.　戻り値設定

入力された文字はinbyte\_buffに格納されているため, それを%d0に移動し, C言語から利用可能な形にする.

6. レジスタ復元

最後にスタックから%d1から%d3を復元し, サブルーチンを終了する.

このサブルーチンにより, 確実に1文字を入力し, その結果をC言語の関数から返り値として利用できるようになっている. ここでは, プログラム内で1バイトサイズでバッファを定義し, それを入力を受け取るために利用している.

**3.2.2　Option: 非待機1文字入力inkey()**

　以下に, Optionとして上記のinchrw.s内に追加作成を行ったinkey()のプログラムリストとその説明を示す.

inkey:

    movem.l %d1-%d3, -(%sp)

inkey\_loop:

    move.l  %d0, %d1

    move.l  #SYSCALL\_NUM\_GETSTRING, %d0

    move.l  #inchrw\_buf, %d2

        move.l  #1, %d3

        trap    #0

        cmpi.l   #0, %d0

        beq     no\_input

        move.b  inchrw\_buf, %d0

    andi.l  #0xff, %d0

no\_input:

    move.l  #-1, %d0

input\_end:

    movem.l (%sp)+, %d1-%d3

    rts

この関数は, inbyte()と同様の構成ではあるが, 戻り値を1文字入力がある場合はその文字を符号なしint型に変換した値とし, 1文字入力がない場合は-1(0xff)となるように記述したものである. なおこの関数は動作の確認は取っておらず, テーマ3の応用プログラムのための準備として作成を行った.

**3.2.3　中難度Option: Cのローカル変数領域に相当する作業領域の確保**

　以下に, 中難度Option課題としてプログラム内でブッファを定義するのではなくローカル変数を作業領域として取ったinbyte()を含むinchrw.sのプログラムリストと説明を示す.

.global inbyte

.include "equdefs.inc"

.text

.even

inbyte:

    movem.l %d1-%d3/%a6, -(%sp)

    link.w  %a6, #-4

inbyte\_loop:

    move.l  #SYSCALL\_NUM\_GETSTRING, %d0

    move.l  #0, %d1

    move.l  %a6, %d2

    sub.l   #1,  %d2

    move.l  #1, %d3

    trap    #0

    cmpi.l   #0, %d0

    beq     inbyte\_loop

    move.b  -1(%a6), %d0

    move.b  %d0, LED0

    unlk    %a6

    movem.l (%sp)+, %d1-%d3/%a6

    rts

ここでのinbyte()及びinbyte\_loop()は, Cのローカル変数領域に相当する作業領域を確保し、効率的なメモリ操作を実現している.

動作手順は以下の通りである.

1. レジスタの退避

関数の先頭で, データレジスタ%d1〜%d3とアドレスレジスタ%a6をスタックに退避する。これにより, サブルーチン内でこれらのレジスタが変更された際の, 関数外部への影響を防いでいる.

2. ローカル作業領域の確保

link.w %a6, #-4命令を使用して, スタックフレームを確保し, 作業領域を設定する. この作業領域を通じてデータの一時的な格納が可能となる.

3. 入力ループの開始

システムコール番号SYSCALL\_NUM\_GETSTRINGを%d0に, バッファアドレスを%d2に, データサイズ（1バイト）を%d3に設定する. そしてtrap #0命令を実行してシステムコールを呼び出し, シリアルポート0からデータを受信する.

4. 入力成功の判定

戻り値として%d0に成功フラグ（1が成功、0が失敗）が格納ため, cmpi.l #0, %d0命令で失敗を判定し, 成功するまでループを繰り返す.

5. データの取得と格納

入力された文字は作業領域内のバッファ（-1(%a6)）に格納されている. この値を%d0に移動し, 関数の戻り値として設定する. また, 入力された文字をLED0に出力することで, デバッグや動作確認が行っている.

6. 作業領域の解放

unlk %a6命令を使用してスタックフレームを解放し, 作業領域を元の状態に戻す.

7. レジスタの復元と終了

スタックから退避していたレジスタを復元し, rts命令で関数を終了する.

このような手順で, ローカル作業領域の確保とLEDを用いた簡易デバッグ機能を組み合わせて, より実用的な設計とした. また, 入力データの成功確認をループで行うことで, 確実なデータ取得を保証している.

**3.3　outbyte()のアセンブリ言語での作成**

　以下に, outbyteサブルーチンを含むファイル内のプログラムリストとその説明を示す.

.global outbyte

.include "equdefs.inc"

.text

.even

outbyte:

    movem.l %d1-%d3, -(%sp)

outbyte\_loop:

    move.l  #SYSCALL\_NUM\_PUTSTRING, %d0

    move.l  #0, %d1

    move.l  %sp, %d2

    addi.l  #19, %d2

    move.l  #1, %d3

    trap    #0

    cmpi.l   #0, %d0

    beq outbyte\_loop

    movem.l  (%sp)+, %d1-%d3

    rts

outbyteは, 引数としてchar型のデータを取り, シリアルポート0に出力するためのアセンブリ言語のサブルーチンである. この関数は, モニタプログラムが提供するPUTSTRINGシステムコールを使用する.

動作手順は以下の通りである.

1.　レジスタ退避

サブルーチンの先頭で%d1から%d3のレジスタをスタックに退避し, サブルーチン内での変更が外部に影響しないようにしている.

2.　引数の取り出し

C言語側から渡された出力文字は、スタックに保存されている. スタックポインタ（%sp）から19バイト進んだ位置に出力文字が格納されているため, アドレス計算を行い, 出力文字のアドレスを%a0に設定する.

3.　システムコール呼び出し準備

PUTSTRINGシステムコール番号を%d0に設定する. 出力するデータのアドレスは%d2に設定する. データのサイズは%d3に1バイトと指定する.

4.　システムコール実行

trap #0命令でシステムコールを呼び出す. この時点で指定されたデータがシリアルポート0を通じて出力される.

5.　出力の確認とループ処理

PUTSTRINGが成功すると, 戻り値として%d0に1が格納される. もし戻り値が1でなければ, 出力が正しく行われなかったことを意味するため, 再度ループしてシステムコールを呼び出す.

6.　レジスタ復元

最後にスタックから%d0から%d3を復元し, サブルーチンを終了する.

このサブルーチンにより, C言語のプログラムから引数で指定された文字を確実に出力することができる.

**3.4　テスト用プログラム test1.c**

**3.4.1　test1.c**

　以下に, テスト用のCプログラムであるtest1.cのプログラムリストとその説明を示す.

#include <stdio.h>

int main()

{

  while(1){

    char str[256];

    scanf("%s",str);

    printf("%s\n",str);

    }

    return 0;

}

　このプログラムは非常に簡素なものであり，入力した文字をそのまま出力するscanf関数とEnterキーを押すことで入力された文字を表示するprintf関数を無限ループで繰り返すという構造になっている. このプログラムが正常に動作したため，作成したinbyteと outbyteによって，標準入出力関数が正常に動作することが確認できた．

**3.4.2　低難度Option: ユーザ定義exit()によるmain()終了時のプログラム停止措置**

　以下に, 同じソースモジュール内に関数exit()を定義したtest1.cのプログラムリストとその説明を示す.

#include <stdio.h>

int main()

{

  char str[256];

    scanf("%s",str);

    printf("%s\n",str);

    return 0;

}

void exit(int value) {

\*(char \*)0x00d00039 = 'H'; /\* LED0 への表示 (HALT) \*/

for (;;) ; /\* 無限ループトラップで停止させる \*/

}

　本実験における実機環境ではmain()の終了後は特に考慮されていないため, main()のテストプログラムはループ内記述が推奨されている. ここでは資料に従い, 万が一main()が終了してしまう場合を想定して, PCがtext領域外に置かれて誤動作を引き起こさないように, exit()を追加定義している. 実際に, 上記のプログラムリストにあるように, main()内のループ処理を外し, 終了するようにして実行すると, LED0へ”H”を表示してプログラムは正常に停止した.

**3.5　低難度Option: trap #0のシステムコール番号5の追加**

　以下に, システムコール番号5の追加を行ったモニタプログラムmon.sの該当部分のプログラムリストを示し、説明を行う.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\* SYSTEM\_CALL

\*\* 入力

\*\* d0:システムコール番号

\*\* d1以降:システムコールの引数

\*\* 出力

\*\* d0:システムコール呼び出しの結果

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

SYSTEM\_CALL:

    cmp.l   #5, %d0

    bne     SYSTEM\_CALL1

    jsr     skipmt

SYSTEM\_CALL1:

    movem.l %d1-%d3,-(%sp)      /\*レジスタの退避\*/

    cmp.l   #1,%d0

    bne SYSTEM\_CALL2        /\*システムコール番号が１でないならば分岐\*/

    jsr GETSTRING       /\*GETSTRINGを呼び出す\*/

    bra SYSTEM\_CALL\_FINISH

SYSTEM\_CALL2:

    cmp.l   #2,%d0

    bne SYSTEM\_CALL3        /\*システムコール番号が2でないならば分岐\*/

    jsr PUTSTRING       /\*PUTSTRINGを呼び出す\*/

    bra SYSTEM\_CALL\_FINISH

SYSTEM\_CALL3:

    cmp.l   #3,%d0

    bne SYSTEM\_CALL4        /\*システムコール番号が3でないならば分岐\*/

    jsr RESET\_TIMER     /\*RESET\_TIMERを呼び出す\*/

    bra SYSTEM\_CALL\_FINISH

SYSTEM\_CALL4:

    cmp.l   #4,%d0

    bne SYSTEM\_CALL\_FINISH  /\*システムコール番号が4でないならば分岐\*/

    jsr SET\_TIMER       /\*SET\_TIMERを呼び出す\*/

SYSTEM\_CALL\_FINISH:

    movem.l (%sp)+,%d1-%d3      /\*レジスタの復帰\*/

    rte

…

skipmt:

rts

.end

　ここでは, trap #0の割り込み処理エントリの先頭にシステムコール番号5の判定を入れ,一致するとタイマ割り込み処理にjmpするように記述している. ここではタイマ割り込み処理を仮にskipmtとし, 後方に何も処理を行わずrtsで返ってくるという空の処理を施し, コンパイルエラーが出ないようにしている. この中身についてはテーマ2において実装を行う部分である.

**4　プログラムにおいて注意したこと**

**4.1　成功判定とループ実行**

　入出力装置とプログラムの処理速度が一致しない場合, 文字の読み取りや書き出しに失敗し, システムコールGETSTRINGやPUTSTRINGが正常に動作しないことがある. 本プログラムでは, inbyte()およびoutbyte()において, 失敗時に再試行を行う仕組みを導入した. 具体的には, 戻り値が格納されるレジスタ%d0を確認し, 成功するまでループでシステムコールを繰り返すようにしている.

**4.2　outbyte()における引数**

　m68k-elf-gccにおいて, 関数呼び出しの際の引数は右から左へ順に評価されてスタックに積まれる. そしてその後, 復帰のためのPCが積まれる. さらに, サブルーチン内でレジスタを退避させた場合, 更にその上に積まれるような構造になっている. このため, outbyte()で引数を取ってきたい場合, 現在の%SPの値をそのまま使うことはできず, 欲しい引数の番地を計算し，%SPに加算する必要がある. 仮に引数が仮に引数がアルファベット小文字のaであった場合のスタックの様子を図に示す.

テーブル が含まれている画像

自動的に生成された説明

図1：outbyte()実行時のスタックの状況

ここでは%SPに即値19を⾜すことによって，char ʻaʼ = 0x00000061 のうち下 1 バイトだけを得られるということになる．このように, スタック構造を正確に理解し, 計算によって引数のアドレスを取得することが重要であった. また, 退避させたレジスタの数も考慮に入れなければ引数の操作が正確に行えないことにも注意を払って実装を行った.

**4.3　中難度Option: Cのローカル変数領域に相当する作業領域の確保**

この関数の実装を行う際, link.w %a6, #-4命令は, 現在のスタックポインタ(%sp)を基に, 4バイト分のローカル作業領域を確保するものであった. そのため入力されたものをアドレス計算の後にスタックに格納する必要があったが, -1(%a6)のアドレス操作は, 作業領域サイズ（linkで確保したバイト数）に依存するため, 正しいサイズ設定を心がけ, バイトサイズで操作を行った. また, スタックポインタが乱れてプログラムが正しく動作しなくなることを防ぐために, unlk %a6命令で作業領域の解放行うことを注意した.

グラフ

自動的に生成された説明

図２：link命令実行時のスタックの状況

**5　プログラムに発生した問題とその原因，解決方法**

**5.1　 outbyte()における引数**

　outbyte() の作成においては, 上記の注意点で示したようにスタックへのデータの積まれ方, また対比させるレジスタの数を考慮したアドレス計算が必要であった. しかし, はじめはこのことに対する理解が不足しており, うまく関数を動かすことができなかった. その中でoption課題へのチャレンジやアドレスを1つずつずらしての地道な試行, また班員との相談などを通して解決することができた.

**5.2　中難度Option: Cのローカル変数領域に相当する作業領域の確保**

　これも上記の注意点で示したものであるが, ローカル領域の仕様にチャレンジしている際に, アドレス操作の正しいサイズ設定に気づけておらず, 関数がうまく動かない事態に陥った. これも一緒の課題にチャレンジしている班員とお互いのコードを検証し合う中で間違いに気づき, 解決することができた.

**6　考察**

本実験を通じて, アセンブリ言語とC言語の連携や, ハードウェア操作を習得することができた. 特に, GETSTRINGやPUTSTRINGを利用したシステムコールの実装を通じて, 標準入出力ライブラリの構造や, レジスタ操作, スタックフレームの管理方法を深く理解することができた. また, アセンブリ言語ではデータサイズやレジスタの配置を厳密に考慮する必要があり, その難しさを体感する一方で, 効率的なメモリ操作が可能であることも確認できた.

一方で, C言語の高級ライブラリが, これらの低水準操作を抽象化し, 開発効率を向上させている理由も明確になった. 本実験の方法を応用すれば、, 他のCライブラリ関数をターゲットシステム上で実現することも可能であり, さらには異なるプログラミング言語の移植や新しいOSの開発への応用も見込まれると考えられる. また, プログラムの分割コンパイルやモジュール化の重要性を再認識し, 大規模プログラムの保守性や拡張性を向上させる手法を学ぶことができたため, 今後のマルチタスクカーネルや応用プログラムの開発において大いに役立つと考える.

**7　テーマ 2 の準備としての思考実験**

ここでは, テーマ2の準備としての思考実験を⾏う．テーマ2において作成するセマフォとタイマ切り替えによるマルチタスク実⾏環境において, 複数のユーザタスクを実⾏した場合の各キューやセマフォの状態について考察する．

**7.1　思考実験の概要と前提条件**

　今回の思考実験では以下の2点を満たすようにユーザタスクを作成を行う．

* セマフォを2つ以上使う
* 各セマフォ, readyキューの全てにおいて, 2つ以上のタスクが入るタイミングが初期状態以外に存在する.

また, 本実験では実験遂行上の都合により, タイマ割り込みは1秒毎に発生し, タスクの切り替え及びP命令, V命令にかかる時間は限りなく短く, この間にタイマ割り込みが発生する可能性はないものとして考える.

**7.2　作成したユーザタスク群とその説明**

　以下に, 作成したユーザタスク群のプログラムリストとその説明を示す.

#include <stdio.h>

#define N 1000 // hypothetical time unit

void task\_1(void);

void task\_2(void);

void task\_3(void);

void task\_4(void);

int main(void)

{

    init\_kernel(); // initialize the kernel

    set\_task(task\_1);

    set\_task(task\_2);

    set\_task(task\_3);

    set\_task(task\_4);

    begin\_sch(); // start the scheduler

    return 0;

}

void task\_1(void)

{

    while (1)

    {

        P(0);

        for (int i = 0; i < N; i++)

        {

            // loop for 1 second

        }

        V(0);

        P(1);

        for (int i = 0; i < N; i++)

        {

            // loop for 1 second

        }

        V(1);

    }

}

void task\_2(void)

{

    while (1)

    {

        P(0);

        for (int i = 0; i < N; i++)

        {

            // loop for 1 second

        }

        V(0);

    }

}

void task\_3(void)

{

    while (1)

    {

        P(1);

        for (int i = 0; i < N; i++)

        {

            // loop for 1 second

        }

        V(1);

    }

}

void task\_4(void)

{

    while (1)

    {

        for (int i = 0; i < N \* 3; i++)

        {

            // loop for 3 seconds

        }

    }

}

　このプログラムでは, task\_1はセマフォ0,1の両方, task\_2はセマフォ0のみ, task\_3はセマフォ1のみを使い, それぞれ1秒間かかる処理, そしてtask\_4はセマフォを使わずに独立に3秒間かかる処理を記述している.

**7.3　実行結果**

　上記の条件において, プログラムの実行を行う際の動作遷移表とその説明を以下に示す.

表1：思考実験プログラムの動作遷移表



　これを見ると, task\_2及びセマフォ0の処理を終えてセマフォ1を利用しようとするtask\_1に関して, セマフォが利用されていてロックされているために待ち行列に入っている時間があることが確認できる. また, task\_4はセマフォを利用しない独立した3秒間の処理を行うために,　1秒毎のタイマ割り込みに合わせて3回に分けて実行されていることが確認できる.