Type parameter broken in multiType abstract

[kevinresol]

4.1.5 prints Warning : Bool
4.2.0 prints Warning : Unknown<0>

comment out the @:to will make it print Bool again

class Main {
	static function main() {
		var c:Collection<Int, Bool> = null;
		$type(c.item); 
	}
}

@:forward
@:multiType(@:followWithAbstracts K)
abstract Collection<K, Item>(ICollection<K, Item>) from ICollection<K, Item> {
	public function new();
	@:to inline function toIntCollection<K:Int, Item>():IntCollection<Item>
		return new IntCollection<Item>();
}

interface ICollection<K, Item> {
	var item:Item;
}

class IntCollection<Item> implements ICollection<Int, Item> {
	public var item:Item;
	public function new() {}
}

[Simn]

This might actually be about @:forward:

class Main {
	static function main() {
		var c:Collection<Int, Bool> = null;
		$type(c.get().item); // Bool
		$type(c.item); // Unknown<0>
	}
}

@:forward
@:multiType
abstract Collection<K, Item>(ICollection<Item>) {
	public function new();

	@:to function toIntCollection<K:Int, Item>():ICollection<Item> {
		return null;
	}

	public function get() {
		return this;
	}
}

interface ICollection<Item> {
	var item:Item;
}

[RealyUniqueName]

Actually, it works better since Haxe 4.2
You're introducing new type params on an instance field instead of using type params of the abstract. That's why they become unbound monomorphs.
To fix that you need to change the code in one of the following ways:

@:to static function toIntCollection<K:Int,V>(t:ICollection<V>):ICollection<V> {
	return null;
}

@:to function toIntCollection():ICollection<V> {
	return null;
}