lv_nmos_cgs_vgs_exp.sch

.LIB "~/Projects/spice/IHP-Open-PDK/ihp-sg13g2/libs.tech/ngspice/models/cornerMOSlv.lib" mos_tt
V1 _net0 _net1 DC 0 SIN(0 1 1K 0 0 0) AC 1 ACPHASE 0
Vg _net1 0 DC 1
Vg_dsb _net2 0 DC 0
Vg_b _net3 0 DC 0
Vg_ds _net4 0 DC 0

X1 _net2  _net0  _net2  _net2 sg13_lv_nmos w=400u l=0.5u nf=40
+ad=80p as=80p pd=436u ps=436u
X2 0  _net0  0  _net3 sg13_lv_nmos w=400u l=0.5u nf=40
+ad=80p as=80p pd=436u ps=436u
X3 _net4  _net0  _net4  0 sg13_lv_nmos w=400u l=0.5u nf=40
+ad=80p as=80p pd=436u ps=436u

.control
pre_osdi ~/Projects/spice/Verilog-A/VA-Models/osdilibs/psp103_nqs.osdi
let points = 300
set vgsp = "$&points"
let Cgdsb = vector($vgsp)
let Cgb = vector($vgsp)
let Cgds = vector($vgsp)
let Vg = vector($vgsp)
let ind = 0
while ind < $vgsp
  let v1_act = -1.5+ind*0.01
  alter Vg = $&v1_act
  ac lin 1 1meg 1meg 
  let Cgdsb[ind] = imag(Vg_dsb#branch)/(2*pi*1e6)
  let Cgb[ind] = imag(Vg_b#branch)/(2*pi*1e6)
  let Cgds[ind] = imag(Vg_ds#branch)/(2*pi*1e6)
  let Vg[ind] = $&v1_act
  let ind = ind + 1
  destroy ac1
end
plot Cgdsb Cgb Cgds vs Vg
.endc
.END