build.gradle

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-android-extensions'
apply plugin: 'io.fabric'

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "uk.co.jakelee.apodwallpaper"
        minSdkVersion 17
        targetSdkVersion 28
        versionCode 8
        versionName "1.1.0"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        buildConfigField "java.util.Date", "BUILD_TIME", "new java.util.Date(" + System.currentTimeMillis() + "L)"
        resConfigs "en"
    }

    flavorDimensions "endpoint"
    productFlavors {
        apod {
            dimension "endpoint"
            applicationId "uk.co.jakelee.apodwallpaper"
            buildConfigField "String", "AUTH_CODE", apod_api_key
        }
        moonmonday {
            dimension "endpoint"
            applicationId "uk.co.jakelee.moonmonday"
            buildConfigField "String", "AUTH_CODE", '""'
        }
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

dependencies {
    // Core
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"

    // Firebase
    implementation 'com.google.firebase:firebase-core:16.0.6'
    implementation 'com.crashlytics.sdk.android:crashlytics:2.9.8'
    implementation 'com.firebase:firebase-jobdispatcher:0.8.5'

    // Android UI libraries
    implementation 'androidx.appcompat:appcompat:1.1.0-alpha01'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.0-alpha3'
    implementation 'com.android.support:preference-v7:28.0.0'
    implementation 'com.android.support:design:28.0.0'

    // Additional UI libraries
    implementation 'com.jsibbold:zoomage:1.2.0'
    implementation 'com.wdullaer:materialdatetimepicker:4.1.0'

    // Networking
    implementation 'com.squareup.okhttp3:okhttp:3.10.0'
    implementation 'com.google.code.gson:gson:2.8.2'

    // Threading
    implementation 'io.reactivex.rxjava2:rxjava:2.1.10'
    implementation 'io.reactivex.rxjava2:rxandroid:2.0.2'

    // Logging
    implementation 'com.jakewharton.timber:timber:4.7.1'

}

apply plugin: 'com.google.gms.google-services'