-
Notifications
You must be signed in to change notification settings - Fork 63
/
Copy pathlila.awk
executable file
·2381 lines (2314 loc) · 113 KB
/
lila.awk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#!/usr/bin/awk -f
###########################################################
#
# "The Name's *Lila*"
#
# A Lil interpreter implemented in POSIX Awk,
# providing a large subset of the Lilt standard library.
# For more information on Lil, see:
#
# http://beyondloom.com/tools/trylil.html
#
###########################################################
BEGIN{
VERSION="1.53";tnames=0
MATH_PI=3.141592653589793
for(z=0;z<256;z++){ordinal[z]=sprintf("%c",z);ascii[sprintf("%c",z)]=z;}
for(z=0;z<16 ;z++){hexdigits[sprintf("%x",z)]=z;hexdigits[sprintf("%X",z)]=z}
}
function max(x,y){return (x>y)?x:y}
function min(x,y){return (x<y)?x:y}
function abs(x){return x<0?-x:x}
function tan(x){return sin(x)/cos(x)}
function floor(n, t){t=int(n);return n==t?n: n>=0?t: t-1}
function ceil(n, t){t=int(n);return n==t?n: n>=0?t+1: t}
function mod(x,y){return y==0?0: x-y*floor(x/y)}
function tempname(){return sprintf("@t%i",tnames++)}
function repeat_char(chr,n, r,z){r="";for(z=0;z<n;z++)r=r chr;return r}
function print_error(text){print text > "/dev/stderr"}
function readline( r){(getline r < "/dev/stdin");return r}
function get_epoch(){
# FIXME: this idiom currently doesn't work correctly in goawk.
# shelling out to `date -u +%s` is tempting, but not actually POSIX-compatible.
# `date` also cannot portably format with ms/ns precision.
return srand(srand())
}
function epoch_to_isodate(x, fmt,gnu,c,r){
# FIXME: doing this in an even moderately portable fashion is a complete nightmare.
# detect GNU coreutils "date" by seeing whether "date" responds to "--version" or pukes:
fmt="+'%Y-%m-%dT%H:%M:%SZ'"
gnu=system("date --version >/dev/null 2>&1")==0
if(gnu){c="date -u -d '1970-01-01 UTC + "x" seconds' "fmt} # GNU coreutils-style
else {c="date -u -r "x" "fmt } # BSD/MacOS-style
c | getline r;close(c);return r
}
function readbytesraw(filename,arr, cmd,i,z){
# rather annoyingly, the -w option for 'od' is not portable.
cmd="od -tu1 -An -v \""filename"\""
c=0;while((cmd | getline)>0)for(z=1;z<=NF;z++)arr[c++]=int($z)
close(cmd);return c
}
function writebytesraw(filename,arr,c){
# FIXME: under gawk, requires the -b flag or LANG=C environment variable set;
# otherwise bytes are mangled into UTF-8 codepoints. thanks, GNU.
printf("")>filename;for(z=0;z<c;z++)printf("%c",arr[z])>>filename;close(filename)
}
function utf8_strip(arr,c, r,z,t){
# Lil strings represent a subset of ASCII;
# UTF-8 data needs to be down-converted at ingestion:
r="";for(z=0;z<c;z++){
t=arr[z]
if(t==226&&arr[z+1]==128&&(arr[z+2]==152||arr[z+2]==153)){t=39;z+=2} # '
if(t==226&&arr[z+1]==128&&(arr[z+2]==156||arr[z+2]==157)){t=34;z+=2} # "
if(t>=240){t=1;z+=3} # skip 4-byte codepoints
if(t>=224){t=1;z+=2} # skip 3-byte codepoints
if(t>=192){t=1;z+=1} # skip 2-byte codepoints
r=r (t==13?"": t==9?" ": (t==10||(t>=32&&t<=126))?ordinal[t]: "?")
};return r
}
function readtext(filename, arr,t,r){
t=readbytesraw(filename,arr);return utf8_strip(arr,t)
# in a world without unicode, we could use a much simpler approach:
if((getline t<filename)<0)return;r=t "\n"
while((getline t<filename)>0)r=r t "\n";close(filename);return r
}
function writetext(filename,text){printf(text)>filename;close(filename);return 1}
function round(x, i,a,f){
i=int(x);if(i==x)return i
if(x<0){a=-x;i=int(a);f=a-i;return f>=.5?int(x)-1:int(x)}
else{f=x-i;return f>=.5?i+1:i}
}
function wnum(y, w,d,s,i,z,t){
w="";d="";if(y<0){y=-y;s="-"}else{s=""};i=floor(y);y=round((y-floor(y))*1000000);if(y>=1000000)i++
while(i>.1){t=int(i%10);t=t<0?0: t>10?10:t;w=t w;i=int(i/10)};w="0"w;while(length(w)>1&&substr(w,1,1)=="0")w=substr(w,2)
for(z=0;z<6;z++){d=int(y%10)d;y=int(y/10)};d="."d;gsub(/\.?0+$/,"",d)
return s w d
}
# some awk implementations provide native bitwise operations,
# but they aren't portable and often come with jagged edges.
# reimplement them from scratch, at the cost of performance:
function lbits(x){return mod(int(x),4294967295)}
function bitwise_and(x,y, v,r){v=1;r=0;while(x>0||y>0){if((x%2)==1&&(y%2)==1)r+=v;x=int(x/2);y=int(y/2);v*=2};return r}
function bitwise_or(x,y, v,r){v=1;r=0;while(x>0||y>0){if((x%2)==1||(y%2)==1)r+=v;x=int(x/2);y=int(y/2);v*=2};return r}
function bitwise_xor(x,y, v,r){v=1;r=0;while(x>0||y>0){if((x%2) !=(y%2) )r+=v;x=int(x/2);y=int(y/2);v*=2};return r}
# many awk builtins interpret strings as regular expressions,
# so we have to escape special chars to use them as literals:
function regex_esc(x){gsub(/[.^$*+?(){}\\|[]/,"\\\\&",x);return x} # . ^ $ * + ? ( ) [ { } \ |
###########################################################
#
# Heap and Garbage Collection
#
###########################################################
BEGIN{
gc_lo=0 # Minimum available heap index
gc_hi=0 # Maximum used heap index (high-water mark)
gc_allocs=0 # Heap values allocated (total)
gc_frees=0 # Heap values freed (total)
gc_gen=0 # Garbage collections performed
gc_intern_base=128+256 # indices reserved for interned ints
}
function heap_make(type, r){
while(heap_type[gc_lo])gc_lo++
gc_hi=max(gc_hi,gc_lo)
heap_type[gc_lo]=type
heap_name[gc_lo]="" # func/native/interface name, block opstream
heap_c [gc_lo]=0 # list/dict count, table colcount
heap_n [gc_lo]=0 # table rowcount, block opcount, string/num raw value
heap_k [gc_lo]="" # key list (dict,table,env), function args
heap_v [gc_lo]="" # val list (list,dict,table,block,env), function block (1-list), image/array data
heap_aux [gc_lo]=-1 # function closure, env parent, native self, array slice-root; -1 if unbound
gc_allocs++;return gc_lo
}
function heap_walk(x, z,c,arr){
if(x<=gc_intern_base||gc_found[x]==1)return;gc_found[x]=1
if(heap_aux[x]!=-1)heap_walk(heap_aux[x])
if(lienv(x)){c=split(heap_name[x],arr,"|");for(z=3;z<=c;z+=2)heap_walk(0+arr[z]);return}
if(lion(x)){heap_walk(lon_body(x));heap_walk(lon_args(x));return}
if(lil(x)||liblk(x)||lid(x)||lit(x)){for(z=0;z<count(x);z++)heap_walk(lst_get(x,z))}
if(lid(x)||lit(x) ){for(z=0;z<count(x);z++)heap_walk(dic_getk(x,z))}
}
function heap_collect( z){
delete gc_found;gc_gen++
for(z=0;z<state_pc;z++)heap_walk(state_p[z])
for(z=0;z<state_ec;z++)heap_walk(state_e[z])
for(z=0;z<state_tc;z++)heap_walk(state_t[z])
for(z=gc_intern_base+1;z<gc_hi;z++)if(heap_type[z]!=0&&gc_found[z]!=1){heap_type[z]=0;gc_frees++;gc_lo=min(gc_lo,z)}
}
###########################################################
#
# Core Datatypes
#
###########################################################
# as a point of discipline, only the functions within this section should
# be directly aware of the internal representation of data structures,
# which includes knowledge of their typecodes and other fields.
# exceptions are made for the "array" and "image" interfaces.
BEGIN{split("number string list dict table function function",typecodes," ")}
function l_typeof(ptr){return lms(lii(ptr)?li_name(ptr): typecodes[heap_type[ptr]])}
# small integers (signed+unsigned byte values) are interned to reduce heap pressure:
function lin(ptr){return heap_type[ptr]==1}
function lvn(ptr){return heap_n[ptr]}
function ln(ptr){return lin(ptr)?lvn(ptr): lis(ptr)?0+lvs(ptr): ln(l_first(ptr))}
BEGIN{for(z=-128;z<=255;z++){r=heap_make(1);heap_n[r]=z;heap_c[r]=1};NONE=lmn(0);ONE=lmn(1)}
function lmn(val, r){val=0+val;if(val==int(val)&&val>=-128&&val<=255)return val+128;r=heap_make(1);heap_n[r]=val;heap_c[r]=1;return r}
# strings are just boxed awk strings; nothing complicated here.
# there might be some potential in interning constant-value strings, perhaps with negative heap indices?
function lis(ptr){return heap_type[ptr]==2}
function lms(val, r){r=heap_make(2);heap_n[r]=string_clean(val);heap_c[r]=length(heap_n[r]);return r}
function lvs(ptr){return heap_n[ptr]}
function ls(ptr){return lis(ptr)?ptr: lin(ptr)?lms(wnum(lvn(ptr))): lil(ptr)?l_fuse(lms(""),ptr): lms("")}
function string_clean(x){gsub(/[\t]/," ",x);gsub(/[‘]/,"'",x);gsub(/[“]/,"\"",x);gsub(/[^ -~\n]/,"?",x);return x}
# lists are represented as fixed-width strings of numeric heap indices (pointers),
# allowing for reasonably efficient random access indexing, appending, and prepending:
function lil(ptr){return heap_type[ptr]==3}
function lml(){return heap_make(3)}
function lst_get(ptr,idx ){return 0+substr(heap_v[ptr],1+(10*idx),10)}
function lst_set(ptr,idx,val, t){t=heap_v[ptr];heap_v[ptr]=substr(t,1,1+(10*idx-1)) sprintf("%10d",val) substr(t,1+(10*(idx+1)))}
function lst_add(ptr,val, t){t=heap_v[ptr];heap_v[ptr]=t sprintf("%10d",val);heap_c[ptr]++ }
function lst_addall(ptr,lst, z){t=heap_v[ptr];heap_v[ptr]=t heap_v[lst] ;heap_c[ptr]+=heap_c[lst]}
function lst_pre(ptr,val, t){t=heap_v[ptr];heap_v[ptr]=sprintf("%10d",val) t;heap_c[ptr]++}
function lst_clone(ptr, r){r=lml();heap_v[r]=heap_v[ptr];heap_c[r]=heap_c[ptr];return r}
function lst_find(ptr,key, z){for(z=0;z<heap_c[ptr];z++)if(matchr(key,lst_get(ptr,z)))return z;return -1}
function lst_allnum(ptr, z){for(z=0;z<heap_c[ptr];z++)if(!lin(lst_get(ptr,z)))return 0;return 1}
function lst_alllst(ptr, z){for(z=0;z<heap_c[ptr];z++)if(!lil(lst_get(ptr,z)))return 0;return 1}
function lst_alldic(ptr, z){for(z=0;z<heap_c[ptr];z++)if(!lid(lst_get(ptr,z)))return 0;return 1}
function l_list(x, r){r=lml();heap_c[r]=1;heap_v[r]=sprintf("%10d" ,x );return r}
function lml2(x,y, r){r=lml();heap_c[r]=2;heap_v[r]=sprintf("%10d%10d" ,x,y );return r}
function lml3(x,y,z, r){r=lml();heap_c[r]=3;heap_v[r]=sprintf("%10d%10d%10d",x,y,z);return r}
function ll(ptr, r,z,t){
if(lid(ptr))return dic_vals(ptr)
if(lis(ptr)){r=lml();t=lvs(ptr);for(z=0;z<heap_c[ptr];z++)lst_add(r,lms(substr(t,z+1,1)));return r}
return lil(ptr)?ptr: lit(ptr)?l_rows(ptr): l_list(ptr)
}
# like lists, dictionaries are represented with fixed-width strings;
# a list of key pointers and a list of value pointers.
function lid(ptr){return heap_type[ptr]==4}
function lmd(){return heap_make(4)}
function ld(ptr){return lid(ptr)?ptr: lit(ptr)?l_cols(ptr): lil(ptr)||lis(ptr)?l_dict(l_range(lmn(count(ptr))),ll(ptr)): lmd()}
function dic_getk(ptr,idx ){return 0+substr(heap_k[ptr],1+(10*idx),10)}
function dic_getv(ptr,idx ){return 0+substr(heap_v[ptr],1+(10*idx),10)}
function dic_keys(ptr, r){r=lml();heap_v[r]=heap_k[ptr];heap_c[r]=heap_c[ptr];return r}
function dic_vals(ptr, r){r=lml();heap_v[r]=heap_v[ptr];heap_c[r]=heap_c[ptr];return r}
function dic_clone(ptr, r){r=lmd();heap_k[r]=heap_k[ptr];heap_v[r]=heap_v[ptr];heap_c[r]=heap_c[ptr];return r}
function dgetv(ptr,key, r){r=dget(ptr,key);return r==-1?NONE:r}
function dget(ptr,key, z){for(z=0;z<heap_c[ptr];z++)if(matchr(key,dic_getk(ptr,z)))return dic_getv(ptr,z);return -1}
function dgeti(ptr,key, z){for(z=0;z<heap_c[ptr];z++)if(matchr(key,dic_getk(ptr,z)))return z ;return -1}
function dsetuq(ptr,key,val, z){dset(ptr,dget(ptr,key)!=-1?lms(lvs(ls(key))"_"):key,val)}
function dset(ptr,key,val, z){
for(z=0;z<heap_c[ptr];z++)if(matchr(key,dic_getk(ptr,z))){lst_set(ptr,z,val);return}
heap_k[ptr]=heap_k[ptr] sprintf("%10d",key)
heap_v[ptr]=heap_v[ptr] sprintf("%10d",val)
heap_c[ptr]++
}
# structurally, a table is a dictionary with some extra constraints:
function lit(ptr){return heap_type[ptr]==5}
function lmt(){return heap_make(5)}
function lt(ptr){
if(lit(ptr))return ptr
if(lid(ptr)){r=lmt();tab_set(r,lms("key"),dic_keys(ptr));tab_set(r,lms("value"),dic_vals(ptr));return torect(r)}
ptr=ll(ptr);r=lmt();tab_set(r,lms("value"),ptr);return torect(r)
}
function tab_getk(ptr,idx){return dic_getk(ptr,idx)}
function tab_getv(ptr,idx){return dic_getv(ptr,idx)}
function tab_getki(ptr,key){return dgeti(ptr,key)}
function tab_get(ptr,col){return dget(ptr,col)}
function tab_set(ptr,key,val){dset(ptr,key,val)} # note: you must call torect() after adding/replacing table columns!
function tab_setuq(ptr,key,val){dsetuq(ptr,key,val)}
function tab_row(ptr,row, r,z){r=lmd();for(z=0;z<count(ptr);z++)dset(r,tab_getk(ptr,z),lst_get(tab_getv(ptr,z),row));return r}
function tab_clone(ptr, r,z){r=lmt();for(z=0;z<count(ptr);z++)tab_set(r,tab_getk(ptr,z),lst_clone(tab_getv(ptr,z)));heap_n[r]=heap_n[ptr];return r}
function tab_addrow(ptr,dic, z){for(z=0;z<count(ptr);z++)lst_add(tab_getv(ptr,z),dgetv(dic,tab_getk(ptr,z)));heap_n[ptr]++}
function torect(ptr, z,t,v){
heap_n[ptr]=0;t=""
for(z=0;z<count(ptr);z++){v=dic_getv(ptr,z);heap_n[ptr]=max(heap_n[ptr],lil(v)?count(v):1)}
for(z=0;z<count(ptr);z++){v=dic_getv(ptr,z);t=t sprintf("%10d",l_take(lmn(heap_n[ptr]),lil(v)?v:l_list(v)))}
heap_v[ptr]=t;return ptr
}
# functions ("on ...") reference an arglist, a block, and (when bound) a closure:
function lion(ptr){return heap_type[ptr]==6}
function lmon(name,args,blk, r){r=heap_make(6);heap_name[r]=name;heap_k[r]=args;heap_v[r]=blk;return r}
function lon_bind(ptr,env, r){r=heap_make(6);heap_name[r]=heap_name[ptr];heap_k[r]=heap_k[ptr];heap_v[r]=heap_v[ptr];heap_aux[r]=env;return r}
function lon_name(ptr){return heap_name[ptr]}
function lon_args(ptr){return heap_k[ptr]}
function lon_body(ptr){return heap_v[ptr]}
function lon_closure(ptr){return heap_aux[ptr]}
# natives are just a "handle" to a native function, since we can't actually carry around function pointers:
function linat(ptr){return heap_type[ptr]==7}
function lmnat(name,inner,self, r){r=heap_make(7);heap_name[r]=name;heap_n[r]=inner;heap_aux[r]=self;return r}
function lnat_name(ptr){return heap_name[ptr]}
function lnat_inner(ptr){return heap_n[ptr]}
function lnat_self(ptr){return heap_aux[ptr]}
# likewise, interfaces are just a "handle",
# though some interfaces may have their own additional state occupying other slots:
function lii(ptr){return heap_type[ptr]==8}
function lmi(name, r){r=heap_make(8);heap_name[r]=name;return r}
function li_name(ptr){return heap_name[ptr]}
# some utilities:
function lb(ptr){return lin(ptr)?lvn(ptr)!=0: lis(ptr)||lil(ptr)||lid(ptr)?count(ptr): 1} # truthiness
function count(ptr){return heap_c[ptr]}
function rowcount(ptr){return heap_n[ptr]}
function matchr(x,y, z){
if(x==y)return 1
if(heap_type[x]!=heap_type[y]||heap_c[x]!=heap_c[y]||heap_n[x]!=heap_n[x])return 0
if(lin(x))return lvn(x)==lvn(y)
if(lis(x))return lvs(x)==lvs(y)
if(lil(x)){for(z=0;z<count(x);z++)if(!matchr(lst_get(x,z),lst_get(y,z)))return 0;return 1}
if(lid(x)){for(z=0;z<count(x);z++)if(!matchr(dic_getk(x,z),dic_getk(y,z))||!matchr(dic_getv(x,z),dic_getv(y,z)))return 0;return 1}
if(lit(x)){for(z=0;z<count(x);z++)if(!matchr(tab_getk(x,z),tab_getk(y,z))||!matchr(tab_getv(x,z),tab_getv(y,z)))return 0;return 1}
return 0
}
# blocks are not a user-facing datatype;
# they represent runs of lil bytecode, bridging the parser and interpreter.
# the opcode stream is a list of variable-width elements in a string.
# this makes random writes very inefficient, but those only occur during parsing/codegen:
# note that a blk invasively _is_ a list of interned local values (ints,strings,funcs...)
function liblk(ptr){return heap_type[ptr]==9}
function lmblk( r){return heap_make(9)} # heap_name is the opcode stream, heap_n is the opcode count
BEGIN{
split("JUMP,JUMPF,LIT,DUP,DROP,SWAP,OVER,BUND,OP1,OP2,OP3,GET,SET,LOC,AMEND,TAIL,CALL,BIND,ITER,EACH,NEXT,COL,IPRE,IPOST",ops,",")
split("2 ,2 ,2 ,1 ,1 ,1 ,1 ,2 ,2 ,2 ,2 ,2 ,2 ,2 ,2 ,1 ,1 ,1 ,1 ,2 ,2 ,1 ,2 ,2 ",len,",")
for(key in ops)oplens[ops[key]]=0+len[key]
}
function blk_here(x){return heap_n[x]}
function blk_set_at(x,i,v, c,arr){c=blk_getops(x,arr);arr[i]=v;blk_setops(x,arr,c)}
function blk_opraw(x,o){heap_name[x]=heap_name[x] (length(heap_name[x])?"`":"")o ;heap_n[x]+=1;}
function blk_op(x,o) {heap_name[x]=heap_name[x] (length(heap_name[x])?"`":"")o ;heap_n[x]+=1;if(o=="COL")blk_op(x,"SWAP")}
function blk_opa(x,o,i){heap_name[x]=heap_name[x] (length(heap_name[x])?"`":"")o"`"i;heap_n[x]+=2;return heap_n[x]}
function blk_getops(blk,arr){return split(heap_name[blk],arr,"`")}
function blk_setops(blk,arr,c, t,z){t=c==0?"":arr[1];for(z=2;z<=c;z++)t=t"`"arr[z];heap_name[blk]=t}
function blk_imm(x,o,k, i){i=lst_find(x,k);if(i==-1){lst_add(x,k);i=count(x)-1};blk_opa(x,o,i);}
function blk_getimm(x,i){return lst_get(x,i)}
function blk_op1(x,n){blk_opa(x,"OP1",n)}
function blk_op2(x,n){blk_opa(x,"OP2",n)}
function blk_op3(x,n){blk_opa(x,"OP3",n)}
function blk_set(x,n){blk_opa(x,"SET",n)}
function blk_loc(x,n){blk_opa(x,"LOC",n)}
function blk_get(x,n){blk_opa(x,"GET",n)}
function blk_lit(x,v){blk_imm(x,"LIT",v)}
function blk_cat(x,y, c,base,arr,z,b,i){
c=blk_getops(y,arr);base=blk_here(x);z=1;while(z<=c){
b=arr[z]
if(b~/^LIT/){blk_imm(x,b,blk_getimm(y,arr[z+1]))}
else if(b~/^JUMP|JUMPF|EACH|NEXT$/){blk_opa(x,b,arr[z+1]+base)}
else if(oplens[b]==1){blk_opraw(x,b)}
else{blk_opa(x,b,arr[z+1])};z+=oplens[b]
}
}
function blk_loop(b,names,body, head,each){
blk_op(b,"ITER");head=blk_here(b);blk_lit(b,names);each=blk_opa(b,"EACH",0)
blk_cat(b,body);blk_opa(b,"NEXT",head);blk_set_at(b,each,blk_here(b))
}
function blk_end(x, c,arr,z,b,t,i){
c=blk_getops(x,arr)
z=1;while(z<=c){
b=arr[z];z+=oplens[b]
if(b!="CALL")continue
t=1;i=z;while(i<=c){
if(arr[i]!="JUMP"){t=0;break}
if(arr[i+1]<=i){t=0;break}
i=1+arr[i+1]
}
if(t)arr[z-1]="TAIL"
}
blk_setops(x,arr,c);return x
}
# environments are specialized string-keyed dictionaries,
# chained together to represent nested lexical scopes.
# we use yet another string representation alternating variable-width keys
# with fixed-width pointer values so that we can use index() for fast(er) lookups:
function lienv(ptr){return heap_type[ptr]==10}
function lmenv( r){r=heap_make(10);return r}
function eget(env,k, i,d){
k="|"k"|";d=heap_name[env];i=index(d,k)
return i==0?-1: 0+substr(d,length(k)+i,10)
}
function eset(env,k,v, i,d){
k="|"k"|";v=sprintf("%10d",0+v);d=heap_name[env];i=index(d,k)
heap_name[env]=i==0?d k v: substr(d,1,length(k)+i-1) v substr(d,length(k)+i+10)
}
function env_bind(env,dic, r,z,ka,va,c,v){
for(z=0;z<count(dic);z++)v=v sprintf("|%s|%10d",lvs(ls(dic_getk(dic,z))),dic_getv(dic,z))
r=lmenv();heap_name[r]=v;heap_aux[r]=env;return r
}
function env_enumerate(env, r,z,c,arr){
c=split(heap_name[env],arr,"|")
r=lmd();for(z=2;z<=c;z+=2)dset(r,lms(arr[z]),0+arr[z+1]);return r
}
function env_parent(ptr){return heap_aux[ptr]}
function env_getr(env,k, r){if(env==-1)return -1;r=eget(env,k);return r!=-1?r: env_getr(env_parent(env),k)}
function env_setr(env,k,v, r){if(env==-1)return;r=eget(env,k);if(r!=-1){eset(env,k,v)}else{env_setr(env_parent(env),k,v)}}
function env_loc(env,k,v){eset(env,k,v)}
function env_get(env,k, r){r=env_getr(env,k);return r==-1?NONE:r}
function env_set(env,k,v, r){r=env_getr(env,k);if(r==-1){env_loc(env,k,v)}else{env_setr(env,k,v)}}
###########################################################
#
# Lil Primitives
#
###########################################################
function l_count(x){return lmn(lit(x)?rowcount(x): lii(x)?1: count(x))}
function l_first(x){return lis(x)?lms(substr(lvs(x),1,1)): lit(x)?l_first(l_rows(x)): lion(x)?lms(lon_name(x)): linat(x)?lms("native"): count(x)?lst_get(ll(x),0): NONE}
function l_last(x){return lis(x)?lms(substr(lvs(x),count(x),1)): lit(x)?l_last(l_rows(x)): count(x)?lst_get(ll(x),count(x)-1): NONE}
function l_keys(x, r,z){return lii(x)?lml(): lion(x)?lon_args(x): dic_keys(ld(x))}
function l_rows(x, r,z){x=lt(x);r=lml();for(z=0;z<rowcount(x);z++)lst_add(r,tab_row(x,z)) ;return r}
function l_cols(x, r,z){x=lt(x);r=lmd();for(z=0;z<count(x) ;z++)dset(r,tab_getk(x,z),tab_getv(x,z));return r}
function l_range(x, r,z){if(lin(x)){x=max(int(ln(x)),0);r=lml();for(z=0;z<x;z++)lst_add(r,lmn(z));return r};return dic_vals(x)}
function table_flip(x, r,z,zz,ks,ki,kl,k,c){
r=lmt();ks=lms("key");ki=tab_getki(x,ks);if(ki==-1)ki=0;
kl=lml();for(z=0;z<count(x);z++)if(z!=ki)lst_add(kl,tab_getk(x,z));tab_set(r,ks,kl)
if(count(x)){
k=tab_getv(x,ki)
for(zz=0;zz<count(k);zz++){c=lml();tab_set(r,ls(lst_get(k,zz)),c);for(z=0;z<count(x);z++)if(z!=ki)lst_add(c,lst_get(tab_getv(x,z),zz))}
};return torect(r)
}
function l_flip(x, r,z,w,t,i,c){
if(lit(x))return table_flip(x);x=ll(x);r=lml();w=0;for(z=0;z<count(x);z++){t=lst_get(x,z);w=max(w,lil(t)?count(t):1)}
for(i=0;i<w;i++){c=lml();lst_add(r,c);for(z=0;z<count(x);z++){t=lst_get(x,z);lst_add(c,!lil(t)?t: i<count(t)?lst_get(t,i):NONE)}}
return r
}
function l_table(x, r,z,m,t,row,col,k,ok){
if(lid(x)){r=lmt();for(z=0;z<count(x);z++)tab_set(r,ls(dic_getk(x,z)),dic_getv(x,z));return torect(r)}
if(lil(x)&&lst_alldic(x)){
r=lmt();ok=lml();
for(row=0;row<count(x);row++){
t=lst_get(x,row)
for(col=0;col<count(t);col++){k=dic_getk(t,col);tab_set(r,ls(k),lml());if(count(r)>count(ok))lst_add(ok,k)}
}
for(row=0;row<count(x);row++){
t=lst_get(x,row)
for(col=0;col<count(r);col++){lst_add(tab_getv(r,col),dgetv(t,lst_get(ok,col)))}
}
return torect(r)
}
if(lil(x)&&lst_alllst(x)){
m=0;for(z=0;z<count(x);z++)m=max(m,count(lst_get(x,z)));r=lmt();for(c=0;c<m;c++)tab_set(r,lms("c"c),lml())
for(z=0;z<count(x);z++){t=lst_get(x,z);for(c=0;c<m;c++)lst_add(tab_getv(r,c),c>=count(t)?NONE: lst_get(t,c))}
return torect(r)
}
return lt(x)
}
function l_raze(x, r){
if(lit(x))return l_dict(count(x)>0?tab_getv(x,0):lml(), count(x)>1?tab_getv(x,1):lml())
x=ll(x);r=l_first(x);for(z=1;z<count(x);z++)r=l_cat(r,lst_get(x,z));return r
}
function monads_atomic(name,x, r,z){
if(lid(x)){r=lmd();for(z=0;z<count(x);z++)dset(r,dic_getk(x,z),monads_atomic(name,dic_getv(x,z)));return r}
if(lil(x)){r=lml();for(z=0;z<count(x);z++)lst_add(r,monads_atomic(name,lst_get(x,z)));return r}
if(name=="-" )return lmn(-ln(x))
if(name=="!" )return lb(x)?NONE:ONE
if(name=="floor")return lmn(floor(ln(x)))
if(name=="cos" )return lmn(cos(ln(x)))
if(name=="sin" )return lmn(sin(ln(x)))
if(name=="tan" )return lmn(sin(ln(x))/cos(ln(x)))
if(name=="exp" )return lmn(exp(ln(x)))
if(name=="ln" )return lmn(log(ln(x)))
if(name=="sqrt" )return lmn(sqrt(ln(x)))
if(name=="unit" )return lml2(lmn(cos(ln(x))),lmn(sin(ln(x))))
return -1
}
function monads_special(name,x, r,z){
if(lil(x)&&!lst_allnum(x)){r=lml();for(z=0;z<count(x);z++)lst_add(r,monads_special(name,lst_get(x,z)));return r}
if(name=="mag" ){x=ll(x);r=0;for(z=0;z<count(x);z++)r+=ln(lst_get(x,z))^2;return lmn(sqrt(r))}
if(name=="heading"){x=ll(x);r=ln(count(x)>0?lst_get(x,0):NONE);z=ln(count(x)>1?lst_get(x,1):NONE);return lmn(atan2(z,r))}
return -1
}
function monads(name,x, r,z){
if(name=="count" )return l_count(x)
if(name=="first" )return l_first(x)
if(name=="last" )return l_last(x)
if(name=="keys" )return l_keys(x)
if(name=="range" )return l_range(x)
if(name=="list" )return l_list(x)
if(name=="flip" )return l_flip(x)
if(name=="rows" )return l_rows(x)
if(name=="cols" )return l_cols(x)
if(name=="table" )return l_table(x)
if(name=="raze" )return l_raze(x)
if(name=="typeof")return l_typeof(x)
if(name=="sum" ){x=ll(x);r=NONE ;for(z=0;z<count(x);z++)r=dyads_atomic("+",r,lst_get(x,z));return r}
if(name=="prod" ){x=ll(x);r=ONE ;for(z=0;z<count(x);z++)r=dyads_atomic("*",r,lst_get(x,z));return r}
if(name=="max" ){x=ll(x);r=l_first(x);for(z=1;z<count(x);z++)r=dyads_atomic("|",r,lst_get(x,z));return r}
if(name=="min" ){x=ll(x);r=l_first(x);for(z=1;z<count(x);z++)r=dyads_atomic("&",r,lst_get(x,z));return r}
if(name=="@tab"){
x=lt(x);r=tab_clone(x);z=lmn(rowcount(r));
tab_set(r,lms("index" ),l_range(z))
tab_set(r,lms("gindex"),l_range(z))
tab_set(r,lms("group" ),l_take(z,NONE))
return torect(r)
}
if(name=="mag"||name=="heading")return monads_special(name,x)
return monads_atomic(name,x)
}
function ina(x,y, z){
if(lil(y))for(z=0;z<count(y);z++)if(matchr(lst_get(y,z),x))return 1
return lis(y)?lvs(y)~lvs(x): lid(y)?dget(y,x)!=-1: lit(y)?tab_get(y,x)!=-1: 0
}
function l_in(x,y, r,z){if(lil(x)){r=lml();for(z=0;z<count(x);z++)lst_add(r,l_in(lst_get(x,z),y));return r};return lmn(ina(x,y))}
function filter(i,x,y, r,z,v,k){
x=lis(x)?l_list(x):ll(x)
if( lid(y)){r=lmd(); for(z=0;z<count(y);z++){k=dic_getk(y,z);if(i==ina(k,x))dset(r,k,dic_getv(y,z))};return r}
if(!lit(y)){r=lml();y=ll(y);for(z=0;z<count(y);z++){v=lst_get(y,z) ;if(i==ina(v,x))lst_add(r,v)} ;return r}
if(lst_allnum(x)){
r=l_take(NONE,y)
if(i){for(i=0;i<count(x);i++){v=ln(lst_get(x,i));if(v>=0&&v<rowcount(y))for(z=0;z<count(y);z++)lst_add(tab_getv(r,z),lst_get(tab_getv(y,z),v))}}
else{for(z=0;z<rowcount(y);z++){if(!ina(lmn(z),x))for(i=0;i<count(y);i++)lst_add(tab_getv(r,i),lst_get(tab_getv(y,i),z))}}
return torect(r)
}
r=lmt();for(z=0;z<count(y);z++){k=tab_getk(y,z);if(i==ina(k,x))tab_set(r,k,tab_getv(y,z))};return torect(r)
}
function dic_index(dic,ix){r=lmd();for(z=0;z<count(ix);z++){i=ln(lst_get(ix,z));dset(r,dic_getk(dic,i),dic_getv(dic,i))};return r}
function l_take(x,y, r,z,s,i){
if(!lin(x))return filter(1,x,y);if(lil(y)&&ln(x)==count(y))return y
if(lis(y)){
if(ln(x)< 0&&abs(int(ln(x)))<=count(y))return lms(substr(lvs(y),1+count(y)+ln(x),-ln(x)))
if(ln(x)>=0&& ln(x) <=count(y))return lms(substr(lvs(y),1,ln(x)))
return l_fuse(lms(""),l_take(x,ll(y)))
}
if(lid(y))return dic_index(y,l_take(x,l_range(lmn(count(y)))))
if(lit(y)){r=tab_clone(y);for(z=0;z<count(r);z++)tab_set(r,tab_getk(r,z),l_take(x,tab_getv(r,z)));return torect(r)}
r=lml();x=ln(x);y=ll(y);s=x<0?mod(x,count(y)):0;
for(z=0;z<abs(x);z++)lst_add(r,count(y)?lst_get(y,mod(z+s,count(y))):NONE);return r
}
function l_drop(x,y, r,z,s){
if(!lin(x))return filter(0,x,y)
if(lis(y)){
if(ln(x)< 0)return lms(substr(lvs(y),1,count(y)+ln(x)))
if(ln(x)>=0)return lms(substr(lvs(y),ln(x)+1))
return l_fuse(lms(""),l_drop(x,ll(y)))
}
if(lid(y))return dic_index(y,l_drop(x,l_range(lmn(count(y)))))
if(lit(y)){r=tab_clone(y);for(z=0;z<count(r);z++)tab_set(r,tab_getk(r,z),l_drop(x,tab_getv(r,z)));return torect(r)}
r=lml();x=ln(x)
if(x>0){for(z=0;z<max(0,count(y)-x);z++)lst_add(r,lst_get(y,x+z))}
else {for(z=0;z<max(0,count(y)+x);z++)lst_add(r,lst_get(y,z ))};return r
}
function l_limit(x,y){return (lit(y)?rowcount(y):count(y))>ln(x)?l_take(lmn(ln(x)),y):y}
function table_cat(x,y, r,i,z,c){
r=lmt()
for(i=0;i<count(x);i++){
c=lst_clone(tab_getv(x,i))
if(tab_get(y,tab_getk(x,i))==-1){for(z=0;z<rowcount(y);z++)lst_add(c,NONE)}
tab_set(r,tab_getk(x,i),c)
}
for(i=0;i<count(y);i++){
c=tab_get(r,tab_getk(y,i))
if(c==-1){c=lml();for(z=0;z<rowcount(x);z++)lst_add(c,NONE);tab_set(r,tab_getk(y,i),c)}
lst_addall(c,tab_getv(y,i))
}
return torect(r)
}
function l_cat(x,y, r,z){
if(lit(x)&&lit(y))return table_cat(x,y)
if(lid(x)){r=dic_clone(x);y=ld(y);for(z=0;z<count(y);z++)dset(r,dic_getk(y,z),dic_getv(y,z));return r}
if(lis(x))x=l_list(x);r=lst_clone(ll(x));
if(lis(y))y=l_list(y);y=ll(y);for(z=0;z<count(y);z++)lst_add(r,lst_get(y,z));return r
}
function l_split(x,y, r,z,n){
x=ls(x);y=ls(y);if(!count(x))return ll(y);r=lml();n=0;for(z=0;z<count(y);z++){
if(substr(lvs(y),z+1,count(x))!=lvs(x))continue
lst_add(r,lms(substr(lvs(y),n+1,z-n)));z+=count(x)-1;n=z+1
}if(n<=count(y)){lst_add(r,lms(substr(lvs(y),n+1,count(y)-n)))};return r
}
function l_fuse(x,y, z,r){x=ls(x);y=ll(y);r="" ;for(z=0;z<count(y);z++){if(z)r=r lvs(x);r=r lvs(ls(lst_get(y,z)))};return lms(r)}
function l_dict(x,y, z,r){x=ll(x);y=ll(y);r=lmd();for(z=0;z<count(x);z++)dset(r,lst_get(x,z),z>=count(y)?NONE:lst_get(y,z));return r}
function l_less(x,y){return lmn(lin(x)&&lin(y)?lvn(x)<lvn(y): lvs(ls(x))<lvs(ls(y)))}
function l_more(x,y){return lmn(lin(x)&&lin(y)?lvn(x)>lvn(y): lvs(ls(x))>lvs(ls(y)))}
function like_convert(p, r,z,c){ # convert lil's glob patterns into awk regexes
r="^";for(z=1;z<=length(p);z++){
c=substr(p,z,1)
if (c=="*"){r=r ".*"}
else if(c=="#"){r=r "[0-9]"}
else if(c=="."){r=r "."}
else if(c=="`"){r=r (z==length(p)?"`":regex_esc(substr(p,z+1,1)));z++}
else {r=r regex_esc(c)}
};return r"$"
}
function like_test(x,pats, key){for(key in pats){if(x~pats[key])return ONE};return NONE}
function l_like(x,y, r,z,pats,p,t){
if(!lil(y))y=l_list(y);for(z=0;z<count(y);z++){pats[z]=like_convert(lvs(ls(lst_get(y,z))))}
if(lil(x)){r=lml();for(z=0;z<count(x);z++)lst_add(r,like_test(lvs(ls(lst_get(x,z))),pats));return r}
else{return like_test(lvs(ls(x)),pats)} # }
}
function l_window(x,y, r,z,t,i){
x=int(ln(x));r=lml();if(lis(y)){y=lvs(y)
if(x>0){ for(z=0;z <length(y);z+=x){lst_add(r,lms(substr(y,z+1,x)))}}
if(x<0){x=-x;for(z=0;z+x-1<length(y);z+=1){lst_add(r,lms(substr(y,z+1,x)))}}
}else{y=ll(y)
if(x>0){ for(z=0;z <count(y) ;z+=x){t=lml();lst_add(r,t);for(i=0;i<x&&z+i<count(y);i++)lst_add(t,lst_get(y,z+i))}}
if(x<0){x=-x;for(z=0;z+x-1<count(y) ;z+=1){t=lml();lst_add(r,t);for(i=0;i<x ;i++)lst_add(t,lst_get(y,z+i))}}
}return r
}
function format_has_names(str, z,d,t){
for(z=1;z<=length(str);){
if(substr(str,z,1)!="%"){z++;continue};z++;if(substr(str,z,1)=="[")return 1
if(substr(str,z,1)=="*")z++;if(substr(str,z,1)=="-")z++;if(substr(str,z,1)=="0")z++
while(substr(str,z,1)~/[0-9]/)z++;if(substr(str,z,1)==".")z++
d=0;while(substr(str,z,1)~/[0-9]/){d=d*10+substr(str,z,1);z++}
if(z>length(str))break;t=substr(str,z,1);z++;if(t~/[ro]/)while(d&&z<=length(str)){d--;f++}
}return 0
}
BEGIN{json_t="";json_i=0;json_f=0;json_n=0;}
function json_c(){return json_n&&json_f?substr(json_t,json_i,1):""}
function json_nx(){if(json_n&&json_f){json_n--;return substr(json_t,json_i++,1)};return ""}
function json_m(x){if(json_c()==x){json_nx();return 1};return 0}
function json_s(){while(json_c()~/[ \n]/)json_nx()}
function json_d(){while(json_c()~/[0-9]/)json_nx()}
function json_lit(x, l){l=length(x);if(json_n>=l&&substr(json_t,json_i,l)==x){json_i+=l;json_n-=l;return 1};return 0}
function json_hex( z,r){r=0;for(z=0;z<4;z++){r=(r*16)+hexdigits[json_nx()]};return r<256?ordinal[r]:"?"}
function json_parse( r,mc,k,e,ns){
if(json_lit("true"))return ONE;if(json_lit("null")||json_lit("false"))return NONE
if(json_m("[")){
r=lml();while(json_c()!=""){
json_s();if(json_m("]"))break;lst_add(r,json_parse());json_s();json_m(",")
};return r
}
if(json_m("{")){
r=lmd();while(json_c()!=""){
json_s();if(json_m("}"))break;k=json_parse()json_s();json_m(":")
json_s();if(json_f)dset(r,k,json_parse());json_s();json_m(",")
}return r
}
if(json_c()~/["']/){
mc=json_c();json_nx();r="";while(json_c()!=""&&!json_m(mc)){
if(json_m("\\")){e=json_nx();r=r (e=="n"?"\n": e~/[\\"\/']/?e: e=="u"&&json_n>=4?json_hex(): " ")}
else{r=r json_nx()}
}return lms(r)
}
ns=json_i;json_m("-");json_d();json_m(".");json_d()
if(json_m("e")||json_m("E")){json_m("-")||json_m("+");json_d()}
if(json_i<=ns){json_f=0;return NONE};return lmn(substr(json_t,ns,min(json_i-ns,512)))
}
function love_parse( r,k){
if(json_m("[")){
r=lml();while(json_c()!=""){
json_s();if(json_m("]"))break;lst_add(r,love_parse());json_s();json_m(",")
};return r
}
if(json_m("{")){
r=lmd();while(json_c()!=""){
json_s();if(json_m("}"))break;k=love_parse()json_s();json_m(":")
json_s();if(json_f)dset(r,k,love_parse());json_s();json_m(",")
}return r
}
if(json_m("<")){
r=lmd();while(json_c()!=""){
json_s();if(json_m(">"))break;k=love_parse()json_s();json_m(":")
json_s();if(json_f)dset(r,ls(k),ll(love_parse()));json_s();json_m(",")
}return l_table(r)
}
if(json_m("%")){
json_m("%");r="%%"
while(json_c()~/[a-zA-Z0-9+\/=]/)r=r json_nx()
if(substr(r,1,5)=="%%IMG")return image_read(r)
if(substr(r,1,5)=="%%DAT")return array_read(r)
return NONE
}
return json_parse()
}
BEGIN{
ISODATE=lms("%[year]04i-%[month]02i-%[day]02iT%[hour]02i:%[minute]02i:%[second]02iZ%n%m")
split("0,31,59,90,120,151,181,212,243,273,304,334",cumulative_month_days,",")
}
function leap_year(year){return year%400==0?1: year%100==0?0: year%4==0?1: 0}
function l_parse(x,y, r,z,f,h,m,pi,named,nk,hn,si,sk,lf,n,d,t,v,s,p,mc,yr,k){
if(lil(y)){r=lml();for(z=0;z<count(y);z++)lst_add(r,l_parse(x,lst_get(y,z)));return r}
x=lvs(ls(x));y=lvs(ls(y));f=1;h=1;m=1;pi=0;named=format_has_names(x);r=named?lmd():lml()
while(f<=length(x)){
if(substr(x,f,1)!="%"){if(m&&substr(x,f,1)==substr(y,h,1)){h++}else{m=0};f++;continue}f++
nk="";hn=0;if(substr(x,f,1)=="["){hn=1;f++;while(f<=length(x)&&substr(x,f,1)!="]"){nk=nk substr(x,f,1);f++};if(substr(x,f,1)=="]")f++}
si=h;v=-1
sk=substr(x,f,1)=="*";if(sk)f++
lf=substr(x,f,1)=="-";if(lf)f++
if(substr(x,f,1)=="0")f++
n=0;while(substr(x,f,1)~/[0-9]/){n=n*10+substr(x,f,1);f++};if(substr(x,f,1)==".")f++
d=0;while(substr(x,f,1)~/[0-9]/){d=d*10+substr(x,f,1);f++};if(f>length(x))break
t=substr(x,f,1);f++
if(t~/[^%mnzsluqarojJ]/){while(m&&h<=length(y)&&(n?h-si<n:1)&&substr(y,h,1)~/[ \n]/)h++;}
if (t=="%"){if(m&&h<=length(y)&&(n?h-si<n:1)){h++}else{m=0}}
else if(t=="m")v=m?ONE:NONE
else if(t=="n")v=lmn(h-1)
else if(t=="z")v=(m&&h==length(y)+1)?ONE:NONE
else if(t=="j"){json_t=y;json_i=h;json_f=1;json_n=n?n:length(y);v=m?json_parse():NONE;h=json_i;}
else if(t=="J"){json_t=y;json_i=h;json_f=1;json_n=n?n:length(y);v=m?love_parse():NONE;h=json_i;}
else if(t=="i"){
if(m&&substr(y,h,1)=="-"){h++;s=-1}else{s=1}
m=m&&substr(y,h,1)~/[0-9]/
z=0;while(m&&h<=length(y)&&(n?h-si<n:1)&&substr(y,h,1)~/[0-9]/){z=z*10+substr(y,h++,1)};v=lmn(z*s)
}
else if(t~/[fcC]/){
if(substr(y,h,1)=="-"){h++;s=-1}else{s=1}
if(t=="c"&&m&&substr(y,h,1)=="$")h++
m=m&&substr(y,h,1)~/[0-9.]/
z=0;while(m&&h<=length(y)&&(n?h-si<n:1)&&substr(y,h,1)~/[0-9]/){z=z*10+substr(y,h++,1)}
if(m&&h<=length(y)&&(n?h-si<n:1)&&substr(y,h,1)==".")h++
p=10;while(m&&h<=length(y)&&(n?h-si<n:1)&&substr(y,h,1)~/[0-9]/){z+=substr(y,h++,1)/p;p*=10};v=lmn(z*s)
}
else if(t~/[hH]/){
m=m&&substr(y,h,1)~/[0-9a-fA-F]/
z=0;while(m&&h<=length(y)&&(n?h-si<n:1)&&substr(y,h,1)~/[0-9a-fA-F]/){z=(z*16)+hexdigits[substr(y,h++,1)]};v=lmn(z)
}
else if(t~/[slu]/){
z="";while(m&&h<=length(y)&&(n?h-si<n:1)&&(n?1:substr(y,h,1)!=substr(x,f,1)))z=z substr(y,h++,1)
v=lms(t=="l"?tolower(z): t=="u"?toupper(z): z)
}
else if(t=="a"){
v=lml();while(m&&h<=length(y)&&(n?h-si<n:1)&&(n?1:substr(y,h,1)!=substr(x,f,1)))lst_add(v,lmn(ascii[substr(y,h++,1)]))
}
else if(t=="b"){
v=(substr(y,h,1)~/[tTyYx1]/)?ONE:NONE
while(m&&h<=length(y)&&(n?h-si<n:1)&&(n?1:substr(y,h,1)!=substr(x,f,1)))h++
}
else if(t=="v"){
m=m&&substr(y,h,1)~/[a-zA-Z_?]/
z="";while(m&&h<=length(y)&&(n?h-si<n:1)&&substr(y,h,1)~/[a-zA-Z0-9_?]/)z=z substr(y,h++,1);v=lms(z)
}
else if(t=="q"){
m=m&&substr(y,h,1)=="\"";if(m)h++
z="";while(m&&h<=length(y)&&(n?h-si<n:1)&&substr(y,h,1)!="\""){
if(substr(y,h,1)=="\\"){h++;m=m&&substr(y,h,1)~/[\\"n]/;if(m){p=substr(y,h,1);z=z (p=="n"?"\n":p)}}
else{z=z substr(y,h,1)}
h++
}
m=m&&substr(y,h,1)=="\"";if(m)h++;v=lms(z)
}
else if(t~/[ro]/){
d=max(1,d);p=f;for(z=0;m&&z<d;z++){if(f>length(x)){m=0}else{f++}};p=substr(x,p,d);
v="";while(m&&h<=length(y)&&(n?h-si<n:1)){
if((0<index(p,substr(y,h,1)))==lf){if(n)m=0;break;}
v=v substr(y,h++,1);if(t=="o")break
}v=lms(m?v:"")
}
else if(t~/[ep]/){
if(m){
p=l_parse(ISODATE,lms(substr(y,h)))
k=lms("year" );dset(p,k,lmn(ln(dget(p,k))-1900))
k=lms("month");dset(p,k,lmn(ln(dget(p,k))- 1))
if(lb(dic_getv(p,7))){h+=ln(dic_getv(p,6))}else{m=0}
}else{p=lmd()}
if(t=="e"){
yr=ln(dget(p,lms("year")))
mo=ln(dget(p,lms("month")))
z =ln(dget(p,lms("second")))+(60*ln(dget(p,lms("minute"))))+(3600*ln(dget(p,lms("hour"))))+86400*(ln(dget(p,lms("day")))-1)
z+=(cumulative_month_days[mo+1]+leap_year(yr+1900))*86400
z+=((yr-70)*31536000)+(int((yr-69)/4)*86400)-(int((yr-1)/100)*86400)+(int((yr+299)/400)*86400)
v=lmn((!m)?0:z)
}
else{
v=lmd()
k=lms("year" );dset(v,k,lmn(1900+ln(dget(p,k))))
k=lms("month" );dset(v,k,lmn( 1+ln(dget(p,k))))
k=lms("day" );dset(v,k, dget(p,k) )
k=lms("hour" );dset(v,k, dget(p,k) )
k=lms("minute");dset(v,k, dget(p,k) )
k=lms("second");dset(v,k, dget(p,k) )
}
}
else{m=0}
while(n&&h<=length(y)&&h-si<n){h++;m=0}
if(!sk&&v!=-1){if(named){dset(r,hn?lms(nk):lmn(pi),v)}else{lst_add(r,v)};pi++}
};
return named?r: count(r)==1?l_first(r): r
}
function format_json(x, r,z,ct,c,e){
if(lin(x))return wnum(lvn(x));if(lit(x))return format_json(l_rows(x))
if(lil(x)){r="[";for(z=0;z<count(x);z++){if(z)r=r",";r=r format_json(lst_get(x,z))};return r"]"}
if(lid(x)){r="{";for(z=0;z<count(x);z++){if(z)r=r",";r=r format_json(dic_getk(x,z))":"format_json(dic_getv(x,z))};return r"}"}
if(lis(x)){
x=lvs(x);r="";ct=0;for(z=1;z<=length(x);z++){
c=substr(x,z,1);e=0
if(c=="<"){ct=1}else if(c=="/"&&ct){e=1}else if(c!=" "&&c!="\n"){ct=0}
if(c=="\n"){c="\\n"}else if(e||c~/[\\"]/){c="\\"c};r=r c
}return "\""r"\""
}return "null"
}
function format_love(x, r,z){
if(lin(x)||lis(x))return format_json(x)
if(lil(x)){r="[";for(z=0;z<count(x);z++){if(z)r=r",";r=r format_love(lst_get(x,z))};return r"]"}
if(lid(x)){r="{";for(z=0;z<count(x);z++){if(z)r=r",";r=r format_love(dic_getk(x,z))":"format_love(dic_getv(x,z))};return r"}"}
if(lit(x)){r="<";for(z=0;z<count(x);z++){if(z)r=r",";r=r format_love(tab_getk(x,z))":"format_love(tab_getv(x,z))};return r">"}
if(lii(x)){return lvs(ls(interfaces(x,lms("encoded"),-1)))}
return "null"
}
function format_type(a,t,n,d,lf,pz, o,v,vn,r,z){
o=""
if (t=="%")o="%"
else if(t~/[sluvro]/)o=lvs(ls(a))
else if(t=="a"){a=ll(a);for(z=0;z<count(a);z++){v=ordinal[int(ln(lst_get(a,z)))%256];o=o (length(v)?v:"?");}o=string_clean(o)}
else if(t=="b"){o=lb(a)?"true":"false"}
else if(t=="f"){o=d?sprintf("%.*f",d,ln(a)): wnum(ln(a))}
else if(t=="c"){v=ln(a);o=sprintf("%s$%.*f",v<0?"-":"",d?d:2,abs(v))}
else if(t=="C"){v=ln(a);o=sprintf("%s%.*f" ,v<0?"-":"",d?d:2,abs(v))}
else if(t=="i"){o=""int(ln(a))}
else if(t=="h"){o=sprintf("%x",int(ln(a)))}
else if(t=="H"){o=sprintf("%X",int(ln(a)))}
else if(t=="j"){o=format_json(a)}
else if(t=="J"){o=format_love(a)}
else if(t=="q"){o=format_json(ls(a))}
else if(t=="e"){o=epoch_to_isodate(int(ln(a)))}
else if(t=="p"){o=lvs(l_format(ISODATE,ld(a)))}
vn=length(o);if(d&&t~/[fcC]/)d=0;if(d&&lf)vn=min(d,vn);if(t=="l")o=tolower(o);if(t=="u")o=toupper(o)
r="";if(n&&!lf)for(z=0;z<n-vn;z++)r=r (pz?"0":" ")
z=d&&!lf?max(0,vn-d):0;r=r substr(o,z+1,vn-z)
if(n&&lf)for(z=0;z<n-vn;z++)r=r (pz?"0":" ");return r
}
function format_simple(x,t){return format_type(x,t,0,0,0,0)}
function format_rec(i,x,y, fuse,named,a,r,z){
if(i>=count(x))return y
fuse=(count(x)-i)%2?0:1;named=format_has_names(lvs(ls(lst_get(x,i+fuse))))
a=lit(y)?l_rows(y):ll(y);r=lml();for(z=0;z<count(a);z++){
lst_add(r,l_format(lst_get(x,i+fuse),format_rec(i+fuse+1,x,lit(y)&&!named?ll(lst_get(a,z)):lst_get(a,z))))
}return fuse?l_fuse(lst_get(x,i),r):r
}
function l_format(x,y, r,f,h,named,nk,hn,sk,lf,pz,n,d,t,a,an){
if(lil(x))return format_rec(0,x,y)
r="";f=1;h=0;x=lvs(ls(x));named=format_has_names(x);y=named?ld(y): lil(y)?y: l_list(y)
while(f<=length(x)){
if(substr(x,f,1)!="%"){r=r substr(x,f,1);f++;continue};f++
nk="";hn=0;if(substr(x,f,1)=="["){
hn=1;f++;while(f<=length(x)&&substr(x,f,1)!="]"){nk=nk substr(x,f,1);f++;}
if(substr(x,f,1)=="]")f++
}
sk=substr(x,f,1)=="*";if(sk)f++
lf=substr(x,f,1)=="-";if(lf)f++
pz=substr(x,f,1)=="0";if(pz)f++
n=0;while(substr(x,f,1)~/[0-9]/){n=n*10+substr(x,f,1);f++};if(substr(x,f,1)==".")f++
d=0;while(substr(x,f,1)~/[0-9]/){d=d*10+substr(x,f,1);f++};if(f>length(x))break
t=substr(x,f,1);f++
a=(t~/[sluvroq]/)?lms(""):NONE; an=named?dget(y,hn?lms(nk):lmn(h)): -1
a=t=="%"?NONE: named?(an!=-1?an:a): (!sk&&h<count(y))?lst_get(y,h): a
if(t~/[ro]/){lf=1;d=max(1,d);while(d&&substr(x,f,1)){d--;f++};d=n}
r=r format_type(a,t,n,d,lf,pz);if(t!="%"&&!sk)h++
}return lms(r)
}
function dyads_atomic(name,x,y, r,z,k){
if(lid(x)&&lid(y)){r=lmd()
for(z=0;z<count(x);z++){k=dic_getk(x,z);dset(r,k,dyads_atomic(name,dic_getv(x,z),dgetv(y,k)))}
for(z=0;z<count(y);z++){k=dic_getk(y,z);if(dget(x,k)==-1)dset(r,k,dyads_atomic(name,NONE,dic_getv(y,z)))};return r
}
if( lil(x)&& lil(y)){r=lml();for(z=0;z<count(x);z++)lst_add(r,dyads_atomic(name,lst_get(x,z),count(y)?lst_get(y,z%count(y)):NONE));return r}
if( lid(x)&&!lid(y)){r=lmd();for(z=0;z<count(x);z++)dset(r,dic_getk(x,z),dyads_atomic(name,dic_getv(x,z),y));return r}
if(!lid(x)&& lid(y)){r=lmd();for(z=0;z<count(y);z++)dset(r,dic_getk(y,z),dyads_atomic(name,x,dic_getv(y,z)));return r}
if( lil(x)&&!lil(y)){r=lml();for(z=0;z<count(x);z++)lst_add(r,dyads_atomic(name,lst_get(x,z),y));return r}
if(!lil(x)&& lil(y)){r=lml();for(z=0;z<count(y);z++)lst_add(r,dyads_atomic(name,x,lst_get(y,z)));return r}
if(name=="+")return lmn(ln(x)+ln(y))
if(name=="-")return lmn(ln(x)-ln(y))
if(name=="*")return lmn(ln(x)*ln(y))
if(name=="/")return ln(y)==0?NONE: lmn(ln(x)/ln(y))
if(name=="%")return ln(x)==0?NONE: lmn(mod(ln(y),ln(x)))
if(name=="^")return lmn(ln(x)^ln(y))
if(name=="<")return l_less(x,y)
if(name==">")return l_more(x,y)
if(name=="=")return lmn(lii(x)||lii(y)?x==y: lin(x)&&lin(y)?lvn(x)==lvn(y): lvs(ls(x))==lvs(ls(y)))
if(name=="&")return lin(x)||lin(y)?lmn(min(ln(x),ln(y))): lvs(ls(x))<lvs(ls(y))?ls(x):ls(y)
if(name=="|")return lin(x)||lin(y)?lmn(max(ln(x),ln(y))): lvs(ls(x))>lvs(ls(y))?ls(x):ls(y)
if(name=="bits_and")return lmn(bitwise_and(lbits(ln(x)),lbits(ln(y))))
if(name=="bits_or" )return lmn(bitwise_or( lbits(ln(x)),lbits(ln(y))))
if(name=="bits_xor")return lmn(bitwise_xor(lbits(ln(x)),lbits(ln(y))))
return -1
}
function dyads(name,x,y, r,z,u,gi,gr,ki,t,ik,dk,ai,bi,m){
if(name=="split" )return l_split(x,y)
if(name=="fuse" )return l_fuse(x,y)
if(name=="dict" )return l_dict(x,y)
if(name=="take" )return l_take(x,y)
if(name=="drop" )return l_drop(x,y)
if(name=="limit" )return l_limit(x,y)
if(name=="in" )return l_in(x,y)
if(name=="like" )return l_like(x,y)
if(name=="window")return l_window(x,y)
if(name=="parse" )return l_parse(x,y)
if(name=="format")return l_format(x,y)
if(name=="," )return l_cat(x,y)
if(name=="~" )return matchr(x,y)?ONE:NONE
if(name=="unless")return lin(y)&&lvn(y)==0?x:y
if(name=="join" ){
if(!lit(x)||!lit(y)){
x=lin(x)?l_range(x):ll(x);y=lin(y)?l_range(y):ll(y)
r=lml();for(z=0;z<count(x);z++)lst_add(r,l_cat(lst_get(x,z),count(y)==0?NONE:lst_get(y,z%count(y))));return r
}
ik=lml();dk=lml();r=l_take(NONE,x);for(z=0;z<count(y);z++){
if(tab_getki(x,tab_getk(y,z))>=0){lst_add(ik,tab_getk(y,z))}else{lst_add(dk,lmn(z));tab_set(r,tab_getk(y,z),lml())}
}
for(ai=0;ai<rowcount(x);ai++)for(bi=0;bi<rowcount(y);bi++){
m=1;for(z=0;z<count(ik);z++){if(!matchr(lst_get(tab_get(x,lst_get(ik,z)),ai),lst_get(tab_get(y,lst_get(ik,z)),bi))){m=0;break}}
if(!m)continue
for(z=0;z<count(x );z++)lst_add(tab_getv(r,z ),lst_get(tab_getv(x,z ),ai))
for(z=0;z<count(dk);z++)lst_add(tab_getv(r,z+count(x)),lst_get(tab_getv(y,int(ln(lst_get(dk,z)))),bi))
};return torect(r)
}
if(name=="cross"){
if(lin(x))x=l_range(x);if(lin(y))y=l_range(y);if(!lit(x)||!lit(y)){x=ll(x);y=ll(y)}
if(lil(x)&&lil(y)){r=lml();for(z=0;z<count(x)*count(y);z++)lst_add(r,lml2(lst_get(x,z%count(x)),lst_get(y,int(z/count(x)))));return r}
x=lt(x);y=lt(y);r=lmt();gr=rowcount(x)*rowcount(y)
for(z=0;z<count(x);z++){t=lml();for(u=0;u<gr;u++)lst_add(t,lst_get(tab_getv(x,z), u%rowcount(x) ));tab_set( r,tab_getk(x,z),t)}
for(z=0;z<count(y);z++){t=lml();for(u=0;u<gr;u++)lst_add(t,lst_get(tab_getv(y,z),int(u/rowcount(x))));tab_setuq(r,tab_getk(y,z),t)}
return torect(r)
}
if(name=="@where"){
x=l_take(lmn(rowcount(y)),ll(x))
r=lml();for(z=0;z<count(x);z++)if(lb(lst_get(x,z)))lst_add(r,lmn(z));r=l_take(r,y)
tab_set(r,lms("gindex"),l_range(lmn(rowcount(r))));return r
}
if(name=="@by"){
x=l_take(lmn(rowcount(y)),ll(x));u=lmd();gi=lms("gindex");gr=lms("group")
for(z=0;z<count(x);z++){
ki=dgeti(u,lst_get(x,z));if(ki==-1){dset(u,lst_get(x,z),l_take(NONE,y));ki=count(u)-1}
t=tab_row(y,z);dset(t,gi,lmn(rowcount(dic_getv(u,ki))));dset(t,gr,lmn(ki));tab_addrow(dic_getv(u,ki),t)
};return ll(u)
}
return dyads_atomic(name,x,y)
}
BEGIN{merge_ix=-1}
function merge(vals,keys,widen, i,t,r,z){
i=lms("@index")
if(!widen){merge_ix=lml();for(z=0;z<count(vals);z++)lst_addall(merge_ix,dget(lst_get(vals,z),i))}
if(widen){t=lml();for(z=0;z<count(vals);z++)if(count(dget(lst_get(vals,z),i)))lst_add(t,lst_get(vals,z));vals=t}
if(count(vals)==0){t=lmd();for(z=0;z<count(keys);z++)dset(t,lst_get(keys,z),lml());lst_add(vals,t)}
r=lml();for(z=0;z<count(vals);z++)lst_add(r,l_table(widen?lst_get(vals,z):l_drop(i,lst_get(vals,z))));r=l_raze(r)
if(widen){merge_ix=dget(r,i);r=l_drop(i,r)}
return r
}
function disclose(x){return l_drop(lml3(lms("index"),lms("gindex"),lms("group")),x)}
function l_select(orig,vals,keys, r){merge_ix=-1;r=merge(vals,keys,0);return (count(keys)>1)?r:l_take(merge_ix,disclose(orig))}
function lex_list(x,y,a,ix, xv,yv){
if(count(x)<ix&&count(y)<ix)return 0
xv=count(x)>ix?lst_get(x,ix):NONE
yv=count(y)>ix?lst_get(y,ix):NONE
return lex_less(xv,yv)?a: lex_more(xv,yv)?!a: lex_list(x,y,a,ix+1)
}
function lex_less(x,y){return lil(x)&&lil(y)?lex_list(x,y,1,0): lb(l_less(x,y))}
function lex_more(x,y){return lil(x)&&lil(y)?lex_list(x,y,0,0): lb(l_more(x,y))}
function sort_swap(perm,i,j, t){t=perm[i];perm[i]=perm[j];perm[j]=t}
function sort_compare(order_dir,order_vec,perm,i,j, iv,jv){
iv=lst_get(order_vec,perm[i])
jv=lst_get(order_vec,perm[j])
if(lex_less(iv,jv))return order_dir
if(lex_more(iv,jv))return -order_dir
return i-j
}
function sort_by(order_dir,order_vec, r,z,i,j,perm){
# an insertion-sort, to keep things simple.
# this routine assembles a permutation vector through which
# the original data may be indexed to place it in order.
# FIXME: swap out for mergesort or quicksort?
for(z=0;z<count(order_vec);z++)perm[z]=z
for(i=1;i<count(order_vec);i++){
for(j=i;j>0&&sort_compare(order_dir,order_vec,perm,j-1,j)>0;j--)sort_swap(perm,j,j-1)
}
r=lml();for(z=0;z<count(order_vec);z++)lst_add(r,lmn(perm[z]));return r
}
function triads(name,x,y,z, r,rc,i,j,col,ci,t){
if(name=="@sel")return l_select(x,y,z)
if(name=="@ext"){
r=l_cols(l_select(x,y,z));
return count(z)==1?(count(r)?l_first(r):lml()): count(r)!=1||count(dic_getk(r,0))?r:l_first(r)
}
if(name=="@upd"){
x=disclose(x);merge_ix=-1;r=merge(y,z,1)
for(i=0;i<count(r);i++){
if(tab_getv(r,i)==merge_ix)continue
t=tab_getk(r,i);ci=tab_getki(x,t);col=lml()
for(j=0;j<rowcount(x);j++)lst_add(col,ci==-1?NONE:lst_get(tab_getv(x,ci),j));tab_set(x,t,col)
for(j=0;j<count(merge_ix);j++){lst_set(col,int(ln(lst_get(merge_ix,j))),lst_get(tab_getv(r,i),j))}
}return x
}
if(name=="@ins"){
rc=ceil(count(x)/count(y));r=lml();for(i=0;i<count(y);i++){
col=lml();lst_add(r,col);for(j=0;j<rc;j++){t=(count(y)*j)+i;lst_add(col,t>=count(x)?NONE:lst_get(x,t))}
};r=l_table(l_dict(y,r));return lin(z)?r:l_cat(lt(z),r)
}
if(name=="@orderby"){
x=l_take(lmn(rowcount(y)),ll(x))
r=l_take(i=sort_by(ln(z),x),y);tab_set(r,lms("gindex"),l_range(lmn(rowcount(r))));return r
}
}
###########################################################
#
# Lil Natives
#
###########################################################
function show_dat(row,w,cols, r,z,c){
r="|";for(z=0;z<count(cols);z++){c=lvs(l_limit(lmn(w[z]),lst_get(dic_getv(cols,z),row)));r=r " "c repeat_char(" ",w[z]-length(c))" |"};return r
}
function show(ptr,toplevel, r,z,t,w,cols,col,row,fmt,arr,c,d){
if(ptr==-1)return "NULL"
if(lin(ptr))return wnum(lvn(ptr))
if(lis(ptr)){
t=lvs(ptr);r=""
for(z=1;z<=length(t);z++){c=substr(t,z,1);if(c=="\n"){c="\\n"}else if(c~/[\\"]/){c="\\"c};r=r c}
return "\""r"\""
}
if(lil(ptr)){r="(";for(z=0;z<count(ptr);z++){if(z)r=r",";r=r show(lst_get(ptr,z))};return r")"}
if(lid(ptr)){r="{";for(z=0;z<count(ptr);z++){if(z)r=r",";r=r show(dic_getk(ptr,z))":"show(dic_getv(ptr,z))};return r"}"}
if(lion(ptr)){return "on "lon_name(ptr)" "lvs(l_fuse(lms(" "),lon_args(ptr)))(count(lon_args(ptr))?" ":"")"do ... end"}
if(linat(ptr)){return "on native x do ... end"}
if(lii(ptr)){return "<"li_name(ptr)">"}
if(lit(ptr)&&!toplevel){
d=rowcount(ptr)?lvs(l_fuse(lms(" "),l_raze(l_flip(l_range(ptr)))))" ":"";
return "insert "lvs(ls(l_fuse(lms(" "),l_keys(ptr))))" with "d"end"
}
if(lit(ptr)){
if(!count(ptr))return"++\n||\n++"
cols=lml();for(z=0;z<count(ptr);z++){
col=lml();lst_add(col,tab_getk(ptr,z));w[z]=count(tab_getk(ptr,z));lst_add(cols,col)
for(row=0;row<rowcount(ptr);row++){fmt=show(lst_get(tab_getv(ptr,z),row));lst_add(col,lms(fmt));w[z]=min(40,max(w[z],length(fmt)))}
}
fmt="+";for(z=0;z<count(ptr);z++){fmt=fmt repeat_char("-",w[z]+2)"+"}
r=fmt"\n"show_dat(0,w,cols)"\n";if(rowcount(ptr))r=r fmt "\n";for(z=1;z<=rowcount(ptr);z++){r=r show_dat(z,w,cols)"\n"}
return r fmt
}
if(liblk(ptr)){
c=blk_getops(ptr,arr)
r="block {";for(z=0;z<c;z++)r=r"\n "z": "arr[z+1]
r=r"\n} locals: <<";for(z=0;z<count(ptr);z++){if(z)r=r",";r=r show(lst_get(ptr,z))};return r">>"
}
if(lienv(ptr))return "<ENVIRONMENT>"
if(ptr=="")return "INVALID"
print "nyi debug show of ptr " ptr " with type " heap_type[ptr]
exit 1
}
function writecsv(args, r,z,t,s,delim,n,c,o,e,badchar){
r="";t=lt(l_first(args));delim=count(args)>2?lvs(l_first(ls(lst_get(args,2)))):","