Performance Difference between argmin and minimum

[Xnartharax]

I recognised that argmin and minimum perform very differently (at least on my machine):

julia> y = rand(5000)
...
julia> @btime minimum($y)
  856.716 ns (0 allocations: 0 bytes)
0.00017745722529260988
julia> @btime argmin($y)
  5.433 μs (0 allocations: 0 bytes)
4842

Also this very naive implementation is faster than the base library for a Vector{Float64}:

function myargmin(y)
     if isempty(y)
         error("can't supply empty array")
     end
     best_i = 0
     best_e = Inf
     for i=1:length(y)
          if best_e > y[i]
               best_e= y[i]
               best_i = i
           end
     end
     best_i
end

julia> @btime myargmin($y)
  2.156 μs (0 allocations: 0 bytes)
4842

A mapreduce implementation (similar to minimum) has the same performance:

argmin_red((ix, fx), (im, fm)) = fx > fm ? (im, fm) : (ix, fx)
myargmin2(y) = mapreduce(identity, argmin_red, (enumerate(y)))

julia> @btime myargmin2($y)
  2.156 μs (0 allocations: 0 bytes)
(4842, 0.00017745722529260988)

Both implementations are faster than the ones provided in Base.
I think we should be able to rely on the base library to have the best performance for these basic tasks.

[Seelengrab]

argmin currently works by calling findmin, ending up here:

julia/base/reduce.jl

Lines 862 to 863 in e37e290

	findmin(f, domain) = mapfoldl( ((k, v),) -> (f(v), k), _rf_findmin, pairs(domain) )
	_rf_findmin((fm, im), (fx, ix)) = isgreater(fm, fx) ? (fx, ix) : (fm, im)

called like findmin(identity, a).

It would be great if a change like this could speed up findmin in general and accelerate argmin incidentally, though you'll have to be careful to keep behavior and guarantees provided by the current implementation (e.g. order of returned values) the same.

[Xnartharax]

I looked at that and the reduce implementation was inspired by this. There is another version of argmin specializing on arrays which didn't have time to look at yet.
What are some of the guarantees of the current implementation?