Q: Lie series method for PDEs

[Audrius-St]

Hello,

I’ve used Sympy for several years now and am interested in giving Symbolics.jl a go with an eye to switching over completely. I’ve previously used Sympy to solve systems of ODES using the symbolic Lie series method, I would now like to use the generalized symbolic Lie series method to solve a particular PDE.

The test example below, of the first part of the method, is from the reference paper

Banks, S. P. (1992) Infinite-dimensional Carleman linearization, the Lie series, and optimal control of non-linear partial differential equations, International Journal of Systems Science, 23:5, 663 675. http://dx.doi.org/10.1080/00207729208949241

After reading the Symbolics.jl documentation, I am stuck on two points:

1. How best to represent Equation 1 to be substituted into Equations 6, 9, . . . ?

2. How to rearrange the order of the differential operators of x, t as in Equations 8, 14, . . . ? Can this be done in Symbolics.jl or would I need to “roll my own” using SymbolicUtils.jl?

Lie_series_PDE_simple_example.pdf

[Audrius-St]

After studying the Symbolics.jl and SymbolicUtils.jl documentation some more, was able to code the following "brute force" method after a bit of trial and error.

It works, but is PDE specific and requires manual inspection of each order in the expansion.

Tried to create a rule using SymbolicUtils.jl to rearrange the order of the differentials, but was unable to figure out how to do so. The @rule did not seem to recognize Differential(x)(~u). The documentation of Symbolics.jl, SymbolicUtils.jl, and especially TermInterface.jl is a bit . . . sparse.

I suggest that it would be helpful if substitute() returned True if the substitution occurred [was successful ] performed and False if it does not [or failed?].

If any SymbolicUtils.jl + Symbolics.jl experts could advise improvements, it would be appreciated.

# test_symbolics_main.jl

using Symbolics
# using Latexify 

function main()

    @variables x, t
    @variables Φ(x, t)

    Dx = Differential(x)
    D2x = Dx * Dx
    D3x = Dx * D2x
    D4x = Dx * D3x

    Dt = Differential(t)

    # 0th order expansion
    γ0 = Φ
    println("γ0 = ", γ0, "\n")

    # 1st order expansion
    ∂Φ∂t = Dx(Dx(Φ)) - Φ^2
    γ1 = ∂Φ∂t
    println("γ1 = ", γ1, "\n")

    # 2nd order expansion
    ∂2Φ∂t2 = expand_derivatives(Dt(γ1))

    # Rearrange the commuting partial derivates with ∂/∂t on the right
    ∂2Φ∂t2_2xt = 
        substitute(
            ∂2Φ∂t2, 
            Dict([Dt(D2x(Φ)) => D2x(Dt(Φ))]))

    γ2 = simplify(
            expand_derivatives(
                substitute(
                    ∂2Φ∂t2_2xt,
                    [Dt(Φ) => ∂Φ∂t])),
            expand=true)
    println("γ2 = ", γ2, "\n")

    # 3rd order expansion
    ∂3Φ∂t3 = expand_derivatives(Dt(γ2))

    # Rearrange the commuting partial derivates with ∂/∂t on the right
    ∂3Φ∂t3_4xt = 
        substitute(
            ∂3Φ∂t3, 
            Dict([Dt(D4x(Φ)) => D4x(Dt(Φ))]))

    ∂3Φ∂t3_4xt_2xt = 
        substitute(
            ∂3Φ∂t3_4xt, 
            Dict([Dt(D2x(Φ)) => D2x(Dt(Φ))]))

    ∂3Φ∂t3_4xt_2xt_xt = 
        substitute(
            ∂3Φ∂t3_4xt_2xt, 
            Dict([Dt(Dx(Φ)) => Dx(Dt(Φ))]))       
       
    γ3 = simplify(
            expand_derivatives(
                substitute(
                    ∂3Φ∂t3_4xt_2xt_xt,
                    [Dt(Φ) => ∂Φ∂t])),
            expand=true)
    println("γ3 = ", γ3, "\n")
 
    # 4th order expansion
    ∂4Φ∂t4 = expand_derivatives(Dt(γ3))

    # . . .

    # To do
    # Higher orders.

end

begin
    main()

end

[bowenszhu]

I completely followed Lie_series_PDE_simple_example.pdf you provided

using Symbolics, SymbolicUtils.Rewriters
@variables x, t, ϕ(x, t)
Dx = Differential(x)
Dt = Differential(t)

rewriter = Prewalk(Chain([@rule Dt(Dx(~f)) => Dx(Dt(~f))]))
reverse_diff(x) = Symbolics.wrap(rewriter(Symbolics.unwrap(x)))

reaction_diffusion = Dict(Dt(ϕ) => (Dx^2)(ϕ) - ϕ^2) # Eq 1

γ₁ = ϕ # Eq 2

γ₂ = Dt(ϕ) # Eq 3

γ₃ = (Dt^2)(ϕ) # Eq 4 & 5
γ₃ = substitute(γ₃, reaction_diffusion) # Eq 6
γ₃ = expand_derivatives(γ₃) # Eq 7.5
γ₃ = reverse_diff(γ₃) # Eq 8
γ₃ = substitute(γ₃, reaction_diffusion) # Eq 9
γ₃ = expand_derivatives(γ₃) # Eq 9.5
γ₃ = expand(γ₃) # Eq 10

γ₄ = (Dt^3)(ϕ) # Eq 11 & 12
γ₄ = substitute(γ₄, Dict((Dt^2)(ϕ) => γ₃)) # Eq 13
γ₄ = expand_derivatives(γ₄) # Eq 13.5
γ₄ = reverse_diff(γ₄) # Eq 14

Here, the term rewriter used to reverse the order of $\frac{\partial}{\partial t}$ and $\frac{\partial}{\partial x}$ is defined as rewriter = Prewalk(Chain([@rule Dt(Dx(~f)) => Dx(Dt(~f))])) which does pre-order traversal to the expression tree. Tree traversal is usually applied on trees, but Differential are unary operators, so Prewalk is just top-to-bottom in this case. Top-to-bottom instead of bottom-to-top is needed because we want to move $\frac{\partial}{\partial t}$ closest to the internal variable. The following demonstrates how this rewriter changes an expression tree step by step from top to bottom.

Dt(Dx(Dx(Dx(f))))
-->
Dx(Dt(Dx(Dx(f))))
-->
Dx(Dx(Dt(Dx(f))))
-->
Dx(Dx(Dx(Dt(f))))

Hope this helps.

BTW, I think the second last term in Equation 14 should be $$-4\frac{\partial \phi}{\partial x}\left(\frac{\partial^2\phi}{\partial x \partial t}\right)$$ instead of $$-4\frac{\partial \phi}{\partial x}\left(\frac{\partial\phi}{\partial t}\right)$$

[Audrius-St]

Hope this helps.

It most certainly does. Thank you for your explanation and solution. Much appreciated.

BTW, I think the second last term in Equation 14 should be −4∂ϕ∂x(∂2ϕ∂x∂t) instead of −4∂ϕ∂x(∂ϕ∂t)

Thanks also for spotting the error. I've updated the pdf and image files with the corrected version.