Quantitative drug sensitivity scoring

Statistical report

Zhigang Wang, Erwin Dreesen 22 June 2023

# Data description

Data items

* CELLINE [integer]
  + 1: EGFP
  + 2: Wild Type (WT)
  + 3: R183W (Mutant)
  + 4: P179R
  + 5: S256F
* DRUG [integer]
  + Clofarabine
* ADDITIVE [integer]
  + OA
* ADDITIVE\_CONC [numeric]
  + OA: 0, 10 nM
* REPEAT [integer]
  + Inter-day variability; 6-7 experimental repeats (days)
* REP [integer]
  + 1, 2, 3
  + Within-day variability; 3 replicates per 96-well plate
* DRUG\_CONC [numeric]
  + Clofarabine: 0, 0.025, 0.05, 0.1, 0.2, 0.4, 0.6, 0.8, 1 µM
* DV [numeric]
  + Dependent variable (Y-axis)
  + Cell viability
* CELLINE\_DRUG\_ADDITIVE
  + Option 1 for Level 1 clustering
  + 5 cell lines \* 1 DRUG \* 1 ADDITIVE = 5 clusters
* CELLINE\_DRUG\_ADDITIVE\_ADDITIVECONC
  + Option 2 for Level 1 clustering
  + 5 cell lines \* 1 DRUG \* 1 ADDITIVE \* 2 ADDITIVE concentrations = 10 clusters
* CELLLINE\_DRUG\_ADDITIVE\_ADDITIVECONC\_REPEAT
  + Option 3 for Level 1 clustering
  + 3 cell lines \* 1 DRUG \* 1 ADDITIVE \* 2 ADDITIVE concentrations \* 7 experimental repeats (days) = 42 clusters\*
  + 2 cell lines \* 1 DRUG \* 1 ADDITIVE \* 2 ADDITIVE concentrations \* 6 experimental repeats (days) = 24 clusters\*
  + In total 66 clusters
* CELLINE\_NAME [character]
* DRUG\_NAME [character]
* ADDITIVE\_NAME [character]
* CELLINE\_DRUG\_ADDITIVE\_NAME [character]

3564 data records.

Print screens of table; next pages.

Beginning of table:

A screen shot of a computer

Description automatically generated with low confidence

End of table:

A screen shot of a computer

Description automatically generated with low confidence

NONMEM code

;; 1. Based on:

;; 2. Description: remove OMEGA close to 0

;; x1. Author: Zhigang Wang

;; 3. Label:

$SIZES LTH=9999 LVR=9999

DIMCNS=9999 DIMTMP=9999 DIMNEW=9999

; DIMVRB=9999 LIM1=9999 MAXFCN=9999 NO=9999 MAXPTHETA=9999

$PROBLEM Quantitative drug sensitivity scoring of 1 compound in 5 strains

$INPUT CELLINE ; 5 cell lines: EGFP, WT, R183W, P179R, S256F

DRUG ; Clofarabine

ADDITIVE ; OA

ADDITIVECONC ; 0,10 nM

DAY ; inter-day repeats

REP ; within-day repeats

DRUGCONC ; 0, 0.025, 0.05, 0.1, 0.2, 0.4, 0.6, 0.8, 1.0

DV

DROP ; ID option 1 --- CELLINE\_DRUG\_ADDITIVE

ID ; **ID option 2 --- CELLINE\_DRUG\_ADDITIVE\_ADDITIVECONC** ; --- Estimate parameters for each value of CELLINE\_DRUG\_ADDITIVE\_ADDITIVECONC = combination of the covariates, with REPEAT in the inter-occation variability and REP in the residual unexplained variability

DROP ; ID option 3 --- CELLINE\_DRUG\_ADDITIVE\_ADDITIVECONC\_DAY ; CELLINE\_DRUG\_ADDITIVE\_ADDITIVECONC\_REPEAT --- Estimate parameters for each value of CELLINE\_DRUG\_ADDITIVE\_ADDITIVECONC (GROUPER, previous line) = combination of the covariates, with REPEAT being the IIV and REP in the RUV

DROP ; CELLINE\_NAME

DROP ; DRUG\_NAME

DROP ; ADDITIVE\_NAME

DROP ; CELLINE\_DRUG\_ADDITIVE\_NAME

$DATA DS\_2023\_final.csv IGNORE=@

$ABBREVIATED DERIV2=NOCOMMON

$PRED ;;; CELL LINE

IF(CELLINE .EQ. 1) TOP\_CELLINE = THETA(1) ;reference --- 1 FIX

IF(CELLINE .EQ. 1) BOTTOM\_CELLINE = THETA(2) ;reference --- 1 FIX

IF(CELLINE .EQ. 1) IC50\_CELLINE = THETA(3) ;reference --- 1 FIX

IF(CELLINE .EQ. 1) GAMMA\_CELLINE = THETA(4) ;reference --- 1 FIX

IF(CELLINE .EQ. 2) TOP\_CELLINE = THETA(5)

IF(CELLINE .EQ. 2) BOTTOM\_CELLINE = THETA(6)

IF(CELLINE .EQ. 2) IC50\_CELLINE = THETA(7)

IF(CELLINE .EQ. 2) GAMMA\_CELLINE = THETA(8)

IF(CELLINE .EQ. 3) TOP\_CELLINE = THETA(9)

IF(CELLINE .EQ. 3) BOTTOM\_CELLINE = THETA(10)

IF(CELLINE .EQ. 3) IC50\_CELLINE = THETA(11)

IF(CELLINE .EQ. 3) GAMMA\_CELLINE = THETA(12)

IF(CELLINE .EQ. 4) TOP\_CELLINE = THETA(13)

IF(CELLINE .EQ. 4) BOTTOM\_CELLINE = THETA(14)

IF(CELLINE .EQ. 4) IC50\_CELLINE = THETA(15)

IF(CELLINE .EQ. 4) GAMMA\_CELLINE = THETA(16)

IF(CELLINE .EQ. 5) TOP\_CELLINE = THETA(17)

IF(CELLINE .EQ. 5) BOTTOM\_CELLINE = THETA(18)

IF(CELLINE .EQ. 5) IC50\_CELLINE = THETA(19)

IF(CELLINE .EQ. 5) GAMMA\_CELLINE = THETA(20)

;;; 1 base drug

IF(DRUG .EQ. 1) TOP\_DRUG = THETA(21) ;reference --- 1 FIX

IF(DRUG .EQ. 1) BOTTOM\_DRUG = THETA(22) ;reference --- 1 FIX

IF(DRUG .EQ. 1) IC50\_DRUG = THETA(23) ;reference --- 1 FIX

IF(DRUG .EQ. 1) GAMMA\_DRUG = THETA(24) ;reference --- 1 FIX

;;; ADDITIVE OA effect

IF(ADDITIVECONC .EQ. 0) TOP\_ADDITIVE = THETA(25) ; no OA

IF(ADDITIVECONC .EQ. 0) BOTTOM\_ADDITIVE = THETA(26) ; no OA

IF(ADDITIVECONC .EQ. 0) IC50\_ADDITIVE = THETA(27) ; no OA

IF(ADDITIVECONC .EQ. 0) GAMMA\_ADDITIVE = THETA(28) ; no OA

IF(ADDITIVECONC .EQ. 10) TOP\_ADDITIVE = THETA(29)

IF(ADDITIVECONC .EQ. 10) BOTTOM\_ADDITIVE = THETA(30)

IF(ADDITIVECONC .EQ. 10) IC50\_ADDITIVE = THETA(31)

IF(ADDITIVECONC .EQ. 10) GAMMA\_ADDITIVE = THETA(32)

; inter-day variability

DAY1=0

DAY2=0

DAY3=0

DAY4=0

DAY5=0

DAY6=0

DAY7=0

IF(DAY.EQ.1) DAY1=1

IF(DAY.EQ.2) DAY2=1

IF(DAY.EQ.3) DAY3=1

IF(DAY.EQ.4) DAY4=1

IF(DAY.EQ.5) DAY5=1

IF(DAY.EQ.6) DAY6=1

IF(DAY.EQ.7) DAY7=1

; within-day variability

REP1=0

REP2=0

REP3=0

IF(REP.EQ.1) REP1=1

IF(REP.EQ.2) REP2=1

IF(REP.EQ.3) REP3=1

TVTOP = TOP\_CELLINE \* TOP\_DRUG \* TOP\_ADDITIVE

TOP = TVTOP \*EXP(REP1\*ETA(1) + REP2\*ETA(2) + REP3\*ETA(3) + DAY1\*ETA(13) + DAY2\*ETA(14) + DAY3\*ETA(15) + DAY4\*ETA(16) + DAY5\*ETA(17) + DAY6\*ETA(18) + DAY7\*ETA(19))

TVBOTTOM = BOTTOM\_CELLINE \* BOTTOM\_DRUG \* BOTTOM\_ADDITIVE

BOTTOM = TVBOTTOM \*EXP(REP1\*ETA(4) + REP2\*ETA(5) + REP3\*ETA(6) + DAY1\*ETA(20) + DAY2\*ETA(21) + DAY3\*ETA(22) + DAY4\*ETA(23) + DAY5\*ETA(24) + DAY6\*ETA(25) + DAY7\*ETA(26))

TVIC50 = IC50\_CELLINE \* IC50\_DRUG \* IC50\_ADDITIVE

IC50 = TVIC50 \*EXP(REP1\*ETA(7) + REP2\*ETA(8) + REP3\*ETA(9) + DAY1\*ETA(27) + DAY2\*ETA(28) + DAY3\*ETA(29) + DAY4\*ETA(30) + DAY5\*ETA(31) + DAY6\*ETA(32) + DAY7\*ETA(33))

TVGAMMA = GAMMA\_CELLINE \* GAMMA\_DRUG \* GAMMA\_ADDITIVE

GAMMA = TVGAMMA \*EXP(REP1\*ETA(10) + REP2\*ETA(11) + REP3\*ETA(12) + DAY1\*ETA(34) + DAY2\*ETA(35) + DAY3\*ETA(36) + DAY4\*ETA(37) + DAY5\*ETA(38) + DAY6\*ETA(39) + DAY7\*ETA(40))

IMAX = (TOP-BOTTOM)/TOP

IPRED = BOTTOM + (TOP-BOTTOM)/(1+(((DRUGCONC)\*\*GAMMA)/(IC50\*\*GAMMA))) ;equation for the drug effect

W = SQRT(IPRED\*\*2\*SIGMA(1,1) + SIGMA(2,2))

Y = IPRED + (IPRED\*EPS(1)) + EPS(2)

IRES = DV-IPRED

IWRES = IRES/W

$THETA

(1) FIX ;reference cell line EFGR (1)

(1) FIX ;reference cell line EFGR

(1) FIX ;reference cell line EFGR

(1) FIX ;reference cell line EFGR

(0, 1.16) ;5

(0, 0.991) ;

(0, 1.17) ;

(0, 0.846) ;

(0, 0.99) ;9

(0, 1) ;

(0, 1.42) ;

(0, 0.915) ;

(0, 1.04) ;13

(0, 1.03) ;

(0, 1.1) ;

(0, 0.994) ;

(0, 1.17) ;17

(0, 1.12) ;

(0, 1.08) ;

(0, 0.931) ;

(1) FIX ;reference Clofarabine (21)

(1) FIX ;reference Clofarabine

(1) FIX ;reference Clofarabine

(1) FIX ;reference Clofarabine

(0, 0.93) ;25

(0, 0.0609) ;

(0, 0.214) ;

(0, 4.94) ;

(0, 0.623) ;29

(0, 0.06) ;

(0, 0.133) ;

(0, 5.85) ;

$OMEGA BLOCK(1) 0.000184 ; within-day variability TOP

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) 0 FIX ; within-day variability BOTTOM

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) 0 FIX ; within-day variability IC50

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) 0 FIX ; within-day variability GAMMA

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) 0.0135 ; inter-day variability TOP

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) 0.0441 ; inter-day variability BOTTOM

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) 0.0244 ; inter-day variability IC50

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) 0.0307 ; inter-day variability GAMMA

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$OMEGA BLOCK(1) SAME

$SIGMA 0.00499 ; residual variability

0 FIX

$COVARIANCE PRINT=E UNCONDITIONAL ;MATRIX=R

$ESTIMATION METHOD=1 INTERACTION MAXEVAL=999999 POSTHOC PRINT=5 NOABORT SADDLE\_RESET=1 ;NSIG=3 SIGL=9

$TABLE ID CELLINE ADDITIVE ADDITIVECONC DRUG DAY REP DRUGCONC

DV Y PRED IPRED IRES IWRES CWRES

TOP BOTTOM IC50 GAMMA

TVTOP TVBOTTOM TVIC50 TVGAMMA

IMAX ETA(1) ETA(2) ETA(3) ETA(4)

ONEHEADER NOPRINT FILE=runfinal\_out.csv

A picture containing line, plot, parallel, diagram

Description automatically generated

**Figure 1. Observed effect of OA on the response to nine drugs in three cell lines.**

Dots represent the original data, lines indicate the median trend per OA concentration.

**Table 1. Model parameters**

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| **EGFP, Clofarabine** *(reference)* | **No OA** | **OA=10 nM** | **Effect of WT** | **Effect of R183W** | **Effect of R179R** | **Effect of S256F** |
| TOP (RSE) | 0.930 (3.6) | 0.623 (3.7) | ×1.16 (7.3) | ×0.990 (6.4) | ×1.04 (4.8) | ×1.17 (6.7) |
| BOTTOM (RSE) | 0.0609 (1.4) | 0.060 (1.4) | ×0.991 (1.3) | ×1.00 (1.9) | ×1.03 (2.5) | ×1.12 (2.4) |
| IC50 (µM) (RSE) | 0.214 (1.0) | 0.133 (1.4) | ×1.17 (3.2) | ×1.42 (1.8) | ×1.10 (1.1) | ×1.08 (2.4) |
| GAMMA (RSE) | 4.94 (1.3) | 5.85 (1.7) | ×0.846 (3.4) | ×0.915 (2.6) | ×0.994 (3.3) | ×0.931 (3.0) |
| *Inter-experiment variability*  *%CV (RSE) [% η-shrinkage]*  TOP  BOTTOM  IC50  GAMMA | 1.4 (20) [49, 50, 61]  0 FIX  0 FIX  0 FIX | | | | | |
| Inter-day\* variability  *%CV (RSE) [% η-shrinkage]*  TOP  BOTTOM  IC50  GAMMA | 11.6 (3.9) [0, 0, 0, 0, 35, 26, 66]  21.0 (9.2) [19, 55, 41, 49, 42, 55, 41]  15.6 (7.1) [46, 34, 36, 30, 0, 25, 62]  17.5 (9.3) [43, 26, 45, 49, 0, 38, 37] | | | | | |
| *Residual variability %CV (RSE) [% ε-shrinkage]*  Additive  Proportional | 0 FIX  7.06 (4.4) [7] | | | | | |

Model parameters are expressed as typical values (%relative standard deviation). CV: coefficient of variation. \* Inter-day/repeat variability. First-order conditional estimation with interaction was used to estimate model parameters (NONMEM version 7.5; Icon Development Solutions, Gaithersburg, Maryland, USA). The parameter estimates with 95% confidence interval including 1 are coloured in grey. RSE: relative standard error. . -2\*Ln(likelihood) = -11552.893

A picture containing plot, line

Description automatically generated

**Figure 2. Observed versus predicted cell viability plot.**  
The predicted cell viabilities consider the inter-experiment and inter-day variability. The red line is a locally weighted smoother.

A picture containing line, plot, screenshot

Description automatically generated

**Figure 3. Conditional weighted residuals (CWRES) versus predicted cell viability plot.**  
The predicted cell viabilities do not consider the inter-experiment and inter-day variability. The red line is a locally weighted smoother.

A picture containing text, line, plot, diagram

Description automatically generated

**Figure 4. Predicted AUC vs observed AUC plot.** The predicted AUC do not consider the inter-experiment and inter-day variability. The observed AUCs are calculated based on the trapezoidal rule and do not consider the inter-experiment and inter-day variability (median of repeats and replicates). The red line is a locally weighted smoother. AUC: Area under the cell viability vs compound concentration curve.

**A screenshot of a graph

Description automatically generated with low confidence**

**Figure 5. The effect of OA on the response to Clofarabine in five cell lines.**

Dots represent the original data, solid lines indicate the model fits. Dashed lines and bold asterisks indicate the IC50.

A picture containing text, screenshot, line, plot

Description automatically generated

**Figure 6. The differential drug sensitivity score (dDSS0) versus the OA concentration in five cell lines.**

The dDSS0 is calculated by subtracting the control DSS0 (OA = 0 nM) from the DSS0 (OA = 10 nM). DSS0 is calculated as .

A picture containing diagram, plan, technical drawing, schematic

Description automatically generated

**Figure 7. The differential drug sensitivity score (dDSS0) when adding OA in five cell lines.**

The dDSS0 is calculated by subtracting the control DSS0 (OA = 0 nM) from the DSS0 (OA = 10 nM). DSS0 is calculated as . The boxplots represent the interquartile range of dDSS0 from 1000 Monte Carlo simulations. The Wilcoxon test is used to examine the statistical difference in dDSS0 between cell lines. The symbols (\*\*\*\*, \*\*\*, \*\*, \*, ns) represent the significance levels of (<0.001, <0.01, <0.05, ≥0.5), respectively.