A Morse Code Generator

Using Flea-Scope and a simple piezo buzzer between pins a7 and a8, you can trivially input strings from the user and translate them to morse code, using the program below. Enter the program below and type “save” followed by <Enter> to save it to the flash filesystem. Then type “run” followed by <Enter> to run it. You can enter strings (in lower-case) at the “?” prompt to be translated to morse code. You can change the speed of the code generation by changing the “ms” variable in line 40 -- lower numbers go faster. Or if the program is already running, you can just type <Ctrl-C> to stop the program, redefine the variable live, like “ms = 50” followed by <Enter>, and then continue the program by typing “cont” followed by <Enter>.

10 dim i, ms, freq, input$[79], codes[128]

  20 dim gnd as pin a7 for digital output

  30 dim buzzer as pin a8 for frequency output

  40 ms = 100, freq = 800, gnd = 0

  50 gosub init

  60 while 1 do

  70   input input$

  80   for i = 0 to input#-1

  90     gosub morse input[i]

100   next

 110   print ""

120 endwhile

 130 end

 140 sub morse letter

150   dim code, key

160   code = codes[letter]

170   while code do

180     key = code&3

190     if key==1 then

200       buzzer = freq

210       sleep ms ms

220     elseif key==2 then

230       buzzer = freq

240       sleep 3\*ms ms

250     endif

 260     buzzer = 0

270     sleep ms ms

280     code = code>>2

290   endwhile

 300   sleep 2\*ms ms

310 endsub

 320 sub init

330   dim a, b

340   do

 350     read a, b

360     if a then

370       codes[a] = b

380     endif

 390   until !a

400 endsub

 410 data '0', 0x2aa

420 data '1', 0x2a9

430 data '2', 0x2a5

440 data '3', 0x295

450 data '4', 0x255

460 data '5', 0x155

470 data '6', 0x156

480 data '7', 0x15a

490 data '8', 0x16a

500 data '9', 0x1aa

510 data ' ', 0xff

520 data 'a', 0x9

530 data 'b', 0x56

540 data 'c', 0x66

550 data 'd', 0x16

560 data 'e', 0x1

570 data 'f', 0x65

580 data 'g', 0x1a

590 data 'h', 0x55

600 data 'i', 0x5

610 data 'j', 0xa9

620 data 'k', 0x26

630 data 'l', 0x59

640 data 'm', 0xa

650 data 'n', 0x6

660 data 'o', 0x2a

670 data 'p', 0x69

680 data 'q', 0x9a

690 data 'r', 0x19

700 data 's', 0x15

710 data 't', 0x2

720 data 'u', 0x25

730 data 'v', 0x95

740 data 'w', 0x29

750 data 'x', 0x96

760 data 'y', 0xa6

770 data 'z', 0x5a

780 data 0, 0