**DOCUMENTATION: table1\_loop Macro**

**Macro Name:** table1\_loop

**Created Date/Author:** Feb. 2021/Stephanie Lobaugh (Note: Debra Goldman is the author of the table1 macro that is called within the table1\_loop macro)

**Last Update Date/Person**: 2021-10-01/Stephanie Lobaugh

**Other Contributors:** Hannah Kalvin

**Current Version (Corresponds to GitHub Repository Tag):** table1\_loopv1.0

**Working Environment:** SAS 9.4 English version

# Contact

Hannah Kalvin [kalvinh@mskcc.org](mailto:kalvinh@mskcc.org)

Stephanie Lobaugh [lobaughs@mskcc.org](mailto:lobaughs@mskcc.org)

# Purpose

To produce a descriptive statistics summary table for each variable in the dataset. The frequency, including # of missing value will be generated for categorical variables; and summary statistics (n, mean, median, Q1, Q3, min, max, standard deviation, # of missing) for numerical variables.

# Notes

In order to use this macro, variables must be numeric; to print items that are character, create format that can be applied in the macro call. Nonparametric testing is the default.

# Parameters

| Macro variable | Description | Required | Default |
| --- | --- | --- | --- |
| DS | The name of the data set to be analyzed.  Must be a single value | Yes |  |
| ROWVARLIST | Row variables for which descriptive statistics will be computed.  Must be a list of values separated by a single space stored in a global macro variable  E.g. height weight agecat | Yes |  |
| ROWVARFMTLIST | format of variable. both numeric and character formats will work. note: can also use formats such as 5.0 for count data or $ formats for categorical data  numeric can be set to percentn, integer, decimal etc.  Must be a list of values separated by a single space stored in a global macro variable  E.g. 8.0 8.0 agecat. | Yes |  |
| TYPELIST | 1: categorical; 2: continuous  Must be a list of values separated by a single space stored in a global macro variable  E.g. 1 1 2 | Yes |  |
| COMBOFORMAT\_SET | Format of combined variable. applies to categorical variables  1: percent to 1 decimal and 2 spaces between freq and pct;  2: percent to integer with % sign with 2 spaces between freq and pct;  3: percent to 1 decimal with % sign with 2 spaces betweens freq and pct;  4: percent to 1 decimal with one space between freq and pct  Must be a single value | No | 1 |
| TABLENAME\_SET | provide table name to store output from calling the macro.  Must be a single value | No | Table1\_combined |
| ORDER\_SET | Order of categorical variable output  freq for descending frequency; internal for unformatted; external for formatted order data for data order  Must be a single value | No | internal |
| GROUPVAR\_SET | Must be a single value  e.g. arm | No |  |
| GROUPVARFMT\_SET | Must be a single value  e.g. arm. | Yes |  |
| GROUPPERCENT\_SET | Must be a single value  e.g. 1 | Yes | 1 |
| TESTLIST | test for statistical significance  0 = do not test; 1 = test  Must be a list of values separated by a single space stored in a global macro variable  E.g. 1 1 0 | Yes (unless TEST\_SET is defined) |  |
| TEST\_SET | test for statistical significance  0 = do not test; 1 = test  Must be a single value  e.g. 0 | Yes (unless TESTLIST is defined) | 0 |
| INCLUDE\_MISSING\_SET | 1: include missing values; 0: exclude missing values.  default is 1 (include missing)  if missing are excluded, also excludes the following  for character variables: ("-999","999","-888","888","missing","unknown","n/a","na");  for numeric variables: (-999,999,-888,888)  note: if missing values are included, then they are included in the denominator when calculating % for categorical variables.  Must be a single value  e.g. 0 | Yes | 0 |
| CONTCOUNT\_SET | 1: include N for continuous var in category label for non-grouped data or as a secondary row for grouped data. label is not an option for grouped data ; 0: exclude print  note that the frequency will still be included in the output dataset  2: include the N as a secondary row with N= as the variable value  Must be a single value  e.g. 1 | Yes | 1 |
| CONTSTAT\_SET | 1 for median and range in combined var; 2 for median and IQR in combined variable  3 for mean and SD  note that all stats are included in output dataset. this simply refers to combined presentation  Must be a single value  e.g. 1 | Yes | 1 (or anything other than 0 will produce the range) |
| NAMEFORMAT\_SET | give variable format name for dataset  Must be a single value  e.g. $varname. | No | Blank (i.e. no format) |

# Usage Example

\*include utility for MSK template and macros;

FILENAME utility URL "https://raw.githubusercontent.com/MSKCC-Epi-Bio/create\_msk\_SAS\_project/main/utility.sas";

%INCLUDE utility;

**data** mydata;

set "C:\Users\lobaughs\GitHub\SAS\sample\_data.sas7bdat";

**run**;

\* Create formats to use in macro call;

**proc** **format**;

value married **0** = "No "

**1** = "Yes"

**.** = "Missing";

value $varname "age" = "Age "

"parity" = "Parity"

"married" = "Marital status"

"cd4" = "CD4"

"sample\_size" = "Sample size" ;

**run**;

\* Define global macro vars to pass through macro;

%Let myrowvarlist = age parity married cd4;

%Let myrowvarfmtlist = 8.0 8.0 married. 8.0;

%Let mytypelist = 2 2 1 2;

%Let mytestlist = 1 1 0 1;

%***table1\_loop***(ds = mydata,

rowvarlist = &myrowvarlist,

rowvarfmtlist = &myrowvarfmtlist,

typelist = &mytypelist,

comboformat\_set = **1**,

tablename\_set = mydescriptives,

order\_set = internal,

groupvar\_set = arm,

groupvarfmt\_set = $30.,

grouppercent\_set = **1**,

testlist = &mytestlist,

include\_missing\_set = **1**,

contcount\_set = **1**,

contstat\_set = **1**,

nameformat\_set = $varname.);

\* Format table for proc report;

**data** mydescriptives2;

set mydescriptives;

by rowvar\_name notsorted rowvar\_value notsorted;

retain cnt;

retain order **0**;

\* Create variable to use in proc report to make sure the p-value prints with the first row associated with each variable;

if rowvar\_value not in("Median (Range)","Mean (SD)","N Missing","Missing","N =","N Total","Median (IQR)") then do;

if first.rowvar\_name then cnt = **0**;

if first.rowvar\_value then cnt = cnt+**1**;

end;

else do;

if rowvar\_value in("Median (Range)","Mean (SD)","Median (IQR)") then cnt = **1**;

if rowvar\_value = "N =" then cnt = **2**;

if rowvar\_value = "N Total" then cnt = **3**;

if rowvar\_value in("N Missing","Missing") then cnt = **99**;

end;

\* Create variable to use for shading every other row in proc report when presenting results;

rowvar\_value = strip(rowvar\_value);

if first.rowvar\_name then order = order+**1**;

**run**;

\* define an escapechar so that footnotes can be used in proc report;

ods escapechar = "^";

\* Present descriptives using proc report;

**proc** **report** data = mydescriptives2 headline nowindows missing

style(report) = [rules = none frame = void fontfamily = Arial font\_size = **11**pt];

where combo ne "" and rowvar\_value ne "N Total";

Title "Table 1. Patient Characteristics";

column rowvar\_name

cnt

rowvar\_value

("Arm" groupvar\_value),

("N (%)" dummy combo)

("p-value^{super 1}" pvalue)

order;

define rowvar\_name / group order = data '' style = [font\_weight = bold] format = $varname.;

define cnt / group order = data '' noprint;

define rowvar\_value / group order = data '' style = [textalign = right];

define groupvar\_value / across '' order = data;

define dummy / computed noprint;

define combo / display '' style = [textalign = center];

define pvalue / sum '' style = [textalign = right];

define order / group order = data noprint;

compute order;

if mod(order, **2**) gt **0** then call define(\_ROW\_, 'STYLE', 'style = [background = LIGHTGRAY]');

endcomp;

compute after / style = {just = l foreground = black font\_weight = bold bordertopwidth = **1** bordertopcolor = black};

line "1. Statistical tests performed: Kruskal-Wallis test, Fisher's exact test.";

endcomp;

**run**; Title;

# Permission

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

# Log of Updates

| Date | By | Description | Version1 |
| --- | --- | --- | --- |
|  | Stephanie Lobaugh  ([lobaughs@mskcc.org](mailto:lobaughs@mskcc.org)) |  | table1\_loopv1.0 |
|  |  |  |  |
|  |  |  |  |
| 1 Corresponds to GitHub repository tag | | | |