`mesh` fails on quadrilateral mesh

[BambOoxX]

It seems Makie assumes that a mesh should have triangular elements.

On the example below Makie (v0.5.1) works fine with triangular faces.

using GLMakie

u1 = LinRange(0, 2 * pi, 100) .* ones(100)'
v1 = LinRange(0, 2 * pi, 100)' .* ones(100)
u2 = cos.(u1) .* sin.(v1)

nl, nc = size(u1)

vertices = hcat(vec(u1), vec(v1), vec(u2))

v = collect(1:(nl-1))

faces = Matrix{Int64}(undef, (nl - 1) * (nc - 1), 3)
for c in 0:(nc-2)
    for (index, vval) in enumerate(v)
        faces[index+c*(nl-1), :] = [vval vval + 1 vval + nl + 1] .+ c * (nl)
    end
end

msh = mesh(vertices, faces, color = vec(u2), shading = false, axis = (type=Axis3,))
wireframe!(msh.axis, msh.plot[1][], color = :black)

If the triangular faces are replaced with quadrangular ones, Makie fails on a to_triangles. Is there a specific reason why ?
Code with quadrangular faces

using GLMakie

u1 = LinRange(0, 2 * pi, 100) .* ones(100)'
v1 = LinRange(0, 2 * pi, 100)' .* ones(100)
u2 = cos.(u1) .* sin.(v1)

nl, nc = size(u1)

vertices = hcat(vec(u1), vec(v1), vec(u2))

v = collect(1:(nl-1))

faces = Matrix{Int64}(undef, (nl - 1) * (nc - 1), 4)
for c in 0:(nc-2)
    for (index, vval) in enumerate(v)
        faces[index+c*(nl-1), :] = [vval vval + 1 vval + nl + 1 vval + nl] .+ c * (nl)
    end
end

msh = mesh(vertices, faces, color = vec(u2), shading = false, axis = (type=Axis3,))
wireframe!(msh.axis, msh.plot[1][], color = :black)

[SimonDanisch]

This is definitely a case of "didn't get around to fully implement it"...
Meanwhile, you can skip the Makie conversion pipeline and construct a GeometryBasics.Mesh directly:

using GLMakie, GeometryBasics
u1 = LinRange(0, 2 * pi, 100) .* ones(100)'
v1 = LinRange(0, 2 * pi, 100)' .* ones(100)
u2 = cos.(u1) .* sin.(v1)
nl, nc = size(u1)
vertices = Point3f.(vec(u1), vec(v1), vec(u2))
v = collect(1:(nl-1))
faces = Vector{QuadFace{GLIndex}}(undef, (nl - 1) * (nc - 1))
for c in 0:(nc-2)
    for (index, vval) in enumerate(v)
        faces[index+c*(nl-1)] = QuadFace{GLIndex}(vval, vval + 1, vval + nl + 1, vval + nl) .+ c * (nl)
    end
end

m = GeometryBasics.Mesh(vertices, faces)
f, ax, pl = mesh(m, color = vec(u2), shading = false, axis = (type=Axis3,))
wireframe!(ax, m, color = (:black,0.5), transparency=true)
f

[BambOoxX]

Thanks for the help, I'm very new to Makie and GeometryBasics. It works very well.

[ffreyer]

I think this should be relatively easy to add. This hits

Makie.jl/src/conversions.jl

Lines 606 to 628 in 2b5931e

	"""
	convert_arguments(Mesh, vertices, indices)::GLNormalMesh
	Takes `vertices` and `indices`, and creates a triangle mesh out of those.
	See `to_vertices` and `to_triangles` for more information about
	accepted types.
	"""
	function convert_arguments(
	::Type{<:Mesh},
	vertices::AbstractArray,
	indices::AbstractArray
	)
	vs = to_vertices(vertices)
	fs = to_triangles(indices)
	if eltype(vs) <: Point{3}
	ns = Vec3f.(normals(vs, fs))
	m = GeometryBasics.Mesh(meta(vs; normals=ns), fs)
	else
	# TODO, we don't need to add normals here, but maybe nice for type stability?
	m = GeometryBasics.Mesh(meta(vs; normals=fill(Vec3f(0, 0, 1), length(vs))), fs)
	end
	return (m,)
	end

and then

Makie.jl/src/conversions.jl

Lines 784 to 789 in 2b5931e

	function to_triangles(faces::AbstractMatrix{T}) where T <: Integer
	@assert size(faces, 2) == 3
	return broadcast(1:size(faces, 1), 3) do fidx, n
	GLTriangleFace(ntuple(i-> faces[fidx, i], n))
	end
	end

which would just need to create a QuadFace or two GLTriangleFaces instead. (I wouldn't bother generalizing this further. Quads are common, larger Polygons are not)