coloring issue with poly!() - attempt to implement drawing (filled) contours on triangulated pointlists

[thomvet]

Tried to implement the functionality to draw contours on list of points that do not necessarily belong to a structured grid, but have issues with coloring filled contours. It works fine when I just cycle through the colors, but when I try to actually give the correct colors to poly!(), it just fails for some reason.

Related discourse thread: https://discourse.julialang.org/t/makie-tricontourf-from-matplotlib-in-makie/77685/10

Below is a MWE illustrating the issue on a very simple dataset:

using TriplotBase, Triangulate, GLMakie, ColorSchemes

function append_with_nan!(a,b)
    append!(a,b)
    push!(a,NaN)
end

conttype(contour::TriplotBase.Contour{T}) where {T} = T
#create some data
x = [0.0, 0.5, 1.0, 0.25, 0.75, 0.5]
y = sqrt(3)/2*[0.0, 0.0, 0.0, 0.5, 0.5, 1.0]
z = [0.0, 0.0, 0.0, 1.0, 0.75, 0.75]

#figure and axes
fighandle = Figure(resolution = (900, 900))
ax2 = Axis(fighandle[1, 1], aspect = AxisAspect(2/sqrt(3)))
ax3 = Axis(fighandle[1, 2], aspect = AxisAspect(2/sqrt(3)))
ax4 = Axis(fighandle[2, 1], aspect = AxisAspect(2/sqrt(3)))
ax5 = Axis(fighandle[2, 2], aspect = AxisAspect(2/sqrt(3)))

#trianulate datapoints
triin=Triangulate.TriangulateIO()
triin.pointlist=[x'; y']
(triout, vorout) = triangulate("Q", triin)
trianglelist = triout.trianglelist

#contours
contours = TriplotBase.tricontour(x, y, z, trianglelist, 15)
filledcontours = TriplotBase.tricontourf(x, y, z, trianglelist, 15)

#plot the contours in ax2 (code adapted to Makie.jl from TriplotRecipes.jl (which is for Plots.jl))
for contour=contours
    T = conttype(contour)
    xs = T[]
    ys = T[]
    zs = T[]
    for polyline=contour.polylines
        append_with_nan!(xs,first.(polyline))
        append_with_nan!(ys,last.(polyline))
        append!(zs,fill(contour.level,length(polyline)))
    end
    if !isempty(zs)
        lines!(ax2, xs, ys, color = zs, colorrange = (0.0, 1.0), colormap = :magma)
    end
end

#try getting filled contours into ax3 (code adapted to Makie.jl from TriplotGR.jl) - works, but just with cycled colors.
for filledcontour = filledcontours
    for polyline=filledcontour.polylines
        points = similar(polyline, Point2f) #this is probably horrible Julia, but it works for now.
        for i in axes(polyline)
            points[i] = polyline[i]
        end
        poly!(ax3, points)
    end
end

#try getting filled contours into ax4 (code adapted to Makie.jl from TriplotGR.jl) - try coloring contours properly by specifying color, colorrange and colormap.
#--> results in an empty plot
lmin,lmax = extrema(getfield.(filledcontours,:lower))
for filledcontour = filledcontours
    for polyline=filledcontour.polylines
        points = similar(polyline, Point2f) #this is probably horrible Julia, but it works for now.
        for i in axes(polyline)
            points[i] = polyline[i]
        end
        poly!(ax4, points, color = filledcontour.lower, colorrange = (lmin, lmax), colormap = :magma)
    end
end

#try getting filled contours into ax5 (code adapted to Makie.jl from TriplotGR.jl) - try coloring contours by specifying colors directly
#--> results in just one contour shown with one color - why?
colors = colorschemes[:magma]
lmin,lmax = extrema(getfield.(filledcontours,:lower))
for filledcontour = filledcontours
    for polyline=filledcontour.polylines
        points = similar(polyline, Point2f) #this is probably horrible Julia, but it works for now.
        for i in axes(polyline)
            points[i] = polyline[i]
        end
        poly!(ax5, points, color = colors[div(255*filledcontour.lower-lmin,lmax-lmin)+1])
    end
end

Results in the following output:

[SimonDanisch]

Is this really an MWE?^^
Could this be reduced to 1-2 lines?

[jkrumbiegel]

This worked for me:

x = [0.0, 0.5, 1.0, 0.25, 0.75, 0.5]
y = sqrt(3)/2*[0.0, 0.0, 0.0, 0.5, 0.5, 1.0]
z = [0.0, 0.0, 0.0, 1.0, 0.75, 0.75]

triin=Triangulate.TriangulateIO()
triin.pointlist=[x'; y']
(triout, vorout) = triangulate("Q", triin)
trianglelist = triout.trianglelist

filledcontours = TriplotBase.tricontourf(x, y, z, trianglelist, 15)

polys = map(filledcontours) do fc
    pointvecs = map(fc.polylines) do vecs
        map(vecs) do tupl
            Point2f(tupl...)
        end
    end
    Makie.Polygon(pointvecs[1], pointvecs[2:end]...)
end

poly(polys, color = 1:length(polys))

However, I haven't bothered to choose the colors correctly.

[thomvet]

I can confirm that this also works for me and this is a solution to my problem! Thanks a lot. For completeness, adjusting the colors can be done via (hard-coding Float64 for the levels here, but can be adapted of course):

x = [0.0, 0.5, 1.0, 0.25, 0.75, 0.5]
y = sqrt(3)/2*[0.0, 0.0, 0.0, 0.5, 0.5, 1.0]
z = [0.0, 0.0, 0.0, 1.0, 0.75, 0.75]

triin=Triangulate.TriangulateIO()
triin.pointlist=[x'; y']
(triout, vorout) = triangulate("Q", triin)
trianglelist = triout.trianglelist

filledcontours = TriplotBase.tricontourf(x, y, z, trianglelist, 15)

levels = Float64[]
polys = map(filledcontours) do fc
    pointvecs = map(fc.polylines) do vecs
        map(vecs) do tupl
            Point2f(tupl...)
        end
    end
    push!(levels, fc.lower)
    Makie.Polygon(pointvecs[1], pointvecs[2:end]...)
end

poly(polys, color = levels)

What confuses me is that I cannot plot a single polygon and specify the color of it in this way. For example, replacing your last line with:
poly(polys[1], color = 1)

Results simply in an empty plot. Is this the intended behavior?

[jkrumbiegel]

You can't use an integer as a color I think, as in "the nth color of a colormap". You can look at the code for contourf where I also had to do some contortions for coloring if I remember correctly

[ffreyer]

Closing as solved