Inspector + line label

[lungd]

Is it currently possible to create an Inspector displaying not only x/y coordinates but also some attributes of an element, e.g. the label of a line?

[ffreyer]

Not in a nice way.

You could replace the show_data method for lines
https://github.com/JuliaPlots/Makie.jl/blob/406978c89ad8ae5fb7ac294bd2fd34745bd5844c/src/interaction/inspector.jl#L607-L627
and adjust a._display_text[] to include the things you want.

[lungd]

Here's my current implementation for displaying the labels. It's not perfect and probably contains some bugs but it seems to fulfill my needs and maybe someone will find it useful.

using GLMakie
GLMakie.activate!();
using Printf
using DataInterpolations

function GLMakie.Makie.show_data(inspector::GLMakie.Makie.DataInspector, plot::Union{GLMakie.Makie.Lines,GLMakie.Makie.LineSegments}, idx)
  a = inspector.plot.attributes
  scene = GLMakie.Makie.parent_scene(plot)

  # cast ray from cursor into screen, find closest point to line
  p0, p1 = plot[1][][idx-1:idx]
  origin, dir = GLMakie.Makie.view_ray(scene)
  pos = GLMakie.Makie.closest_point_on_line(p0, p1, origin, dir)
  lw = plot.linewidth[] isa Vector ? plot.linewidth[][idx] : plot.linewidth[]

  #@show origin
  #@show pos
  proj_pos = GLMakie.Makie.shift_project(scene, plot, to_ndim(Point3f, pos, 0))
  GLMakie.Makie.update_tooltip_alignment!(inspector, proj_pos)

  label = get_closest_line_label(scene, pos)
  p = typeof(p0)(pos)
  a._display_text[] = @sprintf("%s\nx: %0.6f\ny: %0.6f", label, p[1], p[2])
  a._bbox2D[] = GLMakie.Makie.Rect2f(proj_pos .- 0.5 .* lw .- GLMakie.Makie.Vec2f(5), GLMakie.Makie.Vec2f(lw) .+ GLMakie.Makie.Vec2f(10))
  a._px_bbox_visible[] = true
  a._bbox_visible[] = false
  a._visible[] = true

  return true
end


function get_closest_line_label(scene, pos)
  label = "-"
  x, y = pos[1], pos[2]
  idx = round(Int, x)
  diff = Inf
  for pl in scene.plots
    !(pl isa GLMakie.Lines) && continue
    !hasproperty(pl, :converted) && continue
    vals = pl.converted[1].val
    length(vals) < idx && continue
    liney = vals[idx][2]
    if x isa AbstractFloat && (x % trunc(Int, x)) != 0
      x1 = floor(Int, x)
      x2 = ceil(Int, x)
      interp = DataInterpolations.LinearInterpolation([vals[x1], vals[x2]], [x1, x2])
      yinterp = interp(x)[2]
      new_diff = abs(yinterp - y)
      if new_diff < diff
        label = pl.label.val
        diff = new_diff
      end
    else
      new_diff = abs(liney - y)
      if new_diff < diff
        label = pl.label.val
        diff = new_diff
      end
    end
  end
  return label
end

data = rand(10, 100)
fig = GLMakie.Figure()
ax = Axis(fig[1, 1])
for i in 1:size(data, 1)
  lines!(data[i, :], label = "data[$(i),:]")
end
DataInspector(ax)
display(fig)