DataInspector does not work for lines in log10 scale

[mgyoo86]

I am new to Julia and GLMakie and found some bugs in using DataInsepctor with log10 scales.
I guess this bug is strongly related to #3450 and #3526.

• Version Info: GLMakie v0.9.6 has a bug, whereas GLMakie v0.8.12 works correctly.
• Platform: Mac M1
• The bug is reproducible with a fresh start
• The following code is a simple example where the DataInspector gave wrong results in the case of log10 scale.

using GLMakie
fig = Figure()
ax = Axis(fig[1, 1], yscale=log10,xscale=log10)
x = 10.0.^vec(-2:2)
lines!(ax,x,10*x)
DataInspector(fig)
fig

The latest version (v0.9.6) and GitHub branches ("master" and "ff/DataInspector_transform_fixes") have been tested and all cases gave the same error of wrong location of the datatip as shown in the image below.
Furthermore, when the cursor hovers on datapoint smaller than one (x<10^0 or y<10^0), then the following error occurs.
Error in callback:
DomainError with -0.607352:
log10 was called with a negative real argument but will only return a complex result if called with a complex argument. Try log10(Complex(x)).

On the other hand, some older version (I've tested GLMakie v0.8.12) gives the correct location of dataip and works fine for (datapoint <1) without the callback error.

It would be greatly appreciated if there is a workaround for this issue.

[mgyoo86]

I found a simple workaround by overriding the "show_data" method for Line plots as follows:

function Makie.show_data(inspector::DataInspector, plot::Union{Lines, LineSegments}, idx)
   # Inner function to calculate the real value considering the scale of the axis
   a = inspector.attributes
   tt = inspector.plot
   scene = Makie.parent_scene(plot)

   # cast ray from cursor into screen, find closest point to line
   pos = Makie.position_on_plot(plot, idx, apply_transform = false)

   # Convert wrong "pos" to real "pos" values
   INVERSE_TRANSFORMS = Dict(
      identity => (x -> x),
      log => exp,
      log2 => (x -> 2.0 .^ x),
      log10 => (x -> 10.0 .^ x),
      sqrt => (x -> x .^ 2.0)
   )
   trans_func = Makie.transform_func(plot)
   xval = INVERSE_TRANSFORMS[trans_func[1]](pos[1])
   yval = INVERSE_TRANSFORMS[trans_func[2]](pos[2])
   pos = Point3f(xval,yval,pos[3])

   proj_pos = Makie.shift_project(scene, Makie.apply_transform_and_model(plot, pos))
   Makie.update_tooltip_alignment!(inspector, proj_pos)

   tt.offset[] = ifelse(
       a.apply_tooltip_offset[],
       Makie.sv_getindex(plot.linewidth[], idx) + 2,
       a.offset[]
   )

   if haskey(plot, :inspector_label)
       tt.text[] = plot[:inspector_label][](plot, idx, eltype(plot[1][])(pos))
   else
       tt.text[] = Makie.position2string(eltype(plot[1][])(pos))
   end
   tt.visible[] = true
   a.indicator_visible[] && (a.indicator_visible[] = false)

   return true
end

Following is the example of using the modified "show_data" method.
It works well with lines! and scatterlines!, showing the real positional values.

Since I am a newbie to Julia and its ecosystem,
I believe there must be a nicer and safer way to handle this.
Any input or help would be greatly appreciated.

[ffreyer]

Makie.jl/src/interaction/ray_casting.jl

Lines 253 to 269 in 6bba224

	function position_on_plot(plot::Union{Lines, LineSegments}, idx, ray::Ray; apply_transform = true)
	if idx == 1
	idx = 2
	end
	p0, p1 = apply_transform_and_model(plot, plot[1][][(idx-1):idx])
	pos = closest_point_on_line(p0, p1, ray)
	if apply_transform
	return pos
	else
	p4d = inv(plot.model[]) * to_ndim(Point4f, pos, 1f0)
	p3d = p4d[Vec(1, 2, 3)] / p4d[4]
	itf = inverse_transform(transform_func(plot))
	return Makie.apply_transform(itf, p3d, get(plot, :space, :data))
	end
	end

This should already be doing the inverse transform that you added if apply_transform == false.

[mgyoo86]

@ffreyer Thanks for the information.
I think I have found the reason why apply_transform == false is not working correctly.

In the case of apply_transform == false, the following line does not return "inverse-transformed" data as intended.

return Makie.apply_transform(itf, p3d, get(plot, :space, :data)) 

The Makie.apply_transform function returns the original data without the inverse transformation,
because get(plot, :space, :data) returns Observable{Any}(:data) and the following ternary operator in apply_transform space ===:data becomes false, returning original data.

Makie.jl/src/layouting/transformation.jl

Line 213 in 6b7377b

apply_transform(f, data, space) = space === :data ? apply_transform(f, data) : data

I've checked that adding the following more concrete version of apply_transformation for the Observable type of space can make lines! and scatterlines! work correctly for any scales including the log10.

Makie.apply_transform(f, data, space::Observable) = (space[] === :data) ? Makie.apply_transform(f, data) : data