`xticks` is ignored with unit aware axes

[nilshg]

scatter(rand(Date(2000):Day(1):Date(2001), 100), rand(100); axis = (; xticks = Date(2000):Month(3):Date(2001)))

will not change the xticks at all - it appears that the argument is completely ignored (even feeding in obvious nonsense does not yield errors, the plot simply remains unchanged).

[jariji]

Related failure with units:

using CairoMakie, Unitful

julia> let x = rand(50)u"yr"
           hist(x; axis=(;xticks=(0:.1:1)u"yr"))
       end
ERROR: DimensionError:  and yr are not dimensionally compatible.

[nilshg]

Turns out this is too complicated for me to address properly, but for anyone coming across this here's a monkey patch that at least makes it possible to pass xticks and xtickformat kwargs in the axis keyword for plotting functions.

import GLMakie.Makie as Mke
import GLMakie.Makie.get_ticks

function get_ticks(conversion::Mke.DateTimeConversion, ticks, scale, formatter, vmin, vmax)

    if scale != identity
        error("$(scale) scale not supported for DateTimeConversion")
    end
    T = conversion.type[]
    # When automatic, we haven't actually plotted anything yet, so no unit chosen
    # in that case, we can't really have any conversion
    T <: Mke.Automatic && return [], []

    if in((Date, DateTime))(eltype(ticks))
        tickformatter = formatter == Mke.MakieCore.Automatic() ? identity : formatter
        return Dates.value.(ticks), string.(tickformatter.(ticks))
    end

    if T <: DateTime 
        if ticks isa WilkinsonTicks
            k_min = ticks.k_min
            k_max = ticks.k_max
        else
            k_min = 2
            k_max = 3
        end
        conversion, dates = PlotUtils.optimize_datetime_ticks(vmin, vmax; k_min=k_min, k_max=k_max)
        return conversion, dates
    else
        # TODO implement proper ticks for Time Date
        tickvalues = Mke.get_tickvalues(formatter, scale, vmin, vmax)
        dates = Mke.number_to_date.(T, round.(Int64, tickvalues))
        return tickvalues, string.(dates)
    end
end

You'll have to adapt the first couple of lines to your backend. Note that for some reason this doesn't seem to work when building up plots like

f = Figure()
ax1 = Axis(f[1, 1], xlabel = "Month")
lines!(ax1, x, y, axis = (; xticks = some_date_ticks))

[kongdd]

Another short script to reoccur this issue:

using GLMakie, Makie, Dates

x = DateTime(2019):Day(1):DateTime(2020)
y = rand(length(x));

_xticks = DateTime.(2019, [1, 3, 6, 9, 12.0], 1)
_xticklabels = Dates.format.(_xticks, "mm-dd")
xticks = Makie.date_to_number.(_xticks), _xticklabels

fig = Figure()
ax = Axis(fig[1, 1]; xticks)
lines!(ax, x, y)
fig

[briochemc]

Any workaround for building up plots with Axis called first?

[nilshg]

The workaround is to take my workaround from above and finish the work to turn it into a proper PR :)

[jkrumbiegel]

I have some substantial refactor of the date ticks on a branch somewhere. It's not really a quick fix

[briochemc]

The workaround is to take my workaround from above and finish the work to turn it into a proper PR :)

@nilshg I'll admit I didn't try it but I thought you were saying that your workaround would not work in this case:

Note that for some reason this doesn't seem to work when building up plots like

f = Figure()
ax1 = Axis(f[1, 1], xlabel = "Month")
lines!(ax1, x, y, axis = (; xticks = some_date_ticks))

[briochemc]

I have some substantial refactor of the date ticks on a branch somewhere. It's not really a quick fix

@jkrumbiegel Thank you so much for all the features you keep adding! Just my 50c suggestion for that branch and possibly a more generic feature request. One nice option for such date-type axes would be to allow for labels to be placed between ticks. One image is worth many words so this is what I mean:

code

using CairoMakie, Dates, DateFormats
# Some data
x = Date(1999, 9, 15):Month(3):Date(2003, 8, 15) |> collect
xdec = yeardecimal.(x)
y = rand(length(x))# + 0.1randn(size(xA))
# some options
backgroundcolor = "#f5f6fa"
options = (
    titlealign = :left,
    topspinevisible = false,
    leftspinevisible = false,
    rightspinevisible = false,
    bottomspinevisible = false,
)
# start figure
f = Figure(; size = (500, 600), fontsize = 18, backgroundcolor)
# top panel
xticks = Date(2000, 1, 1):Month(12):x[end]
xticks = yeardecimal.(xticks)
color = :tomato
ax = Axis(f[1,1]; options..., xticks, title = rich(rich("Ambiguous ticks..."; color), " At the start or middle of the year?"), xticklabelcolor = color)
lines!(ax, xdec, y; color = :gray)
hideydecorations!(ax)
# middle panel
xticks = Date(2000, 1, 1):Month(12):x[end]
xticks = (yeardecimal.(xticks), string.(xticks))
color = "#EB9C0A"
ax = Axis(f[2,1]; options..., xticks, title = rich(rich("Full date"; color), " is less ambiguous ", rich("but too cluttered..."; color)), xticklabelcolor = color)
lines!(ax, xdec, y; color = :gray)
hideydecorations!(ax)
# bottom panel
xticks = Date(2000, 1, 1):Year(1):x[end]
xticks = yeardecimal.(xticks)
xticks = (xticks, fill("", length(xticks)))
color = "#499167"
ax = Axis(f[3,1]; options..., xticks, title = rich("Best is to label ", rich("between ticks!"; color)))
lines!(ax, xdec, y; color = :gray)
hideydecorations!(ax)
xticks = Date(2000, 7, 1):Year(1):x[end]
xticks = yeardecimal.(xticks)
xticks = (xticks, string.(round.(Int, floor.(xticks))))
ax2 = Axis(f[3,1]; options..., xticks, xticklabelcolor = color, xticksize = 0, xgridvisible = false)
linkaxes!(ax, ax2)
hidespines!(ax2)
hideydecorations!(ax2)
rowgap!(f.layout, 40)

Here this was done by adding a second axis with zero-length ticks, but maybe this can be made a generic option? Maybe with some kwarg like betweenticklabels?

[asinghvi17]

In that last case you can use minorticks for the grid lines and make major ticks invisible. No need for hacks - and you can build this into the theme as well

julia> f, a, p = lines(rand(10))

julia> a.xminorgridvisible = true
true

julia> a.xminorticksvisible = true
true

julia> a.xticksvisible = false
false

julia> a.xgridvisible = false
false

julia> a.xminorgridcolor[] = (:black, 0.2)
(:black, 0.2)