KARLOFF → MAIN FUNC?

MAIN → "void" "main" "(" ")" "{" VARDECL SEQCOMANDOS "}"

VARDECL → VARDECL’

VARDECL’ → "newVar" TIPO TOKEN\_id ";" VARDECL’ | vazio

TIPO → "integer" | "bool"

SEQCOMANDOS → SEQCOMANDOS’

SEQCOMANDOS’ → COMANDO SEQCOMANDOS’ | vazio

COMANDO → TOKEN\_id COMANDO’

| "if" "(" EXP ")" "then" "{" SEQCOMANDOS "}" ";"

| "while" "(" EXP ")" "{" SEQCOMANDOS "}" ";"

| "repeat" "{" SEQCOMANDOS "}" "until" "(" EXP ")" ";"

| "return" EXP ";"

| "System.output" "(" EXP ")" ";"

COMANDO’ → "=" COMANDO’’ | "(" LISTAEXP? ")" ";"

COMANDO’’ → EXP ";" | "System.readint" "(" ")" ";"

EXP → "(" EXP OP EXP ")" | FATOR

FATOR → TOKEN\_id FATOR’| TOKEN\_numliteral | "true" | "false"

FATOR’ → "(" LISTAEXP? ")" | vazio

OP → "+" | "-" | "\*" | "/" | "&" | "|" | "<" | ">" | "=="

LISTAEXP → EXP LISTAEXP’

LISTAEXP’ → "," EXP LISTAEXP’ | vazio

FUNC → "func" TIPO TOKEN\_id "(" LISTAARG? ")" "{" VARDECL SEQCOMANDOS "}" FUNC’

FUNC’ → “func" TIPO TOKEN\_id "(" LISTAARG? ")" "{" VARDECL SEQCOMANDOS "}" FUNC’

| vazio

LISTAARG → TIPO TOKEN\_id LISTAARG’

LISTAARG’ → "," TIPO TOKEN\_id LISTAARG’ | vazio