-
Notifications
You must be signed in to change notification settings - Fork 33
/
GView.mm
1715 lines (1419 loc) · 52.8 KB
/
GView.mm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// GView.mm
// this file is part of Context Free
// ---------------------
// Copyright (C) 2005-2007 Mark Lentczner - markl@glyphic.com
// Copyright (C) 2007-2013 John Horigan - john@glyphic.com
//
// This program is free software; you can redistribute it and/or
// modify it under the terms of the GNU General Public License
// as published by the Free Software Foundation; either version 2
// of the License, or (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
//
// John Horigan can be contacted at john@glyphic.com or at
// John Horigan, 1209 Villa St., Mountain View, CA 94041-1123, USA
//
// Mark Lentczner can be contacted at markl@glyphic.com or at
// Mark Lentczner, 1209 Villa St., Mountain View, CA 94041-1123, USA
//
//
#import "GView.h"
#import "CFDGDocument.h"
#import "VariationFormatter.h"
#import "TopBar.h"
#import "BitmapImageHolder.h"
#include "cfdg.h"
#include "SVGCanvas.h"
#include "ImageCanvas.h"
#include "AVcanvas.h"
#include "tiledCanvas.h"
#include "Rand64.h"
#include <tgmath.h>
#include <tempfile.h>
using cfdg_ptr = std::shared_ptr<CFDG>;
using renderer_ptr = std::unique_ptr<Renderer>;
using canvas_ptr = std::unique_ptr<Canvas>;
using tempfile_ptr = std::unique_ptr<TempFile>;
//#define PROGRESS_ANIMATE_DIRECTLY
//#define USE_SAVE_GRAPHICS_STATE
//#define TIME_AND_LOG_RENDER
#define UPDATE_RATE (1.0/12.0)
#define PROGRESS_DELAY 12
@interface BitmapAndFormat : BitmapImageHolder {
aggCanvas::PixelFormat _aggPixFmt;
}
- (id) initWithAggPixFmt: (aggCanvas::PixelFormat)fmt
pixelsWide: (NSInteger)width
pixelsHigh: (NSInteger)height;
- (aggCanvas::PixelFormat) aggPixelFormat;
@end
@implementation BitmapAndFormat
- (id) initWithAggPixFmt: (aggCanvas::PixelFormat)fmt
pixelsWide: (NSInteger)width
pixelsHigh: (NSInteger)height
{
int bps = (fmt & aggCanvas::Has_16bit_Color) + 8;
switch (fmt) {
case aggCanvas::RGBA8_Blend:
case aggCanvas::AV_Blend:
case aggCanvas::RGBA16_Blend:
self = [super initWithBitmapDataPlanes: nullptr
pixelsWide: width
pixelsHigh: height
bitsPerSample: bps
samplesPerPixel: 4
hasAlpha: YES isPlanar: NO
colorSpaceName: NSCalibratedRGBColorSpace
bytesPerRow: 0 bitsPerPixel: 0];
break;
case aggCanvas::RGB8_Blend:
case aggCanvas::RGB16_Blend:
self = [super initWithBitmapDataPlanes: nullptr
pixelsWide: width
pixelsHigh: height
bitsPerSample: bps
samplesPerPixel: 3
hasAlpha: NO isPlanar: NO
colorSpaceName: NSCalibratedRGBColorSpace
bytesPerRow: 0 bitsPerPixel: 0];
break;
case aggCanvas::Gray8_Blend:
case aggCanvas::Gray16_Blend:
self = [super initWithBitmapDataPlanes: nullptr
pixelsWide: width
pixelsHigh: height
bitsPerSample: bps
samplesPerPixel: 1
hasAlpha: NO isPlanar: NO
colorSpaceName: NSCalibratedWhiteColorSpace
bytesPerRow: 0 bitsPerPixel: 0];
break;
default:
return nil;
}
if (!self) return self;
_aggPixFmt = fmt;
return self;
}
- (aggCanvas::PixelFormat) aggPixelFormat { return _aggPixFmt; }
@end
@interface GView () {
cfdg_ptr mEngine;
renderer_ptr mRenderer;
canvas_ptr mCanvas;
tempfile_ptr mMovieFile;
BitmapAndFormat* mRenderBitmap; // this bitmap must never be drawn
}
@end
@interface GView (internal)
- (void)drawCheckerboardRect:(NSRect)rect;
- (void)buildEngine;
- (void)buildRendererSize:(NSSize)size minimum:(double)minSize;
- (void)buildImageCanvasSize;
- (void)invalidateDrawingImage;
- (bool)validateDrawingImage;
- (void)noteProgress;
- (void)requestRenderUpdate;
- (void)setupPlayer:(NSURL*)movie;
- (void)tearDownPlayer;
- (void)stopLoadingAnimationAndHandleError:(NSError *)error;
- (bool)setupTimeSlider:(AVPlayerItem*)playerItem;
- (void)setUpPlaybackOfAsset:(AVURLAsset *)asset withKeys:(NSArray *)keys;
- (void)showSavePanelTitle:(NSString *)title
fileType:(NSArray *)fileType
accessoryView:(NSView *)view
didEndSelector:(SEL)selector;
- (void)saveImagetoFile:(NSURL*)filename;
- (void)saveTileImagetoFile:(NSURL*)filename;
- (void)saveSvgtoFile:(NSURL*)filename;
- (void)saveMovietoFile:(NSURL*)filename;
- (void)deleteRenderer;
+ (void)rendererDeleteThread:(id)arg;
@end
NSString* PrefKeyMovieZoom = @"MovieZoom";
NSString* PrefKeyMovieLength = @"MovieLength";
NSString* PrefKeyMovieFrameRate = @"MovieFrameRate";
NSString* PrefKeyMovieFormat = @"MovieFormat";
namespace {
NSURL* saveImageDirectory = nil;
void* ItemStatusContext = &ItemStatusContext;
void* LayerStatusContext = &LayerStatusContext;
void* ItemDurationContext = &ItemDurationContext;
NSImage* PlayNormalImage = nil;
NSImage* PlayPressImage = nil;
NSImage* PauseNormalImage = nil;
NSImage* PausePressImage = nil;
class RenderParameters
{
public:
bool render;
bool periodicUpdate;
bool animate;
bool animateZoom;
int animateFrameCount;
int animateFrame;
RenderParameters()
: render(true), periodicUpdate(true), animate(false)
{ }
};
NSArray* ActionStrings = @[@"Stop", @"Render", @"Animate", @"Frame"];
}
@interface GView (renderThread)
- (void) renderBegin:(RenderParameters*)parameters;
- (void) renderThread:(id)arg;
- (void) renderStopped:(id)arg; // sent by thread
@end
@implementation GView
+ (void)initialize {
if (self == [GView self]) {
PlayNormalImage = [[NSImage imageNamed:@"RemotePlay_norm.tif.icns"] retain];
PlayPressImage = [[NSImage imageNamed:@"RemotePlay_press.tif.icns"] retain];
PauseNormalImage = [[NSImage imageNamed:@"RemotePause_norm.tif.icns"] retain];
PausePressImage = [[NSImage imageNamed:@"RemotePause_press.tif.icns"] retain];
}
}
- (id)initWithFrame:(NSRect)frame
{
self = [super initWithFrame:frame];
if (self) {
mRenderBitmap = nil;
mDrawingImage = nil;
mRestartRenderer = false;
mUpdateTimer = nil;
mRendering = false;
mRestartRenderer = false;
mRendererFinishing = false;
mRendererStopping = false;
mLastRenderWasHires = false;
mCloseOnRenderStopped = false;
mCurrentVariation = 0;
mIncrementVariationOnRender = false;
mTiled = false;
mFullScreenMenu = nil;
}
return self;
}
- (void)awakeFromNib
{
[super awakeFromNib];
[mSaveImageAccessory retain];
[mSaveTileAccessory retain];
[mSaveAnimationAccessory retain];
[mDocument retain];
[self initializeVariation];
NSNumber* one = [NSNumber numberWithInt: 1];
NSNumber* hundred = [NSNumber numberWithInt: 100];
NSNumberFormatter* fmt = [mSaveTileWidth formatter];
[fmt setMinimum: one];
[fmt setMaximum: hundred];
fmt = [mSaveTileHeight formatter];
[fmt setMinimum: one];
[fmt setMaximum: hundred];
[mSaveTileWidth setFloatValue: 1.0];
[mSaveTileHeight setFloatValue: 1.0];
NSWindow* window = [self window];
if ([window respondsToSelector:@selector(toggleFullScreen:)]) {
NSWindowCollectionBehavior behavior = [window collectionBehavior];
behavior |= NSWindowCollectionBehaviorFullScreenPrimary;
[window setCollectionBehavior:behavior];
NSButton* fullscreenButton =
[window standardWindowButton:NSWindowFullScreenButton];
[fullscreenButton setAction:@selector(enterFullscreen:)];
[fullscreenButton setTarget:self];
NSMenuItem* winMenu = [[NSApp mainMenu] itemWithTitle: @"Window"];
mFullScreenMenu = [[winMenu submenu] itemWithTag: (NSInteger)420];
}
[window setDelegate: self];
mCurrentAction = ActionType::RenderAction;
mLastAnimateFrame = 1.0;
self.wantsLayer = YES;
}
- (void)windowDidBecomeMain:(NSNotification *)notification
{
[self updateFullScreenMenu];
}
- (void)windowDidEnterFullScreen:(NSNotification *)notification
{
[self updateFullScreenMenu];
}
- (void)windowDidExitFullScreen:(NSNotification *)notification
{
[self updateFullScreenMenu];
}
- (BOOL)windowShouldClose:(id)sender
{
[self tearDownPlayer];
if (mRendering && mRenderer) {
mRenderer->requestStop = true;
mCloseOnRenderStopped = true;
return NO;
}
return YES;
}
- (void)windowWillClose:(NSNotification *)notification
{
[self tearDownPlayer];
[self deleteRenderer];
}
- (void)updateFullScreenMenu
{
NSUInteger masks = [[self window] styleMask];
if (masks & NSFullScreenWindowMask) {
[mFullScreenMenu setTitle: @"Exit Full Screen"];
} else {
[mFullScreenMenu setTitle: @"Enter Full Screen"];
}
}
- (void)dealloc
{
[self tearDownPlayer];
[self deleteRenderer];
[mDocument release]; mDocument = nil;
[mDrawingImage release]; mDrawingImage = nil;
[mRenderBitmap release]; mRenderBitmap = nil;
[mUpdateTimer release]; mUpdateTimer = nil;
[mSaveImageAccessory release]; mSaveImageAccessory = nil;
[mSaveTileAccessory release]; mSaveTileAccessory = nil;
[mSaveAnimationAccessory release]; mSaveAnimationAccessory = nil;
[super dealloc];
}
- (IBAction)enterFullscreen:(id)sender
{
[[self window] toggleFullScreen: nil];
}
- (BOOL)isOpaque
{
return YES;
}
- (void)observeValueForKeyPath:(NSString *)keyPath ofObject:(id)object
change:(NSDictionary *)change context:(void *)context
{
if (context == ItemDurationContext) {
AVPlayerItem* playerItem = (AVPlayerItem*)object;
dispatch_async(dispatch_get_main_queue(),
^{
[self setupTimeSlider: playerItem];
});
return;
}
if (context == ItemStatusContext) {
AVPlayerItem* playerItem = (AVPlayerItem*)object;
dispatch_async(dispatch_get_main_queue(),
^{
AVPlayerItemStatus stat = [playerItem status];
if (stat == AVPlayerItemStatusReadyToPlay &&
[mMoviePlayerLayer isReadyForDisplay])
{
[mMovieControls setHidden: NO];
[mStatus setHidden: YES];
}
if (stat == AVPlayerItemStatusFailed) {
[self stopLoadingAnimationAndHandleError: [playerItem error]];
}
});
return;
}
if (context == LayerStatusContext) {
AVPlayerLayer* playerLayer = (AVPlayerLayer*)object;
dispatch_async(dispatch_get_main_queue(),
^{
AVPlayerItemStatus stat = [[[playerLayer player] currentItem] status];
if (stat == AVPlayerItemStatusReadyToPlay &&
[playerLayer isReadyForDisplay])
{
[mMovieControls setHidden: NO];
[mStatus setHidden: YES];
}
});
return;
}
[super observeValueForKeyPath:keyPath ofObject:object
change:change context:context];
}
- (IBAction) toggleMovieStartStop:(id)sender
{
if ([mMoviePlayer rate] == 0.0f) {
if (mAtEndofMovie)
[mMoviePlayer seekToTime: kCMTimeZero];
[mMoviePlayer play];
mAtEndofMovie = false;
mStartStopButton.image = PauseNormalImage;
mStartStopButton.alternateImage = PausePressImage;
} else {
[mMoviePlayer pause];
mStartStopButton.image = PlayNormalImage;
mStartStopButton.alternateImage = PlayPressImage;
}
}
- (IBAction) movieRewind:(id)sender
{
[mMoviePlayer seekToTime: kCMTimeZero];
mAtEndofMovie = false;
}
- (IBAction) movieTimeChange:(id)sender
{
auto scale = mMoviePlayer.currentItem.duration.timescale;
double time = [mTimeSlider doubleValue];
CMTime t = CMTimeMakeWithSeconds(time, scale);
[mMoviePlayer seekToTime:t toleranceBefore:kCMTimeZero toleranceAfter:kCMTimeZero];
}
- (void)drawRect:(NSRect)rect
{
if (mMoviePlayer || ![self validateDrawingImage]) {
[[NSColor whiteColor] set];
[NSBezierPath fillRect: rect];
return;
}
agg::rgba backgroundColor(1.0, 1.0, 1.0, 1.0);
if (mEngine && mRenderer)
backgroundColor = mEngine->getBackgroundColor();
if (backgroundColor.opacity() < 1.0) {
[self drawCheckerboardRect: rect];
}
[[NSColor colorWithCalibratedRed: backgroundColor.r
green: backgroundColor.g
blue: backgroundColor.b
alpha: backgroundColor.a ] set];
[NSBezierPath fillRect: rect];
NSGraphicsContext* ctx = [NSGraphicsContext currentContext];
NSImageInterpolation oldInterp = [ctx imageInterpolation];
[ctx setImageInterpolation:
[self inLiveResize]
? NSImageInterpolationNone
#if 0
: NSImageInterpolationHigh
#else
: NSImageInterpolationDefault
#endif
];
NSSize fSize = [self frame].size;
NSSize rSize = mRenderedRect.size;
CGFloat scale;
if (rSize.width <= fSize.width && rSize.height <= fSize.height) {
// rendered area fits within frame, center it
scale = 1.0;
} else {
CGFloat wScale = fSize.width / rSize.width;
CGFloat hScale = fSize.height / rSize.height;
scale = (hScale < wScale) ? hScale : wScale;
}
NSRect dRect;
// center scaled image rectangle
dRect.size.width = rSize.width * scale;
dRect.size.height = rSize.height * scale;
int ox = static_cast<int>(dRect.origin.x = floor((fSize.width - dRect.size.width) * ((CGFloat)0.5)));
int oy = static_cast<int>(dRect.origin.y = floor((fSize.height - dRect.size.height) * ((CGFloat)0.5)));
if (mTiled && mRenderer && mRenderer->m_tiledCanvas && scale == 1.0) {
tileList points = mRenderer->m_tiledCanvas->getTessellation(static_cast<int>(fSize.width), static_cast<int>(fSize.height), ox, oy);
for (agg::point_i& pt: points) {
NSPoint dPoint = NSMakePoint(pt.x, pt.y);
if (backgroundColor.opacity() < 1.0) {
NSRect cRect = dRect;
cRect.origin = dPoint;
// redraw checkerboard to erase global fill
[self drawCheckerboardRect: NSIntersectionRect(cRect, rect)];
}
[mDrawingImage drawAtPoint: dPoint fromRect: NSZeroRect
operation: NSCompositeSourceAtop
fraction: 1.0];
}
NSRect boxRect = NSInsetRect(dRect, -0.5, -0.5);
[[NSColor colorWithDeviceWhite: 0.0 alpha: 0.35 ] set];
[NSBezierPath strokeRect: boxRect];
boxRect = NSInsetRect(dRect, -1.5, -1.5);
[[NSColor colorWithDeviceWhite: 1.0 alpha: 0.75 ] set];
[NSBezierPath strokeRect: boxRect];
} else {
if (backgroundColor.opacity() < 1.0) {
// redraw checkerboard to erase global fill
[self drawCheckerboardRect: NSIntersectionRect(dRect, rect)];
}
[mDrawingImage drawInRect: dRect
fromRect: NSZeroRect
operation: NSCompositeSourceAtop
fraction: 1.0];
}
[ctx setImageInterpolation: oldInterp];
}
- (void)viewDidEndLiveResize
{
[super viewDidEndLiveResize];
[self setNeedsDisplay:YES];
}
- (IBAction)toggleRender:(id)sender
{
if ([mActionControl selectedSegment] == 1) {
[[mActionSelect cell] performClickWithFrame:[sender frame]
inView:[sender superview]];
return;
}
if (mRendering) {
[self finishRender: sender];
} else {
float frame = 0.0;
switch (mCurrentAction) {
case RenderAction:
[self startRender: sender];
break;
case AnimateFrameAction:
frame = mLastAnimateFrame;
case AnimateAction: {
NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
float movieWidth = [defaults floatForKey: PrefKeyMovieWidth];
float movieHeight = [defaults floatForKey: PrefKeyMovieHeight];
double movieMinSize = [defaults doubleForKey: PrefKeyMinumumSize];
[self startAnimation: NSMakeSize(movieWidth, movieHeight)
minimum: movieMinSize
frame: frame];
break;
}
case StopAction:
break;
}
}
}
- (IBAction)selectAction:(id)sender
{
NSInteger newAction = [mActionSelect selectedTag];
mCurrentAction = (ActionType)newAction;
[mActionControl setLabel: ActionStrings[newAction]
forSegment: 0];
}
- (IBAction)saveOutput:(id)sender
{
if (mMovieFile) {
if (!mMovieFile->written()) {
[mDocument noteStatus: @"Movie file is already saved."];
NSBeep();
return;
}
[self showSavePanelTitle: NSLocalizedString(@"Save as Animation", @"")
fileType: @[@"mov"]
accessoryView: nil
didEndSelector: @selector(saveMovietoFile:)];
} else if (mTiled) {
[self saveTileImage: sender];
} else {
[self showSavePanelTitle: NSLocalizedString(@"Save Image", @"")
fileType: @[@"png"]
accessoryView: mSaveImageAccessory
didEndSelector: @selector(saveImagetoFile:)];
}
}
- (IBAction)saveTileImage:(id)sender
{
CFDG::frieze_t frz = mEngine->isFrieze();
switch (frz) {
case CFDG::no_frieze:
[mSaveTileWidth setEnabled: YES];
[mSaveTileHeight setEnabled: YES];
break;
case CFDG::frieze_x:
[mSaveTileHeight setFloatValue: 1.0];
[mSaveTileWidth setEnabled: YES];
[mSaveTileHeight setEnabled: NO];
break;
case CFDG::frieze_y:
[mSaveTileWidth setFloatValue: 1.0];
[mSaveTileWidth setEnabled: NO];
[mSaveTileHeight setEnabled: YES];
break;
}
[self showSavePanelTitle: NSLocalizedString(@"Save Image", @"")
fileType: @[@"png"]
accessoryView: mSaveTileAccessory
didEndSelector: @selector(saveTileImagetoFile:)];
}
- (IBAction)saveAsSVG:(id)sender
{
[self showSavePanelTitle: NSLocalizedString(@"Save as SVG", @"")
fileType: @[@"svg"]
accessoryView: nil
didEndSelector: @selector(saveSvgtoFile:)];
}
- (BOOL)validateMenuItem:(NSMenuItem *)anItem
{
SEL action = [anItem action];
if (action == @selector(startRender:))
return !mRestartRenderer;
if (action == @selector(enterFullscreen:))
return YES;
if (action == @selector(showHiresRenderSheet:)
|| action == @selector(repeatRender:)
|| action == @selector(showAnimateSheet:))
return !mRendering;
if (action == @selector(finishRender:))
return mRendering && !mRendererFinishing && !mRendererStopping;
if (action == @selector(stopRender:))
return mRendering && !mRendererStopping;
if (action == @selector(saveAsSVG:)
|| action == @selector(uploadToGallery:))
return !mRendering && mRenderBitmap;
if (action == @selector(saveOutput:))
return !mRendering && (mRenderBitmap || mMovieFile);
return [super validateMenuItem: anItem];
}
- (IBAction) showHiresRenderSheet:(id)sender
{
[mDocument showHiresRenderSheet: sender];
}
- (IBAction) showAnimationSheet:(id)sender
{
[mDocument showAnimateSheet: sender];
}
- (IBAction)showAnimationFrameSheet:(id)sender
{
[mDocument showAnimateFrameSheet: sender];
}
- (void)redisplayImage:(NSValue*)rectObj
{
mRenderedRect = [rectObj rectValue];
[self invalidateDrawingImage];
[self setNeedsDisplay: YES];
}
- (void)noteStats:(NSValue*)value
{
AbstractSystem::Stats s;
[value getValue: &s];
NSString *message =
[NSString localizedStringWithFormat: @"%d shapes",
s.shapeCount];
if (s.inOutput || s.animating) {
if (s.fullOutput || s.finalOutput || s.animating) {
NSString* prefix = s.finalOutput ? @"drawing - " : @"rescaling - ";
message = [NSLocalizedString(prefix, @"")
stringByAppendingString: message];
}
}
if (s.toDoCount > 0 && !s.finalOutput) {
message = [message stringByAppendingString:
[NSString localizedStringWithFormat:
@" - %d expansions to do", s.toDoCount]];
}
else {
message = [message stringByAppendingString:
[NSString localizedStringWithFormat:
@", %d x %d pixels",
(int)mRenderedRect.size.width,
(int)mRenderedRect.size.height]];
if (mTiled) {
message = [message stringByAppendingString: @", tiled"];
}
}
#if 0
if (!s.inOutput) {
message = [message stringByAppendingString:
[NSString localizedStringWithFormat:
@" in %.3f seconds",
static_cast<double>(s.outputTime) / CLOCKS_PER_SEC]];
}
#endif
[mStatus setStringValue: message];
if ((s.inOutput && s.fullOutput) || s.showProgress) {
if (mOutputProgressDelay == PROGRESS_DELAY) {
[mOutputProgress setHidden: NO];
[mTopBar relayout];
mOutputProgressDelay += 1;
}
if (mOutputProgressDelay >= PROGRESS_DELAY) {
double v = 100.0 * s.outputDone / s.outputCount;
[mOutputProgress setDoubleValue: v];
}
else {
mOutputProgressDelay += 1;
}
}
else {
if (![mOutputProgress isHidden]) {
[mOutputProgress setHidden: YES];
[mTopBar relayout];
mOutputProgressDelay = 0;
}
}
}
-(int)variation
{
return mCurrentVariation;
}
-(bool)canvasColor256
{
return mCanvasColor256;
}
-(bool)isTiled
{
return mTiled;
}
-(int)isFrieze
{
return (mTiled && mEngine) ? mEngine->isFrieze() : 0;
}
- (NSData*) pngImageDataCropped:(BOOL)cropped multiplier:(NSSize*) mult
{
NSBitmapImageRep* bits;
if (mult && (mult->width != 1.0 || mult->height != 1.0)) {
int width = static_cast<int>(mRenderedRect.size.width * mult->width);
int height = static_cast<int>(mRenderedRect.size.height * mult->height);
auto fmt = [mRenderBitmap aggPixelFormat];
BitmapAndFormat* png_bm = [[BitmapAndFormat alloc]
initWithAggPixFmt: fmt
pixelsWide: width
pixelsHigh: height];
if (!png_bm) return nil;
[png_bm autorelease];
auto pngCanvas = std::make_unique<ImageCanvas>(self, png_bm, fmt);
auto srcCanvas = std::make_unique<ImageCanvas>(self, mRenderBitmap, fmt);
if (!srcCanvas || !pngCanvas) return nil;
tileList points = mRenderer->m_tiledCanvas->getTessellation(width, height, 0, 0);
for (agg::point_i& pt: points)
pngCanvas->draw(*srcCanvas, pt.x, pt.y);
bits = [png_bm getImageRep];
}
else if (cropped && !mult) {
bits = [mRenderBitmap getImageRepCropped: mRenderedRect];
}
else {
bits = [mRenderBitmap getImageRep];
}
CGImageRef iref = [bits CGImage];
if (!iref) return nil;
NSMutableData* mdata = [NSMutableData data];
CGImageDestinationRef destref =
CGImageDestinationCreateWithData((CFMutableDataRef)mdata, kUTTypePNG, 1, nil);
if (!destref) return nil;
CGImageDestinationAddImage(destref, iref, nullptr);
CGImageDestinationFinalize(destref);
CFRelease(destref);
return mdata;
}
@end
@implementation GView (renderControl)
- (IBAction) repeatRender:(id)sender
{
if (mLastRenderWasHires) {
[self updateVariation: YES];
[self startHiresRender: mLastRenderSize
minimum: mLastRenderMin];
} else {
[self startRender: sender];
}
}
- (IBAction) startRender:(id)sender
{
mCurrentAction = ActionType::RenderAction;
mLastRenderWasHires = false;
[self tearDownPlayer];
if (mRendering) {
if (!mRestartRenderer) {
mRestartRenderer = true;
[self stopRender: sender];
}
return;
}
mMovieFile.reset();
[self updateVariation: YES];
NSSize size = [self frame].size;
[self buildEngine];
if (!mEngine) return;
if (mEngine->isTiled()) {
size.width *= 0.9f;
size.height *= 0.9f;
}
[self buildRendererSize: size minimum: 0.3];
if (!mRenderer) return;
[self buildImageCanvasSize];
NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
RenderParameters parameters;
parameters.periodicUpdate = [defaults boolForKey: @"ProgressiveUpdate"];
[self renderBegin: ¶meters];
}
- (IBAction) finishRender:(id)sender
{
if (mRendererFinishing) {
[self stopRender: sender];
}
if (mRendering && !mRendererFinishing && !mRendererStopping) {
if (mRenderer)
mRenderer->requestFinishUp = true;
mRendererFinishing = true;
[mActionControl setLabel: NSLocalizedString(@"Stop Now", @"") forSegment: 0];
}
}
- (IBAction) stopRender:(id)sender
{
if (mRendering && !mRendererStopping) {
if (mRenderer)
mRenderer->requestStop = true;
mRendererStopping = true;
[mActionControl setEnabled: NO];
}
}
- (void) startHiresRender: (NSSize) size
minimum: (double) minSize
{
mLastRenderWasHires = true;
mLastRenderSize = size;
mLastRenderMin = minSize;
mCurrentAction = ActionType::RenderAction;
[self tearDownPlayer];
if (mRendering)
return;
mMovieFile.reset();
[self updateVariation: NO];
[self buildEngine];
if (!mEngine) return;
[self buildRendererSize: size minimum: minSize];
if (!mRenderer) return;
[self buildImageCanvasSize];
RenderParameters parameters;
parameters.periodicUpdate = false;
[self renderBegin: ¶meters];
}
- (void) startAnimation: (NSSize) size
minimum: (double) minSize
frame: (float) fr
{
RenderParameters parameters;
parameters.render = false;
parameters.periodicUpdate = false;
parameters.animate = true;
parameters.animateFrame = static_cast<int>(fr);
NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
float movieLength = [defaults floatForKey: PrefKeyMovieLength];
NSInteger movieFrameRate = [defaults integerForKey: PrefKeyMovieFrameRate];
auto fmt = AVcanvas::H264;
switch ([defaults integerForKey: PrefKeyMovieFormat]) {
case 2:
fmt = AVcanvas::ProRes422;
break;
case 3:
fmt = AVcanvas::ProRes4444;
break;
default:
break;
}
parameters.animateFrameCount = static_cast<int>(movieLength * movieFrameRate * 0.01);
[self buildEngine];
if (!mEngine) return;
[self buildRendererSize: size minimum: minSize];
if (!mRenderer) return;
parameters.animateZoom = [defaults boolForKey: PrefKeyMovieZoom] && !mTiled;
auto width = mRenderer->m_width;
auto height = mRenderer->m_height;
if (width & 7)
width = (width + 8) & (~7);
if (height & 7)
height = (height + 8) & (~7);
mRenderSize.width = (CGFloat)width;
mRenderSize.height = (CGFloat)height;
mRenderedRect.origin.x = 0.0;
mRenderedRect.origin.y = 0.0;
mRenderedRect.size = mRenderSize;
if (!NSEqualSizes(size, mRenderSize))
[mDocument noteStatus: [NSString stringWithFormat:@"Size reduced to %dx%d",
width, height]];
if (width != mRenderer->m_width || height != mRenderer->m_height)
[mDocument noteStatus: [NSString stringWithFormat:@"TiledCanvas desired size was %dx%d",
mRenderer->m_width, mRenderer->m_height]];
if (parameters.animateFrame == 0) {
mCurrentAction = ActionType::AnimateAction;
BitmapAndFormat* bits = [BitmapAndFormat alloc];
[bits initWithAggPixFmt: aggCanvas::AV_Blend
pixelsWide: (NSInteger)width
pixelsHigh: (NSInteger)height];
if (!bits) {
[mDocument noteStatus: @"An error occured while initializing the movie canvas."];
NSBeep();
return;
}
[self tearDownPlayer];