Skip to content

HTTPS clone URL

Subversion checkout URL

You can clone with HTTPS or Subversion.

Download ZIP
Fetching contributors…

Cannot retrieve contributors at this time

39 lines (29 sloc) 1.092 kb
include (../settings.pro)
TEMPLATE = subdirs
# Libraries without dependencies
SUBDIRS += libmythsamplerate
SUBDIRS += libmythsoundtouch libmythdvdnav
SUBDIRS += libmythbluray libmythfreesurround libmythbase
SUBDIRS += libmythservicecontracts
using_mheg:SUBDIRS += libmythfreemheg
using_live:SUBDIRS += libmythlivemedia
using_hdhomerun:SUBDIRS += libmythhdhomerun
using_x11:SUBDIRS += libmythnvctrl
!contains( CONFIG_LIBMPEG2EXTERNAL, yes):SUBDIRS += libmythmpeg2
# Libraries with dependencies
SUBDIRS += libmythui libmythupnp libmyth
libmythui.depends = libmythbase
libmythupnp.depends = libmythbase
libmyth.depends = libmythbase libmythui libmythupnp
libmyth.depends += libmythsamplerate libmythsoundtouch libmythfreesurround
libmythupnp.depends = libmythbase libmythservicecontracts
LIBMYTHTVDEPS = $$SUBDIRS
# libmythtv
libmythtv.depends = $$LIBMYTHTVDEPS
SUBDIRS += libmythtv
# libmythmetadata
SUBDIRS += libmythmetadata
libmythmetadata.depends = $$LIBMYTHTVDEPS libmythtv
#libmythmediaserver
SUBDIRS += libmythprotoserver
libmythprotoserver.depends = $$LIBMYTHTVDEPS libmythtv
Jump to Line
Something went wrong with that request. Please try again.