|  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
| auart | vkorg | vtweg | spart | bstkd | kunnr | bstdk | ketdat | kprgbz | prsdt | mabnr | arktx | kwmeng | vrkme |
| Document Type | Sales Org | Dis Chan | Division | PO | Customer | Doc Date | Req DD | Date Indicator | Pricing Date | Material | Description | Quantity | UoM |
| ZQOR | 2051 | 10 | 20 | Test2 | 10003284 | 21.03.2016 | 21.03.2016 | D | 21.03.2016 | 20000101 | Testing1 | 1 | KG |
|  |  |  |  |  |  |  |  |  |  | 20000101 | Testing2 | 2 | KG |
| ZQOR | 2051 | 10 | 20 | Test2 | 10003284 | 21.03.2016 | 21.03.2016 | D | 21.03.2016 | 20000101 | Testing1 | 1 | KG |
|  |  |  |  |  |  |  |  |  |  | 20000101 | Testing2 | 2 | KG |

\*&---------------------------------------------------------------------\*  
\*& Report  ZBDC\_SESSION\_03  
\*&  
\*&---------------------------------------------------------------------\*  
\*&  
\*&  
\*&---------------------------------------------------------------------\*  
  
REPORT  zbdc\_session\_03.  
TYPE-POOLS: truxs.  
TYPES: BEGIN OF ty\_data,  
  auart   TYPE vbak-auart,    "Document Type  
  vkorg   TYPE vbak-vkorg,    "Sales Org  
  vtweg   TYPE vbak-vtweg,    "Dis Chan  
  spart   TYPE vbak-spart,    "Division  
  bstkd   TYPE vbkd-bstkd,    "PO  
  kunnr   TYPE kuagv-kunnr,   "Customer  
  bstdk   TYPE rv45a-ketdat, "vbkd-bstdk,    "Doc Date  
  ketdat  TYPE rv45a-ketdat,  " Req DD  
  kprgbz  TYPE rv45a-kprgbz,  "Date Indicator  
  prsdt   TYPE rv45a-ketdat, "vbkd-prsdt,    "Pricing Date  
  mabnr   TYPE rv45a-mabnr,   "Material  
  arktx   TYPE vbap-arktx,    "Description  
  kwmeng  TYPE c LENGTH 17,   "RV45A-KWMENG, "Quantity  
  vrkme TYPE vbap-vrkme,      "UoM  
  END OF ty\_data.  
  
TYPES:  
  BEGIN OF ty\_header,  
  index   TYPE sy-tabix,  
  auart   TYPE vbak-auart,    "Document Type  
  vkorg   TYPE vbak-vkorg,    "Sales Org  
  vtweg   TYPE vbak-vtweg,    "Dis Chan  
  spart   TYPE vbak-spart,    "Division  
  bstkd   TYPE vbkd-bstkd,    "PO  
  kunnr   TYPE kuagv-kunnr,   "Customer  
  bstdk   TYPE rv45a-ketdat, "vbkd-bstdk,    "Doc Date  
  ketdat  TYPE rv45a-ketdat,  " Req DD  
  kprgbz  TYPE rv45a-kprgbz,  "Date Indicator  
  prsdt   TYPE rv45a-ketdat, "vbkd-prsdt,    "Pricing Date  
  END OF ty\_header,  
  BEGIN OF ty\_item,  
  index   TYPE sy-tabix,      " Index  
  mabnr   TYPE rv45a-mabnr,   "Material  
  arktx   TYPE vbap-arktx,    "Description  
  kwmeng  TYPE c LENGTH 17,   "RV45A-KWMENG, "Quantity  
  vrkme TYPE vbap-vrkme,      "UoM  
  END OF ty\_item.  
  
DATA:  
    t\_data TYPE TABLE OF ty\_data,  
    t\_header TYPE TABLE OF ty\_header,  
    t\_item   TYPE TABLE OF ty\_item,  
    st\_header TYPE ty\_header,  
    st\_item   TYPE ty\_item,  
    st\_data TYPE ty\_data.  
  
  
DATA: t\_bdcdata TYPE TABLE OF bdcdata,  
      st\_bdcdata TYPE bdcdata.  
  
PARAMETERS:  
  p\_file TYPE ibipparms-path.  
PARAMETERS:  
p\_group TYPE apqi-groupid.  
  
DATA:  
      w\_keep TYPE apqi-qerase VALUE 'X',  
      w\_user TYPE apqi-userid VALUE 'RCHITT',  
      w\_qid  TYPE apqi-qid.  
  
DATA: w\_item TYPE n LENGTH 2,  
      w\_field TYPE c LENGTH 30.  
  
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p\_file.  
  PERFORM choose\_file.  
  
START-OF-SELECTION.  
  PERFORM upload\_file.  
  PERFORM split\_data.  
  PERFORM open\_bdcgroup.  " <-- Open the Group  
  LOOP AT t\_item INTO st\_item.  
    AT NEW index.  
      READ TABLE t\_header INTO st\_header WITH KEY INDEX = st\_item-index.  
      IF sy-subrc = 0.  
        CLEAR w\_item.  
        PERFORM fill\_header\_bdcdata.  
      ENDIF.  
    ENDAT.  
    w\_item = w\_item + 1.  
    PERFORM fill\_bdcdata.  
    AT END OF index.  
      "Save  
      PERFORM bdc\_dynpro      USING 'SAPMV45A' '4001'.  
      PERFORM bdc\_field       USING 'BDC\_OKCODE'  
                                    '=SICH'.  
      PERFORM insert\_record.  " <-- Insert into group  
      CLEAR t\_bdcdata.  
    ENDAT.  
  ENDLOOP.  
  PERFORM close\_bdcgroup. " <-- Close the Group  
\*&---------------------------------------------------------------------\*  
\*&      Form  choose\_file  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
FORM choose\_file.  
  CALL FUNCTION 'F4\_FILENAME'  
    IMPORTING  
      file\_name = p\_file.  
ENDFORM.                    "choose\_file  \*&---------------------------------------------------------------------\*  
\*&      Form  upload\_file  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
FORM upload\_file.  
  DATA: l\_raw TYPE truxs\_t\_text\_data,  
        l\_file TYPE rlgrap-filename.  
  MOVE p\_file TO l\_file.  
  CALL FUNCTION 'TEXT\_CONVERT\_XLS\_TO\_SAP'  
    EXPORTING  
\*   I\_FIELD\_SEPERATOR          =  
\*   I\_LINE\_HEADER              =  
      i\_tab\_raw\_data             = l\_raw  
      i\_filename                 = l\_file  
    TABLES  
      i\_tab\_converted\_data       = t\_data  
   EXCEPTIONS  
     conversion\_failed          = 1  
     OTHERS                     = 2.  
  IF sy-subrc <> 0.  
\* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO  
\*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.  
  ENDIF.  
  
ENDFORM.                    "upload\_file  
\*----------------------------------------------------------------------\*  
\*        Start new screen                                              \*  
\*----------------------------------------------------------------------\*  
FORM bdc\_dynpro USING program dynpro.  
  CLEAR st\_bdcdata.  
  st\_bdcdata-program  = program.  
  st\_bdcdata-dynpro   = dynpro.  
  st\_bdcdata-dynbegin = 'X'.  
  APPEND st\_bdcdata TO t\_bdcdata.  
ENDFORM.                    "BDC\_DYNPRO  
  
\*----------------------------------------------------------------------\*  
\*        Insert field                                                  \*  
\*----------------------------------------------------------------------\*  
FORM bdc\_field USING fnam fval.  
  CLEAR st\_bdcdata.  
  st\_bdcdata-fnam = fnam.  
  st\_bdcdata-fval = fval.  
  APPEND st\_bdcdata TO t\_bdcdata.  
ENDFORM.                    "BDC\_FIELD  
\*&---------------------------------------------------------------------\*  
\*&      Form  OPEN\_BDCGROUP  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
\*  -->  p1        text  
\*  <--  p2        text  
\*----------------------------------------------------------------------\*  
FORM open\_bdcgroup .  
  CALL FUNCTION 'BDC\_OPEN\_GROUP'  
   EXPORTING  
\*   CLIENT                    = SY-MANDT  
\*   DEST                      = FILLER8  
     group                     = p\_group  "Group Name/File Name/ Session Name  
\*   HOLDDATE                  = FILLER8  
     keep                      = w\_keep  
     user                      = w\_user  " Imp  
\*   RECORD                    = FILLER1  
\*   PROG                      = SY-CPROG  
\*   DCPFM                     = '%'  
\*   DATFM                     = '%'  
   IMPORTING  
     qid                       = w\_qid  
   EXCEPTIONS  
     client\_invalid            = 1  
     destination\_invalid       = 2  
     group\_invalid             = 3  
     group\_is\_locked           = 4  
     holddate\_invalid          = 5  
     internal\_error            = 6  
     queue\_error               = 7  
     running                   = 8  
     system\_lock\_error         = 9  
     user\_invalid              = 10  
     OTHERS                    = 11  
            .  
  IF sy-subrc <> 0.  
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno  
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.  
  ENDIF.  
  
ENDFORM.                    " OPEN\_BDCGROUP  
\*&---------------------------------------------------------------------\*  
\*&      Form  INSERT\_RECORD  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
\*  -->  p1        text  
\*  <--  p2        text  
\*----------------------------------------------------------------------\*  
FORM insert\_record .  
  CALL FUNCTION 'BDC\_INSERT'  
   EXPORTING  
     tcode                  = 'VA01'  
\*   POST\_LOCAL             = NOVBLOCAL  
\*   PRINTING               = NOPRINT  
\*   SIMUBATCH              = ' '  
\*   CTUPARAMS              = ' '  
    TABLES  
      dynprotab              = t\_bdcdata  
   EXCEPTIONS  
     internal\_error         = 1  
     not\_open               = 2  
     queue\_error            = 3  
     tcode\_invalid          = 4  
     printing\_invalid       = 5  
     posting\_invalid        = 6  
     OTHERS                 = 7  
            .  
  IF sy-subrc <> 0.  
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno  
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.  
  ENDIF.  
  
ENDFORM.                    " INSERT\_RECORD  
\*&---------------------------------------------------------------------\*  
\*&      Form  CLOSE\_BDCGROUP  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
\*  -->  p1        text  
\*  <--  p2        text  
\*----------------------------------------------------------------------\*  
FORM close\_bdcgroup .  
  CALL FUNCTION 'BDC\_CLOSE\_GROUP'  
    EXCEPTIONS  
      not\_open    = 1  
      queue\_error = 2  
      OTHERS      = 3.  
  IF sy-subrc <> 0.  
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno  
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.  
  ENDIF.  
  
ENDFORM.                    " CLOSE\_BDCGROUP  
\*&---------------------------------------------------------------------\*  
\*&      Form  FILL\_BDCDATA  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
\*  -->  p1        text  
\*  <--  p2        text  
\*----------------------------------------------------------------------\*  
FORM fill\_bdcdata .  
  " Item Details  
  "Material  
  CLEAR w\_field.  
  CONCATENATE 'RV45A-MABNR(' w\_item ')' INTO w\_field.  
  PERFORM bdc\_field       USING w\_field  
                              st\_item-mabnr.  
  "Short Text  
  CLEAR w\_field.  
  CONCATENATE 'VBAP-ARKTX(' w\_item ')' INTO w\_field.  
  PERFORM bdc\_field       USING w\_field  
                              st\_item-arktx.  
  "Quantity  
  CLEAR w\_field.  
  CONCATENATE 'RV45A-KWMENG(' w\_item ')' INTO w\_field.  
  PERFORM bdc\_field       USING w\_field  
                              st\_item-kwmeng.  
  "UoM  
  CLEAR w\_field.  
  CONCATENATE 'VBAP-VRKME(' w\_item ')' INTO w\_field.  
  PERFORM bdc\_field       USING w\_field  
                              st\_item-vrkme.  
ENDFORM.                    " FILL\_BDCDATA  
\*&---------------------------------------------------------------------\*  
\*&      Form  SPLIT\_DATA  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
\*  -->  p1        text  
\*  <--  p2        text  
\*----------------------------------------------------------------------\*  
FORM split\_data .  
  DATA: w\_index TYPE sy-tabix.  
  LOOP AT t\_data INTO st\_data.  
    IF st\_data-auart IS NOT INITIAL. " Header data  
      w\_index = w\_index + 1.  
      MOVE:  
        w\_index TO st\_header-index,  
        w\_index TO st\_item-index.  
      MOVE-CORRESPONDING st\_data TO st\_header.  
      APPEND st\_header TO t\_header.  
    ENDIF.  
    MOVE-CORRESPONDING st\_data TO st\_item.  
    APPEND st\_item TO t\_item.  
  ENDLOOP.  
ENDFORM.                    " SPLIT\_DATA  
\*&---------------------------------------------------------------------\*  
\*&      Form  FILL\_HEADER\_BDCDATA  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
\*  -->  p1        text  
\*  <--  p2        text  
\*----------------------------------------------------------------------\*  
FORM fill\_header\_bdcdata .  
  " Header Details  
  PERFORM bdc\_dynpro      USING 'SAPMV45A' '0101'.  
  PERFORM bdc\_field       USING 'BDC\_CURSOR'  
                                'VBAK-AUART'.  
  PERFORM bdc\_field       USING 'BDC\_OKCODE'  
                                '/00'.  
  PERFORM bdc\_field       USING 'VBAK-AUART'  
                                st\_header-auart.  
  PERFORM bdc\_field       USING 'VBAK-VKORG'  
                                st\_header-vkorg.  
  PERFORM bdc\_field       USING 'VBAK-VTWEG'  
                                st\_header-vtweg.  
  PERFORM bdc\_field       USING 'VBAK-SPART'  
                                st\_header-spart.  
  PERFORM bdc\_dynpro      USING 'SAPMV45A' '4001'.  
  PERFORM bdc\_field       USING 'BDC\_OKCODE'  
                                '/00'.  
  PERFORM bdc\_field       USING 'VBKD-BSTKD'  
                                st\_header-bstkd.  
  PERFORM bdc\_field       USING 'VBKD-BSTDK'  
                                st\_header-bstdk.  
  PERFORM bdc\_field       USING 'KUAGV-KUNNR'  
                                st\_header-kunnr.  
  PERFORM bdc\_field       USING 'RV45A-KETDAT'  
                                st\_header-ketdat.  
  PERFORM bdc\_field       USING 'RV45A-KPRGBZ'  
                                st\_header-kprgbz.  
  PERFORM bdc\_field       USING 'VBKD-PRSDT'  
                                st\_header-prsdt.  
ENDFORM.                    " FILL\_HEADER\_BDCDATA