Skip to content
Permalink
Branch: master
Find file Copy path
Find file Copy path
12 contributors

Users who have contributed to this file

@fpletz @wkennington @ruuda @matthewbauer @thoughtpolice @r-ryantm @zimbatm @basvandijk @markuskowa @globin @Mic92 @Izorkin
60 lines (45 sloc) 1.64 KB
{ stdenv, fetchurl, lib, cmake }:
let
generic = { version, sha256 }: stdenv.mkDerivation rec {
name = "libressl-${version}";
inherit version;
src = fetchurl {
url = "mirror://openbsd/LibreSSL/${name}.tar.gz";
inherit sha256;
};
nativeBuildInputs = [ cmake ];
cmakeFlags = [ "-DENABLE_NC=ON" "-DBUILD_SHARED_LIBS=ON" ];
# The autoconf build is broken as of 2.9.1, resulting in the following error:
# libressl-2.9.1/tls/.libs/libtls.a', needed by 'handshake_table'.
# Fortunately LibreSSL provides a CMake build as well, so opt for CMake by
# removing ./configure pre-config.
preConfigure = ''
rm configure
'';
enableParallelBuilding = true;
outputs = [ "bin" "dev" "out" "man" "nc" ];
postFixup = ''
moveToOutput "bin/nc" "$nc"
moveToOutput "bin/openssl" "$bin"
moveToOutput "bin/ocspcheck" "$bin"
moveToOutput "share/man/man1/nc.1${lib.optionalString (dontGzipMan==null) ".gz"}" "$nc"
'';
dontGzipMan = if stdenv.isDarwin then true else null; # not sure what's wrong
meta = with lib; {
description = "Free TLS/SSL implementation";
homepage = "https://www.libressl.org";
license = with licenses; [ publicDomain bsdOriginal bsd0 bsd3 gpl3 isc openssl ];
platforms = platforms.all;
maintainers = with maintainers; [ thoughtpolice fpletz globin ];
};
};
in {
libressl_2_8 = generic {
version = "2.8.3";
sha256 = "0xw4z4z6m7lyf1r4m2w2w1k7as791c04ygnfk4d7d0ki0h9hnr4v";
};
libressl_2_9 = generic {
version = "2.9.2";
sha256 = "1m6mz515dcbrbnyz8hrpdfjzdmj1c15vbgnqxdxb89g3z9kq3iy4";
};
}
You can’t perform that action at this time.