diff --git a/pkgs/applications/blockchains/mycrypto/default.nix b/pkgs/applications/blockchains/mycrypto/default.nix
new file mode 100644
index 00000000000000..717683f91bc7d5
--- /dev/null
+++ b/pkgs/applications/blockchains/mycrypto/default.nix
@@ -0,0 +1,57 @@
+{ lib, appimageTools, fetchurl, makeDesktopItem
+, gsettings-desktop-schemas, gtk2
+}:
+
+let
+  pname = "MyCrypto";
+  version = "1.7.11";
+  sha256 = "0k9vpmy6q5vkypicfsw87qg8s4xrs5gmzvdabhxpn0i5yikl8qy0";
+  name = "${pname}-${version}";
+
+  src = fetchurl {
+    url = "https://github.com/mycryptohq/mycrypto/releases/download/${version}/linux-x86-64_${version}_MyCrypto.AppImage";
+    inherit sha256;
+  };
+
+  appimageContents = appimageTools.extractType2 {
+    inherit name src;
+  };
+
+  desktopItem = makeDesktopItem {
+    name = pname;
+    desktopName = pname;
+    comment = "MyCrypto is a free, open-source interface for interacting with the blockchain";
+    exec = pname;
+    icon = "mycrypto";
+    categories = "Finance;";
+  };
+
+in appimageTools.wrapType2 rec {
+  inherit name src;
+
+  profile = ''
+    export XDG_DATA_DIRS=${gsettings-desktop-schemas}/share/gsettings-schemas/${gsettings-desktop-schemas.name}:${gtk2}/share/gsettings-schemas/${gtk2.name}:$XDG_DATA_DIRS
+  '';
+
+  multiPkgs = null; # no p32bit needed
+  extraPkgs = appimageTools.defaultFhsEnvArgs.multiPkgs;
+
+  extraInstallCommands = ''
+    mv $out/bin/{${name},${pname}}
+
+    mkdir -p $out/share
+    cp -rt $out/share ${desktopItem}/share/applications ${appimageContents}/usr/share/icons
+  '';
+
+  meta = with lib; {
+    description = "A free, open-source interface for interacting with the blockchain";
+    longDescription = ''
+      MyCrypto is an open-source, client-side tool for generating ether wallets,
+      handling ERC-20 tokens, and interacting with the blockchain more easily.
+    '';
+    homepage = "https://mycrypto.com";
+    license = licenses.mit;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ oxalica ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 3a15825b5a665f..3f8d1d0b4900f9 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5472,6 +5472,8 @@ in
 
   mycli = callPackage ../tools/admin/mycli { };
 
+  mycrypto = callPackage ../applications/blockchains/mycrypto { };
+
   mydumper = callPackage ../tools/backup/mydumper { };
 
   mysql2pgsql = callPackage ../tools/misc/mysql2pgsql { };