From 4d5b27458b0db7fb95ba0a3e03ea9d8f65b74049 Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:24:18 +0100
Subject: [PATCH 1/9] python3Packages.azure-mgmt-frontdoor: init at 1.0.1

---
 .../azure-mgmt-frontdoor/default.nix          | 38 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 40 insertions(+)
 create mode 100644 pkgs/development/python-modules/azure-mgmt-frontdoor/default.nix

diff --git a/pkgs/development/python-modules/azure-mgmt-frontdoor/default.nix b/pkgs/development/python-modules/azure-mgmt-frontdoor/default.nix
new file mode 100644
index 0000000000000..4afabdf64ddde
--- /dev/null
+++ b/pkgs/development/python-modules/azure-mgmt-frontdoor/default.nix
@@ -0,0 +1,38 @@
+{ azure-common
+, azure-mgmt-core
+, buildPythonPackage
+, fetchPypi
+, lib
+, msrest
+, msrestazure
+}:
+
+buildPythonPackage rec {
+  pname = "azure-mgmt-frontdoor";
+  version = "1.0.1";
+
+  src = fetchPypi {
+    inherit pname version;
+    extension = "zip";
+    sha256 = "sha256-nJXQ/BpyOwmybNUqE4cBxq5xxZE56lqgHSTKZTIHIuU=";
+  };
+
+  propagatedBuildInputs = [
+    msrest
+    msrestazure
+    azure-common
+    azure-mgmt-core
+  ];
+
+  # has no tests
+  doCheck = false;
+
+  pythonImportsCheck = [ "azure.mgmt.frontdoor" ];
+
+  meta = with lib; {
+    description = "Microsoft Azure Front Door Service Client Library for Python";
+    homepage = "https://github.com/Azure/azure-sdk-for-python";
+    license = licenses.mit;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index d900cef9ec565..1986b260d3211 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -985,6 +985,8 @@ self: super: with self; {
 
   azure-mgmt-extendedlocation = callPackage ../development/python-modules/azure-mgmt-extendedlocation { };
 
+  azure-mgmt-frontdoor = callPackage ../development/python-modules/azure-mgmt-frontdoor { };
+
   azure-mgmt-hanaonazure = callPackage ../development/python-modules/azure-mgmt-hanaonazure { };
 
   azure-mgmt-hdinsight = callPackage ../development/python-modules/azure-mgmt-hdinsight { };

From 1153bb884e199dca10e2c4714b7e70c62214542b Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:25:47 +0100
Subject: [PATCH 2/9] python3Packages.django-pattern-library: init at 1.0.0

---
 .../django-pattern-library/default.nix        | 55 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 57 insertions(+)
 create mode 100644 pkgs/development/python-modules/django-pattern-library/default.nix

diff --git a/pkgs/development/python-modules/django-pattern-library/default.nix b/pkgs/development/python-modules/django-pattern-library/default.nix
new file mode 100644
index 0000000000000..40cc4f64188ab
--- /dev/null
+++ b/pkgs/development/python-modules/django-pattern-library/default.nix
@@ -0,0 +1,55 @@
+{ beautifulsoup4
+, buildPythonPackage
+, django
+, fetchFromGitHub
+, lib
+, markdown
+, poetry-core
+, python
+, pyyaml
+}:
+
+buildPythonPackage rec {
+  pname = "django-pattern-library";
+  version = "1.0.0";
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    repo = pname;
+    owner = "torchbox";
+    rev = "v${version}";
+    sha256 = "sha256-V299HpbfNLa9cpVhBfzD41oe95xqh+ktQVMMVvm5Xao=";
+  };
+
+  propagatedBuildInputs = [
+    django
+    pyyaml
+    markdown
+  ];
+
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+    --replace poetry.masonry.api poetry.core.masonry.api
+  '';
+
+  nativeBuildInputs = [ poetry-core ];
+
+  checkInputs = [
+    beautifulsoup4
+  ];
+
+  checkPhase = ''
+    export DJANGO_SETTINGS_MODULE=tests.settings.dev
+    ${python.interpreter} -m django test
+  '';
+
+  pythonImportsCheck = [ "pattern_library" ];
+
+  meta = with lib; {
+    description = "UI pattern libraries for Django templates";
+    homepage = "https://github.com/torchbox/django-pattern-library/";
+    changelog = "https://github.com/torchbox/django-pattern-library/blob/v${version}/CHANGELOG.md";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 1986b260d3211..52b6d13d9fbdb 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -2669,6 +2669,8 @@ self: super: with self; {
 
   django-paintstore = callPackage ../development/python-modules/django-paintstore { };
 
+  django-pattern-library = callPackage ../development/python-modules/django-pattern-library { };
+
   django-pglocks = callPackage ../development/python-modules/django-pglocks { };
 
   django-phonenumber-field = callPackage ../development/python-modules/django-phonenumber-field { };

From 5c618b25974dbaf3f381a1efa4d52e7b28453b2f Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:31:25 +0100
Subject: [PATCH 3/9] python3Packages.draftjs-exporter: init at 2.1.7

---
 .../draftjs-exporter/default.nix              | 45 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 47 insertions(+)
 create mode 100644 pkgs/development/python-modules/draftjs-exporter/default.nix

diff --git a/pkgs/development/python-modules/draftjs-exporter/default.nix b/pkgs/development/python-modules/draftjs-exporter/default.nix
new file mode 100644
index 0000000000000..aac2ed2f6baf5
--- /dev/null
+++ b/pkgs/development/python-modules/draftjs-exporter/default.nix
@@ -0,0 +1,45 @@
+{ beautifulsoup4
+, buildPythonPackage
+, fetchFromGitHub
+, html5lib
+, lib
+, lxml
+, python
+}:
+
+buildPythonPackage rec {
+  pname = "draftjs-exporter";
+  version = "2.1.7";
+
+  src = fetchFromGitHub {
+    repo = "draftjs_exporter";
+    owner = "springload";
+    rev = "v${version}";
+    sha256 = "sha256-tw0r9RnQdIwcY+pqnW8fcV0o2LzmxW0MZPn5drNgK80=";
+  };
+
+  passthru.optional-dependencies = {
+    lxml = [ lxml ];
+    html5lib = [ beautifulsoup4 html5lib ];
+  };
+
+  checkInputs = passthru.optional-dependencies.lxml ++ passthru.optional-dependencies.html5lib;
+
+  checkPhase = ''
+    # 2 tests in this file randomly fail because they depend on the order of
+    # HTML attributes
+    rm tests/test_exports.py
+
+    ${python.interpreter} -m unittest discover
+  '';
+
+  pythonImportsCheck = [ "draftjs_exporter" ];
+
+  meta = with lib; {
+    description = "Library to convert Draft.js ContentState to HTML";
+    homepage = "https://github.com/springload/draftjs_exporter";
+    changelog = "https://github.com/springload/draftjs_exporter/blob/v${version}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 52b6d13d9fbdb..982993fe505c3 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -2877,6 +2877,8 @@ self: super: with self; {
 
   dpkt = callPackage ../development/python-modules/dpkt { };
 
+  draftjs-exporter = callPackage ../development/python-modules/draftjs-exporter { };
+
   dragonfly = callPackage ../development/python-modules/dragonfly { };
 
   drawille = callPackage ../development/python-modules/drawille { };

From 11019dc245a39faedebefd2137945716d3667c09 Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:32:01 +0100
Subject: [PATCH 4/9] python3Packages.l18n: init at 2021.3

---
 .../python-modules/l18n/default.nix           | 30 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 ++
 2 files changed, 32 insertions(+)
 create mode 100644 pkgs/development/python-modules/l18n/default.nix

diff --git a/pkgs/development/python-modules/l18n/default.nix b/pkgs/development/python-modules/l18n/default.nix
new file mode 100644
index 0000000000000..61ac6fa3ff1c4
--- /dev/null
+++ b/pkgs/development/python-modules/l18n/default.nix
@@ -0,0 +1,30 @@
+{ buildPythonPackage
+, django
+, fetchFromGitHub
+, fetchPypi
+, lib
+, pytz
+, six
+}:
+
+buildPythonPackage rec {
+  pname = "l18n";
+  version = "2021.3";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-GVbokNZz0XE1zCCRMlPBVPa8HAAmbCK31QPMGlpC2Eg=";
+  };
+
+  propagatedBuildInputs = [ pytz six ];
+
+  pythonImportsCheck = [ "l18n" ];
+
+  meta = with lib; {
+    description = "Locale internationalization package";
+    homepage = "https://github.com/tkhyn/l18n";
+    changelog = "https://github.com/tkhyn/l18n/blob/${version}/CHANGES.rst";
+    license = licenses.mit;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 982993fe505c3..300013d2e4faf 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -5297,6 +5297,8 @@ self: super: with self; {
 
   kubernetes = callPackage ../development/python-modules/kubernetes { };
 
+  l18n = callPackage ../development/python-modules/l18n { };
+
   labelbox = callPackage ../development/python-modules/labelbox { };
 
   labgrid = callPackage ../development/python-modules/labgrid { };

From 1f094cd8e38765b8daffd22e1039fe8199559097 Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:33:39 +0100
Subject: [PATCH 5/9] python3Packages.permissionedforms: init at 0.1

---
 .../permissionedforms/default.nix             | 39 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 41 insertions(+)
 create mode 100644 pkgs/development/python-modules/permissionedforms/default.nix

diff --git a/pkgs/development/python-modules/permissionedforms/default.nix b/pkgs/development/python-modules/permissionedforms/default.nix
new file mode 100644
index 0000000000000..db4f02bef9158
--- /dev/null
+++ b/pkgs/development/python-modules/permissionedforms/default.nix
@@ -0,0 +1,39 @@
+{ buildPythonPackage
+, django
+, django-modelcluster
+, fetchFromGitHub
+, lib
+, python
+}:
+
+buildPythonPackage rec {
+  pname = "permissionedforms";
+  version = "0.1";
+
+  src = fetchFromGitHub {
+    repo = "django-permissionedforms";
+    owner = "wagtail";
+    rev = "v${version}";
+    sha256 = "sha256-DQzPGmh5UEVpGWnW3IrEVPkZZ8mdiW9J851Ej4agTDc=";
+  };
+
+  propagatedBuildInputs = [
+    django
+  ];
+
+  checkInputs = [ django-modelcluster ];
+
+  checkPhase = ''
+    ${python.interpreter} runtests.py
+  '';
+
+  pythonImportsCheck = [ "permissionedforms" ];
+
+  meta = with lib; {
+    description = "A Django extension for creating forms that vary according to user permissions";
+    homepage = "https://github.com/wagtail/permissionedforms";
+    changelog = "https://github.com/wagtail/permissionedforms/blob/v${version}/CHANGELOG.md";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 300013d2e4faf..fa20f197898c1 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -7147,6 +7147,8 @@ self: super: with self; {
 
   periodictable = callPackage ../development/python-modules/periodictable { };
 
+  permissionedforms = callPackage ../development/python-modules/permissionedforms { };
+
   persim = callPackage ../development/python-modules/persim { };
 
   persistent = callPackage ../development/python-modules/persistent { };

From 640cfc04ee9634e3b9bd22cd4a4b800b6a0dc5b0 Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:34:15 +0100
Subject: [PATCH 6/9] python3Packages.telepath: init at 0.3

---
 .../python-modules/telepath/default.nix       | 34 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 ++
 2 files changed, 36 insertions(+)
 create mode 100644 pkgs/development/python-modules/telepath/default.nix

diff --git a/pkgs/development/python-modules/telepath/default.nix b/pkgs/development/python-modules/telepath/default.nix
new file mode 100644
index 0000000000000..5a38142eade3c
--- /dev/null
+++ b/pkgs/development/python-modules/telepath/default.nix
@@ -0,0 +1,34 @@
+{ buildPythonPackage
+, django
+, fetchFromGitHub
+, lib
+, python
+}:
+
+buildPythonPackage rec {
+  pname = "telepath";
+  version = "0.3";
+
+  src = fetchFromGitHub {
+    repo = "telepath";
+    owner = "wagtail";
+    rev = "v${version}";
+    sha256 = "sha256-kfEAYCXbK0HTf1Gut/APkpw2krMa6C6mU/dJ0dsqzS0=";
+  };
+
+  checkInputs = [ django ];
+
+  checkPhase = ''
+    ${python.interpreter} -m django test --settings=telepath.test_settings
+  '';
+
+  pythonImportsCheck = [ "telepath" ];
+
+  meta = with lib; {
+    description = "A library for exchanging data between Python and JavaScript";
+    homepage = "https://github.com/wagtail/telepath";
+    changelog = "https://github.com/wagtail/telepath/blob/v${version}/CHANGELOG.md";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index fa20f197898c1..1a5ef33e7abbc 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -11475,6 +11475,8 @@ self: super: with self; {
 
   telegraph = callPackage ../development/python-modules/telegraph { };
 
+  telepath = callPackage ../development/python-modules/telepath { };
+
   telethon = callPackage ../development/python-modules/telethon {
     inherit (pkgs) openssl;
   };

From 61ddac6d5eb80bac668744c5547b717a2d4e9ad7 Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:35:51 +0100
Subject: [PATCH 7/9] python3Packages.wagtail-factories: init at 4.0.0

---
 .../wagtail-factories/default.nix             | 38 +++++++++++++++++++
 .../wagtail-factories/tests.nix               | 24 ++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 3 files changed, 64 insertions(+)
 create mode 100644 pkgs/development/python-modules/wagtail-factories/default.nix
 create mode 100644 pkgs/development/python-modules/wagtail-factories/tests.nix

diff --git a/pkgs/development/python-modules/wagtail-factories/default.nix b/pkgs/development/python-modules/wagtail-factories/default.nix
new file mode 100644
index 0000000000000..990fd0d8416af
--- /dev/null
+++ b/pkgs/development/python-modules/wagtail-factories/default.nix
@@ -0,0 +1,38 @@
+{ buildPythonPackage
+, callPackage
+, factory_boy
+, fetchFromGitHub
+, lib
+, wagtail
+}:
+
+buildPythonPackage rec {
+  pname = "wagtail-factories";
+  version = "4.0.0";
+
+  src = fetchFromGitHub {
+    repo = pname;
+    owner = "wagtail";
+    rev = version;
+    sha256 = "sha256-JmFWf+TODQNsSSxYD/JYVhWc82o6rJL13j5J23r8J9A=";
+  };
+
+  propagatedBuildInputs = [
+    factory_boy
+    wagtail
+  ];
+
+  # Tests require wagtail which in turn requires wagtail-factories
+  # Note that pythonImportsCheck is not used because it requires a Django app
+  doCheck = false;
+
+  passthru.tests.wagtail-factories = callPackage ./tests.nix { };
+
+  meta = with lib; {
+    description = "Factory boy classes for wagtail";
+    homepage = "https://github.com/wagtail/wagtail-factories";
+    changelog = "https://github.com/wagtail/wagtail-factories/blob/${version}/CHANGES";
+    license = licenses.mit;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/development/python-modules/wagtail-factories/tests.nix b/pkgs/development/python-modules/wagtail-factories/tests.nix
new file mode 100644
index 0000000000000..b340705f2e882
--- /dev/null
+++ b/pkgs/development/python-modules/wagtail-factories/tests.nix
@@ -0,0 +1,24 @@
+{ buildPythonPackage
+, django-pattern-library
+, pytest-django
+, pytestCheckHook
+, wagtail
+, wagtail-factories
+}:
+
+buildPythonPackage {
+  pname = "wagtail-factories-tests";
+  format = "other";
+  inherit (wagtail-factories) src version;
+
+  dontBuild = true;
+  dontInstall = true;
+
+  checkInputs = [
+    django-pattern-library
+    pytestCheckHook
+    pytest-django
+    wagtail
+    wagtail-factories
+  ];
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 1a5ef33e7abbc..35e98e6a906d7 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -12397,6 +12397,8 @@ self: super: with self; {
 
   wadllib = callPackage ../development/python-modules/wadllib { };
 
+  wagtail-factories = callPackage ../development/python-modules/wagtail-factories { };
+
   waitress = callPackage ../development/python-modules/waitress { };
 
   waitress-django = callPackage ../development/python-modules/waitress-django { };

From 5f25c053fabe0d60aba59f34984f97a8e21a3eae Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:37:15 +0100
Subject: [PATCH 8/9] python3Packages.wagtail-localize: init at 1.5

---
 .../wagtail-localize/default.nix              | 59 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 61 insertions(+)
 create mode 100644 pkgs/development/python-modules/wagtail-localize/default.nix

diff --git a/pkgs/development/python-modules/wagtail-localize/default.nix b/pkgs/development/python-modules/wagtail-localize/default.nix
new file mode 100644
index 0000000000000..bff5431e1832b
--- /dev/null
+++ b/pkgs/development/python-modules/wagtail-localize/default.nix
@@ -0,0 +1,59 @@
+{ buildPythonPackage
+, dj-database-url
+, django
+, django-rq
+, fetchFromGitHub
+, flit-core
+, freezegun
+, google-cloud-translate
+, lib
+, polib
+, python
+, typing-extensions
+, wagtail
+}:
+
+buildPythonPackage rec {
+  pname = "wagtail-localize";
+  version = "1.5";
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    repo = pname;
+    owner = "wagtail";
+    rev = "v${version}";
+    sha256 = "sha256-aNz4OoUUXWMCahMxuYBxvNWnw7Inxd5svBgwLgoirW8=";
+  };
+
+  propagatedBuildInputs = [
+    django
+    wagtail
+    polib
+    typing-extensions
+  ];
+
+  checkInputs = [
+    dj-database-url
+    django-rq
+    freezegun
+    google-cloud-translate
+  ];
+
+  nativeBuildInputs = [ flit-core ];
+
+  passthru.optional-dependencies = {
+    google = [ google-cloud-translate ];
+  };
+
+  checkPhase = ''
+    ${python.interpreter} testmanage.py test
+  '';
+
+  meta = with lib; {
+    description = "Translation plugin for Wagtail CMS";
+    homepage = "https://github.com/wagtail/wagtail-localize";
+    changelog = "https://github.com/wagtail/wagtail-localize/blob/v${version}/CHANGELOG.md";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 35e98e6a906d7..4e490d38c2a75 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -12399,6 +12399,8 @@ self: super: with self; {
 
   wagtail-factories = callPackage ../development/python-modules/wagtail-factories { };
 
+  wagtail-localize = callPackage ../development/python-modules/wagtail-localize { };
+
   waitress = callPackage ../development/python-modules/waitress { };
 
   waitress-django = callPackage ../development/python-modules/waitress-django { };

From b6629ca286230b808fdcf287109cf324e99ec7d6 Mon Sep 17 00:00:00 2001
From: Sylvain Fankhauser <sephi@fhtagn.top>
Date: Mon, 27 Feb 2023 10:41:09 +0100
Subject: [PATCH 9/9] python3Packages.wagtail: init at 4.2

---
 .../python-modules/wagtail/default.nix        | 66 +++++++++++++++++++
 .../python-modules/wagtail/tests.nix          | 42 ++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 3 files changed, 110 insertions(+)
 create mode 100644 pkgs/development/python-modules/wagtail/default.nix
 create mode 100644 pkgs/development/python-modules/wagtail/tests.nix

diff --git a/pkgs/development/python-modules/wagtail/default.nix b/pkgs/development/python-modules/wagtail/default.nix
new file mode 100644
index 0000000000000..5d14f80369e76
--- /dev/null
+++ b/pkgs/development/python-modules/wagtail/default.nix
@@ -0,0 +1,66 @@
+{ anyascii
+, beautifulsoup4
+, buildPythonPackage
+, callPackage
+, django
+, django-filter
+, django-modelcluster
+, django-taggit
+, django_treebeard
+, djangorestframework
+, draftjs-exporter
+, fetchPypi
+, html5lib
+, l18n
+, lib
+, openpyxl
+, permissionedforms
+, pillow
+, requests
+, telepath
+, willow
+}:
+
+buildPythonPackage rec {
+  pname = "wagtail";
+  version = "4.2";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-VUdVG2YHfH1Q3QGx8Gvg2DuJolxlq6REZmn8fG8xgxw=";
+  };
+
+  propagatedBuildInputs = [
+    django
+    django-modelcluster
+    django-taggit
+    django_treebeard
+    djangorestframework
+    django-filter
+    pillow
+    beautifulsoup4
+    html5lib
+    willow
+    requests
+    openpyxl
+    anyascii
+    draftjs-exporter
+    permissionedforms
+    telepath
+    l18n
+  ];
+
+  # Tests are in separate derivation because they require a package that depends
+  # on wagtail (wagtail-factories)
+  doCheck = false;
+
+  passthru.tests.wagtail = callPackage ./tests.nix {};
+
+  meta = with lib; {
+    description = "A Django content management system focused on flexibility and user experience";
+    homepage = "https://github.com/wagtail/wagtail";
+    changelog = "https://github.com/wagtail/wagtail/blob/v${version}/CHANGELOG.txt";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ sephi ];
+  };
+}
diff --git a/pkgs/development/python-modules/wagtail/tests.nix b/pkgs/development/python-modules/wagtail/tests.nix
new file mode 100644
index 0000000000000..23eb87c1b17c2
--- /dev/null
+++ b/pkgs/development/python-modules/wagtail/tests.nix
@@ -0,0 +1,42 @@
+{ azure-mgmt-cdn
+, azure-mgmt-frontdoor
+, boto3
+, buildPythonPackage
+, django-pattern-library
+, elasticsearch
+, freezegun
+, jinja2
+, python-dateutil
+, python
+, pytz
+, wagtail
+, wagtail-factories
+}:
+
+buildPythonPackage {
+  pname = "wagtail-tests";
+  inherit (wagtail) src version;
+  format = "other";
+
+  dontBuild = true;
+  dontInstall = true;
+
+  checkInputs = [
+    wagtail
+    wagtail-factories
+    jinja2
+    freezegun
+    elasticsearch
+    azure-mgmt-cdn
+    python-dateutil
+    pytz
+    boto3
+    django-pattern-library
+    azure-mgmt-frontdoor
+  ];
+
+  checkPhase = ''
+    export DJANGO_SETTINGS_MODULE=wagtail.test.settings
+    ${python.interpreter} -m django test
+  '';
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 4e490d38c2a75..19f07dd394a59 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -12397,6 +12397,8 @@ self: super: with self; {
 
   wadllib = callPackage ../development/python-modules/wadllib { };
 
+  wagtail = callPackage ../development/python-modules/wagtail { };
+
   wagtail-factories = callPackage ../development/python-modules/wagtail-factories { };
 
   wagtail-localize = callPackage ../development/python-modules/wagtail-localize { };