From 999d9b63cb16a82f854bcc846e6266a6853af4aa Mon Sep 17 00:00:00 2001
From: Tobias Pape <tobias@netshed.de>
Date: Thu, 30 Apr 2020 00:45:48 +0200
Subject: [PATCH] [unix] [config] missing m4 [ci skip]

---
 platforms/unix/config/acinclude.m4       |  1 +
 platforms/unix/config/ax_prepend_flag.m4 | 51 ++++++++++++++++++++++++
 2 files changed, 52 insertions(+)
 create mode 100644 platforms/unix/config/ax_prepend_flag.m4

diff --git a/platforms/unix/config/acinclude.m4 b/platforms/unix/config/acinclude.m4
index 6344077d15..ce85f75191 100644
--- a/platforms/unix/config/acinclude.m4
+++ b/platforms/unix/config/acinclude.m4
@@ -294,6 +294,7 @@ AC_DEFUN([AC_PLUGIN_CHECK_LIB],[
 dnl Recent Unix stuff
 m4_include([ax_require_defined.m4])
 m4_include([ax_append_flag.m4])
+m4_include([ax_prepend_flag.m4])
 m4_include([ax_have_epoll.m4])
 m4_include([ax_pthread.m4])
 m4_include([ax_compiler_vendor.m4])
diff --git a/platforms/unix/config/ax_prepend_flag.m4 b/platforms/unix/config/ax_prepend_flag.m4
new file mode 100644
index 0000000000..adac8c5acb
--- /dev/null
+++ b/platforms/unix/config/ax_prepend_flag.m4
@@ -0,0 +1,51 @@
+# ===========================================================================
+#     https://www.gnu.org/software/autoconf-archive/ax_prepend_flag.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_PREPEND_FLAG(FLAG, [FLAGS-VARIABLE])
+#
+# DESCRIPTION
+#
+#   FLAG is added to the front of the FLAGS-VARIABLE shell variable, with a
+#   space added in between.
+#
+#   If FLAGS-VARIABLE is not specified, the current language's flags (e.g.
+#   CFLAGS) is used.  FLAGS-VARIABLE is not changed if it already contains
+#   FLAG.  If FLAGS-VARIABLE is unset in the shell, it is set to exactly
+#   FLAG.
+#
+#   NOTE: Implementation based on AX_APPEND_FLAG.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
+#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
+#   Copyright (c) 2018 John Zaitseff <J.Zaitseff@zap.org.au>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved.  This file is offered as-is, without any
+#   warranty.
+
+#serial 2
+
+AC_DEFUN([AX_PREPEND_FLAG],
+[dnl
+AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_SET_IF
+AS_VAR_PUSHDEF([FLAGS], [m4_default($2,_AC_LANG_PREFIX[FLAGS])])
+AS_VAR_SET_IF(FLAGS,[
+  AS_CASE([" AS_VAR_GET(FLAGS) "],
+    [*" $1 "*], [AC_RUN_LOG([: FLAGS already contains $1])],
+    [
+     FLAGS="$1 $FLAGS"
+     AC_RUN_LOG([: FLAGS="$FLAGS"])
+    ])
+  ],
+  [
+  AS_VAR_SET(FLAGS,[$1])
+  AC_RUN_LOG([: FLAGS="$FLAGS"])
+  ])
+AS_VAR_POPDEF([FLAGS])dnl
+])dnl AX_PREPEND_FLAG